configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 dnl Not all of these are actually used, depending on the configure options.
  32 GLIB_REQUIRED=2.31.13
  33 LIBXML_REQUIRED=2.7
  34 VALA_REQUIRED=0.22.0
  35 VALADOC_REQUIRED=0.2
  36 GSSDP_REQUIRED=0.13.0
  37 GUPNP_REQUIRED=0.19.0
  38 GUPNP_AV_REQUIRED=0.11.4
  39 GUPNP_DLNA_REQUIRED=0.9.4
  40 GSTREAMER_REQUIRED=1.0
  41 GSTPBU_REQUIRED=1.0
  42 GIO_REQUIRED=2.26
  43 GEE_REQUIRED=0.8.0
  44 UUID_REQUIRED=1.41.3
  45 LIBSOUP_REQUIRED=2.34.0
  46 GTK_REQUIRED=3.0
  47
  48 dnl Additional requirements for media-export plugin
  49 GSTREAMER_TAG_REQUIRED=1.0
  50 GSTREAMER_APP_REQUIRED=1.0
  51 LIBSQLITE3_REQUIRED=3.5
  52
  53 dnl Additional requirements for tracker plugin
  54 TRACKER_SPARQL_REQUIRED_MIN=0.14.0
  55
  56 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  57
  58 RYGEL_BASE_MODULES="gupnp-1.0 >= $GUPNP_REQUIRED gee-0.8 >= $GEE_REQUIRED"
  59 PKG_CHECK_MODULES([LIBRYGEL_CORE_DEPS], [$RYGEL_BASE_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED gmodule-2.0 libxml-2.0 >= $LIBXML_REQUIRED])
  60 RYGEL_BASE_MODULES_VALAFLAGS='--pkg gupnp-1.0 --pkg gee-0.8'
  61 LIBRYGEL_CORE_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg gmodule-2.0"
  62 AC_SUBST([LIBRYGEL_CORE_DEPS_VALAFLAGS])
  63
  64 RYGEL_COMMON_MODULES="$RYGEL_BASE_MODULES gupnp-av-1.0 >= $GUPNP_AV_REQUIRED"
  65 PKG_CHECK_MODULES([LIBRYGEL_SERVER_DEPS], [$RYGEL_COMMON_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED gmodule-2.0 libxml-2.0 >= $LIBXML_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  66 RYGEL_COMMON_MODULES_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gupnp-av-1.0"
  67 LIBRYGEL_SERVER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg libsoup-2.4 --pkg gmodule-2.0"
  68 AC_SUBST([LIBRYGEL_SERVER_DEPS_VALAFLAGS])
  69
  70 PKG_CHECK_MODULES([LIBRYGEL_RENDERER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  71 LIBRYGEL_RENDERER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg libsoup-2.4"
  72 AC_SUBST([LIBRYGEL_RENDERER_DEPS_VALAFLAGS])
  73
  74 PKG_CHECK_MODULES([RYGEL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  75
  76 # Not all tests use all of these dependencies,
  77 # but having one set of dependencies keeps things simple.
  78 PKG_CHECK_MODULES([TEST_DEPS], [$RYGEL_COMMON_MODULES uuid >= $UUID_REQUIRED gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED])
  79 TEST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg gssdp-1.0 --pkg libsoup-2.4 --pkg libxml-2.0 --pkg gmodule-2.0"
  80 AC_SUBST([TEST_DEPS_VALAFLAGS])
  81
  82 PKG_CHECK_MODULES([EXAMPLE_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  83
  84
  85
  86 dnl Media engine to use
  87 BUILT_ENGINES="librygel-media-engine-simple"
  88
  89 dnl Disabling the gstreamer media_engine also disables
  90 dnl anything else that uses gstreamer.
  91 AC_ARG_WITH([media_engine],
  92             AS_HELP_STRING(
  93                 [--with-media-engine=@<:@gstreamer|simple@:>@],
  94                 [Media Engine to use]),
  95             [with_media_engine="$withval"],
  96             [with_media_engine="gstreamer"])
  97
  98 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  99       [
 100         enable_gstreamer="yes"
 101         BUILT_ENGINES="$BUILT_ENGINES;librygel-media-engine-gst"
 102
 103         PKG_CHECK_MODULES([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS],
 104                           [$RYGEL_COMMON_MODULES
 105                            gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED
 106                            gstreamer-app-1.0 >= $GSTREAMER_APP_REQUIRED
 107                            gupnp-dlna-2.0 >= $GUPNP_DLNA_REQUIRED
 108                            gio-2.0 >= $GIO_REQUIRED])
 109         RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-base-1.0 --pkg gstreamer-pbutils-1.0 --pkg gupnp-dlna-2.0"
 110         AC_SUBST([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS])
 111
 112         PKG_CHECK_MODULES([LIBRYGEL_RENDERER_GST_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_REQUIRED gio-2.0 >= $GIO_REQUIRED])
 113         LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-1.0"
 114         AC_SUBST([LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS])
 115       ],
 116       [enable_gstreamer="no"])
 117 AM_CONDITIONAL([HAVE_GSTREAMER],[test "x$enable_gstreamer" = "xyes"])
 118 AC_SUBST([BUILT_ENGINES])
 119
 120 dnl Add plugins
 121 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
 122 AS_IF([test "x$enable_external_plugin" = "xyes"],
 123   [
 124     PKG_CHECK_MODULES([RYGEL_PLUGIN_EXTERNAL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 125   ])
 126
 127 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
 128 AS_IF([test "x$enable_mpris_plugin" = "xyes"],
 129   [
 130     PKG_CHECK_MODULES([RYGEL_PLUGIN_MPRIS_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 131   ])
 132
 133 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
 134 AS_IF([test "x$enable_mediathek_plugin" = "xyes"],
 135   [
 136     PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIATHEK_DEPS],
 137                       [$RYGEL_COMMON_MODULES
 138                        gio-2.0 >= $GIO_REQUIRED
 139                        libsoup-2.4 >= $LIBSOUP_REQUIRED
 140                        libxml-2.0 >= $LIBXML_REQUIRED])
 141   ])
 142
 143 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 144       [
 145         RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
 146         AS_IF([test "x$enable_playbin_plugin" = "xyes"],
 147           [
 148             PKG_CHECK_MODULES([RYGEL_PLUGIN_PLAYBIN_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_TAG_REQUIRED])
 149           ])
 150
 151         RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
 152         AS_IF([test "x$enable_media_export_plugin" = "xyes"],
 153           [
 154             PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS],
 155                               [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED
 156                                gupnp-dlna-2.0 >= $GUPNP_DLNA_REQUIRED
 157                                gupnp-dlna-gst-2.0 >= $GUPNP_DLNA_REQUIRED
 158                                gstreamer-app-1.0 >= $GSTREAMER_APP_REQUIRED
 159                                gstreamer-tag-1.0 >= $GSTREAMER_TAG_REQUIRED
 160                                gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED
 161                                libsoup-2.4 >= $LIBSOUP_REQUIRED
 162                                sqlite3 >= $LIBSQLITE3_REQUIRED
 163                                uuid])
 164             RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gupnp-dlna-2.0 --pkg gupnp-dlna-gst-2.0 --pkg gstreamer-tag-1.0 --pkg gstreamer-app-1.0 --pkg gstreamer-pbutils-1.0 --pkg sqlite3"
 165             AC_SUBST([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS])
 166           ])
 167
 168         RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
 169         AS_IF([test "x$enable_gst_launch_plugin" = "xyes"],
 170           [
 171             PKG_CHECK_MODULES([RYGEL_PLUGIN_GST_LAUNCH_DEPS], [$RYGEL_COMMON_MODULES])
 172             RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS"
 173             AC_SUBST([RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS])
 174           ])
 175
 176         RYGEL_ADD_STAMP([src/media-engines/gstreamer/librygel_media_engine_gst_la_vala.stamp])
 177         RYGEL_ADD_STAMP([src/librygel-renderer-gst/librygel_renderer_gst_2_0_la_vala.stamp])
 178       ],
 179       [
 180         RYGEL_DISABLE_PLUGIN([playbin])
 181         RYGEL_DISABLE_PLUGIN([media-export])
 182         RYGEL_DISABLE_PLUGIN([gst-launch])
 183       ])
 184
 185 dnl Example plugins:
 186 AC_ARG_ENABLE([example-plugins],
 187               AS_HELP_STRING([--enable-example-plugins],[enable example plugins]),,
 188               enable_example_plugins=no)
 189 AM_CONDITIONAL([BUILD_EXAMPLE_PLUGINS], [test "x$[]enable_example_plugins" = "xyes"])
 190
 191 dnl Explicitly add stamp files for targets that are not plugins
 192 RYGEL_ADD_STAMP([src/librygel-core/librygel_core_2_0_la_vala.stamp])
 193 RYGEL_ADD_STAMP([src/librygel-server/librygel_server_2_0_la_vala.stamp])
 194 RYGEL_ADD_STAMP([src/librygel-renderer/librygel_renderer_2_0_la_vala.stamp])
 195 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
 196 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
 197 RYGEL_ADD_STAMP([src/media-engines/simple/librygel_media_engine_simple_la_vala.stamp])
 198
 199 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 200       [
 201         RYGEL_CHECK_PACKAGES([gupnp-dlna-2.0 gstreamer-1.0
 202                               gstreamer-pbutils-1.0])
 203       ])
 204
 205 dnl Debugging
 206 AC_ARG_ENABLE(debug,
 207         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 208         enable_debug=no)
 209 if test "x$enable_debug" = "xyes"; then
 210         CFLAGS="$CFLAGS -O0 -g"
 211         RYGEL_DEBUG_VALAFLAGS="-g"
 212 fi
 213
 214 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 215
 216 dnl Strict compiler
 217 AC_ARG_ENABLE(strict-cc,
 218         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 219         enable_strict_cc=no)
 220 if test "x$enable_strict_cc" = "xyes"; then
 221         CFLAGS="$CFLAGS -Wall -Werror"
 222 else
 223         CFLAGS="$CFLAGS -w"
 224 fi
 225
 226 dnl Run uninstalled
 227 AC_ARG_ENABLE(uninstalled,
 228     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 229         enable_uninstalled=no)
 230 if test "x$enable_uninstalled" = "xyes"; then
 231         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 232 fi
 233 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 234
 235 dnl Check wether user wants to build UIs
 236 AC_ARG_WITH( ui,
 237   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 238   try_ui=$withval, try_ui=yes )
 239
 240 HAVE_GTK=no
 241 if test x$try_ui = xyes ; then
 242     dnl check for gtk
 243     PKG_CHECK_MODULES([RYGEL_UI_DEPS], [$RYGEL_BASE_MODULES gtk+-3.0 >= $GTK_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gee-0.8 >= $GEE_REQUIRED],
 244       [
 245         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 246         RYGEL_UI_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gtk+-3.0 --pkg gssdp-1.0 --pkg gee-0.8"
 247         AC_SUBST([RYGEL_UI_DEPS_VALAFLAGS])
 248
 249         PKG_CHECK_MODULES([EXAMPLE_UI_DEPS],
 250                           [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED
 251                            gssdp-1.0 >= $GSSDP_REQUIRED
 252                            gstreamer-video-1.0 >= $GSTREAMER_REQUIRED
 253                            gtk+-3.0 >= $GTK_REQUIRED])
 254       ],
 255       [
 256         AC_MSG_WARN([UI dependencies not found.])
 257         AC_MSG_WARN([UI applications will not be built.])
 258       ])
 259
 260 else
 261     AC_MSG_NOTICE([UI applications disabled.])
 262 fi
 263
 264 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 265
 266 dnl Tests
 267 AC_ARG_ENABLE([tests],
 268               AS_HELP_STRING([--enable-tests],[always build tests]),,
 269               enable_tests=no)
 270 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 271
 272 dnl Generate coverage data
 273 AC_ARG_ENABLE([coverage],
 274   AS_HELP_STRING([--enable-coverage],
 275                  [Generate converage reports for unit tests]),
 276   [],
 277   [enable_coverage=no])
 278 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 279 AS_IF([test "x$enable_coverage" != "xno"],
 280   [
 281     AC_PATH_PROG([LCOV], [lcov])
 282     AC_PATH_PROG([GENHTML], [genhtml])
 283     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 284     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 285     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 286   ]
 287 )
 288
 289 dnl Check additional requirements for MediaExport plugins
 290 if test "x$enable_media_export_plugin" = "xyes";
 291 then
 292     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-1.0 gstreamer-app-1.0])
 293     AC_CHECK_HEADER([unistr.h],
 294                     AC_CHECK_LIB([unistring],
 295                                  [u8_strcoll],
 296                                  [have_unistring=yes],[have_unistring=no]))
 297     if test "x$have_unistring" = "xyes"; then
 298         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 299         RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_LIBS="$RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_LIBS -lunistring"
 300     fi
 301 fi
 302
 303
 304 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
 305 AS_IF([test "x$enable_tracker_plugin" = "xyes"],
 306   [
 307     PKG_CHECK_MODULES([RYGEL_PLUGIN_TRACKER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 308
 309     tracker_api_version="0.14"
 310     PKG_CHECK_MODULES(TRACKER_SPARQL,
 311                       tracker-sparql-0.14 >= $TRACKER_SPARQL_REQUIRED_MIN,
 312                       [tracker_api_version="0.14"],
 313                       [tracker_api_version=""])
 314     AS_IF([test "x$[]tracker_api_version" = "x"],
 315           [
 316             PKG_CHECK_MODULES(TRACKER_SPARQL,
 317                               tracker-sparql-0.15 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 318                               [tracker_api_version="0.15"],
 319                               [tracker_api_version=""])
 320           ])
 321     AS_IF([test "x$[]tracker_api_version" = "x"],
 322           [
 323             PKG_CHECK_MODULES(TRACKER_SPARQL,
 324                               tracker-sparql-0.16 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 325                               [tracker_api_version="0.16"],
 326                               [])
 327           ])
 328     AS_IF([test "x$enable_vala" = "xyes"],
 329           [VALA_CHECK_PACKAGES([tracker-sparql-$tracker_api_version])])
 330
 331     RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS="--pkg tracker-sparql-$tracker_api_version"
 332     AC_SUBST([RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS])
 333   ])
 334
 335 # This should be called only after all RYGEL_CHECK_VALA() and RYGEL_ADD_PLUGIN() calls:
 336 RYGEL_CHECK_VALA([$VALA_REQUIRED],
 337                  [gupnp-1.0
 338                   gupnp-av-1.0
 339                   gio-2.0
 340                   gee-0.8
 341                   posix])
 342
 343 dnl Gettext
 344 GETTEXT_PACKAGE=rygel
 345 AC_SUBST(GETTEXT_PACKAGE)
 346 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 347   [Define the gettext package to be used])
 348
 349 AM_GLIB_GNU_GETTEXT
 350 IT_PROG_INTLTOOL([0.40.0])
 351
 352 dnl Shave the output
 353 AM_SILENT_RULES([yes])
 354
 355 dnl documenation
 356 AC_PATH_PROG([XSLTPROC], [xsltproc])
 357 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 358
 359 dnl Use valadoc for API documentation:
 360 dnl This is on by default when using autogen.sh
 361 dnl (so it is not on by default when building from a tarball with configure.)
 362 AC_ARG_ENABLE(valadoc,
 363   AS_HELP_STRING([--enable-valadoc[=@<:@no/auto/yes@:>@]], [Enable valadoc support]),,
 364     [enable_valadoc=auto])
 365
 366 found_valadoc=no
 367 AS_IF([test "x$enable_valadoc" != "xno"], [
 368     AC_PATH_PROG(VALADOC, valadoc, :)
 369     AS_IF([test -x "$VALADOC"], [
 370       found_valadoc=yes
 371       AC_SUBST(VALADOC)
 372       PKG_CHECK_MODULES([GTKDOC],[gtk-doc >= 1.0],,
 373                         AS_IF([test "x$enable_valadoc" == "xyes"],
 374                               [AC_MSG_ERROR([Unable to find gtk-doc])],
 375                               [found_valadoc=no])
 376                         )
 377     ], [
 378       AS_IF([test "x$enable_valadoc" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 379     ])
 380   ])
 381
 382 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 383
 384 AC_SUBST([RYGEL_PLUGIN_LINKER_FLAGS],
 385          ["-module -avoid-version -Wl,-z,defs"])
 386 AC_SUBST([RYGEL_PLUGIN_DIR],
 387          [${libdir}/rygel-2.0/plugins])
 388 AC_SUBST([RYGEL_MEDIA_ENGINE_DIR],
 389          [${libdir}/rygel-2.0/engines])
 390
 391 AC_CONFIG_FILES([
 392 Makefile
 393 src/Makefile
 394 src/librygel-core/Makefile
 395 src/librygel-renderer/Makefile
 396 src/librygel-renderer-gst/Makefile
 397 src/librygel-server/Makefile
 398 src/rygel/Makefile
 399 src/ui/Makefile
 400 src/media-engines/Makefile
 401 src/media-engines/gstreamer/Makefile
 402 src/media-engines/gstreamer/media-engine-gst.plugin
 403 src/media-engines/simple/Makefile
 404 src/media-engines/simple/media-engine-simple.plugin
 405 src/plugins/Makefile
 406 data/Makefile
 407 data/xml/Makefile
 408 data/xml/MediaServer3.xml.in
 409 data/xml/MediaRenderer2.xml.in
 410 data/icons/Makefile
 411 data/icons/32x32/Makefile
 412 data/icons/48x48/Makefile
 413 data/icons/120x120/Makefile
 414 data/icons/128x128/Makefile
 415 data/icons/scalable/Makefile
 416 data/rygel.desktop.in
 417 data/rygel-preferences.desktop.in
 418 doc/Makefile
 419 doc/reference/Makefile
 420 doc/reference/librygel-core/Makefile
 421 doc/reference/librygel-renderer/Makefile
 422 doc/reference/librygel-server/Makefile
 423 doc/reference/librygel-renderer-gst/Makefile
 424 po/Makefile.in
 425 rygel-core-2.0.pc
 426 rygel-renderer-2.0.pc
 427 rygel-server-2.0.pc
 428 rygel-renderer-gst-2.0.pc
 429 tests/Makefile
 430 examples/Makefile
 431 examples/renderer-plugins/Makefile
 432 examples/renderer-plugins/vala/Makefile
 433 examples/renderer-plugins/vala/example-renderer-vala.plugin
 434 examples/renderer-plugins/C/Makefile
 435 examples/renderer-plugins/C/example-renderer-c.plugin
 436 examples/server-plugins/Makefile
 437 examples/server-plugins/vala/Makefile
 438 examples/server-plugins/vala/example-server-vala.plugin
 439 examples/server-plugins/C/Makefile
 440 examples/server-plugins/C/example-server-c.plugin
 441 ])
 442 AC_OUTPUT
 443
 444 echo "
 445
 446                     ${PACKAGE} ${VERSION}
 447                     ============
 448
 449
 450         Prefix:                 ${prefix}
 451         Source code location:   ${srcdir}
 452         Compiler:               ${CC}
 453         CFLAGS:                 ${CFLAGS}
 454         VALAFLAGS:              ${VALAFLAGS}
 455         uninstalled:            ${enable_uninstalled}
 456         preferences ui:         ${HAVE_GTK}
 457         Media Engine:           ${with_media_engine}
 458     Plugins:
 459         examples:               ${enable_example_plugins}
 460         tracker:                ${enable_tracker_plugin}
 461             version:            ${tracker_api_version}
 462         mediathek:              ${enable_mediathek_plugin}
 463         media-export            ${enable_media_export_plugin}
 464         external:               ${enable_external_plugin}
 465         MPRIS2:                 ${enable_mpris_plugin}
 466         gst-launch:             ${enable_gst_launch_plugin}
 467         playbin:                ${enable_playbin_plugin}
 468 "