configure.ac

   1 AC_INIT([btrfs-progs],
   2         m4_esyscmd([./version.sh --configure]),
   3         [linux-btrfs@vger.kernel.org],,
   4         [http://btrfs.wiki.kernel.org])
   5
   6 dnl library version
   7 LIBBTRFS_MAJOR=0
   8 LIBBTRFS_MINOR=1
   9 LIBBTRFS_PATCHLEVEL=1
  10
  11 CFLAGS="-g -O1"
  12
  13 AC_PREREQ([2.60])
  14
  15 AC_CONFIG_AUX_DIR([config])
  16 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  17 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  18 AC_USE_SYSTEM_EXTENSIONS
  19
  20 AC_CONFIG_SRCDIR([btrfs.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 AC_PROG_CC
  24 AC_CANONICAL_HOST
  25 AC_C_CONST
  26 AC_C_VOLATILE
  27 AC_C_BIGENDIAN
  28
  29 AC_SYS_LARGEFILE
  30
  31 AC_PROG_INSTALL
  32 AC_PROG_LN_S
  33 AC_PATH_PROG([AR], [ar])
  34 AC_PATH_PROG([RM], [rm], [rm])
  35 AC_PATH_PROG([RMDIR], [rmdir], [rmdir])
  36
  37 AC_CHECK_FUNCS([openat], [],
  38         [AC_MSG_ERROR([cannot find openat() function])])
  39
  40 m4_ifndef([PKG_PROG_PKG_CONFIG],
  41   [m4_fatal([Could not locate the pkg-config autoconf
  42     macros. These are usually located in /usr/share/aclocal/pkg.m4.
  43     If your macros are in a different location, try setting the
  44     environment variable AL_OPTS="-I/other/macro/dir" before running
  45     ./autogen.sh or autoreconf again.])])
  46 PKG_PROG_PKG_CONFIG
  47
  48
  49 dnl
  50 dnl Calls pkg-config --static
  51 dnl
  52 AC_DEFUN([PKG_STATIC], [
  53   if AC_RUN_LOG([pkg-config --exists --print-errors "$2"]); then
  54     $1=`pkg-config --libs --static "$2"`
  55     AC_SUBST([$1])
  56   else
  57     AC_MSG_ERROR([pkg-config description of $2, needed for static build, is not available])
  58   fi
  59 ])
  60
  61
  62 AC_ARG_ENABLE([backtrace],
  63   AS_HELP_STRING([--disable-backtrace], [disable btrfs backtrace]),
  64   [], [enable_backtrace=yes]
  65 )
  66
  67 AS_IF([test "x$enable_backtrace" = xno], [
  68   AC_DEFINE([BTRFS_DISABLE_BACKTRACE], [1], [disable backtrace stuff in kerncompat.h ])
  69 ])
  70
  71 if test "x$enable_backtrace" = xyes; then
  72         AC_CHECK_HEADERS([execinfo.h])
  73         AC_CHECK_FUNCS([backtrace backtrace_symbols_fd], [],
  74               AC_MSG_ERROR([standard library does not have backtrace support]))
  75 fi
  76
  77
  78 AC_ARG_ENABLE([documentation],
  79               AS_HELP_STRING([--disable-documentation], [do not build domumentation]),
  80   [], [enable_documentation=yes]
  81 )
  82 AS_IF([test "x$enable_documentation" = xyes], [DISABLE_DOCUMENTATION=0], [DISABLE_DOCUMENTATION=1])
  83 AC_SUBST([DISABLE_DOCUMENTATION])
  84
  85 dnl detect tools to build documentation
  86 if test "x$enable_documentation" = xyes; then
  87         AC_PATH_PROG([ASCIIDOC], [asciidoc], [asciidoc])
  88         AC_PATH_PROG([XMLTO], [xmlto], [xmlto])
  89         AC_PATH_PROG([GZIP], [gzip], [gzip])
  90         AC_PATH_PROG([MV], [mv], [mv])
  91         AC_PROG_SED
  92 fi
  93
  94 AC_ARG_ENABLE([convert],
  95               AS_HELP_STRING([--disable-convert], [do not build btrfs-convert]),
  96   [], [enable_btrfsconvert=yes]
  97 )
  98
  99 AS_IF([test "x$enable_btrfsconvert" = xyes], [DISABLE_BTRFSCONVERT=0], [DISABLE_BTRFSCONVERT=1])
 100 AC_SUBST([DISABLE_BTRFSCONVERT])
 101
 102
 103 dnl Define <NAME>_LIBS= and <NAME>_CFLAGS= by pkg-config
 104 dnl
 105 dnl The default PKG_CHECK_MODULES() action-if-not-found is end the
 106 dnl execution with error. The static libs are optional.
 107
 108 PKG_CHECK_MODULES(BLKID, [blkid])
 109 PKG_STATIC(BLKID_LIBS_STATIC, [blkid])
 110
 111 PKG_CHECK_MODULES(UUID, [uuid])
 112 PKG_STATIC(UUID_LIBS_STATIC, [uuid])
 113
 114 PKG_CHECK_MODULES(ZLIB, [zlib])
 115 PKG_STATIC(ZLIB_LIBS_STATIC, [zlib])
 116
 117 dnl lzo library does not provide pkg-config, let use classic way
 118 AC_CHECK_LIB([lzo2], [lzo_version], [
 119         LZO2_LIBS="-llzo2"
 120         LZO2_CFLAGS=""
 121         LZO2_LIBS_STATIC="-llzo2"],[
 122         AC_MSG_ERROR([cannot find lzo2 library])
 123 ])
 124 AC_SUBST([LZO2_LIBS])
 125 AC_SUBST([LZO2_LIBS_STATIC])
 126 AC_SUBST([LZO2_CFLAGS])
 127
 128
 129 dnl library stuff
 130 AC_SUBST([LIBBTRFS_MAJOR])
 131 AC_SUBST([LIBBTRFS_MINOR])
 132 AC_SUBST([LIBBTRFS_PATCHLEVEL])
 133
 134 AC_CONFIG_HEADERS([config.h])
 135
 136 AC_CONFIG_FILES([
 137 Makefile
 138 Documentation/Makefile
 139 version.h
 140 ])
 141
 142 AC_OUTPUT
 143
 144 AC_MSG_RESULT([
 145         ${PACKAGE_NAME} ${PACKAGE_VERSION}
 146
 147         prefix:            ${prefix}
 148         exec prefix:       ${exec_prefix}
 149
 150         bindir:            ${bindir}
 151         libdir:            ${libdir}
 152         includedir:        ${includedir}
 153
 154         compiler:          ${CC}
 155         cflags:            ${CFLAGS}
 156         ldflags:           ${LDFLAGS}
 157
 158         documentaton:      ${enable_documentation}
 159         backtrace support: ${enable_backtrace}
 160         btrfs-convert:     ${enable_btrfsconvert}
 161
 162         Type 'make' to compile.
 163 ])
 164