configure.ac

   1 m4_define([weston_major_version], [1])
   2 m4_define([weston_minor_version], [4])
   3 m4_define([weston_micro_version], [0])
   4 m4_define([weston_version],
   5           [weston_major_version.weston_minor_version.weston_micro_version])
   6
   7 AC_PREREQ([2.64])
   8 AC_INIT([weston],
   9         [weston_version],
  10         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=weston&version=weston_version],
  11         [weston],
  12         [http://wayland.freedesktop.org/])
  13
  14 AC_SUBST([WESTON_VERSION_MAJOR], [weston_major_version])
  15 AC_SUBST([WESTON_VERSION_MINOR], [weston_minor_version])
  16 AC_SUBST([WESTON_VERSION_MICRO], [weston_micro_version])
  17 AC_SUBST([WESTON_VERSION], [weston_version])
  18
  19 AC_CONFIG_AUX_DIR([build-aux])
  20 AC_CONFIG_HEADERS([config.h])
  21
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24
  25 AM_INIT_AUTOMAKE([1.11 parallel-tests foreign no-dist-gzip dist-xz color-tests subdir-objects])
  26
  27 AM_SILENT_RULES([yes])
  28
  29 # Check for programs
  30 AC_PROG_CC
  31 AC_PROG_SED
  32
  33 # Initialize libtool
  34 LT_PREREQ([2.2])
  35 LT_INIT([disable-static])
  36
  37 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  38            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  39 AC_ARG_VAR([WESTON_SHELL_CLIENT],
  40            [Set the default desktop shell client to load if none is specified in weston.ini. @<:@default=weston-desktop-shell@:>@])
  41
  42 PKG_PROG_PKG_CONFIG()
  43
  44 AC_CHECK_FUNC([dlopen], [],
  45               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  46 AC_SUBST(DLOPEN_LIBS)
  47
  48 AC_CHECK_DECL(SFD_CLOEXEC,[],
  49               [AC_MSG_ERROR("SFD_CLOEXEC is needed to compile weston")],
  50               [[#include <sys/signalfd.h>]])
  51 AC_CHECK_DECL(TFD_CLOEXEC,[],
  52               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile weston")],
  53               [[#include <sys/timerfd.h>]])
  54 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
  55               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile weston")],
  56               [[#include <time.h>]])
  57 AC_CHECK_HEADERS([execinfo.h])
  58
  59 AC_CHECK_FUNCS([mkostemp strchrnul initgroups posix_fallocate])
  60
  61 COMPOSITOR_MODULES="wayland-server >= 1.3.90 pixman-1"
  62
  63 AC_ARG_ENABLE(egl, [  --disable-egl],,
  64               enable_egl=yes)
  65 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
  66 if test x$enable_egl = xyes; then
  67         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
  68         PKG_CHECK_MODULES(EGL, [egl >= 7.10 glesv2])
  69         PKG_CHECK_MODULES([EGL_TESTS], [egl >= 7.10 glesv2 wayland-client wayland-egl])
  70 fi
  71
  72 AC_ARG_ENABLE(xkbcommon,
  73               AS_HELP_STRING([--disable-xkbcommon], [Disable libxkbcommon
  74                               support: This is only useful in environments
  75                               where you do not have a hardware keyboard. If
  76                               libxkbcommon support is disabled clients will not
  77                               be sent a keymap and and must know how to
  78                               interpret the keycode sent for any key event.]),,
  79               enable_xkbcommon=yes)
  80 if test x$enable_xkbcommon = xyes; then
  81         AC_DEFINE(ENABLE_XKBCOMMON, [1], [Build Weston with libxkbcommon support])
  82         COMPOSITOR_MODULES="$COMPOSITOR_MODULES xkbcommon >= 0.3.0"
  83 fi
  84
  85 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
  86               enable_setuid_install=yes)
  87 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
  88
  89
  90 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
  91               enable_xwayland=yes)
  92 AC_ARG_ENABLE(xwayland-test, [  --enable-xwayland-test],,
  93               enable_xwayland_test=yes)
  94 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
  95 AM_CONDITIONAL(ENABLE_XWAYLAND_TEST, test x$enable_xwayland = xyes -a x$enable_xwayland_test = xyes)
  96 if test x$enable_xwayland = xyes; then
  97   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcb-composite xcursor cairo-xcb)
  98   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
  99
 100   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
 101               [Path to X server]), [XSERVER_PATH="$withval"],
 102               [XSERVER_PATH="$bindir/Xorg"])
 103   AC_SUBST([XSERVER_PATH])
 104   if test x$enable_xwayland_test = xyes; then
 105     PKG_CHECK_MODULES([XWAYLAND_TEST], xcb xcb-dri2 libdrm)
 106   fi
 107 fi
 108
 109 PKG_CHECK_MODULES(LIBDRM, [libdrm],
 110                   [AC_DEFINE(HAVE_LIBDRM, 1, [Define if libdrm is available]) have_libdrm=yes], have_libdrm=no)
 111
 112 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
 113               enable_x11_compositor=yes)
 114 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
 115 if test x$enable_x11_compositor = xyes; then
 116   PKG_CHECK_MODULES([XCB], xcb)
 117   xcb_save_LIBS=$LIBS
 118   xcb_save_CFLAGS=$CFLAGS
 119   CFLAGS=$XCB_CFLAGS
 120   LIBS=$XCB_LIBS
 121   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
 122   LIBS=$xcb_save_LIBS
 123   CFLAGS=$xcb_save_CFLAGS
 124
 125   X11_COMPOSITOR_MODULES="x11 x11-xcb xcb-shm"
 126
 127   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb],
 128                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
 129   if test "x$have_xcb_xkb" = xyes; then
 130         # Most versions of XCB have totally broken XKB bindings, where the
 131         # events don't work.  Make sure we can actually use them.
 132         xcb_xkb_save_CFLAGS=$CFLAGS
 133         CFLAGS=$X11_COMPOSITOR_XKB_CFLAGS
 134         AC_CHECK_MEMBER([struct xcb_xkb_state_notify_event_t.xkbType],
 135                         [], [have_xcb_xkb=no], [[#include <xcb/xkb.h>]])
 136         CFLAGS=$xcb_xkb_save_CFLAGS
 137   fi
 138   if test "x$have_xcb_xkb" = xyes; then
 139         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
 140         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
 141   fi
 142
 143   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
 144   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
 145 fi
 146
 147
 148 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 149               enable_drm_compositor=yes)
 150 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes)
 151 if test x$enable_drm_compositor = xyes; then
 152   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 153   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm mtdev >= 1.1.0])
 154 fi
 155
 156
 157 AC_ARG_ENABLE(libinput-backend, [  --enable-libinput-backend],,
 158               enable_libinput_backend=no)
 159 AM_CONDITIONAL([ENABLE_LIBINPUT_BACKEND], [test x$enable_libinput_backend = xyes])
 160 if test x$enable_libinput_backend = xyes; then
 161   AC_DEFINE([BUILD_LIBINPUT_BACKEND], [1], [Build the libinput input device backend])
 162   PKG_CHECK_MODULES(LIBINPUT_BACKEND, [libinput >= 0.1.0])
 163 fi
 164
 165
 166 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
 167
 168 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 169               enable_wayland_compositor=yes)
 170 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 171                test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes)
 172 if test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes; then
 173   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 174             [Build the Wayland (nested) compositor])
 175   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl wayland-cursor])
 176 fi
 177
 178
 179 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 180               enable_headless_compositor=yes)
 181 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 182                test x$enable_headless_compositor = xyes)
 183
 184
 185 AC_ARG_ENABLE(rpi-compositor,
 186               AS_HELP_STRING([--disable-rpi-compositor],
 187                              [do not build the Raspberry Pi backend]),,
 188               enable_rpi_compositor=yes)
 189 AM_CONDITIONAL(ENABLE_RPI_COMPOSITOR, test "x$enable_rpi_compositor" = "xyes")
 190 have_bcm_host="no"
 191 if test "x$enable_rpi_compositor" = "xyes"; then
 192   AC_DEFINE([BUILD_RPI_COMPOSITOR], [1], [Build the compositor for Raspberry Pi])
 193   PKG_CHECK_MODULES(RPI_COMPOSITOR, [libudev >= 136 mtdev >= 1.1.0])
 194   PKG_CHECK_MODULES(RPI_BCM_HOST, [bcm_host],
 195                     [have_bcm_host="yes"
 196                      AC_DEFINE([HAVE_BCM_HOST], [1], [have Raspberry Pi BCM headers])],
 197                     [AC_MSG_WARN([Raspberry Pi BCM host libraries not found, will use stubs instead.])])
 198 fi
 199 AM_CONDITIONAL(INSTALL_RPI_COMPOSITOR, test "x$have_bcm_host" = "xyes")
 200
 201
 202 AC_ARG_ENABLE([fbdev-compositor], [  --enable-fbdev-compositor],,
 203               enable_fbdev_compositor=yes)
 204 AM_CONDITIONAL([ENABLE_FBDEV_COMPOSITOR],
 205                [test x$enable_fbdev_compositor = xyes])
 206 AS_IF([test x$enable_fbdev_compositor = xyes], [
 207   AC_DEFINE([BUILD_FBDEV_COMPOSITOR], [1], [Build the fbdev compositor])
 208   PKG_CHECK_MODULES([FBDEV_COMPOSITOR], [libudev >= 136 mtdev >= 1.1.0])
 209 ])
 210
 211 AC_ARG_ENABLE([rdp-compositor], [  --enable-rdp-compositor],,
 212               enable_rdp_compositor=no)
 213 AM_CONDITIONAL([ENABLE_RDP_COMPOSITOR],
 214                [test x$enable_rdp_compositor = xyes])
 215 if test x$enable_rdp_compositor = xyes; then
 216   AC_DEFINE([BUILD_RDP_COMPOSITOR], [1], [Build the RDP compositor])
 217   PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp >= 1.1.0])
 218
 219   SAVED_CPPFLAGS="$CPPFLAGS"
 220   CPPFLAGS="$CPPFLAGS $RDP_COMPOSITOR_CFLAGS"
 221   AC_CHECK_HEADERS([freerdp/version.h])
 222   CPPFLAGS="$SAVED_CPPFLAGS"
 223 fi
 224
 225 AC_ARG_WITH(cairo,
 226             AS_HELP_STRING([--with-cairo=@<:@image|gl|glesv2@:>@]
 227                            [Which Cairo renderer to use for the clients]),
 228                            [],[with_cairo="image"])
 229
 230 if test "x$with_cairo" = "ximage"; then
 231         cairo_modules="cairo"
 232 else
 233 if test "x$with_cairo" = "xgl"; then
 234         cairo_modules="cairo-gl"
 235 else
 236 if test "x$with_cairo" = "xglesv2"; then
 237         cairo_modules="cairo-glesv2"
 238 else
 239         AC_ERROR([Unknown cairo renderer requested])
 240 fi
 241 fi
 242 fi
 243
 244 # Included for legacy compat
 245 AC_ARG_WITH(cairo-glesv2,
 246             AS_HELP_STRING([--with-cairo-glesv2],
 247                            [Use GLESv2 cairo]))
 248 if test "x$with_cairo_glesv2" = "xyes"; then
 249   cairo_modules="cairo-glesv2"
 250   with_cairo="glesv2"
 251 fi
 252
 253 if test "x$cairo_modules" = "xcairo-glesv2"; then
 254 AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 255 fi
 256
 257 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 258 PKG_CHECK_MODULES(PNG, [libpng])
 259 PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 260 AS_IF([test "x$have_webp" = "xyes"],
 261       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 262
 263 AC_ARG_ENABLE(vaapi-recorder, [  --enable-vaapi-recorder],,
 264               enable_vaapi_recorder=auto)
 265 if test x$enable_vaapi_recorder != xno; then
 266   PKG_CHECK_MODULES(LIBVA, [libva >= 0.34.0 libva-drm >= 0.34.0],
 267                     [have_libva=yes], [have_libva=no])
 268   if test "x$have_libva" = "xno" -a "x$enable_vaapi_recorder" = "xyes"; then
 269     AC_MSG_ERROR([vaapi-recorder explicitly enabled, but libva couldn't be found])
 270   fi
 271   AS_IF([test "x$have_libva" = "xyes"],
 272         [AC_DEFINE([BUILD_VAAPI_RECORDER], [1], [Build the vaapi recorder])])
 273 fi
 274 AM_CONDITIONAL(ENABLE_VAAPI_RECORDER, test "x$have_libva" = xyes)
 275
 276
 277 AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 278 if test x$have_jpeglib = xyes; then
 279   JPEG_LIBS="-ljpeg"
 280 else
 281   AC_ERROR([libjpeg not found])
 282 fi
 283 AC_SUBST(JPEG_LIBS)
 284
 285 PKG_CHECK_MODULES(CAIRO, [cairo])
 286
 287 PKG_CHECK_MODULES(TEST_CLIENT, [wayland-client])
 288
 289 AC_ARG_ENABLE(simple-clients,
 290               AS_HELP_STRING([--disable-simple-clients],
 291                              [do not build the simple wl_shm clients]),,
 292               enable_simple_clients=yes)
 293 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 294 if test x$enable_simple_clients = xyes; then
 295   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 296 fi
 297
 298 AC_ARG_ENABLE(simple-egl-clients,
 299               AS_HELP_STRING([--disable-simple-egl-clients],
 300                              [do not build the simple EGL clients]),,
 301               enable_simple_egl_clients="$enable_egl")
 302 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes")
 303 if test x$enable_simple_egl_clients = xyes; then
 304   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 305                     [egl >= 7.10 glesv2 wayland-client wayland-egl wayland-cursor])
 306 fi
 307
 308 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 309 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 310 if test x$enable_clients = xyes; then
 311   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 312
 313   PKG_CHECK_MODULES(CLIENT, [wayland-client cairo >= 1.10.0 xkbcommon wayland-cursor])
 314   PKG_CHECK_MODULES(SERVER, [wayland-server])
 315   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client])
 316
 317   # Only check for cairo-egl if a GL or GLES renderer requested
 318   AS_IF([test "x$cairo_modules" = "xcairo-gl" -o "x$cairo_modules" = "xcairo-glesv2"], [
 319     PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl >= 7.10 cairo-egl >= 1.11.3 $cairo_modules],
 320                       [have_cairo_egl=yes], [have_cairo_egl=no])
 321     AS_IF([test "x$have_cairo_egl" = "xyes"],
 322           [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 323           [AC_ERROR([cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])],
 324   [have_cairo_egl=no])
 325
 326   PKG_CHECK_MODULES(PANGO, [pangocairo], [have_pango=yes], [have_pango=no])
 327 fi
 328
 329 AC_ARG_ENABLE(resize-optimization,
 330               AS_HELP_STRING([--disable-resize-optimization],
 331                              [disable resize optimization allocating a big buffer in toytoolkit]),,
 332               enable_resize_optimization=yes)
 333 AS_IF([test "x$enable_resize_optimization" = "xyes"],
 334       [AC_DEFINE([USE_RESIZE_POOL], [1], [Use resize memory pool as a performance optimization])])
 335
 336 PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login >= 198],
 337                   [have_systemd_login=yes], [have_systemd_login=no])
 338 AS_IF([test "x$have_systemd_login" = "xyes"],
 339       [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 340 AM_CONDITIONAL(HAVE_SYSTEMD_LOGIN, test "x$have_systemd_login" = "xyes")
 341
 342 PKG_CHECK_MODULES(SYSTEMD_LOGIN_209, [libsystemd-login >= 209],
 343                   [have_systemd_login_209=yes], [have_systemd_login_209=no])
 344 AS_IF([test "x$have_systemd_login_209" = "xyes"],
 345       [AC_DEFINE([HAVE_SYSTEMD_LOGIN_209], [1], [Have systemd-login >= 209])])
 346
 347 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 348 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch == xyes)
 349 if test x$enable_weston_launch == xyes; then
 350   AC_CHECK_LIB([pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 351   if test x$have_pam == xno; then
 352     AC_ERROR([weston-launch requires pam])
 353   fi
 354   PAM_LIBS=-lpam
 355   AC_SUBST(PAM_LIBS)
 356 fi
 357
 358 if test x$enable_egl = xyes; then
 359   PKG_CHECK_MODULES(GLU, [glu], [have_glu=yes], [have_glu=no])
 360 fi
 361 AM_CONDITIONAL(HAVE_GLU, test "x$have_glu" = "xyes")
 362
 363 AM_CONDITIONAL(HAVE_PANGO, test "x$have_pango" = "xyes")
 364
 365 AM_CONDITIONAL(HAVE_CAIRO_GLESV2,
 366                [test "x$have_cairo_egl" = "xyes" -a "x$cairo_modules" = "xcairo-glesv2" -a "x$enable_egl" = "xyes"])
 367
 368 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 369                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 370
 371 AM_CONDITIONAL(BUILD_SUBSURFACES_CLIENT,
 372                [test '(' "x$have_cairo_egl" != "xyes" -o "x$cairo_modules" = "xcairo-glesv2" ')' -a "x$enable_simple_egl_clients" = "xyes"])
 373
 374 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 375
 376 AC_ARG_ENABLE(fullscreen-shell,
 377               AS_HELP_STRING([--disable-fullscreen-shell],
 378                              [do not build fullscreen-shell server plugin]),,
 379               enable_fullscreen_shell=yes)
 380 AM_CONDITIONAL(ENABLE_FULLSCREEN_SHELL,
 381                test "x$enable_fullscreen_shell" = "xyes")
 382
 383 # CMS modules
 384 AC_ARG_ENABLE(colord,
 385               AS_HELP_STRING([--disable-colord],
 386                              [do not build colord CMS support]),,
 387               enable_colord=auto)
 388 if test "x$enable_colord" != "xno"; then
 389         PKG_CHECK_MODULES(COLORD,
 390                           colord >= 0.1.27,
 391                           have_colord=yes,
 392                           have_colord=no)
 393         if test "x$have_colord" = "xno" -a "x$enable_colord" = "xyes"; then
 394           AC_MSG_ERROR([colord support explicitly requested, but colord couldn't be found])
 395         fi
 396         if test "x$have_colord" = "xyes"; then
 397              enable_colord=yes
 398         fi
 399 fi
 400 AM_CONDITIONAL(ENABLE_COLORD, test "x$enable_colord" = "xyes")
 401
 402 # dbus support
 403 AC_ARG_ENABLE(dbus,
 404               AS_HELP_STRING([--disable-dbus],
 405                              [do not build with dbus support]),,
 406               enable_dbus=auto)
 407 if test "x$enable_dbus" != "xno"; then
 408         PKG_CHECK_MODULES(DBUS,
 409                           dbus-1 >= 1.6,
 410                           have_dbus=yes,
 411                           have_dbus=no)
 412         if test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"; then
 413                 AC_MSG_ERROR([dbus support explicitly requested, but libdbus couldn't be found])
 414         fi
 415         if test "x$have_dbus" = "xyes"; then
 416                 enable_dbus=yes
 417                 AC_DEFINE([HAVE_DBUS], [1], [Build with dbus support])
 418         else
 419                 enable_dbus=no
 420         fi
 421 fi
 422 AM_CONDITIONAL(ENABLE_DBUS, test "x$enable_dbus" = "xyes")
 423
 424 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 425 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 426 if test x$enable_wcap_tools = xyes; then
 427   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 428   PKG_CHECK_MODULES(WCAP, [cairo])
 429   WCAP_LIBS="$WCAP_LIBS -lm"
 430 fi
 431
 432 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 433 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 434
 435 if test "x$GCC" = "xyes"; then
 436         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter \
 437                 -Wno-missing-field-initializers -g -fvisibility=hidden \
 438                 -Wstrict-prototypes -Wmissing-prototypes -Wsign-compare"
 439 fi
 440 AC_SUBST(GCC_CFLAGS)
 441
 442 AC_ARG_ENABLE(libunwind,
 443               AS_HELP_STRING([--disable-libunwind],
 444                              [Disable libunwind usage for backtraces]),,
 445               enable_libunwind=auto)
 446 AM_CONDITIONAL(HAVE_LIBUNWIND, [test "x$enable_libunwind" = xyes])
 447 if test "x$enable_libunwind" != "xno"; then
 448         PKG_CHECK_MODULES(LIBUNWIND,
 449                           libunwind,
 450                           have_libunwind=yes,
 451                           have_libunwind=no)
 452         if test "x$have_libunwind" = "xno" -a "x$enable_libunwind" = "xyes"; then
 453           AC_MSG_ERROR([libunwind support explicitly requested, but libunwind couldn't be found])
 454         fi
 455         if test "x$have_libunwind" = "xyes"; then
 456              enable_libunwind=yes
 457              AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
 458         fi
 459 fi
 460
 461
 462 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 463         WESTON_NATIVE_BACKEND="drm-backend.so"
 464 fi
 465 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 466 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 467                    [The default backend to load, if not wayland nor x11.])
 468
 469 if test "x$WESTON_SHELL_CLIENT" = "x"; then
 470         WESTON_SHELL_CLIENT="weston-desktop-shell"
 471 fi
 472 AC_MSG_NOTICE([Weston's default desktop shell client: $WESTON_SHELL_CLIENT])
 473 AC_DEFINE_UNQUOTED([WESTON_SHELL_CLIENT], ["$WESTON_SHELL_CLIENT"],
 474                    [The default desktop shell client to load.])
 475
 476 AC_ARG_ENABLE(demo-clients-install,
 477               AS_HELP_STRING([--enable-demo-clients-install],
 478                              [Install demo clients built with weston]),,
 479                              enable_demo_clients_install=no)
 480 AM_CONDITIONAL(INSTALL_DEMO_CLIENTS, [test "x$enable_demo_clients_install" = "xyes"])
 481
 482 PKG_CHECK_MODULES(LCMS, lcms2,
 483                   [have_lcms=yes], [have_lcms=no])
 484 if test "x$have_lcms" = xyes; then
 485        AC_DEFINE(HAVE_LCMS, 1, [Have lcms support])
 486 fi
 487 AM_CONDITIONAL(HAVE_LCMS, [test "x$have_lcms" = xyes])
 488
 489 AC_PATH_PROG([wayland_scanner], [wayland-scanner])
 490 if test x$wayland_scanner = x; then
 491         AC_MSG_ERROR([wayland-scanner is needed to compile weston])
 492 fi
 493
 494 PKG_CHECK_MODULES(WAYLAND_SCANNER, wayland-scanner)
 495
 496 AC_CONFIG_FILES([Makefile src/version.h src/weston.pc])
 497
 498 AM_CONDITIONAL([HAVE_GIT_REPO], [test -f $srcdir/.git/logs/HEAD])
 499
 500 AC_OUTPUT
 501
 502 AC_MSG_RESULT([
 503         Native Backend                  ${WESTON_NATIVE_BACKEND}
 504         setuid Install                  ${enable_setuid_install}
 505
 506         Cairo Renderer                  ${with_cairo}
 507         EGL                             ${enable_egl}
 508         libxkbcommon                    ${enable_xkbcommon}
 509         xcb_xkb                         ${have_xcb_xkb}
 510         XWayland                        ${enable_xwayland}
 511         dbus                            ${enable_dbus}
 512
 513         Build wcap utility              ${enable_wcap_tools}
 514         Build Fullscreen Shell          ${enable_fullscreen_shell}
 515
 516         weston-launch utility           ${enable_weston_launch}
 517         systemd-login support           ${have_systemd_login}
 518
 519         DRM Compositor                  ${enable_drm_compositor}
 520         X11 Compositor                  ${enable_x11_compositor}
 521         Wayland Compositor              ${enable_wayland_compositor}
 522         Headless Compositor             ${enable_headless_compositor}
 523         RPI Compositor                  ${enable_rpi_compositor}
 524         FBDEV Compositor                ${enable_fbdev_compositor}
 525         RDP Compositor                  ${enable_rdp_compositor}
 526
 527         libinput Backend                ${enable_libinput_backend}
 528
 529         Raspberry Pi BCM headers        ${have_bcm_host}
 530
 531         Build Clients                   ${enable_clients}
 532         Build EGL Clients               ${have_cairo_egl}
 533         Build Simple Clients            ${enable_simple_clients}
 534         Build Simple EGL Clients        ${enable_simple_egl_clients}
 535
 536         Install Demo Clients            ${enable_demo_clients_install}
 537
 538         Colord Support                  ${have_colord}
 539         GLU Support                     ${have_glu}
 540         LCMS2 Support                   ${have_lcms}
 541         libwebp Support                 ${have_webp}
 542         libunwind Support               ${have_libunwind}
 543         VA H.264 encoding Support       ${have_libva}
 544 ])