configure.ac

   1 # clutter package version number, (as distinct from shared library version)
   2 # An odd micro number indicates in-progress development from Git
   3 # An even micro number indicates a released version
   4 #
   5 # Making a point release:
   6 # - increase clutter_micro_version to the next even number
   7 # - increase clutter_interface_age to the next even number
   8 # After the release:
   9 # - increase clutter_micro_version to the next odd number
  10 # - increase clutter_interface_version to the next odd number
  11 m4_define([clutter_major_version], [1])
  12 m4_define([clutter_minor_version], [9])
  13 m4_define([clutter_micro_version], [1])
  14
  15 # • for stable releases: increase the interface age by 1 for each release;
  16 #   if the API changes, set to 0. interface_age and binary_age are used to
  17 #   create the soname of the shared object:
  18 #
  19 #  (<minor> * 100 + <micro>) - <interface_age>
  20 #
  21 # this allows using the same soname for different micro-releases in case
  22 # no API was added or deprecated. for instance:
  23 #
  24 #   clutter 1.2.0  -> 100 * 2 + 0  = 200, interface age = 0 -> 200
  25 #   clutter 1.2.2  -> 100 * 2 + 2  = 202, interface age = 2 -> 200
  26 #   clutter 1.2.4  -> 100 * 2 + 4  = 204, interface age = 4 -> 200
  27 #   [ API addition, deprecation ]
  28 #   clutter 1.2.6  -> 100 * 2 + 6  = 206, interface age = 0 -> 206
  29 #   clutter 1.2.8  -> 100 * 2 + 8  = 208, interface age = 2 -> 206
  30 #   clutter 1.2.10 -> 100 * 2 + 10 = 210, interface age = 4 -> 206
  31 #   ...
  32 #
  33 # • for development releases: keep clutter_interface_age to 0
  34 m4_define([clutter_interface_age], [0])
  35
  36 m4_define([clutter_binary_age], [m4_eval(100 * clutter_minor_version + clutter_micro_version)])
  37
  38 m4_define([clutter_release_status],
  39           [m4_if(m4_eval(clutter_micro_version % 2), [1], [git],
  40                  [m4_if(m4_eval(clutter_minor_version % 2), [1], [snapshot],
  41                                                                  [release])])])
  42
  43 m4_define([clutter_version], [clutter_major_version.clutter_minor_version.clutter_micro_version])
  44
  45 # change this only when breaking the API
  46 m4_define([clutter_api_version], [1.0])
  47
  48 AC_PREREQ([2.63])
  49
  50 AC_INIT([clutter],
  51         [clutter_version],
  52         [http://bugzilla.gnome.org/enter_bug.cgi?product=clutter],
  53         [clutter],
  54         [http://www.clutter-project.org])
  55
  56 AC_CONFIG_SRCDIR([clutter/clutter.h])
  57 AC_CONFIG_HEADERS([config.h])
  58 AC_CONFIG_AUX_DIR([build])
  59 AC_CONFIG_MACRO_DIR([build/autotools])
  60
  61 AM_INIT_AUTOMAKE([1.11 foreign -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  62 AM_SILENT_RULES([yes])
  63
  64 AC_SUBST([CLUTTER_MAJOR_VERSION],  [clutter_major_version])
  65 AC_SUBST([CLUTTER_MINOR_VERSION],  [clutter_minor_version])
  66 AC_SUBST([CLUTTER_MICRO_VERSION],  [clutter_micro_version])
  67 AC_SUBST([CLUTTER_VERSION],        [clutter_version])
  68 AC_SUBST([CLUTTER_API_VERSION],    [clutter_api_version])
  69 AC_SUBST([CLUTTER_API_VERSION_AM], [$CLUTTER_MAJOR_VERSION\_0])
  70 AC_SUBST([CLUTTER_RELEASE_STATUS], [clutter_release_status])
  71
  72 m4_define([lt_current],  [m4_eval(100 * clutter_minor_version + clutter_micro_version - clutter_interface_age)])
  73 m4_define([lt_revision], [clutter_interface_age])
  74 m4_define([lt_age],      [m4_eval(clutter_binary_age - clutter_interface_age)])
  75 CLUTTER_LT_CURRENT=lt_current
  76 CLUTTER_LT_REV=lt_revision
  77 CLUTTER_LT_AGE=lt_age
  78 CLUTTER_LT_VERSION="$CLUTTER_LT_CURRENT:$CLUTTER_LT_REV:$CLUTTER_LT_AGE"
  79 CLUTTER_LT_LDFLAGS="-version-info $CLUTTER_LT_VERSION"
  80 AC_SUBST([CLUTTER_LT_CURRENT],  [lt_current])
  81 AC_SUBST([CLUTTER_LT_REVISION], [lt_revision])
  82 AC_SUBST([CLUTTER_LT_VERSION],  [$CLUTTER_LT_VERSION])
  83
  84 AC_PROG_SED
  85
  86 AC_CANONICAL_HOST
  87
  88 platform_win32=no
  89 platform_quartz=no
  90 platform_linux=no
  91
  92 AC_MSG_CHECKING([if building for some Win32 platform])
  93 AS_CASE([$host],
  94         [*-*-mingw*|*-*-cygwin*],
  95         [
  96           CLUTTER_LT_LDFLAGS="$CLUTTER_LT_LDFLAGS -no-undefined"
  97           platform_win32=yes
  98         ],
  99
 100         []
 101 )
 102 AC_MSG_RESULT([$platform_win32])
 103
 104 AM_CONDITIONAL(OS_WIN32, [test "$platform_win32" = "yes"])
 105
 106 AC_CHECK_HEADER([OpenGL/gl.h], [platform_quartz=yes], [platform_quartz=no])
 107 AM_CONDITIONAL(OS_QUARTZ, [test "$platform_quartz" = "yes"])
 108
 109 AC_CHECK_HEADER([GL/glx.h], [platform_glx=yes], [platform_glx=no])
 110 AC_CHECK_LIB([GL], [glXCreateContext], [platform_glx=yes], [platform_glx=no])
 111 AM_CONDITIONAL(OS_GLX, [test "$platform_glx" = "yes"])
 112
 113 AC_SUBST(CLUTTER_LT_LDFLAGS)
 114
 115 dnl ========================================================================
 116
 117 # Checks for programs.
 118 AM_PROG_CC_C_O
 119
 120 # require libtool >= 2.2
 121 LT_PREREQ([2.2.6])
 122 LT_INIT([disable-static])
 123
 124 # Checks for header files.
 125 AC_HEADER_STDC
 126
 127 # required versions for dependencies
 128 m4_define([glib_req_version],           [2.31.0])
 129 m4_define([cogl_req_version],           [1.9.1])
 130 m4_define([json_glib_req_version],      [0.12.0])
 131 m4_define([atk_req_version],            [2.1.5])
 132 m4_define([cairo_req_version],          [1.10])
 133 m4_define([pango_req_version],          [1.20])
 134 m4_define([gi_req_version],             [0.9.5])
 135 m4_define([uprof_req_version],          [0.3])
 136 m4_define([gtk_doc_req_version],        [1.15])
 137 m4_define([xfixes_req_version],         [3])
 138 m4_define([xcomposite_req_version],     [0.4])
 139 m4_define([gdk_req_version],            [3.0.0])
 140
 141 AC_SUBST([GLIB_REQ_VERSION],       [glib_req_version])
 142 AC_SUBST([COGL_REQ_VERSION],       [cogl_req_version])
 143 AC_SUBST([JSON_GLIB_REQ_VERSION],  [json_glib_req_version])
 144 AC_SUBST([ATK_REQ_VERSION],        [atk_req_version])
 145 AC_SUBST([CAIRO_REQ_VERSION],      [cairo_req_version])
 146 AC_SUBST([PANGO_REQ_VERSION],      [pango_req_version])
 147 AC_SUBST([GI_REQ_VERSION],         [gi_req_version])
 148 AC_SUBST([UPROF_REQ_VERSION],      [uprof_req_version])
 149 AC_SUBST([GTK_DOC_REQ_VERSION],    [gtk_doc_req_version])
 150 AC_SUBST([XFIXES_REQ_VERSION],     [xfixes_req_version])
 151 AC_SUBST([XCOMPOSITE_REQ_VERSION], [xcomposite_req_version])
 152 AC_SUBST([GDK_REQ_VERSION],        [gdk_req_version])
 153
 154 # Checks for typedefs, structures, and compiler characteristics.
 155 AM_PATH_GLIB_2_0([glib_req_version],
 156                  [],
 157                  [AC_MSG_ERROR([glib-2.0 is required])],
 158                  [gobject gthread gmodule-no-export])
 159
 160 # Check for -Bsymbolic-functions to avoid intra-library PLT jumps
 161 AC_ARG_ENABLE([Bsymbolic],
 162               [AS_HELP_STRING([--disable-Bsymbolic],
 163                               [Avoid linking with -Bsymbolic])],
 164               [],
 165               [
 166                 saved_LDFLAGS="${LDFLAGS}"
 167                 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 168                 LDFLAGS=-Wl,-Bsymbolic-functions
 169                 AC_TRY_LINK([], [int main (void) { return 0; }],
 170                             [
 171                               AC_MSG_RESULT([yes])
 172                               enable_Bsymbolic=yes
 173                             ],
 174                             [
 175                               AC_MSG_RESULT([no])
 176                               enable_Bsymbolic=no
 177                             ])
 178                 LDFLAGS="${saved_LDFLAGS}"
 179               ])
 180
 181 AS_IF([test "x$enable_Bsymbolic" = "xyes"], [CLUTTER_LINK_FLAGS=-Wl[,]-Bsymbolic-functions])
 182 AC_SUBST(CLUTTER_LINK_FLAGS)
 183
 184 dnl ========================================================================
 185
 186 FLAVOUR_LIBS=""
 187 FLAVOUR_CFLAGS=""
 188 CLUTTER_BACKENDS=""
 189
 190 experimental_backend=no
 191
 192 # base dependencies for core
 193 CLUTTER_BASE_PC_FILES="cogl-1.0 >= $COGL_REQ_VERSION cairo-gobject >= $CAIRO_REQ_VERSION atk >= $ATK_REQ_VERSION pangocairo >= $PANGO_REQ_VERSION cogl-pango-1.0 json-glib-1.0 >= $JSON_GLIB_REQ_VERSION"
 194
 195 # backend specific pkg-config files
 196 BACKEND_PC_FILES=""
 197
 198 dnl === Clutter windowing system backend ======================================
 199
 200 AC_ARG_ENABLE([x11-backend],
 201               [AS_HELP_STRING([--enable-x11-backend=@<:@yes/no@:>@], [Enable the X11 backend (default=check)])],
 202               [enable_x11=$enableval],
 203               [enable_x11=check])
 204 AC_ARG_ENABLE([win32-backend],
 205               [AS_HELP_STRING([--enable-win32-backend=@<:@yes/no@:>@], [Enable the Windows backend (default=check)])],
 206               [enable_win32=$enableval],
 207               [enable_win32=check])
 208 AC_ARG_ENABLE([quartz-backend],
 209               [AS_HELP_STRING([--enable-quartz-backend=@<:@yes/no@:>@], [Enable the OS X backend (default=check)])],
 210               [enable_osx=$enableval],
 211               [enable_osx=check])
 212 AC_ARG_ENABLE([gdk-backend],
 213               [AS_HELP_STRING([--enable-gdk-backend=@<:@yes/no@:>@], [Enable the GDK backend (default=check)])],
 214               [enable_gdk=$enableval],
 215               [enable_gdk=check])
 216 AC_ARG_ENABLE([wayland-backend],
 217               [AS_HELP_STRING([--enable-wayland-backend=@<:@yes/no@:>@], [Enable the Wayland client backend (default=no)])],
 218               [enable_wayland=$enableval],
 219               [enable_wayland=no])
 220 AC_ARG_ENABLE([egl-backend],
 221               [AS_HELP_STRING([--enable-egl-backend=@<:@yes/no@:>@], [Enable the EGL framebuffer backend (default=no)])],
 222               [enable_egl=$enableval],
 223               [enable_egl=no])
 224
 225 dnl Define default values
 226 AS_IF([test "x$enable_x11" = "xcheck"],
 227       [
 228         AS_IF([test "x$platform_glx" = "xyes"], [enable_x11=yes], [enable_x11=no])
 229       ])
 230
 231 AS_IF([test "x$enable_win32" = "xcheck"],
 232       [
 233         AS_IF([test "x$platform_win32" = "xyes"], [enable_win32=yes], [enable_win32=no])
 234       ])
 235
 236 AS_IF([test "x$enable_osx" = "xcheck"],
 237       [
 238         AS_IF([test "x$platform_quartz" = "xyes"], [enable_osx=yes], [enable_osx=no])
 239       ])
 240
 241 AS_IF([test "x$enable_gdk" = "xcheck"],
 242       [
 243         PKG_CHECK_EXISTS([gdk-3.0 >= gdk_req_version], [enable_gdk=yes], [enable_gdk=no])
 244       ])
 245
 246 dnl Per-backend rules
 247 AS_IF([test "x$enable_x11" = "xyes"],
 248       [
 249         CLUTTER_BACKENDS="$CLUTTER_BACKENDS x11"
 250
 251         SUPPORT_X11=1
 252         SUPPORT_GLX=1
 253         SUPPORT_COGL=1
 254
 255         # Mesa 7.3 added a GL pkg-config file, finally, but if a pkg-config
 256         # file isn't found just add -lGL and hope for the best.
 257         PKG_CHECK_EXISTS([gl],
 258                          [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"],
 259                          [FLAVOUR_LIBS="$FLAVOUR_LIBS -lGL"])
 260
 261         # We might fall back to DRM for sync-to-vblank on GLX
 262         PKG_CHECK_EXISTS([libdrm],
 263                          [
 264                            AC_DEFINE([HAVE_DRM], [1], [Have libdrm support])
 265                            BACKEND_PC_FILES="$BACKEND_PC_FILES libdrm"
 266                          ],
 267                          [])
 268
 269         # we use fontconfig API and pango-fc when the fontconfig
 270         # configuration changes
 271         PKG_CHECK_EXISTS([pangoft2],
 272                          [
 273                            AC_DEFINE([HAVE_PANGO_FT2], [1], [Supports PangoFt2])
 274                            BACKEND_PC_FILES="$BACKEND_PC_FILES pangoft2"
 275                          ],
 276                          [])
 277
 278         AC_DEFINE([HAVE_CLUTTER_GLX], [1], [Have the GLX backend])
 279       ])
 280
 281 AS_IF([test "x$enable_gdk" = "xyes"],
 282       [
 283         CLUTTER_BACKENDS="$CLUTTER_BACKENDS gdk"
 284
 285         SUPPORT_GDK=1
 286         SUPPORT_COGL=1
 287
 288         BACKEND_PC_FILES="$BACKEND_PC_FILES gdk-3.0"
 289         PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 290       ])
 291
 292 AS_IF([test "x$enable_wayland" = "xyes"],
 293       [
 294         CLUTTER_BACKENDS="$CLUTTER_BACKENDS wayland"
 295
 296         experimental_backend="yes"
 297
 298         SUPPORT_WAYLAND=1
 299         SUPPORT_EVDEV=1
 300
 301         PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 302         PKG_CHECK_EXISTS([egl], [BACKEND_PC_FILES="$BACKEND_PC_FILES egl"], [])
 303         PKG_CHECK_EXISTS([wayland-client xkbcommon],
 304                          [BACKEND_PC_FILES="$BACKEND_PC_FILES wayland-client xkbcommon"],
 305                          [])
 306
 307         AC_DEFINE([HAVE_CLUTTER_WAYLAND], [1], [Have the Wayland backend])
 308       ])
 309
 310 AS_IF([test "x$enable_egl" = "xyes"],
 311       [
 312         CLUTTER_BACKENDS="$CLUTTER_BACKENDS egl"
 313
 314         SUPPORT_EGL=1
 315         SUPPORT_COGL=1
 316
 317         # if Mesa has support for egl, we can use it as well
 318         PKG_CHECK_EXISTS([egl],
 319                          [
 320                            BACKEND_PC_FILES="$BACKEND_PC_FILES egl"
 321                          ],
 322                          [])
 323
 324         AC_ARG_WITH([tslib],
 325                     [AS_HELP_STRING([--with-tslib=@<:@yes/no@:>@], [Use TSLib for events (default=no)])],
 326                     [],
 327                     [with_tslib=no])
 328
 329         AC_ARG_WITH([evdev],
 330                     [AS_HELP_STRING([--with-evdev=@<:@yes/no@:>@], [Use evdev for events (default=yes)])],
 331                     [],
 332                     [with_evdev=yes])
 333
 334         AC_ARG_WITH([gdl],
 335                     [AS_HELP_STRING([--with-gdl=@<:@yes/no@:>@], [Use libgdl for CE3100/CE4100 support (default=no)])],
 336                     [],
 337                     [with_gdl=no])
 338
 339         AS_IF([test "x$with_tslib" = "xyes"],
 340               [
 341                 PKG_CHECK_MODULES(TSLIB, [tslib-1.0], [have_tslib=yes], [have_tslib=no])
 342                 AS_IF([test "x$have_tslib" = "xyes"],
 343                       [
 344                         AC_DEFINE([HAVE_TSLIB], [1], [Have tslib for touchscreen handling])
 345                         SUPPORT_TSLIB=1
 346                       ])
 347               ],
 348               [have_tslib=no])
 349
 350         AS_IF([test "x$with_evdev" = "xyes"],
 351               [
 352                 PKG_CHECK_MODULES(EVDEV, [gudev-1.0 xkbcommon], [have_evdev=yes], [have_evdev=no])
 353                 AS_IF([test "x$have_evdev" = "xyes"],
 354                       [
 355                         AC_DEFINE([HAVE_EVDEV], [1], [Have evdev support for input handling])
 356                         SUPPORT_EVDEV=1
 357                       ])
 358               ],
 359               [have_evdev=no])
 360
 361         AS_IF([test "x$with_gdl" = "xyes"],
 362               [
 363                 have_gdl=no
 364
 365                 AC_CHECK_HEADERS([libgdl.h], [have_gdl=yes])
 366
 367                 AS_IF([test "x$have_gdl" = "xno"],
 368                       [
 369                         AC_CHECK_HEADERS([CE4100/libgdl.h],
 370                                          [
 371                                            FLAVOUR_CFLAGS="-I/usr/include/CE4100"
 372                                            have_gdl=yes
 373                                            CLUTTER_CEX100_LIBGDL_PREFIX=CE4100/
 374                                          ])
 375                       ])
 376
 377                 AC_SUBST(CLUTTER_CEX100_LIBGDL_PREFIX)
 378
 379                 AS_IF([test "x$have_gdl" = "xno"], [AC_MSG_ERROR([libgdl.h not found])])
 380
 381                 FLAVOUR_LIBS="$FLAVOUR_LIBS -lgdl"
 382
 383                 SUPPORT_EGL_PLATFORM_GDL=1
 384
 385                 AC_DEFINE([CLUTTER_EGL_BACKEND_CEX100], [1], [Use CEX100 EGL backend])
 386               ],
 387               [have_gdl=no])
 388
 389         FLAVOUR_LIBS="$FLAVOUR_LIBS $TSLIB_LIBS $EVDEV_LIBS"
 390         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $TSLIB_CFLAGS $EVDEV_CFLAGS"
 391
 392         AC_DEFINE([CLUTTER_EGL_BACKEND_GENERIC], [1], [Use Generic EGL backend])
 393
 394         AC_DEFINE([HAVE_CLUTTER_EGL], [1], [Have the EGL backend])
 395       ])
 396
 397 AS_IF([test "x$enable_osx" = "xyes"],
 398       [
 399         CLUTTER_BACKENDS="$CLUTTER_BACKENDS osx"
 400
 401         AC_DEFINE([HAVE_CLUTTER_OSX], [1], [Have the OSX backend])
 402
 403         FLAVOUR_LIBS="$FLAVOUR_LIBS -framework Cocoa -framework OpenGL"
 404
 405         SUPPORT_OSX=1
 406       ])
 407
 408 AS_IF([test "x$enable_win32" = "xyes"],
 409       [
 410         CLUTTER_BACKENDS="$CLUTTER_BACKENDS win32"
 411
 412         AC_DEFINE([HAVE_CLUTTER_WIN32], [1], [Have the Win32 backend])
 413
 414         FLAVOUR_LIBS="$FLAVOUR_LIBS -lopengl32 -lgdi32 -lwinmm"
 415         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS -D_WIN32_WINNT=0x0500"
 416
 417         AC_CHECK_TOOL(WINDRES, [windres], [AC_MSG_ERROR([*** windres is required])])
 418
 419         SUPPORT_WIN32=1
 420       ])
 421
 422 AS_IF([test "x$CLUTTER_BACKENDS" = "x"],
 423       [
 424         AC_MSG_ERROR([No backend enabled. You need to enable at least one backend.])
 425       ])
 426
 427 # conditionals for use in automake files...
 428 AM_CONDITIONAL(SUPPORT_GLX,     [test "x$SUPPORT_GLX" = "x1"])
 429 AM_CONDITIONAL(SUPPORT_X11,     [test "x$SUPPORT_X11" = "x1"])
 430 AM_CONDITIONAL(SUPPORT_GDK,     [test "x$SUPPORT_GDK" = "x1"])
 431 AM_CONDITIONAL(SUPPORT_EGL,     [test "x$SUPPORT_EGL" = "x1"])
 432 AM_CONDITIONAL(SUPPORT_OSX,     [test "x$SUPPORT_OSX" = "x1"])
 433 AM_CONDITIONAL(SUPPORT_WIN32,   [test "x$SUPPORT_WIN32" = "x1"])
 434 AM_CONDITIONAL(SUPPORT_CEX100,  [test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"])
 435 AM_CONDITIONAL(SUPPORT_WAYLAND, [test "x$SUPPORT_WAYLAND" = "x1"])
 436 AM_CONDITIONAL(SUPPORT_STUB,    [test "x$SUPPORT_WIN32" = "x1" -o \
 437                                       "x$SUPPORT_OSX" = "x1" -o \
 438                                       "x$SUPPORT_WAYLAND" = "x1"])
 439
 440 AM_CONDITIONAL(USE_COGL,  [test "x$SUPPORT_COGL" = "x1"])
 441 AM_CONDITIONAL(USE_TSLIB, [test "x$have_tslib" = "xyes"])
 442 AM_CONDITIONAL(USE_EVDEV, [test "x$have_evdev" = "xyes"])
 443 AM_CONDITIONAL(USE_GLD,   [test "x$have_gdl" = "xyes"])
 444
 445 dnl Instead of using AM_CFLAGS to ensure
 446 dnl COGL_ENABLE_EXPERIMENTAL_2_0_API is defined while compiling clutter
 447 dnl and cogl code we use a define in config.h instead. This helps ensure
 448 dnl other tools such as glib-mkenums and gir-scanner don't end up
 449 dnl using the define also.
 450 AC_DEFINE([COGL_ENABLE_EXPERIMENTAL_2_0_API], [1], [Can use Cogl 2.0 API internally])
 451
 452 dnl strip leading spaces
 453 CLUTTER_BACKENDS=${CLUTTER_BACKENDS#* }
 454 AC_SUBST(CLUTTER_BACKENDS)
 455
 456 dnl === Clutter configuration =================================================
 457
 458 CLUTTER_CONFIG_DEFINES=
 459
 460 # windowing systems
 461 AS_IF([test "x$SUPPORT_X11" = "x1"],
 462       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 463 #define CLUTTER_WINDOWING_X11 \"x11\""])
 464 AS_IF([test "x$SUPPORT_GDK" = "x1"],
 465       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 466 #define CLUTTER_WINDOWING_GDK \"gdk\""])
 467 AS_IF([test "x$SUPPORT_GLX" = "x1"],
 468       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 469 #define CLUTTER_WINDOWING_GLX \"glx\""])
 470 AS_IF([test "x$SUPPORT_EGL" = "x1"],
 471       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 472 #define CLUTTER_WINDOWING_EGL \"eglnative\""])
 473 AS_IF([test "x$SUPPORT_WAYLAND" = "x1"],
 474       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 475 #define CLUTTER_WINDOWING_WAYLAND \"wayland\""])
 476 AS_IF([test "x$SUPPORT_OSX" = "x1"],
 477       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 478 #define CLUTTER_WINDOWING_OSX \"osx\""])
 479 AS_IF([test "x$SUPPORT_WIN32" = "x1"],
 480       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 481 #define CLUTTER_WINDOWING_WIN32 \"win32\""])
 482 AS_IF([test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"],
 483       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 484 #define CLUTTER_WINDOWING_CEX100 \"cex100\""])
 485 AS_IF([test "x$SUPPORT_EVDEV" = "x1"],
 486       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 487 #define CLUTTER_INPUT_EVDEV \"evdev\""])
 488 AS_IF([test "x$SUPPORT_TSLIB" = "x1"],
 489       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 490 #define CLUTTER_INPUT_TSLIB \"tslib\""])
 491
 492 AC_SUBST([CLUTTER_CONFIG_DEFINES])
 493
 494 dnl === Clutter substitutions kept for backwards compatibility ================
 495 AC_SUBST([CLUTTER_WINSYS],       [deprecated])
 496 AC_SUBST([CLUTTER_WINSYS_BASE],  [deprecated])
 497 AC_SUBST([CLUTTER_STAGE_TYPE],   [deprecated])
 498 AC_SUBST([CLUTTER_SONAME_INFIX], [deprecated])
 499 AC_SUBST([CLUTTER_FLAVOUR],      [deprecated])
 500 AC_SUBST([CLUTTER_COGL],         [deprecated])
 501 AC_SUBST([COGL_DRIVER],          [deprecated])
 502
 503 dnl === Image loading backend =================================================
 504 IMAGE_PC_FILES=""
 505
 506 dnl === X11 checks, only for X11-based backends ===============================
 507 X11_PC_FILES=""
 508 x11_tests=no
 509
 510 AS_IF([test "x$SUPPORT_X11" = "x1"],
 511       [
 512         # base X11 includes and libraries
 513         AC_MSG_CHECKING([for X11])
 514
 515         # start with pkg-config
 516         PKG_CHECK_EXISTS([x11], [have_x11=yes], [have_x11=no])
 517         AS_IF([test "x$have_x11" = "xyes"],
 518               [
 519                 X11_PC_FILES="x11"
 520
 521                 # we actually need to ask for CFLAGS and LIBS
 522                 X11_CFLAGS=`$PKG_CONFIG --cflags $X11_PC_FILES`
 523                 X11_LIBS=`$PKG_CONFIG --libs $X11_PC_FILES`
 524
 525                 AC_MSG_RESULT([found])
 526               ],
 527               [
 528                 # no pkg-config, let's go old school
 529                 AC_PATH_X
 530
 531                 AS_IF([test "x$no_x" = "xyes"],
 532                       [AC_MSG_ERROR([No X11 Libraries found])],
 533                       [
 534                         AS_IF([test "x$x_includes" != "xNONE" && test -n "$x_includes"],
 535                               [X11_CFLAGS=-I`echo $x_includes | sed -e "s/:/ -I/g"`])
 536
 537                         AS_IF([test "x$x_libraries" != "xNONE" && test -n "$x_libraries"],
 538                               [X11_LIBS=-L`echo $x_libraries | sed -e "s/:/ -L/g"`])
 539
 540                         AC_MSG_RESULT([found])
 541                       ]
 542                 )
 543               ]
 544         )
 545
 546         # XEXT (required)
 547         AC_MSG_CHECKING([for XEXT extension])
 548         PKG_CHECK_EXISTS([xext], [have_xext=yes], [have_xext=no])
 549         AS_IF([test "x$have_xext" = "xyes"],
 550               [
 551                 AC_DEFINE(HAVE_XEXT, [1], [Define to 1 if we have the XEXT X extension])
 552
 553                 X11_LIBS="$X11_LIBS -lXext"
 554                 X11_PC_FILES="$X11_PC_FILES xext"
 555
 556                 AC_MSG_RESULT([found])
 557               ],
 558               [AC_MSG_ERROR([Not found])]
 559         )
 560
 561         # XFIXES (required)
 562         AC_MSG_CHECKING([for XFIXES extension >= $XFIXES_REQ_VERSION])
 563         PKG_CHECK_EXISTS([xfixes >= $XFIXES_REQ_VERSION], [have_xfixes=yes], [have_xfixes=no])
 564         AS_IF([test "x$have_xfixes" = "xyes"],
 565               [
 566                 AC_DEFINE(HAVE_XFIXES, [1], [Define to 1 if we have the XFIXES X extension])
 567
 568                 X11_LIBS="$X11_LIBS -lXfixes"
 569                 X11_PC_FILES="$X11_PC_FILES xfixes >= $XFIXES_REQ_VERSION"
 570
 571                 AC_MSG_RESULT([found])
 572               ],
 573               [AC_MSG_ERROR([Not found])]
 574         )
 575
 576         # XDAMAGE (required)
 577         AC_MSG_CHECKING([for XDAMAGE extension])
 578         PKG_CHECK_EXISTS([xdamage], [have_xdamage=yes], [have_xdamage=no])
 579         AS_IF([test "x$have_xdamage" = "xyes"],
 580               [
 581                 AC_DEFINE(HAVE_XDAMAGE, [1], [Define to 1 if we have the XDAMAGE X extension])
 582
 583                 X11_LIBS="$X11_LIBS -lXdamage"
 584                 X11_PC_FILES="$X11_PC_FILES xdamage"
 585
 586                 AC_MSG_RESULT([found])
 587               ],
 588               [AC_MSG_ERROR([not found])]
 589         )
 590
 591         # XCOMPOSITE (optional)
 592         AC_MSG_CHECKING([for XCOMPOSITE extension >= $XCOMPOSITE_REQ_VERSION])
 593         PKG_CHECK_EXISTS([xcomposite >= $XCOMPOSITE_REQ_VERSION], [have_xcomposite=yes], [have_xcomposite=no])
 594         AS_IF([test "x$have_xcomposite" = "xyes"],
 595               [
 596                 AC_DEFINE(HAVE_XCOMPOSITE, [1], [Define to 1 if we have the XCOMPOSITE X extension])
 597
 598                 X11_LIBS="$X11_LIBS -lXcomposite"
 599                 X11_PC_FILES="$X11_PC_FILES xcomposite >= $XCOMPOSITE_REQ_VERSION"
 600
 601                 AC_MSG_RESULT([found])
 602               ],
 603               [AC_MSG_ERROR([not found])]
 604         )
 605
 606         # X Generic Extensions (optional)
 607         clutter_save_CPPFLAGS="$CPPFLAGS"
 608         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 609
 610         clutter_save_LIBS="$LIBS"
 611         LIBS="$LIBS $X11_LIBS"
 612
 613         have_xge=no
 614         AC_CHECK_FUNC([XGetEventData],
 615                       [
 616                         AC_DEFINE([HAVE_XGE], [1], [Define to 1 if X Generic Extensions is available])
 617                         have_xge=yes
 618                       ])
 619
 620         CPPFLAGS="$clutter_save_CPPFLAGS"
 621         LIBS="$clutter_save_LIBS"
 622
 623         # XI (optional)
 624         AC_ARG_ENABLE([xinput],
 625                       [AS_HELP_STRING([--enable-xinput], [Use the XI X extension])],
 626                       [],
 627                       [enable_xinput=yes])
 628
 629         AS_IF([test "x$enable_xinput" = "xyes"],
 630               [
 631                 PKG_CHECK_EXISTS([xi], [have_xinput=yes], [have_xinput=no])
 632               ],
 633               [
 634                 have_xinput=no
 635               ])
 636
 637         AS_CASE([$have_xinput],
 638
 639                 [yes],
 640                 [
 641                   AC_CHECK_HEADERS([X11/extensions/XInput2.h],
 642                                    [
 643                                      have_xinput2=yes
 644                                      AC_DEFINE([HAVE_XINPUT_2],
 645                                                [1],
 646                                                [Define to 1 if XI2 is available])
 647                                    ],
 648                                    [
 649                                      have_xinput2=no
 650                                      AC_DEFINE([HAVE_XINPUT],
 651                                                [1],
 652                                                [Define to 1 if XInput is available])
 653                                    ])
 654
 655                   X11_LIBS="$X11_LIBS $XINPUT_LIBS"
 656                   X11_PC_FILES="$X11_PC_FILES xi"
 657                 ],
 658
 659                 [no],
 660                 [have_xinput2=no],
 661
 662                 [*],
 663                 [AC_MSG_ERROR([Invalid argument for --enable-xinput])]
 664         )
 665
 666         # XKB
 667         clutter_save_CPPFLAGS="$CPPFLAGS"
 668         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 669
 670         clutter_save_LIBS="$LIBS"
 671         LIBS="$LIBS $X11_LIBS"
 672
 673         have_xkb=no
 674         AC_CHECK_FUNC([XkbQueryExtension],
 675                       [
 676                         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
 677                         have_xkb=yes
 678                       ])
 679
 680         CPPFLAGS="$clutter_save_CPPFLAGS"
 681         LIBS="$clutter_save_LIBS"
 682
 683         x11_tests=yes
 684         BACKEND_PC_FILES="$BACKEND_PC_FILES $X11_PC_FILES"
 685         FLAVOUR_LIBS="$FLAVOUR_LIBS $X11_LIBS"
 686         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $X11_CFLAGS"
 687       ]
 688 )
 689
 690 AM_CONDITIONAL([BUILD_XI2], [test "x$have_xinput2" = "xyes"])
 691 AM_CONDITIONAL([X11_TESTS], [test "x$x11_tests" = "xyes"])
 692
 693 dnl === Enable debug level ====================================================
 694
 695 m4_define([debug_default], [m4_if(m4_eval(clutter_minor_version % 2), [1], [yes], [minimum])])
 696 AC_ARG_ENABLE([debug],
 697               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 698                               [Control Clutter debugging level @<:@default=]debug_default[@:>@])],
 699               [],
 700               [enable_debug=debug_default])
 701
 702 AS_CASE([$enable_debug],
 703
 704         [yes],
 705         [
 706           test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 707           CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG"
 708         ],
 709
 710         [minimum],
 711         [CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"],
 712
 713         [no],
 714         [CLUTTER_DEBUG_CFLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"],
 715
 716         [AC_MSG_ERROR([Unknown argument for --enable-debug])]
 717 )
 718
 719 AC_SUBST(CLUTTER_DEBUG_CFLAGS)
 720
 721 dnl === Enable deprecation guards ==================================================
 722
 723 m4_define([deprecated_default],
 724           [m4_if(m4_eval(clutter_minor_version % 2),
 725                  [1],
 726                  [no],
 727                  [yes])])
 728
 729 AC_ARG_ENABLE([deprecated],
 730               [AS_HELP_STRING([--enable-deprecated=@<:@no/yes@:>@],
 731                               [Whether deprecated symbols should be disabled when compiling Clutter @<:@default=]deprecated_default[@:>@])],
 732               [],
 733               [enable_deprecated=deprecated_default])
 734
 735 AS_CASE([$enable_deprecated],
 736
 737         [no],
 738         [
 739           CLUTTER_DEPRECATED_CFLAGS="-DG_DISABLE_SINGLE_INCLUDES -DCOGL_DISABLE_DEPRECATED -DCLUTTER_DISABLE_DEPRECATED"
 740         ],
 741
 742         [yes],
 743         [
 744           CLUTTER_DEPRECATED_CFLAGS="-DGLIB_DISABLE_DEPRECATION_WARNINGS -DCLUTTER_DISABLE_DEPRECATION_WARNINGS"
 745         ],
 746
 747         [AC_MSG_ERROR([Unknown argument for --enable-deprecated])]
 748 )
 749
 750 AC_SUBST([CLUTTER_DEPRECATED_CFLAGS])
 751
 752
 753 dnl === Conformance test suite ================================================
 754
 755 AC_ARG_ENABLE([conformance],
 756               [AS_HELP_STRING([--enable-conformance=@<:@no/yes@:>@],
 757                               [Build conformance test suite @<:@default=yes@:>@])],
 758               [],
 759               [enable_conformance=yes])
 760
 761 AM_CONDITIONAL([BUILD_TESTS], [test "x$enable_conformance" = "xyes"])
 762
 763 dnl === Profiling =============================================================
 764
 765 m4_define([profile_default], [no])
 766 AC_ARG_ENABLE(profile,
 767               AS_HELP_STRING([--enable-profile=@<:@no/yes@:>@],
 768                              [Turn on profiling support. yes; All profiling probe points are compiled in and may be runtime enabled. no; No profiling support will built into clutter.  @<:@default=no@:>@]),
 769               [],
 770               [enable_profile=profile_default])
 771
 772 AS_CASE([$enable_profile],
 773
 774         [yes],
 775         [
 776           AS_IF([test "x$GCC" = "xyes"],
 777                 [
 778                   PKG_CHECK_MODULES([PROFILE_DEP], [uprof-0.3])
 779                   CLUTTER_PROFILE_CFLAGS="-DCLUTTER_ENABLE_PROFILE $PROFILE_DEP_CFLAGS"
 780                   CLUTTER_PROFILE_LDFLAGS="$PROFILE_DEP_LIBS"
 781
 782                   AS_IF([test "x$enable_debug" = "xyes"], [CLUTTER_PROFILE_CFLAGS+=" -DUPROF_DEBUG"])
 783                 ],
 784                 [
 785                   AC_MSG_ERROR([--enable-profile is currently only supported if using GCC])
 786                 ])
 787         ],
 788
 789         [no],
 790         [
 791           CLUTTER_PROFILE_CFLAGS=""
 792           CLUTTER_PROFILE_LDFLAGS=""
 793         ],
 794
 795         [*], [AC_MSG_ERROR([Invalid value for --enable-profile])]
 796 )
 797 AM_CONDITIONAL(PROFILE, test "x$enable_profile" != "xno")
 798 AC_SUBST(CLUTTER_PROFILE_CFLAGS)
 799 AC_SUBST(CLUTTER_PROFILE_LDFLAGS)
 800
 801 dnl === Coverage report =======================================================
 802
 803 AC_PATH_PROG([GCOV], [gcov], [enable_gcov=no])
 804
 805 AC_MSG_CHECKING([whether to build with gcov testing])
 806
 807 AC_ARG_ENABLE([gcov],
 808               [AS_HELP_STRING([--enable-gcov],
 809                               [Whether to enable coverage testing (requires gcc
 810 and gcov)])],
 811               [],
 812               [enable_gcov=no])
 813
 814 AS_IF([test "x$enable_gcov" = "xyes" && test "x$GCC" = "xyes"],
 815       [
 816         AS_IF([test "x$enable_conformance" = "xno"],
 817               [AC_MSG_WARN([Conformance test suite is disabled, the coverage report will be incomplete])],
 818               [AC_MSG_RESULT([yes])]
 819         )
 820
 821         GCOV_CFLAGS="-g -O0 -fprofile-arcs -ftest-coverage"
 822         GCOV_LDFLAGS="-lgcov"
 823       ],
 824       [AC_MSG_RESULT([no])]
 825 )
 826
 827 AM_CONDITIONAL([GCOV_ENABLED], [test "x$enable_gcov" = "xyes"])
 828 AC_SUBST([GCOV_CFLAGS])
 829 AC_SUBST([GCOV_LDFLAGS])
 830
 831 dnl === Enable strict compiler flags ==========================================
 832
 833 # use strict compiler flags only when building from git; the rules for
 834 # distcheck will take care of turning this on when making a release
 835 m4_define([maintainer_flags_default], [m4_if(m4_eval(clutter_micro_version % 2), [1], [yes], [no])])
 836 AC_ARG_ENABLE([maintainer-flags],
 837               [AS_HELP_STRING([--enable-maintainer-flags=@<:@no/yes/error@:>@],
 838                               [Use strict compiler flags @<:@default=]maintainer_flags_default[@:>@])],
 839               [],
 840               [enable_maintainer_flags=maintainer_flags_default])
 841
 842 MAINTAINER_COMPILER_FLAGS="-Wall -Wshadow -Wcast-align -Wuninitialized
 843                            -Wno-strict-aliasing -Wempty-body -Wformat
 844                            -Wformat-security -Winit-self
 845                            -Wdeclaration-after-statement -Wvla
 846                            -Wpointer-arith"
 847
 848 AS_CASE([$enable_maintainer_flags],
 849         [yes],
 850         [
 851           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 852         ],
 853
 854         [no],
 855         [
 856         ],
 857
 858         [error],
 859         [
 860           MAINTAINER_COMPILER_FLAGS="$MAINTAINER_COMPILER_FLAGS -Werror"
 861           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 862         ],
 863
 864         [*],
 865         [AC_MSG_ERROR([Invalid option for --enable-maintainer-flags])]
 866 )
 867
 868 # strip leading spaces
 869 MAINTAINER_CFLAGS=${MAINTAINER_CFLAGS#*  }
 870 AC_SUBST(MAINTAINER_CFLAGS)
 871
 872 dnl === Dependencies, compiler flags and linker libraries =====================
 873 # strip leading space
 874 BACKEND_PC_FILES=${BACKEND_PC_FILES#* }
 875
 876 CLUTTER_REQUIRES="$CLUTTER_BASE_PC_FILES $IMAGE_PC_FILES $BACKEND_PC_FILES"
 877 PKG_CHECK_MODULES(CLUTTER_DEPS, [$CLUTTER_REQUIRES])
 878 AC_SUBST(CLUTTER_REQUIRES)
 879
 880 CLUTTER_CFLAGS="$FLAVOUR_CFLAGS $CLUTTER_DEPS_CFLAGS $CLUTTER_PROFILE_CFLAGS $GLIB_CFLAGS"
 881 CLUTTER_LIBS="$FLAVOUR_LIBS $CLUTTER_DEPS_LIBS $CLUTTER_PROFILE_LDFLAGS $GLIB_LIBS"
 882 AC_SUBST(CLUTTER_CFLAGS)
 883 AC_SUBST(CLUTTER_LIBS)
 884
 885
 886 dnl === GObject-Introspection check ===========================================
 887
 888 GOBJECT_INTROSPECTION_CHECK([gi_req_version])
 889
 890 dnl === GTK Doc check =========================================================
 891
 892 GTK_DOC_CHECK([gtk_doc_req_version], [--flavour no-tmpl])
 893
 894 # we don't want to build the documentation from a Git clone unless we
 895 # explicitly tell configure to do so; this allows avoiding to recurse into
 896 # the documentation directory when building Clutter inside Poky for a
 897 # target device that doesn't have gtk-doc installed. for reference
 898 # see: http://bugzilla.openedhand.com/show_bug.cgi?id=1047
 899 #
 900 # we use autogen.sh as it exists only inside the Git clones, and it
 901 # is not packaged into tarballs.
 902 AM_CONDITIONAL([BUILD_GTK_DOC], [test "x$enable_gtk_doc" = "xyes" || test ! -f "autogen.sh"])
 903
 904 # prefixes for fixing gtk-doc references
 905 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
 906 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 907 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
 908 COGL_PREFIX="`$PKG_CONFIG --variable=prefix cogl-1.0`"
 909 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
 910 AC_SUBST(CAIRO_PREFIX)
 911 AC_SUBST(GLIB_PREFIX)
 912 AC_SUBST(PANGO_PREFIX)
 913 AC_SUBST(COGL_PREFIX)
 914 AC_SUBST(ATK_PREFIX)
 915
 916 dnl === Manual ================================================================
 917
 918 AC_ARG_ENABLE([docs],
 919               [AS_HELP_STRING([--enable-docs=@<:@no/yes@:>@],
 920                               [Build optional documentation; requires xsltproc and jw.])],
 921               [enable_docs=$enableval],
 922               [enable_docs=no])
 923
 924 enable_pdfs=no
 925 AS_IF([test "x$enable_docs" = "xyes"],
 926       [
 927         AC_PATH_PROG(JW, [jw], [no])
 928         AS_IF([test "x$JW" = "xno"],
 929               [
 930                 AC_MSG_WARN([jw not found; pdf generation has been disabled])
 931               ],
 932               [enable_pdfs=yes])
 933
 934         AC_PATH_PROG(XSLTPROC, [xsltproc], [no])
 935         AS_IF([test "x$XSLTPROC" = "xno"],
 936               [
 937                 AC_MSG_ERROR([xsltproc not found])
 938               ])
 939       ]
 940 )
 941
 942 AM_CONDITIONAL(ENABLE_DOCS, [test "x$enable_docs" = "xyes"])
 943 AM_CONDITIONAL(ENABLE_PDFS, [test "x$enable_pdfs" = "xyes"])
 944
 945 dnl === I18N ==================================================================
 946
 947 AM_GNU_GETTEXT_VERSION([0.17])
 948 AM_GNU_GETTEXT([external])
 949
 950 GETTEXT_PACKAGE="clutter-1.0"
 951 AC_SUBST(GETTEXT_PACKAGE)
 952 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
 953                    ["$GETTEXT_PACKAGE"],
 954                    [The prefix for our gettext translation domains.])
 955 AS_ALL_LINGUAS
 956
 957 dnl ===========================================================================
 958
 959 AC_CONFIG_FILES([
 960         Makefile
 961
 962         README
 963
 964         build/Makefile
 965         build/autotools/Makefile
 966         build/mingw/Makefile
 967
 968         clutter/Makefile
 969         clutter/clutter-config.h
 970         clutter/clutter-version.h
 971         clutter/clutter-$CLUTTER_API_VERSION.pc:clutter/clutter.pc.in
 972
 973         clutter/cally/cally-$CLUTTER_API_VERSION.pc:clutter/cally/cally.pc.in
 974
 975         clutter/egl/clutter-cex100.h
 976
 977         tests/Makefile
 978         tests/accessibility/Makefile
 979         tests/conform/Makefile
 980         tests/conform/test-launcher.sh
 981         tests/data/Makefile
 982         tests/interactive/Makefile
 983         tests/interactive/wrapper.sh
 984         tests/micro-bench/Makefile
 985         tests/performance/Makefile
 986
 987         doc/Makefile
 988         doc/reference/Makefile
 989         doc/reference/clutter/Makefile
 990         doc/reference/clutter/clutter-docs.xml
 991         doc/reference/cally/Makefile
 992         doc/reference/cally/cally-docs.xml
 993         doc/common/Makefile
 994         doc/cookbook/Makefile
 995         doc/cookbook/clutter-cookbook.xml
 996         doc/cookbook/examples/Makefile
 997
 998         po/Makefile.in
 999 ])
1000
1001 AC_OUTPUT
1002
1003 dnl === Summary ===============================================================
1004
1005 echo ""
1006 echo "Clutter - $VERSION (${CLUTTER_RELEASE_STATUS})"
1007
1008 # Global flags
1009 echo ""
1010 echo " • Global:"
1011 echo "        Prefix: ${prefix}"
1012 echo "        Libdir: ${libdir}"
1013 echo "        Sysconfdir: ${sysconfdir}"
1014
1015 # Compiler/Debug related flags
1016 echo ""
1017 echo " • Compiler options:"
1018 echo "        Clutter debug level: ${enable_debug}"
1019 echo "        Compiler flags: ${CFLAGS} ${MAINTAINER_CFLAGS}"
1020 echo "        Profiling enabled: ${enable_profile}"
1021 echo "        Enable coverage tests: ${enable_gcov}"
1022 echo "        Enable deprecated symbols: ${enable_deprecated}"
1023
1024 # Documentation
1025 echo ""
1026 echo " • Documentation:"
1027 echo "        Build API Reference: ${enable_gtk_doc}"
1028 echo "        Build Additional Documentation: ${enable_docs} (Generate PDF: ${enable_pdfs})"
1029
1030 # Miscellaneous
1031 echo ""
1032 echo " • Extra:"
1033 echo "        Build introspection data: ${enable_introspection}"
1034 echo "        Build conformance test suite: ${enable_conformance}"
1035 echo "        Build X11-specific tests: ${x11_tests}"
1036
1037 # Clutter backend related flags
1038 echo ""
1039 echo " • Clutter Backends:"
1040
1041 if test "x$experimental_backend" = "xno"; then
1042 echo "        Windowing systems: ${CLUTTER_BACKENDS}"
1043 else
1044 echo "        Windowing systems: ${CLUTTER_BACKENDS} (WARNING: Experimental backends enabled)"
1045 fi
1046
1047 if test "x$SUPPORT_X11" = "x1"; then
1048 echo ""
1049 echo "        Enable XComposite: ${have_xcomposite}"
1050 echo "        Enable XInput: ${have_xinput}"
1051 echo "        Enable Xge: ${have_xge}"
1052 echo "        Enable XI2: ${have_xinput2}"
1053 echo "        Enable XKB: ${have_xkb}"
1054 fi
1055
1056 if test "x$SUPPORT_EGL" = "x1"; then
1057 echo ""
1058 echo "        Enable TSLib: ${have_tslib}"
1059 echo "        Enable evdev: ${have_evdev}"
1060 echo "        Enable GDL: ${have_gdl}"
1061 fi
1062
1063 echo ""
1064
1065 # General warning about experimental features
1066 if test "x$experimental_backend" = "xyes"; then
1067 echo ""
1068 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1069 echo " *WARNING*"
1070 echo ""
1071 echo "  The stability of your build might be affected by one or more"
1072 echo "  experimental backends or experimental and unsupported features"
1073 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1074 echo ""
1075 fi