configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v exported || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])],
  15 [m4_define([v_ver], [v_maj.v_min.v_mic])])
  16 m4_define([lt_rev], m4_eval(v_maj + v_min))
  17 m4_define([lt_cur], v_mic)
  18 m4_define([lt_age], v_min)
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  21
  22 AC_INIT([e_dbus], [v_ver-alpha], [enlightenment-devel@lists.sourceforge.net])
  23 AC_PREREQ([2.52])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_MACRO_DIR([m4])
  26 AC_CANONICAL_BUILD
  27 AC_CANONICAL_HOST
  28
  29 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  30 AM_CONFIG_HEADER([config.h])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 AC_LIBTOOL_WIN32_DLL
  34 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  35 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  36 AC_PROG_LIBTOOL
  37
  38 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  41 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  42 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  43 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  44 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  45 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  46 version_info="lt_rev:lt_cur:lt_age"
  47 release_info="v_rel"
  48 AC_SUBST(version_info)
  49 AC_SUBST(release_info)
  50 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 VMAJ=v_maj
  53 AC_SUBST(VMAJ)
  54
  55 ### Needed information
  56
  57 want_ebluez="yes"
  58 want_econnman="yes"
  59 want_ehal="yes"
  60 want_enotify="yes"
  61 want_eofono="yes"
  62 want_eukit="yes"
  63
  64 case "$host_os" in
  65    mingw*)
  66       want_ebluez="no"
  67       want_econnman="no"
  68       want_ehal="no"
  69       want_enotify="no"
  70       want_eofono="no"
  71       want_eukit="no"
  72       ;;
  73 esac
  74
  75 requirement_ebluez="edbus >= 1.0.0"
  76 requirement_econnman="edbus >= 1.0.0"
  77 requirement_edbus="ecore >= 1.0.0 eina >= 1.0.0 dbus-1 >= 0.62"
  78 requirement_ehal="edbus >= 1.0.0"
  79 requirement_enotify="edbus >= 1.0.0"
  80 requirement_eofono="edbus >= 1.0.0"
  81 requirement_eukit="edbus >= 1.0.0"
  82 requirement_dbus="dbus-1 >= 0.62"
  83
  84 ### Additional options to configure
  85
  86 dnl Check enabled modules to build
  87
  88 AC_ARG_ENABLE([ebluez],
  89    [AC_HELP_STRING([--enable-ebluez], [Enable ebluez build])],
  90    [enable_ebluez=$enableval],
  91    [enable_ebluez="${want_ebluez}"])
  92
  93 AC_ARG_ENABLE([econnman],
  94    [AC_HELP_STRING([--enable-econnman], [Enable econnman build])],
  95    [enable_econnman=$enableval],
  96    [enable_econnman="${want_econnman}"])
  97
  98 AC_ARG_ENABLE([ehal],
  99    [AC_HELP_STRING([--disable-ehal], [Disable ehal build])],
 100    [enable_ehal=$enableval],
 101    [enable_ehal="${want_ehal}"])
 102
 103 AC_ARG_ENABLE([enotify],
 104    [AC_HELP_STRING([--disable-enotify], [Disable enotify build])],
 105    [enable_enotify=$enableval],
 106    [enable_enotify="${want_enotify}"])
 107
 108 AC_ARG_ENABLE([eofono],
 109    [AC_HELP_STRING([--enable-eofono], [Enable eofono build])],
 110    [enable_eofono=$enableval],
 111    [enable_eofono="${want_eofono}"])
 112
 113 AC_ARG_ENABLE([eukit],
 114    [AC_HELP_STRING([--disable-eukit], [Disable eukit build])],
 115    [enable_eukit=$enableval],
 116    [enable_eukit="${want_eukit}"])
 117
 118
 119 ### Checks for programs
 120
 121 AC_PROG_CC
 122 AM_PROG_CC_C_O
 123
 124 # pkg-config
 125 PKG_PROG_PKG_CONFIG
 126
 127 # Check whether pkg-config supports Requires.private
 128 if $PKG_CONFIG --atleast-pkgconfig-version 0.22 ; then
 129    pkgconfig_requires_private="Requires.private"
 130 else
 131    pkgconfig_requires_private="Requires"
 132 fi
 133 AC_SUBST(pkgconfig_requires_private)
 134
 135 # doxygen program for documentation building
 136 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 137
 138
 139 ### Checks for libraries
 140
 141 PKG_CHECK_MODULES([EDBUS], [ecore >= 1.0.0 eina >= 1.0.0 dbus-1 >= 0.62])
 142
 143 # Find out the version of DBUS we're using
 144 dbus_version=`pkg-config --modversion dbus-1`
 145 DBUS_VERSION_MAJOR=`echo $dbus_version | awk -F. '{print $1}'`
 146 DBUS_VERSION_MINOR=`echo $dbus_version | awk -F. '{print $2}'`
 147 DBUS_VERSION_MICRO=`echo $dbus_version | awk -F. '{print $3}'`
 148
 149 if test "z$DBUS_VERSION_MAJOR" = "z" ; then
 150    DBUS_VERSION_MAJOR="0"
 151 fi
 152
 153 if test "z$DBUS_VERSION_MINOR" = "z" ; then
 154    DBUS_VERSION_MINOR="0"
 155 fi
 156
 157 if test "z$DBUS_VERSION_MICRO" = "z" ; then
 158    DBUS_VERSION_MICRO="0"
 159 fi
 160
 161 DBUS_VERSION_CFLAGS="$DBUS_VERSION_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 162 DBUS_VERSION_CFLAGS="$DBUS_VERSION_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 163 DBUS_VERSION_CFLAGS="$DBUS_VERSION_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 164 AC_SUBST(DBUS_VERSION_CFLAGS)
 165
 166 # evas
 167 if test "x${enable_enotify}" = "xyes" ; then
 168    PKG_CHECK_MODULES(EVAS,
 169       [evas >= 1.0.0],
 170       [requirement_enotify="evas >= 1.0.0 ${requirement_enotify}"],
 171       [enable_enotify="no"])
 172 fi
 173
 174 AM_CONDITIONAL([BUILD_EBLUEZ],   [test "x${enable_ebluez}"   = "xyes"])
 175 AM_CONDITIONAL([BUILD_ECONNMAN], [test "x${enable_econnman}" = "xyes"])
 176 AM_CONDITIONAL([BUILD_EHAL],     [test "x${enable_ehal}"     = "xyes"])
 177 AM_CONDITIONAL([BUILD_ENOTIFY],  [test "x${enable_enotify}"  = "xyes"])
 178 AM_CONDITIONAL([BUILD_EOFONO],   [test "x${enable_eofono}"   = "xyes"])
 179 AM_CONDITIONAL([BUILD_EUKIT],    [test "x${enable_eukit}"    = "xyes"])
 180
 181
 182 ### Checks for header files
 183
 184
 185 ### Checks for types
 186
 187
 188 ### Checks for structures
 189
 190
 191 ### Checks for compiler characteristics
 192
 193 EFL_EDBUS_BUILD=""
 194 case "$host_os" in
 195    mingw*)
 196       EFL_EDBUS_BUILD="-DEFL_EDBUS_BUILD"
 197    ;;
 198 esac
 199 AC_SUBST(EFL_EDBUS_BUILD)
 200
 201 AC_HEADER_STDC
 202 AC_C___ATTRIBUTE__
 203
 204 if ! test "x${VMIC}" = "x" ; then
 205    EFL_COMPILER_FLAG([-Wall])
 206    EFL_COMPILER_FLAG([-W])
 207 fi
 208
 209 EFL_COMPILER_FLAG([-Wshadow])
 210
 211
 212 ### Checks for linker characteristics
 213
 214 lt_enable_auto_import=""
 215 case "$host_os" in
 216    mingw*)
 217       lt_enable_auto_import="-Wl,--enable-auto-import"
 218    ;;
 219 esac
 220 AC_SUBST(lt_enable_auto_import)
 221
 222
 223 ### Checks for library functions
 224
 225 AC_FUNC_ALLOCA
 226
 227
 228 AC_SUBST(requirement_ebluez)
 229 AC_SUBST(requirement_econnman)
 230 AC_SUBST(requirement_edbus)
 231 AC_SUBST(requirement_ehal)
 232 AC_SUBST(requirement_enotify)
 233 AC_SUBST(requirement_eofono)
 234 AC_SUBST(requirement_eukit)
 235 AC_SUBST(requirement_dbus)
 236
 237 AC_OUTPUT([
 238 e_dbus.spec
 239 Makefile
 240 doc/Makefile
 241 src/Makefile
 242 src/lib/Makefile
 243 src/lib/bluez/Makefile
 244 src/lib/connman/Makefile
 245 src/lib/dbus/Makefile
 246 src/lib/hal/Makefile
 247 src/lib/notification/Makefile
 248 src/lib/ofono/Makefile
 249 src/lib/ukit/Makefile
 250 src/bin/Makefile
 251 ebluez.pc
 252 econnman.pc
 253 edbus.pc
 254 ehal.pc
 255 enotify.pc
 256 eofono.pc
 257 eukit.pc
 258 ])
 259
 260
 261 #####################################################################
 262 ## Info
 263
 264 echo
 265 echo
 266 echo
 267 echo "------------------------------------------------------------------------"
 268 echo "$PACKAGE $VERSION"
 269 echo "------------------------------------------------------------------------"
 270 echo
 271 echo "Configuration Options Summary:"
 272 echo
 273 echo "  Modules:"
 274 echo
 275 echo "    EBluez.............: $enable_ebluez"
 276 echo "    EConnman...........: $enable_econnman"
 277 echo "    EHal...............: $enable_ehal"
 278 echo "    ENotify............: $enable_enotify"
 279 echo "    EOfono.............: $enable_eofono"
 280 echo "    EUkit..............: $enable_eukit"
 281 echo
 282 echo "Documentation..........: ${build_doc}"
 283 echo
 284 echo "Compilation............: make (or gmake)"
 285 echo "  CPPFLAGS.............: $CPPFLAGS"
 286 echo "  CFLAGS...............: $CFLAGS"
 287 echo "  LDFLAGS..............: $LDFLAGS"
 288 echo
 289 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 290 echo "  prefix...............: $prefix"
 291 echo