configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.10.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.10.21
  51 GSTPB_REQ=0.10.21
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION([0.11.5])
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101
 102 dnl determine c++ compiler
 103 AC_PROG_CXX
 104 dnl determine if c++ is available on this system
 105 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 106
 107 dnl determine c++ preprocessor
 108 dnl FIXME: do we need this ?
 109 AC_PROG_CXXCPP
 110
 111 AS_PROG_OBJC
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 dnl find an assembler
 117 AM_PROG_AS
 118
 119 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 120 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 121
 122 dnl check for gconftool-2
 123 dnl this macro defines an am conditional, so it needs to be run always
 124 AM_GCONF_SOURCE_2
 125
 126 dnl check for documentation tools
 127 GTK_DOC_CHECK([1.3])
 128 AS_PATH_PYTHON([2.1])
 129 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 AC_CHECK_LIBM
 135 AC_SUBST(LIBM)
 136
 137 dnl *** checks for header files ***
 138
 139 dnl check if we have ANSI C header files
 140 AC_HEADER_STDC
 141
 142 dnl used by ext/wavpack
 143 AX_CREATE_STDINT_H
 144
 145 dnl used in gst/rtp/gstasteriskh263.c
 146 AC_CHECK_HEADERS([netinet/in.h])
 147 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 148 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 149
 150 dnl used in gst/udp
 151 AC_CHECK_HEADERS([sys/time.h])
 152
 153 dnl *** checks for types/defines ***
 154
 155 dnl Check for FIONREAD ioctl declaration.  This check is needed
 156 dnl for the UDP plugin to build on Solaris
 157 GST_CHECK_FIONREAD
 158
 159 dnl *** checks for structures ***
 160
 161 dnl *** checks for compiler characteristics ***
 162
 163 dnl check if we have GCC inline-asm
 164 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 165 if test x$HAVE_GCC_ASM = xyes ; then
 166   AC_DEFINE(HAVE_GCC_ASM, 1,
 167     [Define if compiler supports gcc inline assembly])
 168 fi
 169 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 170
 171 dnl *** checks for library functions ***
 172
 173 LIBS_SAVE=$LIBS
 174 LIBS="$LIBS $LIBM"
 175 AC_CHECK_FUNCS(rint sinh cosh asinh)
 176 LIBS=$LIBS_SAVE
 177
 178 dnl Check for mmap (needed by electricfence plugin)
 179 AC_FUNC_MMAP
 180 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 181
 182 dnl *** checks for dependency libraries ***
 183
 184 dnl GLib is required
 185 AG_GST_GLIB_CHECK([2.12])
 186
 187 dnl liboil is required
 188 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 189 if test "x$HAVE_LIBOIL" != "xyes"; then
 190   AC_ERROR([liboil-0.3.8 or later is required])
 191 fi
 192
 193 dnl checks for gstreamer
 194 dnl uninstalled is selected preferentially -- see pkg-config(1)
 195 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 196 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 197 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 198 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 199 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 200 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 201
 202 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 203 if test -z $GST_TOOLS_DIR; then
 204   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 205 fi
 206 AC_SUBST(GST_TOOLS_DIR)
 207
 208 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 209 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 210
 211 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 212
 213 dnl Check for documentation xrefs
 214 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 215 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 216 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 217 AC_SUBST(GLIB_PREFIX)
 218 AC_SUBST(GST_PREFIX)
 219 AC_SUBST(GSTPB_PREFIX)
 220
 221 dnl GTK is optional and used in examples
 222 HAVE_GTK=NO
 223 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 224 if test "x$HAVE_GTK_22" = "xyes"; then
 225   HAVE_GTK=yes
 226   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 227   AC_SUBST(GTK_VERSION)
 228   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 229   AC_SUBST(GTK_BASE_DIR)
 230   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 231   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 232   AC_SUBST(GTK_BASE_DIR)
 233 else
 234   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 235 fi
 236 if test "x$HAVE_GTK_20" = "xyes"; then
 237   HAVE_GTK=yes
 238 fi
 239 GTK_CFLAGS=$GTK2_CFLAGS
 240 GTK_LIBS=$GTK2_LIBS
 241 AC_SUBST(GTK_LIBS)
 242 AC_SUBST(GTK_CFLAGS)
 243 AC_SUBST(HAVE_GTK)
 244 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 245
 246 dnl should we install schemas ?
 247 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 248 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 249   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 250   if test x$GCONFTOOL = xno; then
 251     AC_MSG_WARN(Not installing GConf schemas)
 252     HAVE_GCONFTOOL="no"
 253   else
 254     HAVE_GCONFTOOL="yes"
 255   fi
 256   AC_SUBST(HAVE_GCONFTOOL)
 257 ])
 258
 259 dnl *** set variables based on configure arguments ***
 260
 261 dnl set license and copyright notice
 262 GST_LICENSE="LGPL"
 263 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 264 AC_SUBST(GST_LICENSE)
 265
 266 dnl set location of plugin directory
 267 AG_GST_SET_PLUGINDIR
 268
 269 dnl define an ERROR_CFLAGS Makefile variable
 270 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 271
 272 dnl define an ERROR_CXXFLAGS Makefile variable
 273 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 274
 275 dnl define correct level for debugging messages
 276 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 277
 278 dnl used in examples
 279 AG_GST_DEFAULT_ELEMENTS
 280
 281 dnl *** plug-ins to include ***
 282
 283 dnl these are all the gst plug-ins, compilable without additional libs
 284 dnl videofilter is at the top because others depend on it
 285 AG_GST_CHECK_PLUGIN(videofilter)
 286 AG_GST_CHECK_PLUGIN(alpha)
 287 AG_GST_CHECK_PLUGIN(apetag)
 288 AG_GST_CHECK_PLUGIN(audiofx)
 289 AG_GST_CHECK_PLUGIN(auparse)
 290 AG_GST_CHECK_PLUGIN(autodetect)
 291 AG_GST_CHECK_PLUGIN(avi)
 292 AG_GST_CHECK_PLUGIN(cutter)
 293 AG_GST_CHECK_PLUGIN(debug)
 294 AG_GST_CHECK_PLUGIN(effectv)
 295 AG_GST_CHECK_PLUGIN(equalizer)
 296 AG_GST_CHECK_PLUGIN(id3demux)
 297 AG_GST_CHECK_PLUGIN(icydemux)
 298 AG_GST_CHECK_PLUGIN(interleave)
 299 AG_GST_CHECK_PLUGIN(flx)
 300 AG_GST_CHECK_PLUGIN(goom)
 301 AG_GST_CHECK_PLUGIN(goom2k1)
 302 AG_GST_CHECK_PLUGIN(law)
 303 AG_GST_CHECK_PLUGIN(level)
 304 AG_GST_CHECK_PLUGIN(matroska)
 305 AG_GST_CHECK_PLUGIN(monoscope)
 306 AG_GST_CHECK_PLUGIN(multifile)
 307 AG_GST_CHECK_PLUGIN(multipart)
 308 AG_GST_CHECK_PLUGIN(qtdemux)
 309 AG_GST_CHECK_PLUGIN(replaygain)
 310 AG_GST_CHECK_PLUGIN(rtp)
 311 AG_GST_CHECK_PLUGIN(rtsp)
 312 AG_GST_CHECK_PLUGIN(smpte)
 313 AG_GST_CHECK_PLUGIN(spectrum)
 314 AG_GST_CHECK_PLUGIN(udp)
 315 AG_GST_CHECK_PLUGIN(videobox)
 316 AG_GST_CHECK_PLUGIN(videocrop)
 317 AG_GST_CHECK_PLUGIN(videomixer)
 318 AG_GST_CHECK_PLUGIN(wavenc)
 319 AG_GST_CHECK_PLUGIN(wavparse)
 320
 321 dnl disable gst plugins we might not be able to build on this
 322 dnl platform: udp and rtsp (ugly but minimally invasive)
 323 dnl FIXME: maybe move to sys
 324 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 325 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 326
 327 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 328   AG_GST_DISABLE_PLUGIN(udp)
 329   AG_GST_DISABLE_PLUGIN(rtsp)
 330 fi
 331
 332 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 333   WIN32_LIBS="-lws2_32"
 334   AC_SUBST(WIN32_LIBS)
 335 fi
 336
 337 dnl disable experimental plug-ins
 338 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 339   AG_GST_DISABLE_PLUGIN(monoscope)
 340 fi
 341
 342 dnl *** sys plug-ins ***
 343
 344 echo
 345 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 346 echo
 347
 348 dnl DirectDraw
 349 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 350 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 351   HAVE_DIRECTDRAW="no"
 352   save_CFLAGS="$CFLAGS"
 353   save_LDFLAGS="$LDFLAGS"
 354   save_LIBS="$LIBS"
 355   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 356   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 357   LIBS="$LIBS -lddraw -lgdi32"
 358   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 359   AC_LINK_IFELSE([
 360 #include <windows.h>
 361 #include <ddraw.h>
 362
 363 int main ()
 364 {
 365   GetStockObject(0);
 366   DirectDrawCreate(NULL, NULL, NULL);
 367
 368   return 0;
 369 }
 370 ],
 371     [HAVE_DIRECTDRAW="yes"],
 372     [HAVE_DIRECTDRAW="no"])
 373   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 374   CFLAGS=$save_CFLAGS
 375   LDFLAGS=$save_LDFLAGS
 376   LIBS=$save_LIBS
 377
 378   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 379     dnl this is much more than we want
 380     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 381     AC_SUBST(DIRECTDRAW_CFLAGS)
 382     AC_SUBST(DIRECTDRAW_LDFLAGS)
 383     AC_SUBST(DIRECTDRAW_LIBS)
 384   fi
 385   AC_SUBST(HAVE_DIRECTDRAW)
 386 ])
 387
 388 dnl DirectSound
 389 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 390 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 391   HAVE_DIRECTSOUND="no"
 392   save_CFLAGS="$CFLAGS"
 393   save_LDFLAGS="$LDFLAGS"
 394   save_LIBS="$LIBS"
 395   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 396   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 397   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 398   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 399   AC_LINK_IFELSE([
 400 #include <windows.h>
 401 #include <dxerr9.h>
 402 #include <dsound.h>
 403
 404 int main ()
 405 {
 406   DXGetErrorString9 (0);
 407   DirectSoundCreate(NULL, NULL, NULL);
 408
 409   return 0;
 410 }
 411 ],
 412     [HAVE_DIRECTSOUND="yes"],
 413     [HAVE_DIRECTSOUND="no"])
 414   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 415   CFLAGS=$save_CFLAGS
 416   LDFLAGS=$save_LDFLAGS
 417   LIBS=$save_LIBS
 418
 419   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 420     dnl this is much more than we want
 421     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 422     AC_SUBST(DIRECTSOUND_CFLAGS)
 423     AC_SUBST(DIRECTSOUND_LDFLAGS)
 424     AC_SUBST(DIRECTSOUND_LIBS)
 425   fi
 426   AC_SUBST(HAVE_DIRECTSOUND)
 427 ])
 428
 429 dnl *** OSS audio *** (Linux, *BSD)
 430 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 431 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 432  HAVE_OSS="yes"
 433 dnl Linux and newer BSD versions :
 434  AC_CHECK_HEADER(sys/soundcard.h, [
 435    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 436    ] , [
 437 dnl Some old BSD versions and also newer OpenBSD versions :
 438    AC_CHECK_HEADER(soundcard.h, [
 439      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 440      ], [
 441   dnl Some old BSD versions :
 442      AC_CHECK_HEADER(machine/soundcard.h, [
 443        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 444          [Define if OSS includes are in /machine/])
 445        ], [
 446        HAVE_OSS="no"
 447      ])
 448    ])
 449  ])
 450 ])
 451
 452 dnl *** Sun Audio ***
 453 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 454 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 455   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 456 ])
 457
 458 dnl *** OSX Audio ***
 459 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 460 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 461   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 462 ])
 463
 464 dnl *** OS X video ***
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 466 HAVE_OSX_VIDEO="no"
 467 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 468   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 469 ])
 470 dnl in case header OpenGL/gl.h is found on other platforms
 471 case "$host" in
 472   *-*darwin*)
 473     dnl do nothing
 474     ;;
 475   *)
 476     HAVE_OSX_VIDEO="no"
 477     ;;
 478 esac
 479
 480
 481 dnl *** Video 4 Linux 2 ***
 482 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 483 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 484 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 485 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 486   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 487   AC_TRY_COMPILE([
 488 #include <sys/types.h>
 489 #ifdef __sun /* Solaris */
 490 #include <sys/types.h>
 491 #include <sys/videodev2.h>
 492 #else /* Linux */
 493 #include <linux/types.h>
 494 #define _LINUX_TIME_H
 495 #define __user
 496 #include <linux/videodev2.h>
 497 #endif
 498 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 499 #error too early v4l2 version or no v4l2 at all
 500 #endif
 501     ], [
 502 return 0;
 503     ], [
 504       HAVE_GST_V4L2="yes"
 505       AC_MSG_RESULT(yes)
 506     ], [
 507       HAVE_GST_V4L2="no"
 508       AC_MSG_RESULT(no)
 509
 510       HAVE_VIDEODEV=no
 511       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 512       [
 513         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 514       ])
 515
 516       if test "x$HAVE_VIDEODEV" = "xyes"; then
 517         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 518         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 519       else
 520         AC_MSG_WARN([video4linux2 was not found])
 521       fi
 522     ])
 523
 524   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 525     dnl check for missing v4l2_buffer declaration (see #135919)
 526     MISSING_DECL=0
 527     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 528     AC_TRY_COMPILE([
 529 #include <sys/types.h>
 530 #ifdef __sun /* Solaris */
 531 #include <sys/types.h>
 532 #include <sys/videodev2.h>
 533 #else /* Linux */
 534 #include <linux/types.h>
 535 #define _LINUX_TIME_H
 536 #define __user
 537 #include <linux/videodev2.h>
 538 #endif
 539     ],[
 540 struct v4l2_buffer buf;
 541 buf.index = 0;
 542 return 0;
 543     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 544     if [ test x$MISSING_DECL = x1 ]; then
 545       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 546     fi
 547
 548     dnl check for XOverlay libraries
 549     AG_GST_CHECK_XV
 550   fi
 551 ])
 552
 553 dnl Check for X11
 554 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 555 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 556                   [ximagesrc], [
 557   AC_PATH_XTRA
 558
 559   dnl now try to find the HEADER
 560   ac_cflags_save="$CFLAGS"
 561   ac_cppflags_save="$CPPFLAGS"
 562   CFLAGS="$CFLAGS $X_CFLAGS"
 563   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 564   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 565
 566   if test "x$HAVE_X" = "xno"
 567   then
 568     AC_MSG_NOTICE([cannot find X11 development files])
 569   else
 570     dnl this is much more than we want
 571     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 572     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 573     dnl it does not add the libs; therefore we add them here
 574     X_LIBS="$X_LIBS -lX11"
 575     AC_SUBST(X_CFLAGS)
 576     AC_SUBST(X_LIBS)
 577
 578     dnl check for Xfixes
 579     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 580     if test "x$HAVE_XFIXES" = "xyes"
 581     then
 582         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 583     fi
 584     AC_SUBST(XFIXES_LIBS)
 585     AC_SUBST(XFIXES_CFLAGS)
 586
 587     dnl check for Xdamage
 588     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 589     if test "x$HAVE_XDAMAGE" = "xyes"
 590     then
 591         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 592     fi
 593     AC_SUBST(XDAMAGE_LIBS)
 594     AC_SUBST(XDAMAGE_CFLAGS)
 595   fi
 596   AC_SUBST(HAVE_X)
 597   CFLAGS="$ac_cflags_save"
 598   CPPFLAGS="$ac_cppflags_save"
 599 ])
 600
 601 dnl FIXME: this should be rolled into the test above, it's just an additional
 602 dnl feature of the ximagesrc plug-in
 603 dnl This is the same as in gst-plugins-base
 604 dnl check for X Shm
 605 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 606 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 607   if test x$HAVE_X = xyes; then
 608     AC_CHECK_LIB(Xext, XShmAttach,
 609                  HAVE_XSHM="yes", HAVE_XSHM="no",
 610                  $X_LIBS)
 611     if test "x$HAVE_XSHM" = "xyes"; then
 612       XSHM_LIBS="-lXext"
 613     else
 614       dnl On AIX, it is in XextSam instead, but we still need -lXext
 615       AC_CHECK_LIB(XextSam, XShmAttach,
 616                    HAVE_XSHM="yes", HAVE_XSHM="no",
 617                    $X_LIBS)
 618       if test "x$HAVE_XSHM" = "xyes"; then
 619         XSHM_LIBS="-lXext -lXextSam"
 620       fi
 621     fi
 622   fi
 623 ], ,[
 624   AC_SUBST(HAVE_XSHM)
 625   AC_SUBST(XSHM_LIBS)
 626 ])
 627
 628 dnl for V4L2, we also need to know if we have XVIDEO
 629 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 630 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 631                   [], [
 632   AG_GST_CHECK_XV
 633 ])
 634
 635 dnl *** ext plug-ins ***
 636 dnl keep this list sorted alphabetically !
 637
 638 if test "x$BUILD_EXTERNAL" = "xyes"; then
 639
 640 echo
 641 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 642 echo
 643
 644 dnl *** aalib ***
 645 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 646 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 647   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 648   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 649 ])
 650
 651 dnl *** annodex ***
 652 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 653 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 654   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 655 ])
 656
 657 dnl *** cairo ***
 658 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 659 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 660   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 661 ])
 662
 663 dnl **** ESound ****
 664 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 665 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 666   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 667   if test $HAVE_ESD = no
 668   then
 669     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 670     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 671   fi
 672 ])
 673
 674 dnl *** FLAC ***
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 676 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 677   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.3)
 678 ])
 679
 680 dnl *** GConf ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 682 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 683   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 684 ])
 685
 686 dnl *** GDK pixbuf ***
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 688 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 689   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 690 ])
 691
 692 dnl *** HAL ***
 693 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 694 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 695   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 696 ])
 697
 698 dnl *** jpeg ***
 699 dnl FIXME: we could use header checks here as well IMO
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 701 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 702   AC_ARG_WITH(jpeg-mmx,
 703     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 704   OLD_LIBS="$LIBS"
 705   if test x$with_jpeg_mmx != x; then
 706     LIBS="$LIBS -L$with_jpeg_mmx"
 707   fi
 708   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 709   JPEG_LIBS="$LIBS -ljpeg-mmx"
 710   LIBS="$OLD_LIBS"
 711   if test x$HAVE_JPEG != xyes; then
 712     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 713     JPEG_LIBS="-ljpeg"
 714   fi
 715   AC_SUBST(JPEG_LIBS)
 716 ])
 717
 718 dnl *** libcaca ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 720 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 721   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 722   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 723   if test "x$HAVE_LIBCACA" != "xyes"; then
 724     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 725     dnl see if it compilation works too, might not if we are cross-compiling
 726     if test "x$HAVE_LIBCACA" = "xyes"; then
 727       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 728                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 729     fi
 730   fi
 731 ])
 732
 733 dnl *** libdv ***
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 735 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 736   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 737 ])
 738
 739 dnl *** libpng ***
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 741 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 742   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 743 ])
 744
 745 dnl *** pulseaudio ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 747 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 748   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.8)
 749 ])
 750
 751 dnl *** dv1394 ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 753 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 754   dnl first test for libraw1394 >= 1.2.1
 755   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 756   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 757   dnl now see how far we got
 758   if test x$HAVE_RAW1394 = xyes && \
 759      test x$HAVE_LIBIEC61883 = xyes; then
 760        AG_GST_CHECK_LIBHEADER(AVC1394,
 761         avc1394, avc1394_send_command, $RAW1394_LIBS,
 762         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 763        AG_GST_CHECK_LIBHEADER(ROM1394,
 764         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 765         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 766        if test x$HAVE_AVC1394 = xyes && \
 767           test x$HAVE_AVC1394 = xyes && \
 768           test x$HAVE_ROM1394 = xyes; then
 769           HAVE_DV1394=yes
 770           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 771           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 772           AC_SUBST(DV1394_CFLAGS)
 773           AC_SUBST(DV1394_LIBS)
 774         fi
 775   else
 776        if test x$HAVE_RAW1394 = xno; then
 777           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 778           AG_GST_CHECK_LIBHEADER(AVC1394,
 779            avc1394, avc1394_send_command, $RAW1394_LIBS,
 780            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 781           AG_GST_CHECK_LIBHEADER(ROM1394,
 782            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 783            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 784           if test x$HAVE_RAW1394 = xyes && \
 785              test x$HAVE_AVC1394 = xyes && \
 786              test x$HAVE_ROM1394 = xyes; then
 787              HAVE_DV1394=yes
 788              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 789              DV1394_CFLAGS="$RAW1394_CFLAGS"
 790              if test x$HAVE_LIBIEC61883 = xyes; then
 791                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 792                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 793              fi
 794              AC_SUBST(DV1394_CFLAGS)
 795              AC_SUBST(DV1394_LIBS)
 796            fi
 797          fi
 798   fi
 799 ])
 800
 801 dnl *** shout2 ***
 802 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 803 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 804   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 805   if test $HAVE_SHOUT2 = no
 806   then
 807     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 808     AC_SUBST(SHOUT2_CFLAGS)
 809     AC_SUBST(SHOUT2_LIBS)
 810   fi
 811 ])
 812
 813 dnl *** soup ***
 814 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 815 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 816   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.3.2, HAVE_SOUP="yes", [
 817     HAVE_SOUP="no"
 818     AC_MSG_RESULT(no)
 819   ])
 820   AC_SUBST(SOUP_CFLAGS)
 821   AC_SUBST(SOUP_LIBS)
 822 ])
 823
 824 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 825 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 826 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 827 dnl   speex_jitter.h is 1.1.x only
 828 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 829 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 830   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 831   if test $HAVE_SPEEX = no
 832   then
 833     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 834       AC_CHECK_HEADER(speex/speex_jitter.h, [
 835         dnl speex 1.1.x :
 836         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 837           dnl speex 1.1.5 or + :
 838           HAVE_SPEEX="yes"
 839           SPEEX_LIBS="-lspeex"
 840           AC_SUBST(SPEEX_CFLAGS)
 841           AC_SUBST(SPEEX_LIBS)
 842         ],[
 843           HAVE_SPEEX="no"
 844         ])
 845       ],[
 846         dnl speex 1.0.x :
 847           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 848             dnl speex 1.0.4
 849             HAVE_SPEEX="yes"
 850             SPEEX_LIBS="-lspeex"
 851             AC_SUBST(SPEEX_CFLAGS)
 852             AC_SUBST(SPEEX_LIBS)
 853
 854             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 855               [defined if speex 1.0.x API detected])
 856         ],[
 857             HAVE_SPEEX="no"
 858             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 859         ], [
 860 #include <speex/speex.h>
 861         ])
 862       ])
 863     ])
 864   fi
 865 ])
 866
 867 dnl *** taglib ***
 868 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 869 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 870   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 871   if test "x$HAVE_CXX" != "xyes"; then
 872     USE_TAGLIB=false
 873     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 874   else
 875     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 876     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 877         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 878       ], [
 879         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 880     ])
 881     AC_SUBST(TAGLIB_CXXFLAGS)
 882   fi
 883 ])
 884
 885 dnl *** wavpack ***
 886 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 887 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 888   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 889     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 890       HAVE_WAVPACK=yes
 891       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 892     ],[
 893       HAVE_WAVPACK=no
 894       AC_MSG_RESULT(no)
 895     ])
 896   ])
 897   AC_SUBST(WAVPACK_CFLAGS)
 898   AC_SUBST(WAVPACK_LIBS)
 899 ])
 900
 901 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 902 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 903 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 904   AG_GST_CHECK_LIBHEADER(ZLIB,
 905     z, uncompress,, zlib.h, [
 906     HAVE_ZLIB="yes"
 907     ZLIB_LIBS="-lz"
 908     AC_SUBST(ZLIB_LIBS)
 909   ])
 910 ])
 911
 912 dnl *** matroska prefers to have bz2 ***
 913 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 914 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 915   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 916   AC_SUBST(BZ2_LIBS)
 917 ])
 918
 919 else
 920
 921 dnl not building plugins with external dependencies,
 922 dnl but we still need to set the conditionals
 923 AM_CONDITIONAL(USE_AALIB, false)
 924 AM_CONDITIONAL(USE_ANNODEX, false)
 925 AM_CONDITIONAL(USE_BZ2, false)
 926 AM_CONDITIONAL(USE_CAIRO, false)
 927 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 928 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 929 AM_CONDITIONAL(USE_DV1394, false)
 930 AM_CONDITIONAL(USE_ESD, false)
 931 AM_CONDITIONAL(USE_FLAC, false)
 932 AM_CONDITIONAL(USE_GCONF, false)
 933 AM_CONDITIONAL(USE_GCONFTOOL, false)
 934 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 935 AM_CONDITIONAL(USE_GST_V4L2, false)
 936 AM_CONDITIONAL(USE_HAL, false)
 937 AM_CONDITIONAL(USE_JPEG, false)
 938 AM_CONDITIONAL(USE_LIBCACA, false)
 939 AM_CONDITIONAL(USE_LIBDV, false)
 940 AM_CONDITIONAL(USE_LIBPNG, false)
 941 AM_CONDITIONAL(USE_OSS, false)
 942 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 943 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 944 AM_CONDITIONAL(USE_PULSE, false)
 945 AM_CONDITIONAL(USE_SHOUT2, false)
 946 AM_CONDITIONAL(USE_SOUP, false)
 947 AM_CONDITIONAL(USE_SPEEX, false)
 948 AM_CONDITIONAL(USE_SUNAUDIO, false)
 949 AM_CONDITIONAL(USE_TAGLIB, false)
 950 AM_CONDITIONAL(USE_WAVPACK, false)
 951 AM_CONDITIONAL(USE_X, false)
 952 AM_CONDITIONAL(USE_XSHM, false)
 953 AM_CONDITIONAL(USE_XVIDEO, false)
 954 AM_CONDITIONAL(USE_ZLIB, false)
 955
 956 fi dnl of EXT plugins
 957
 958 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 959
 960 dnl Overview:
 961 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 962 dnl GST_*:              flags shared by all built objects
 963 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 964 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 965 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 966 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 967
 968 dnl GST_OPTION_CFLAGS
 969 if test "x$USE_DEBUG" = xyes; then
 970    PROFILE_CFLAGS="-g"
 971 fi
 972 AC_SUBST(PROFILE_CFLAGS)
 973
 974 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 975   dnl Define _only_ during CVS (not pre-releases or releases)
 976   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 977 else
 978   DEPRECATED_CFLAGS=""
 979 fi
 980 AC_SUBST(DEPRECATED_CFLAGS)
 981
 982 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 983 dnl at make time with e.g. make ERROR_CFLAGS=""
 984 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 985 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 986 AC_SUBST(GST_OPTION_CFLAGS)
 987 AC_SUBST(GST_OPTION_CXXFLAGS)
 988
 989 dnl our libraries need to be versioned correctly
 990 AC_SUBST(GST_LT_LDFLAGS)
 991
 992 dnl FIXME: do we want to rename to GST_ALL_* ?
 993 dnl prefer internal headers to already installed ones
 994 dnl also add builddir include for enumtypes and marshal
 995 dnl add ERROR_CFLAGS, but overridable
 996 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 997 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"
 998 AC_SUBST(GST_CFLAGS)
 999 AC_SUBST(GST_CXXFLAGS)
1000 AC_SUBST(GST_LIBS)
1001
1002 dnl LDFLAGS really should only contain flags, not libs - they get added before
1003 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1004 GST_ALL_LDFLAGS="-no-undefined"
1005 AC_SUBST(GST_ALL_LDFLAGS)
1006
1007 dnl this really should only contain flags, not libs - they get added before
1008 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1009 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1010 AC_SUBST(GST_PLUGIN_LDFLAGS)
1011
1012 dnl *** output files ***
1013
1014 dnl keep this alphabetic per directory, please
1015 AC_CONFIG_FILES(
1016 Makefile
1017 gst/Makefile
1018 gst/alpha/Makefile
1019 gst/apetag/Makefile
1020 gst/audiofx/Makefile
1021 gst/auparse/Makefile
1022 gst/autodetect/Makefile
1023 gst/avi/Makefile
1024 gst/cutter/Makefile
1025 gst/debug/Makefile
1026 gst/effectv/Makefile
1027 gst/equalizer/Makefile
1028 gst/id3demux/Makefile
1029 gst/icydemux/Makefile
1030 gst/interleave/Makefile
1031 gst/goom/Makefile
1032 gst/goom2k1/Makefile
1033 gst/law/Makefile
1034 gst/level/Makefile
1035 gst/matroska/Makefile
1036 gst/monoscope/Makefile
1037 gst/multifile/Makefile
1038 gst/multipart/Makefile
1039 gst/qtdemux/Makefile
1040 gst/replaygain/Makefile
1041 gst/rtp/Makefile
1042 gst/rtsp/Makefile
1043 gst/smpte/Makefile
1044 gst/spectrum/Makefile
1045 gst/udp/Makefile
1046 gst/videobox/Makefile
1047 gst/videocrop/Makefile
1048 gst/videofilter/Makefile
1049 gst/videomixer/Makefile
1050 gst/wavenc/Makefile
1051 gst/wavparse/Makefile
1052 gst/flx/Makefile
1053 ext/jpeg/Makefile
1054 ext/Makefile
1055 ext/aalib/Makefile
1056 ext/annodex/Makefile
1057 ext/cairo/Makefile
1058 ext/dv/Makefile
1059 ext/esd/Makefile
1060 ext/flac/Makefile
1061 ext/gconf/Makefile
1062 ext/gdk_pixbuf/Makefile
1063 ext/hal/Makefile
1064 ext/ladspa/Makefile
1065 ext/libcaca/Makefile
1066 ext/libpng/Makefile
1067 ext/pulse/Makefile
1068 ext/raw1394/Makefile
1069 ext/shout2/Makefile
1070 ext/soup/Makefile
1071 ext/speex/Makefile
1072 ext/taglib/Makefile
1073 ext/wavpack/Makefile
1074 sys/Makefile
1075 sys/directdraw/Makefile
1076 sys/directsound/Makefile
1077 sys/oss/Makefile
1078 sys/sunaudio/Makefile
1079 sys/osxaudio/Makefile
1080 sys/osxvideo/Makefile
1081 sys/v4l2/Makefile
1082 sys/waveform/Makefile
1083 sys/ximage/Makefile
1084 po/Makefile.in
1085 tests/Makefile
1086 tests/check/Makefile
1087 tests/examples/Makefile
1088 tests/examples/equalizer/Makefile
1089 tests/examples/level/Makefile
1090 tests/examples/rtp/Makefile
1091 tests/examples/spectrum/Makefile
1092 tests/files/Makefile
1093 tests/icles/Makefile
1094 gconf/Makefile
1095 gconf/gstreamer.schemas
1096 common/Makefile
1097 common/m4/Makefile
1098 m4/Makefile
1099 docs/Makefile
1100 docs/plugins/Makefile
1101 docs/version.entities
1102 win32/common/config.h
1103 pkgconfig/Makefile
1104 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1105 gst-plugins-good.spec
1106 )
1107 AC_OUTPUT
1108
1109 AG_GST_OUTPUT_PLUGINS