configure.ac

   1 ## Process this file with autoconf to produce configure.
   2 ## In general, the safest way to proceed is to run the following:
   3 ##    % aclocal -I . -I `pwd`/../autoconf && autoheader && autoconf && automake
   4
   5 # make sure we're interpreted by some minimal autoconf
   6 AC_PREREQ(2.57)
   7
   8 AC_INIT(glog, 0.3.2, opensource@google.com)
   9 # The argument here is just something that should be in the current directory
  10 # (for sanity checking)
  11 AC_CONFIG_SRCDIR(README)
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AM_INIT_AUTOMAKE
  14 AM_CONFIG_HEADER(src/config.h)
  15
  16 AC_LANG(C++)
  17
  18 # Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_CXX
  22 AM_CONDITIONAL(GCC, test "$GCC" = yes)   # let the Makefile know if we're gcc
  23
  24 AC_PROG_LIBTOOL
  25 AC_SUBST(LIBTOOL_DEPS)
  26
  27 # Check whether some low-level functions/files are available
  28 AC_HEADER_STDC
  29
  30 # These are tested for by AC_HEADER_STDC, but I check again to set the var
  31 AC_CHECK_HEADER(stdint.h, ac_cv_have_stdint_h=1, ac_cv_have_stdint_h=0)
  32 AC_CHECK_HEADER(sys/types.h, ac_cv_have_systypes_h=1, ac_cv_have_systypes_h=0)
  33 AC_CHECK_HEADER(inttypes.h, ac_cv_have_inttypes_h=1, ac_cv_have_inttypes_h=0)
  34 AC_CHECK_HEADERS(unistd.h, ac_cv_have_unistd_h=1, ac_cv_have_unistd_h=0)
  35 AC_CHECK_HEADERS(syscall.h)
  36 AC_CHECK_HEADERS(sys/syscall.h)
  37 # For backtrace with glibc.
  38 AC_CHECK_HEADERS(execinfo.h)
  39 # For backtrace with libunwind.
  40 AC_CHECK_HEADERS(libunwind.h, ac_cv_have_libunwind_h=1, ac_cv_have_libunwind_h=0)
  41 AC_CHECK_HEADERS(ucontext.h)
  42 AC_CHECK_HEADERS(sys/utsname.h)
  43 AC_CHECK_HEADERS(pwd.h)
  44 AC_CHECK_HEADERS(syslog.h)
  45 AC_CHECK_HEADERS(sys/time.h)
  46 AC_CHECK_HEADERS(glob.h)
  47 # For backtrace with gcc.
  48 AC_CHECK_HEADERS(unwind.h)
  49
  50 AC_CHECK_SIZEOF(void *)
  51
  52 # These are the types I need.  We look for them in either stdint.h,
  53 # sys/types.h, or inttypes.h, all of which are part of the default-includes.
  54 AC_CHECK_TYPE(uint16_t, ac_cv_have_uint16_t=1, ac_cv_have_uint16_t=0)
  55 AC_CHECK_TYPE(u_int16_t, ac_cv_have_u_int16_t=1, ac_cv_have_u_int16_t=0)
  56 AC_CHECK_TYPE(__uint16, ac_cv_have___uint16=1, ac_cv_have___uint16=0)
  57
  58 AC_CHECK_FUNC(sigaltstack,
  59               AC_DEFINE(HAVE_SIGALTSTACK, 1,
  60                         [Define if you have the `sigaltstack' function]))
  61 AC_CHECK_FUNC(dladdr,
  62               AC_DEFINE(HAVE_DLADDR, 1,
  63                         [Define if you have the `dladdr' function]))
  64 AC_CHECK_FUNC(fcntl,
  65               AC_DEFINE(HAVE_FCNTL, 1,
  66                         [Define if you have the `fcntl' function]))
  67
  68 AX_C___ATTRIBUTE__
  69 # We only care about these two attributes.
  70 if test x"$ac_cv___attribute__" = x"yes"; then
  71   ac_cv___attribute___noreturn="__attribute__ ((noreturn))"
  72   ac_cv___attribute___printf_4_5="__attribute__((__format__ (__printf__, 4, 5)))"
  73 else
  74   ac_cv___attribute___noreturn=
  75   ac_cv___attribute___printf_4_5=
  76 fi
  77
  78 AX_C___BUILTIN_EXPECT
  79 if test x"$ac_cv___builtin_expect" = x"yes"; then
  80   ac_cv_have___builtin_expect=1
  81 else
  82   ac_cv_have___builtin_expect=0
  83 fi
  84
  85 AX_C___SYNC_VAL_COMPARE_AND_SWAP
  86
  87 # On x86_64, instead of libunwind, we can choose to compile with frame-pointers
  88 # (This isn't needed on i386, where -fno-omit-frame-pointer is the default).
  89 AC_ARG_ENABLE(frame_pointers,
  90               AS_HELP_STRING([--enable-frame-pointers],
  91                              [On x86_64 systems, compile with -fno-omit-frame-pointer (see INSTALL)]),,
  92               enable_frame_pointers=no)
  93 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [return __x86_64__ == 1 ? 0 : 1])],
  94                   [is_x86_64=yes], [is_x86_64=no])
  95 AM_CONDITIONAL(ENABLE_FRAME_POINTERS, test "$enable_frame_pointers" = yes)
  96 AM_CONDITIONAL(X86_64, test "$is_x86_64" = yes)
  97
  98 AC_ARG_ENABLE(rtti,
  99               AS_HELP_STRING([--disable-rtti],
 100                              [Disable RTTI in glog]))
 101 AM_CONDITIONAL(DISABLE_RTTI, test x"$enable_rtti" = x"no")
 102 if test x"$enable_rtti" = x"no"; then
 103   AC_DEFINE(DISABLE_RTTI, 1, [define if glog doesn't use RTTI])
 104 fi
 105
 106 # Some of the code in this directory depends on pthreads
 107 ACX_PTHREAD
 108 if test x"$acx_pthread_ok" = x"yes"; then
 109   # To make libglog depend on libpthread on Linux, we need to add
 110   # -lpthread in addition to -pthread.
 111   AC_CHECK_LIB(pthread, pthread_self)
 112 fi
 113
 114 # Check if there is google-gflags library installed.
 115 SAVE_CFLAGS="$CFLAGS"
 116 SAVE_LIBS="$LIBS"
 117 AC_ARG_WITH(gflags, AS_HELP_STRING[--with-gflags=GFLAGS_DIR],
 118   GFLAGS_CFLAGS="-I${with_gflags}/include"
 119   GFLAGS_LIBS="-L${with_gflags}/lib -lgflags"
 120   CFLAGS="$CFLAGS $GFLAGS_CFLAGS"
 121   LIBS="$LIBS $GFLAGS_LIBS"
 122 )
 123 AC_CHECK_LIB(gflags, main, ac_cv_have_libgflags=1, ac_cv_have_libgflags=0)
 124 if test x"$ac_cv_have_libgflags" = x"1"; then
 125   AC_DEFINE(HAVE_LIB_GFLAGS, 1, [define if you have google gflags library])
 126   if test x"$GFLAGS_LIBS" = x""; then
 127     GFLAGS_LIBS="-lgflags"
 128   fi
 129 else
 130   GFLAGS_CFLAGS=
 131   GFLAGS_LIBS=
 132 fi
 133 CFLAGS="$SAVE_CFLAGS"
 134 LIBS="$SAVE_LIBS"
 135
 136 # TODO(hamaji): Use official m4 macros provided by testing libraries
 137 #               once the m4 macro of Google Mocking becomes ready.
 138 # Check if there is Google Test library installed.
 139 AC_CHECK_PROG(GTEST_CONFIG, gtest-config, "yes")
 140 if test x"$GTEST_CONFIG" = "xyes"; then
 141   GTEST_CFLAGS=`gtest-config --cppflags --cxxflags`
 142   GTEST_LIBS=`gtest-config --ldflags --libs`
 143   AC_DEFINE(HAVE_LIB_GTEST, 1, [define if you have google gtest library])
 144
 145   # Check if there is Google Mocking library installed.
 146   AC_CHECK_PROG(GMOCK_CONFIG, gmock-config, "yes")
 147   if test x"$GMOCK_CONFIG" = "xyes"; then
 148     GMOCK_CFLAGS=`gmock-config --cppflags --cxxflags`
 149     GMOCK_LIBS=`gmock-config --ldflags --libs`
 150     AC_DEFINE(HAVE_LIB_GMOCK, 1, [define if you have google gmock library])
 151   else
 152     # We don't run test cases which use Google Mocking framework.
 153     GMOCK_CFLAGS=
 154     GMOCK_LIBS=
 155   fi
 156 else
 157   # We'll use src/googletest.h for our unittests.
 158   GTEST_CFLAGS=
 159   GTEST_LIBS=
 160 fi
 161 AM_CONDITIONAL(HAVE_GMOCK, test x"$GMOCK_CONFIG" = "xyes")
 162
 163 # We want to link in libunwind if it exists
 164 UNWIND_LIBS=
 165 # Unfortunately, we need to check the header file in addition to the
 166 # lib file to check if libunwind is available since libunwind-0.98
 167 # doesn't install all necessary header files.
 168 if test x"$ac_cv_have_libunwind_h" = x"1"; then
 169  AC_CHECK_LIB(unwind, backtrace, UNWIND_LIBS=-lunwind)
 170 fi
 171 AC_SUBST(UNWIND_LIBS)
 172 if test x"$UNWIND_LIBS" != x""; then
 173   AC_DEFINE(HAVE_LIB_UNWIND, 1, [define if you have libunwind])
 174 fi
 175
 176 # We'd like to use read/write locks in several places in the code.
 177 # See if our pthreads support extends to that.  Note: for linux, it
 178 # does as long as you define _XOPEN_SOURCE appropriately.
 179 AC_RWLOCK
 180
 181 # Find out what namespace 'normal' STL code lives in, and also what namespace
 182 # the user wants our classes to be defined in
 183 AC_CXX_STL_NAMESPACE
 184 AC_DEFINE_GOOGLE_NAMESPACE(google)
 185
 186 AC_CXX_USING_OPERATOR
 187
 188 AC_PC_FROM_UCONTEXT(AC_MSG_WARN(Could not find the PC.  Will not output failed addresses...))
 189
 190 AC_DEFINE_UNQUOTED(TEST_SRC_DIR, "$srcdir", [location of source code])
 191
 192 # These are what's needed by logging.h.in and raw_logging.h.in
 193 AC_SUBST(ac_google_start_namespace)
 194 AC_SUBST(ac_google_end_namespace)
 195 AC_SUBST(ac_google_namespace)
 196 AC_SUBST(ac_cv_cxx_using_operator)
 197 AC_SUBST(ac_cv___attribute___noreturn)
 198 AC_SUBST(ac_cv___attribute___printf_4_5)
 199 AC_SUBST(ac_cv_have___builtin_expect)
 200 AC_SUBST(ac_cv_have_stdint_h)
 201 AC_SUBST(ac_cv_have_systypes_h)
 202 AC_SUBST(ac_cv_have_inttypes_h)
 203 AC_SUBST(ac_cv_have_unistd_h)
 204 AC_SUBST(ac_cv_have_uint16_t)
 205 AC_SUBST(ac_cv_have_u_int16_t)
 206 AC_SUBST(ac_cv_have___uint16)
 207 AC_SUBST(ac_cv_have_libgflags)
 208 AC_SUBST(GFLAGS_CFLAGS)
 209 AC_SUBST(GTEST_CFLAGS)
 210 AC_SUBST(GMOCK_CFLAGS)
 211 AC_SUBST(GFLAGS_LIBS)
 212 AC_SUBST(GTEST_LIBS)
 213 AC_SUBST(GMOCK_LIBS)
 214
 215 # Write generated configuration file
 216 AC_CONFIG_FILES([Makefile src/glog/logging.h src/glog/raw_logging.h src/glog/vlog_is_on.h src/glog/stl_logging.h])
 217 AC_OUTPUT(libglog.pc)