configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [9])
   6 m4_define([folks_micro_version], [1])
   7 m4_define([folks_nano_version], [1])
   8
   9 # If library source has changed since last release, increment revision
  10 # If public symbols have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If public symbols have been added since last release, increment age
  13 # If public symbols have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [38])
  15 m4_define([folks_lt_revision], [1])
  16 m4_define([folks_lt_age], [13])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-xz no-define
  46                   no-dist-gzip tar-ustar -Wno-portability color-tests])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54 GLIB_GSETTINGS
  55
  56 AC_SUBST([CFLAGS])
  57 AC_SUBST([CPPFLAGS])
  58 AC_SUBST([LDFLAGS])
  59
  60 LT_CURRENT=folks_lt_current
  61 LT_REVISION=folks_lt_revision
  62 LT_AGE=folks_lt_age
  63 AC_SUBST([LT_CURRENT])
  64 AC_SUBST([LT_REVISION])
  65 AC_SUBST([LT_AGE])
  66
  67 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  68 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  69
  70 API_VERSION=0.6
  71 AC_SUBST([API_VERSION])
  72
  73 AC_ARG_ENABLE(tracker-backend,
  74         AC_HELP_STRING([--enable-tracker-backend],
  75                        [ build the Tracker backend]),
  76         enable_tracker_backend=$enableval,
  77         enable_tracker_backend=no )
  78
  79 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  80
  81 AS_IF([test "x$enable_tracker_backend" = "xyes"], [
  82         AC_DEFINE(HAVE_TRACKER, [1],
  83                   [Define as 1 if you have the Tracker backend])
  84 ], [
  85         AC_DEFINE(HAVE_TRACKER, [0],
  86                   [Define as 1 if you have the Tracker backend])
  87 ])
  88
  89 AC_ARG_ENABLE(eds-backend,
  90         AC_HELP_STRING([--enable-eds-backend],
  91                        [ build the E-D-S backend]),
  92         enable_eds_backend=$enableval,
  93         enable_eds_backend=yes )
  94
  95 AS_IF([test "x$enable_eds_backend" = "xyes"], [
  96         AC_DEFINE(HAVE_EDS, [1], [Define as 1 if you have the eds backend])
  97 ], [
  98         AC_DEFINE(HAVE_EDS, [0], [Define as 1 if you have the eds backend])
  99 ])
 100
 101 AM_CONDITIONAL([ENABLE_EDS], [test "x$enable_eds_backend" = "xyes"])
 102
 103 AC_ARG_ENABLE(ofono-backend,
 104         AC_HELP_STRING([--enable-ofono-backend],
 105                        [ build the ofono backend]),
 106         enable_ofono_backend=$enableval,
 107         enable_ofono_backend=yes )
 108
 109 AS_IF([test "x$enable_ofono_backend" = "xyes"], [
 110         AC_DEFINE(HAVE_OFONO, [1], [Define as 1 if you have the ofono backend])
 111 ], [
 112         AC_DEFINE(HAVE_OFONO, [0], [Define as 1 if you have the ofono backend])
 113 ])
 114
 115 AM_CONDITIONAL([ENABLE_OFONO], [test "x$enable_ofono_backend" = "xyes"])
 116
 117 AC_ARG_ENABLE(telepathy-backend,
 118         AC_HELP_STRING([--enable-telepathy-backend],
 119                        [ build the Telepathy backend]),
 120         enable_telepathy_backend=$enableval,
 121         enable_telepathy_backend=yes )
 122
 123 AS_IF([test "x$enable_telepathy_backend" = "xyes"], [
 124         AC_DEFINE(HAVE_TELEPATHY, [1], [Define as 1 if you have the Telepathy backend])
 125 ], [
 126         AC_DEFINE(HAVE_TELEPATHY, [0], [Define as 1 if you have the Telepathy backend])
 127 ])
 128
 129 AM_CONDITIONAL([ENABLE_TELEPATHY], [test "x$enable_telepathy_backend" = "xyes"])
 130
 131 AC_ARG_ENABLE(zeitgeist,
 132         AC_HELP_STRING([--enable-zeitgeist],
 133                        [ build Zeitgeist support in the Telepathy backend]),
 134         enable_zeitgeist=$enableval,
 135         enable_zeitgeist=auto)
 136
 137 # Automatically check the dependencies for the libsocialweb backend
 138 SW_CLIENT_REQUIRED=0.25.20
 139 AC_ARG_ENABLE(libsocialweb-backend,
 140         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
 141                        [build the Libsocialweb backend (default: auto)]),
 142         enable_libsocialweb_backend=$enableval,
 143         enable_libsocialweb_backend=auto )
 144
 145 # this may be overwritten farther down
 146 AC_DEFINE(HAVE_LIBSOCIALWEB, [0],
 147           [Define as 1 if you have the libsocialweb backend])
 148 AS_IF([test "x$enable_libsocialweb_backend" != "xno"], [
 149   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
 150       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
 151   AS_IF([test "x$have_libsocialweb_backend" = "xyes" -a \
 152           "x$enable_vala" = "xyes"], [
 153     VALA_CHECK_PACKAGES([telepathy-glib
 154                          gio-2.0
 155                          gee-0.8
 156                          libsocialweb-client],
 157         ,
 158         have_libsocialweb_backend="no")
 159   ])
 160
 161   AS_IF([test "x$have_libsocialweb_backend" = "xyes"], [
 162     AC_DEFINE(HAVE_LIBSOCIALWEB, [1],
 163               [Define if you have the libsocialweb backend])
 164   ])
 165 ], [
 166    have_libsocialweb_backend=no
 167 ])
 168
 169 AS_IF([test "x$enable_libsocialweb_backend" = "xyes" -a \
 170   "x$have_libsocialweb_backend" != "xyes"], [
 171     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 172 ])
 173
 174 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 175         [test "x$have_libsocialweb_backend" = "xyes"])
 176
 177 # -----------------------------------------------------------
 178 # Dependencies
 179 # -----------------------------------------------------------
 180
 181 GLIB_REQUIRED=2.32.0
 182 VALA_REQUIRED=0.17.6
 183 VALADOC_REQUIRED=0.3.1
 184 TRACKER_SPARQL_MAJOR=0.16
 185 TRACKER_SPARQL_REQUIRED=0.15.2
 186 EBOOK_REQUIRED=3.8.1
 187 EDATASERVER_REQUIRED=3.5.3.1
 188 ZEITGEIST_REQUIRED=0.3.14
 189 GEE_REQUIRED=0.8.4
 190
 191 AC_SUBST([TRACKER_SPARQL_MAJOR])
 192
 193 PKG_CHECK_MODULES([GLIB],
 194                   [glib-2.0 >= $GLIB_REQUIRED
 195                    gobject-2.0 >= $GLIB_REQUIRED])
 196 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 197 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 198 # FIXME: get rid of this when our dependencies stop using dbus-1 (GNOME#696177)
 199 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1 dbus-1])
 200
 201 PKG_CHECK_MODULES([GEE], [gee-0.8 >= $GEE_REQUIRED])
 202
 203 TP_GLIB_REQUIRED=0.19.0
 204
 205 AS_IF([test x$enable_telepathy_backend = xyes], [
 206         PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])])
 207 case "x$enable_zeitgeist" in
 208   xyes)
 209     AS_IF([test x$enable_telepathy_backend = xyes],
 210           [PKG_CHECK_MODULES([ZEITGEIST], [zeitgeist-1.0 >= $ZEITGEIST_REQUIRED],
 211            ,
 212            [AC_MSG_ERROR([Zeitgeist support requires Zeitgeist development package])])])
 213     have_zeitgeist=yes
 214     ;;
 215   xauto)
 216     AS_IF([test x$enable_telepathy_backend = xyes],
 217           [PKG_CHECK_MODULES([ZEITGEIST], [zeitgeist-1.0 >= $ZEITGEIST_REQUIRED],
 218                              have_zeitgeist="yes",have_zeitgeist="no")],
 219           [have_zeitgeist=no])
 220     ;;
 221   xno)
 222     have_zeitgeist=no
 223     ;;
 224   x*)
 225     AC_MSG_ERROR([Unknown --enable-zeitgeist argument: $enable_zeitgeist])
 226 esac
 227
 228 AS_IF([test "x$have_zeitgeist" == "xyes"], [
 229    ZEITGEIST_VALAFLAGS="-D HAVE_ZEITGEIST"
 230    AC_SUBST([ZEITGEIST_VALAFLAGS])
 231    ZEITGEIST_PKG="--pkg zeitgeist-1.0"
 232    AC_SUBST([ZEITGEIST_PKG])
 233 ])
 234
 235 # Ignore post 0.20 deprecations
 236 TP_GLIB_CFLAGS="$TP_GLIB_CFLAGS -DTP_VERSION_MIN_REQUIRED=TP_VERSION_0_20"
 237 # Prevent post 0.20 APIs
 238 TP_GLIB_CFLAGS="$TP_GLIB_CFLAGS -DTP_VERSION_MAX_ALLOWED=TP_VERSION_0_20"
 239
 240 AS_IF([test x$enable_tracker_backend = xyes], [
 241         PKG_CHECK_MODULES([TRACKER_SPARQL],
 242                           [tracker-sparql-$TRACKER_SPARQL_MAJOR >= \
 243                            $TRACKER_SPARQL_REQUIRED])
 244 ])
 245
 246 AS_IF([test x$enable_eds_backend = xyes], [
 247         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED
 248                                     libebook-contacts-1.2 >= $EBOOK_REQUIRED])
 249         PKG_CHECK_MODULES([EDATASERVER], [libedataserver-1.2 >= $EDATASERVER_REQUIRED])
 250 ])
 251
 252 AS_IF([test x$enable_ofono_backend = xyes], [
 253         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED])
 254 ])
 255
 256 #
 257 # Vala building options -- allows tarball builds without installing Vala
 258 #
 259 AC_ARG_ENABLE([vala],
 260               AS_HELP_STRING([--enable-vala],
 261                              [Enable building from the Vala sources]),
 262               [enable_vala=$enableval],
 263               [enable_vala=no])
 264
 265 # will be re-set as necessary below
 266 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 267 sd=${srcdir}/
 268
 269 # Force Vala for non-release builds
 270 m4_if(folks_released, [1], [],
 271     [
 272         enable_vala=yes
 273         echo "Vala compiler required for non-release builds; requiring Vala..."
 274     ])
 275
 276 # Force Vala if generated source is missing or outdated
 277 AS_IF([test \
 278         ! -e ${sd}tools/folks_import_vala.stamp -o \
 279         ! -e ${sd}tests/folks/abstract_field_details_vala.stamp -o \
 280         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 281         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 282         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 283         ! -e ${sd}tests/lib/folks-test.vapi -o \
 284         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 285         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 286         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 287         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 288         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 289         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 290         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 291         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 292         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 293         ! -e ${sd}backends/key-file/key_file_la_vala.stamp -o \
 294         ! -e ${sd}backends/telepathy/telepathy_la_vala.stamp \
 295                 -o \
 296         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 297         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 298         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 299         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 300         ! -e ${sd}folks/folks-internal.h -o \
 301         ! -e ${sd}folks/folks-internal.vapi -o \
 302         ! -e ${sd}folks/libfolks_internal_la_vala.stamp -o \
 303         ! -e ${sd}folks/folks.vapi -o \
 304         ! -e ${sd}folks/libfolks_la_vala.stamp \
 305       ], [
 306         enable_vala=yes
 307         echo "Vala source needs to be re-compiled; requiring Vala..."
 308 ])
 309
 310 AS_IF([test "x$enable_vala" = "xyes"], [
 311         AM_PROG_VALAC([$VALA_REQUIRED])
 312         AS_IF([test "x$VALAC" = "x"], [
 313               AC_MSG_ERROR([Vala requested but valac is not installed])
 314         ])
 315
 316         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 317         AS_IF([test "x$VAPIGEN" = "x"], [
 318               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 319         ])
 320
 321         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 322         # automatically
 323         AM_VALAFLAGS="--target-glib=2.24"
 324         # within the libfolks tree, select inline code paths
 325         AM_VALAFLAGS="$AM_VALAFLAGS -D FOLKS_COMPILATION"
 326         AC_SUBST([AM_VALAFLAGS])
 327         AC_SUBST([VAPIGENFLAGS])
 328         AC_SUBST([VAPIDIR])
 329
 330         VALA_CHECK_PACKAGES([gio-2.0
 331                              gee-0.8])
 332
 333         AS_IF([test x$enable_telepathy_backend = xyes], [
 334           VALA_CHECK_PACKAGES([telepathy-glib])
 335           AS_IF([test "x$have_zeitgeist" == "xyes"], [
 336               VALA_CHECK_PACKAGES([zeitgeist-1.0])
 337           ])
 338         ])
 339
 340         AS_IF([test x$enable_tracker_backend = xyes], [
 341           VALA_CHECK_PACKAGES([tracker-sparql-$TRACKER_SPARQL_MAJOR])
 342         ])
 343
 344         AS_IF([test x$enable_eds_backend = xyes], [
 345           VALA_CHECK_PACKAGES([libebook-1.2 libebook-contacts-1.2 libedataserver-1.2 libxml-2.0])
 346         ])
 347
 348         AS_IF([test x$enable_ofono_backend = xyes], [
 349           VALA_CHECK_PACKAGES([libebook-1.2])
 350         ])
 351 ])
 352
 353 # this will set HAVE_INTROSPECTION
 354 GOBJECT_INTROSPECTION_REQUIRE([1.30])
 355
 356 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 357
 358 # Various functions that we need (used in C code generated from Vala)
 359 AC_CHECK_FUNCS([memset])
 360 AC_CHECK_FUNCS([strstr])
 361
 362 AM_CONDITIONAL([NOT_RELEASE], [test "x$folks_released" = "x0"])
 363
 364 # -----------------------------------------------------------
 365 # Backends
 366 # -----------------------------------------------------------
 367
 368 FOLKS_MODULE_VERSION=folks_module_version
 369 AC_SUBST([FOLKS_MODULE_VERSION])
 370 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 371
 372 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 373 AC_SUBST([BACKEND_DIR])
 374
 375 # -----------------------------------------------------------
 376 # Tools
 377 # -----------------------------------------------------------
 378
 379 AC_ARG_ENABLE([import-tool],
 380               AS_HELP_STRING([--enable-import-tool],
 381                              [Enable building the meta-contact import tool]),
 382               [enable_import_tool=$enableval with_import_tool=$enableval],
 383               [enable_import_tool=maybe with_import_tool=no])
 384 AS_IF([test "$enable_import_tool" != "no"],
 385       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 386                          [with_import_tool=yes], [with_import_tool=no])])
 387 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 388       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 389 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 390
 391 # Readline's required for the folks-inspect program
 392 AC_ARG_ENABLE([inspect-tool],
 393               AS_HELP_STRING([--enable-inspect-tool],
 394                              [Enable building the data inspection tool]),
 395               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 396               [enable_inspect_tool=maybe with_inspect_tool=no])
 397 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 398       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 399                      using --enable-vala])])
 400 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 401       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 402                       --enable-vala])])
 403 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 404       [AC_CHECK_LIB([readline], [main],
 405                     [with_inspect_tool=yes], [with_inspect_tool=no],
 406                     [-lncurses])])
 407 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 408        "x$enable_vala" = "xyes"],
 409       [VALA_CHECK_PACKAGES([readline])
 410        LIBREADLINE="-lreadline -lncurses"
 411        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 412        AC_SUBST([LIBREADLINE])])
 413 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 414       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 415 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 416
 417 # -----------------------------------------------------------
 418 # Tests
 419 # -----------------------------------------------------------
 420
 421 AC_ARG_ENABLE([tests],
 422               AS_HELP_STRING([--enable-tests],[Enable building of tests]),
 423               [enable_tests=$enableval], [enable_tests=yes])
 424 AM_CONDITIONAL([ENABLE_TESTS], [test x$enable_tests = xyes])
 425
 426 # -----------------------------------------------------------
 427 # Documentation
 428 # -----------------------------------------------------------
 429
 430 AC_ARG_ENABLE([docs],
 431               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 432               [enable_docs=$enableval], [enable_docs=no])
 433 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 434
 435 have_valadoc=no
 436 AS_IF([test x$enable_docs = xyes], [
 437   # make sure the library is new enough and the program exists
 438   PKG_CHECK_MODULES([VALADOC], [valadoc-1.0 >= $VALADOC_REQUIRED])
 439   AC_PATH_PROG([VALADOC], [valadoc], [:])
 440   AS_IF([test "$VALADOC" != :], have_valadoc=yes)
 441 ])
 442 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 443
 444 AS_IF([test "x$enable_docs" = "xyes" -a "x$have_valadoc" != "xyes"], [
 445     AC_MSG_ERROR([Doc building requested but valadoc not installed.])
 446 ])
 447
 448 # -----------------------------------------------------------
 449 # Gettext
 450 # -----------------------------------------------------------
 451
 452 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 453 AC_SUBST(GETTEXT_PACKAGE)
 454 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 455 IT_PROG_INTLTOOL([0.50.0])
 456
 457 # -----------------------------------------------------------
 458 # Error flags
 459 # -----------------------------------------------------------
 460
 461 # Disable GLib deprecation warnings for now (#670196); GValueArray is deprecated
 462 # but we need it for dbus-glib. Porting to GDBus will solve this (#653198)
 463 AC_DEFINE(GLIB_DISABLE_DEPRECATION_WARNINGS, 1, [Build with GLib deprecated])
 464
 465 # C_ERROR_CFLAGS are only used for C code from telepathy-glib for now,
 466 # while ERROR_CFLAGS are used for everything.
 467
 468 ERROR_CFLAGS=
 469
 470 AC_ARG_ENABLE([fatal-warnings],
 471               AS_HELP_STRING([--disable-fatal-warnings],
 472                              [Make various warnings non-fatal]),
 473               [enable_fatal_warnings=$enableval], [enable_fatal_warnings=yes])
 474
 475 AC_DEFUN([FOLKS_ADD_WARNING],
 476   [
 477     AS_COMPILER_FLAG([-Werror=$2],
 478       [
 479         AS_IF([test "x$enable_fatal_warnings" = xyes],
 480           [$1="[$]$1 -Werror=$2"],
 481           [$1="[$]$1 -W$2"])
 482       ])
 483   ])
 484
 485 # It isn't 1970 any more. Require that we write proper ISO C with declarations,
 486 # avoiding hard-to-trace bugs on platforms where sizeof(int) != sizeof(void *).
 487 FOLKS_ADD_WARNING([ERROR_CFLAGS], [implicit])
 488 FOLKS_ADD_WARNING([ERROR_CFLAGS], [missing-declarations])
 489 FOLKS_ADD_WARNING([ERROR_CFLAGS], [missing-parameter-type])
 490 FOLKS_ADD_WARNING([ERROR_CFLAGS], [missing-prototypes])
 491 FOLKS_ADD_WARNING([ERROR_CFLAGS], [nested-externs])
 492 FOLKS_ADD_WARNING([ERROR_CFLAGS], [old-style-declaration])
 493 FOLKS_ADD_WARNING([ERROR_CFLAGS], [old-style-definition])
 494 FOLKS_ADD_WARNING([ERROR_CFLAGS], [strict-prototypes])
 495
 496 AS_COMPILER_FLAG([-Wall], [C_ERROR_CFLAGS="-Wall"], [C_ERROR_CFLAGS=""])
 497 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 498
 499 AC_ARG_ENABLE([debug],
 500               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 501               [enable_debug=$enableval], [enable_debug=yes])
 502
 503 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 504 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 505                  [wno_missing_field_initializers=yes],
 506                  [wno_missing_field_initializers=no])
 507 AS_COMPILER_FLAG([-Wno-unused-parameter],
 508                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 509 AS_COMPILER_FLAG([-Wstrict-prototypes], [wstrict_prototypes=yes],
 510                  [wstrict_prototypes=no])
 511 AS_COMPILER_FLAG([-Wmissing-prototypes], [wmissing_prototypes=yes],
 512                  [wmissing_prototypes=no])
 513 AS_COMPILER_FLAG([-Wimplicit-function-declaration],
 514                  [wimplicit_function_declaration=yes],
 515                  [wimplicit_function_declaration=no])
 516 AS_COMPILER_FLAG([-Wpointer-arith], [wpointer_arith=yes], [wpointer_arith=no])
 517 AS_COMPILER_FLAG([-Winit-self], [winit_self=yes], [winit_self=no])
 518 AS_COMPILER_FLAG([-Wformat=2], [wformat=yes], [wformat=no])
 519 AS_COMPILER_FLAG([-Wmissing-include-dirs], [wmissing_include_dirs=yes],
 520                  [wmissing_include_dirs=no])
 521 AS_COMPILER_FLAG([-Waggregate-return], [waggregate_return=yes],
 522                  [waggregate_return=no])
 523 AS_COMPILER_FLAG([-Wdeclaration-after-statement],
 524                  [wdeclaration_after_statement=yes],
 525                  [wdeclaration_after_statement=no])
 526
 527 m4_if(folks_released, [1], [],
 528     [
 529         # Iff we support -Werror, then use it with all our compiler warnings.
 530         if test x$werror = xyes; then
 531             flag="-Werror="
 532         else
 533             flag="-W"
 534         fi
 535
 536         if test x$wextra = xyes -a \
 537             x$wno_missing_field_initializers = xyes -a \
 538             x$wno_unused_parameter = xyes -a x$wstrict_prototypes = xyes -a \
 539             x$wmissing_prototypes = xyes -a \
 540             x$wimplicit_function_declaration = xyes -a x$wpointer_arith = xyes \
 541             -a x$winit_self = xyes -a x$wformat = xyes -a \
 542             x$wmissing_include_dirs = xyes -a x$waggregate_return = xyes -a \
 543             x$wdeclaration_after_statement = xyes; then
 544             C_ERROR_CFLAGS="$C_ERROR_CFLAGS -Wextra \
 545                 -Wno-missing-field-initializers \
 546                 -Wno-unused-parameter ${flag}strict-prototypes \
 547                 ${flag}missing-prototypes ${flag}implicit-function-declaration \
 548                 ${flag}pointer-arith ${flag}init-self ${flag}format=2 \
 549                 ${flag}missing-include-dirs ${flag}aggregate-return \
 550                 ${flag}declaration-after-statement"
 551         fi
 552     ])
 553
 554 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [C_ERROR_CFLAGS="$C_ERROR_CFLAGS -D_POSIX_SOURCE"])
 555 AS_COMPILER_FLAG([-std=c99], [C_ERROR_CFLAGS="$C_ERROR_CFLAGS -std=c99"])
 556 AS_COMPILER_FLAG([-Wshadow], [C_ERROR_CFLAGS="$C_ERROR_CFLAGS -Wshadow"])
 557 AS_COMPILER_FLAG([-Wmissing-prototypes], [C_ERROR_CFLAGS="$C_ERROR_CFLAGS \
 558                                           -Wmissing-prototypes"])
 559 AS_COMPILER_FLAG([-Wmissing-declarations], [C_ERROR_CFLAGS="$C_ERROR_CFLAGS \
 560                                             -Wmissing-declarations"])
 561 AS_COMPILER_FLAG([-Wstrict-prototypes], [C_ERROR_CFLAGS="$C_ERROR_CFLAGS \
 562                                          -Wstrict-prototypes"])
 563
 564 AC_SUBST([ERROR_CFLAGS])
 565 AC_SUBST([C_ERROR_CFLAGS])
 566
 567 # -----------------------------------------------------------
 568 # Code coverage flags
 569 # -----------------------------------------------------------
 570
 571 AC_ARG_ENABLE([code-coverage],
 572               AS_HELP_STRING([--enable-code-coverage],
 573                              [compile with code coverage code]),
 574               [enable_code_coverage=$enableval], [enable_code_coverage=no])
 575
 576 # Only enable code coverage if this isn't a release.
 577 m4_if(folks_released, [1], [],
 578     [
 579         if test "x$GCC" = "xyes"; then
 580             if test "x$enable_code_coverage" = "xyes"; then
 581                 CODE_COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage -O0 -ggdb"
 582                 CODE_COVERAGE_LDFLAGS="-lgcov"
 583             fi
 584         fi
 585     ])
 586
 587 AC_SUBST([CODE_COVERAGE_CFLAGS])
 588 AC_SUBST([CODE_COVERAGE_LDFLAGS])
 589
 590 # Vala-related flags
 591 AS_IF([test "x$enable_vala" = "xyes" && test "x$enable_fatal_warnings" = "xyes"],
 592       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 593                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 594        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 595
 596 # Disable -g if we're building with code coverage enabled, since Vala's
 597 # insertion of #line directives into .c files confuses lcov. For the moment,
 598 # we'll have to do with looking at code coverage of the generated C files only.
 599 # We set the debug flags in CODE_COVERAGE_CFLAGS instead in that case.
 600 m4_if(folks_released, [1], [],
 601     [
 602         if test "x$enable_code_coverage" != "xyes" -o "x$GCC" != "xyes"; then
 603             ERROR_VALAFLAGS="$ERROR_VALAFLAGS -g"
 604         fi
 605     ])
 606
 607 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 608 AC_SUBST([ERROR_VALAFLAGS])
 609
 610 # -----------------------------------------------------------
 611 # Profiling
 612 # -----------------------------------------------------------
 613
 614 AC_ARG_ENABLE([profiling],
 615               AS_HELP_STRING([--enable-profiling],
 616                              [Enable building profiling points]),
 617               [enable_profiling=$enableval],
 618               [enable_profiling=no])
 619 AM_CONDITIONAL([ENABLE_PROFILING], [test "$enable_profiling" = "yes"])
 620
 621 # -----------------------------------------------------------
 622 # Final output
 623 # -----------------------------------------------------------
 624
 625 AC_CONFIG_FILES([
 626     backends/telepathy/lib/folks-telepathy.pc
 627     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 628     backends/tracker/lib/folks-tracker.deps
 629     backends/tracker/lib/folks-tracker.pc
 630     backends/tracker/lib/folks-tracker-uninstalled.pc
 631     backends/eds/lib/folks-eds.pc
 632     backends/eds/lib/folks-eds-uninstalled.pc
 633     folks/folks.pc
 634     folks/folks-uninstalled.pc
 635     folks/org.freedesktop.folks.gschema.xml
 636     Makefile
 637     backends/Makefile
 638     backends/key-file/Makefile
 639     backends/libsocialweb/Makefile
 640     backends/libsocialweb/lib/Makefile
 641     backends/libsocialweb/lib/folks-libsocialweb.pc
 642     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 643     backends/telepathy/Makefile
 644     backends/telepathy/lib/Makefile
 645     backends/tracker/Makefile
 646     backends/tracker/lib/Makefile
 647     backends/eds/Makefile
 648     backends/eds/lib/Makefile
 649     backends/ofono/Makefile
 650     folks/Makefile
 651     docs/Makefile
 652     po/Makefile.in
 653     tests/Makefile
 654     tests/data/Makefile
 655     tests/eds/Makefile
 656     tests/folks/Makefile
 657     tests/key-file/Makefile
 658     tests/libsocialweb/Makefile
 659     tests/telepathy/Makefile
 660     tests/tracker/Makefile
 661     tests/lib/Makefile
 662     tests/lib/folks-test-uninstalled.pc
 663     tests/lib/eds/Makefile
 664     tests/lib/key-file/Makefile
 665     tests/lib/libsocialweb/Makefile
 666     tests/lib/telepathy/Makefile
 667     tests/lib/tracker/Makefile
 668     tests/lib/telepathy/contactlist/Makefile
 669     tests/tools/Makefile
 670     tools/Makefile
 671     tools/inspect/Makefile
 672 ])
 673
 674 AC_OUTPUT
 675
 676 echo "
 677 Configure summary:
 678
 679         Vala........................:  ${enable_vala}
 680         Vala Compiler...............:  ${VALAC}
 681         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS} ${CODE_COVERAGE_CFLAGS}
 682         Linker Flags................:  ${LDFLAGS} ${CODE_COVERAGE_LDFLAGS}
 683         Prefix......................:  ${prefix}
 684         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 685         Documentation...............:  ${have_valadoc}
 686         Import tool.................:  ${with_import_tool}
 687         Inspector tool..............:  ${with_inspect_tool}
 688         Telepathy backend...........:  ${enable_telepathy_backend}
 689         Tracker backend.............:  ${enable_tracker_backend}
 690         Libsocialweb backend........:  ${have_libsocialweb_backend}
 691         E-D-S backend...............:  ${enable_eds_backend}
 692         Ofono backend...............:  ${enable_ofono_backend}
 693         Zeitgeist support...........:  ${have_zeitgeist}
 694         Build tests.................:  ${enable_tests}
 695 "