configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [51])
  34 m4_define([glib_micro_version], [3])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS:+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 dnl
 121
 122 AC_MSG_CHECKING([for Win32])
 123 LIB_EXE_MACHINE_FLAG=X86
 124 case "$host" in
 125   *-*-mingw*)
 126     glib_native_win32=yes
 127     glib_pid_type='void *'
 128     glib_pid_format='p'
 129     glib_pollfd_format='%#x'
 130     glib_cv_stack_grows=no
 131     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 132     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 133     # (Sorry, I don't know exactly what is the problem, but it is related to
 134     # floating point formatting and decimal point vs. comma.)
 135     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 136     # rigorous enough to notice, though.
 137     # So preset the autoconf cache variables.
 138     ac_cv_func_vsnprintf_c99=no
 139     ac_cv_func_snprintf_c99=no
 140     case "$host" in
 141     x86_64-*-*)
 142       LIB_EXE_MACHINE_FLAG=X64
 143       glib_pollfd_format='%#I64x'
 144       ;;
 145     esac
 146
 147     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 148     ;;
 149   *)
 150     glib_native_win32=no
 151     glib_pid_type=int
 152     glib_pid_format='i'
 153     glib_pollfd_format='%d'
 154     ;;
 155 esac
 156 case $host in
 157   *-*-linux*)
 158     glib_os_linux=yes
 159     ;;
 160 esac
 161
 162 AC_MSG_RESULT([$glib_native_win32])
 163
 164 AC_MSG_CHECKING([for the Android])
 165 case $host in
 166   *android*)
 167     glib_native_android="yes"
 168     ;;
 169   *)
 170     glib_native_android="no"
 171     ;;
 172 esac
 173 AC_MSG_RESULT([$glib_native_android])
 174
 175 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 176
 177 glib_have_carbon=no
 178 AC_MSG_CHECKING([for Mac OS X Carbon support])
 179 AC_TRY_CPP([
 180 #include <Carbon/Carbon.h>
 181 #include <CoreServices/CoreServices.h>
 182 ], glib_have_carbon=yes)
 183
 184 AC_MSG_RESULT([$glib_have_carbon])
 185
 186 glib_have_cocoa=no
 187 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 188 AC_TRY_CPP([
 189 #include <Cocoa/Cocoa.h>
 190 #ifdef GNUSTEP_BASE_VERSION
 191 #error "Detected GNUstep, not Cocoa"
 192 #endif
 193 ], glib_have_cocoa=yes)
 194
 195 AC_MSG_RESULT([$glib_have_cocoa])
 196
 197 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 198 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 199 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 200 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 201 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 202 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 203
 204 AS_IF([test "$glib_native_win32" = "yes"], [
 205   AC_CHECK_TOOL(WINDRES, windres, no)
 206   if test "$WINDRES" = no; then
 207     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 208   fi
 209   AC_CHECK_TOOL(NM, nm, no)
 210   if test "$NM" = no; then
 211     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 212   fi
 213   AC_CHECK_TOOL(RANLIB, ranlib, :)
 214   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 215   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 216 ])
 217 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 218
 219 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 220   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 221   CARBON_LIBS="-Wl,-framework,Carbon"
 222   LDFLAGS="$LDFLAGS $CARBON_LIBS"
 223 ], [CARBON_LIBS=""])
 224
 225 AC_SUBST([CARBON_LIBS])
 226
 227 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
 228   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 229   COCOA_LIBS="-Wl,-framework,Foundation"
 230   LDFLAGS="$LDFLAGS $COCOA_LIBS"
 231
 232   osx_version=`sw_vers -productVersion`
 233   osx_min_version="10.9.0"
 234   AC_MSG_CHECKING([OSX version >= $osx_min_version])
 235   AS_VERSION_COMPARE([$osx_version], [$osx_min_version], [
 236     AC_MSG_RESULT([no])
 237     AC_MSG_ERROR([OSX version is too old!])
 238   ])
 239   AC_MSG_RESULT([yes])
 240 ], [COCOA_LIBS=""])
 241
 242 AC_SUBST([COCOA_LIBS])
 243
 244 dnl declare --enable-* args and collect ac_help strings
 245 AC_ARG_ENABLE(debug,
 246               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 247                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 248               enable_debug=glib_debug_default)
 249
 250 AC_ARG_ENABLE(gc_friendly,
 251               [AS_HELP_STRING([--enable-gc-friendly],
 252                               [turn on garbage collector friendliness [default=no]])],,
 253               [enable_gc_friendly=no])
 254 AC_ARG_ENABLE(mem_pools,
 255               [AS_HELP_STRING([--disable-mem-pools],
 256                               [disable all glib memory pools])],,
 257               [disable_mem_pools=no])
 258 AC_ARG_ENABLE(rebuilds,
 259               [AS_HELP_STRING([--disable-rebuilds],
 260                               [disable all source autogeneration rules])],,
 261               [enable_rebuilds=yes])
 262
 263 GLIB_TESTS
 264
 265 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 266 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 267   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 268   AC_MSG_RESULT([yes])
 269 ], [ AC_MSG_RESULT([no]) ])
 270
 271 AC_MSG_CHECKING([whether to disable memory pools])
 272 AS_IF([test "x$disable_mem_pools" = "xno"], [
 273   AC_MSG_RESULT([no])
 274 ], [
 275   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 276   AC_MSG_RESULT([yes])
 277 ])
 278
 279 dnl location to install runtime libraries, e.g. ../../lib to install
 280 dnl to /lib if libdir is /usr/lib
 281 AC_ARG_WITH(runtime-libdir,
 282            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 283                            [install runtime libraries relative to libdir])],
 284            [],
 285            [with_runtime_libdir=""])
 286 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 287 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 288 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 289
 290 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 291 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 292 AC_LANG_SAVE
 293 AC_LANG_CPLUSPLUS
 294 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 295 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 296 AC_LANG_RESTORE
 297
 298 AM_PROG_CC_C_O
 299 AC_PROG_INSTALL
 300
 301 AC_SYS_LARGEFILE
 302
 303 PKG_PROG_PKG_CONFIG(0.16)
 304
 305 if test "x$enable_debug" = "xyes"; then
 306   if test "x$cflags_set" != "x" ; then
 307       case " $CFLAGS " in
 308       *[[\ \    ]]-g[[\ \       ]]*) ;;
 309       *) CFLAGS="$CFLAGS -g" ;;
 310       esac
 311   fi
 312   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 313 else
 314   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 315
 316   if test "x$enable_debug" = "xno"; then
 317     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 318   fi
 319 fi
 320
 321 # Ensure MSVC-compatible struct packing convention is used when
 322 # compiling for Win32 with gcc.
 323 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 324 # gcc2 uses "-fnative-struct".
 325 if test x"$glib_native_win32" = xyes; then
 326   if test x"$GCC" = xyes; then
 327     msnative_struct=''
 328     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 329     if test -z "$ac_cv_prog_CC"; then
 330       our_gcc="$CC"
 331     else
 332       our_gcc="$ac_cv_prog_CC"
 333     fi
 334     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 335       2.)
 336         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 337           msnative_struct='-fnative-struct'
 338         fi
 339         ;;
 340       *)
 341         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 342           msnative_struct='-mms-bitfields'
 343         fi
 344         ;;
 345     esac
 346     if test x"$msnative_struct" = x ; then
 347       AC_MSG_RESULT([no way])
 348       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 349     else
 350       CFLAGS="$CFLAGS $msnative_struct"
 351       AC_MSG_RESULT([${msnative_struct}])
 352     fi
 353   fi
 354 fi
 355 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 356 AC_SUBST(GLIB_EXTRA_CFLAGS)
 357
 358 AC_EXEEXT
 359
 360 # define a MAINT-like variable REBUILD which is set if Perl
 361 # and awk are found, so autogenerated sources can be rebuilt
 362 AC_PROG_AWK
 363 AC_CHECK_PROGS(PERL, [perl5 perl])
 364 # We would like indent, but don't require it.
 365 AC_CHECK_PROG(INDENT, indent, indent)
 366 REBUILD=\#
 367 if test "x$enable_rebuilds" = "xyes" && \
 368      test -n "$PERL" && \
 369      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 370      test -n "$AWK" ; then
 371   REBUILD=
 372 fi
 373 AC_SUBST(REBUILD)
 374
 375 # Need full path to Perl for glib-mkenums
 376 #
 377 if test "x$PERL" != x ; then
 378   AC_PATH_PROG(PERL_PATH, [$PERL])
 379 fi
 380 if test "x$PERL_PATH" = x ; then
 381   PERL_PATH="/usr/bin/env perl"
 382 fi
 383 AC_SUBST(PERL_PATH)
 384
 385 # option to specify python interpreter to use; this just sets $PYTHON, so that
 386 # we will fallback to reading $PYTHON if --with-python is not given, and
 387 # python.m4 will get the expected input
 388 AC_ARG_WITH(python,
 389             AS_HELP_STRING([--with-python=PATH],
 390                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 391             [PYTHON="$withval"], [])
 392 if test x"$PYTHON" = xyes; then
 393   AC_MSG_ERROR([--with-python option requires a path or program argument])
 394 fi
 395 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 396
 397
 398 dnl ***********************
 399 dnl *** Tests for iconv ***
 400 dnl ***********************
 401 dnl
 402 dnl We do this before the gettext checks, to avoid distortion
 403
 404 dnl On Windows we use a native implementation
 405
 406 AS_IF([ test x"$glib_native_win32" = xyes], [
 407   with_libiconv=native
 408 ], [
 409   AC_ARG_WITH(libiconv,
 410               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 411                               [use the libiconv library])],,
 412               [with_libiconv=maybe])
 413
 414   found_iconv=no
 415   case $with_libiconv in
 416     maybe)
 417       # Check in the C library first
 418       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 419       # Check if we have GNU libiconv
 420       if test $found_iconv = "no"; then
 421         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 422       fi
 423       # Check if we have a iconv in -liconv, possibly from vendor
 424       if test $found_iconv = "no"; then
 425         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 426       fi
 427       ;;
 428     no)
 429       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 430       ;;
 431     gnu|yes)
 432       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 433       ;;
 434     native)
 435       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 436       ;;
 437   esac
 438
 439   if test "x$found_iconv" = "xno" ; then
 440      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 441   fi
 442 ])
 443
 444 dnl
 445 dnl zlib support
 446 dnl
 447 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 448 AS_IF([test "x$found_zlib" = "xno"], [
 449   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 450   if test "x$found_zlib" = "xno" ; then
 451     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 452   fi
 453   ZLIB_LIBS='-lz'
 454   AC_SUBST(ZLIB_LIBS)
 455 ])
 456
 457 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 458 AC_SUBST(LIBFFI_CFLAGS)
 459 AC_SUBST(LIBFFI_LIBS)
 460
 461 dnl
 462 dnl gettext support
 463 dnl
 464
 465 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 466 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 467 GLIB_GNU_GETTEXT
 468
 469 if test "$gt_cv_have_gettext" != "yes" ; then
 470   AC_MSG_ERROR([
 471 *** You must have either have gettext support in your C library, or use the
 472 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 473 ])
 474 fi
 475
 476 LIBS="$INTLLIBS $LIBS"
 477
 478 GETTEXT_PACKAGE=glib20
 479 AC_SUBST(GETTEXT_PACKAGE)
 480 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 481   [Define the gettext package to be used])
 482
 483 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 484
 485 dnl
 486 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 487 dnl
 488
 489 AS_IF([test x"$glib_native_win32" != xyes], [
 490   if test x$with_libiconv != xno ; then
 491     case " $INTLLIBS " in
 492     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 493     *) ICONV_LIBS="-liconv" ;;
 494     esac
 495   fi
 496 ])
 497 AC_SUBST(ICONV_LIBS)
 498
 499 case $with_libiconv in
 500   gnu)
 501     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 502     ;;
 503   native)
 504     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 505     ;;
 506 esac
 507
 508 dnl Initialize libtool
 509 LT_PREREQ([2.2])
 510 LT_INIT([disable-static win32-dll])
 511 dnl when using libtool 2.x create libtool early, because it's used in configure
 512 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 513
 514
 515 AS_IF([test "$glib_native_win32" = "yes"], [
 516   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 517     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 518   fi
 519   if test x$enable_static = xyes; then
 520     glib_win32_static_compilation=yes
 521     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 522 #define GOBJECT_STATIC_COMPILATION 1"
 523     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 524   fi
 525 ])
 526 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 527
 528 # Checks for library functions.
 529 AC_FUNC_ALLOCA
 530 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 531 AC_CHECK_FUNCS(timegm gmtime_r strerror_r)
 532
 533 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 534   [AC_TRY_LINK([#include <unistd.h>
 535     extern int __libc_enable_secure;],
 536     [return __libc_enable_secure;],
 537    glib_cv_have_libc_enable_secure=yes,
 538    glib_cv_have_libc_enable_secure=no)])
 539 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 540    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 541      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 542 ])
 543
 544 AC_CHECK_SIZEOF(char)
 545 AC_CHECK_SIZEOF(short)
 546 AC_CHECK_SIZEOF(long)
 547 AC_CHECK_SIZEOF(int)
 548 AC_CHECK_SIZEOF(void *)
 549 AC_CHECK_SIZEOF(long long)
 550 AC_CHECK_SIZEOF(__int64)
 551
 552 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 553   [AC_TRY_LINK([#include <signal.h>
 554      #include <sys/types.h>
 555      sig_atomic_t val = 42;],
 556     [return val == 42 ? 0 : 1],
 557    ac_cv_type_sig_atomic_t=yes,
 558    ac_cv_type_sig_atomic_t=no)])
 559 if test x$ac_cv_type_sig_atomic_t = xyes; then
 560    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 561      [Define if you have the 'sig_atomic_t' type.])
 562 fi
 563
 564 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 565   :
 566 else
 567   AC_MSG_ERROR([
 568 *** GLib requires a 64 bit type. You might want to consider
 569 *** using the GNU C compiler.
 570 ])
 571 fi
 572
 573 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 574         # long long is a 64 bit integer.
 575         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 576         AC_CACHE_VAL(glib_cv_long_long_format,[
 577                 for format in ll q I64; do
 578                   AC_TRY_RUN([#include <stdio.h>
 579                         int main()
 580                         {
 581                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 582                           char buffer[1000];
 583                           sprintf (buffer, "%${format}u", a);
 584                           sscanf (buffer, "%${format}u", &b);
 585                           exit (b!=a);
 586                         }
 587                         ],
 588                         [glib_cv_long_long_format=${format}
 589                         break],
 590                         [],[:])
 591                 done])
 592         AS_IF([ test -n "$glib_cv_long_long_format"], [
 593           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 594           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 595           if test x"$glib_cv_long_long_format" = xI64; then
 596             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 597           fi
 598         ], [AC_MSG_RESULT(none)])
 599 ],[ test x$ac_cv_sizeof___int64 = x8], [
 600         # __int64 is a 64 bit integer.
 601         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 602         # We know this is MSVCRT.DLL, and what the formats are
 603         glib_cv_long_long_format=I64
 604         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 605         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 606         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 607 ])
 608
 609 AC_C_CONST
 610
 611 dnl
 612 dnl check in which direction the stack grows
 613 dnl
 614 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 615         AC_TRY_RUN([
 616         volatile int *a = 0, *b = 0;
 617         void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
 618         int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
 619         ],
 620         glib_cv_stack_grows=yes
 621         ,
 622         glib_cv_stack_grows=no
 623         ,)
 624 ])
 625
 626 # check for flavours of varargs macros
 627 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 628 AC_TRY_COMPILE([],[
 629 int a(int p1, int p2, int p3);
 630 #define call_a(...) a(1,__VA_ARGS__)
 631 call_a(2,3);
 632 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 633 AC_MSG_RESULT($g_have_iso_c_varargs)
 634
 635 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 636 AS_IF([test "$CXX" = ""], [
 637 dnl No C++ compiler
 638   g_have_iso_cxx_varargs=no
 639 else
 640   AC_LANG_CPLUSPLUS
 641   AC_TRY_COMPILE([],[
 642 int a(int p1, int p2, int p3);
 643 #define call_a(...) a(1,__VA_ARGS__)
 644 call_a(2,3);
 645 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 646   AC_LANG_C
 647 ])
 648 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 649
 650 AC_MSG_CHECKING(for GNUC varargs macros)
 651 AC_TRY_COMPILE([],[
 652 int a(int p1, int p2, int p3);
 653 #define call_a(params...) a(1,params)
 654 call_a(2,3);
 655 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 656 AC_MSG_RESULT($g_have_gnuc_varargs)
 657
 658 # check for GNUC visibility support
 659 AC_MSG_CHECKING(for GNUC visibility attribute)
 660 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 661 void
 662 __attribute__ ((visibility ("hidden")))
 663      f_hidden (void)
 664 {
 665 }
 666 void
 667 __attribute__ ((visibility ("internal")))
 668      f_internal (void)
 669 {
 670 }
 671 void
 672 __attribute__ ((visibility ("protected")))
 673      f_protected (void)
 674 {
 675 }
 676 void
 677 __attribute__ ((visibility ("default")))
 678      f_default (void)
 679 {
 680 }
 681 int main (void)
 682 {
 683         f_hidden();
 684         f_internal();
 685         f_protected();
 686         f_default();
 687         return 0;
 688 }
 689 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 690 AC_MSG_RESULT($g_have_gnuc_visibility)
 691 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 692
 693 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 694 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 695 #else
 696 # include "error: this is not Sun Studio."
 697 #endif
 698 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 699 AC_MSG_RESULT($g_have_sunstudio_visibility)
 700 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 701
 702 # check for bytesex stuff
 703 AC_C_BIGENDIAN
 704 if test x$ac_cv_c_bigendian = xuniversal ; then
 705   AC_MSG_ERROR([Universal builds not supported: see https://bugs.gnome.org/742548])
 706 fi
 707
 708
 709 # check for header files
 710 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
 711 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
 712 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 713 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 714 AC_CHECK_HEADERS([linux/magic.h])
 715 AC_CHECK_HEADERS([termios.h])
 716
 717 # Some versions of MSC lack these
 718 AC_CHECK_HEADERS([dirent.h sys/time.h])
 719
 720 # We don't care about this, but we need to keep including it in
 721 # glibconfig.h for backward compatibility
 722 AC_CHECK_HEADERS([values.h])
 723
 724 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 725 [#if HAVE_SYS_PARAM_H
 726  #include <sys/param.h>
 727  #endif
 728 ])
 729 AC_CHECK_FUNCS(sysctlbyname)
 730
 731 AC_HEADER_MAJOR
 732 AC_CHECK_HEADERS([xlocale.h])
 733
 734 # check for structure fields
 735 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
 736 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 737 #include <sys/stat.h>
 738 #ifdef G_OS_UNIX
 739 #include <unistd.h>
 740 #endif
 741 #ifdef HAVE_SYS_STATFS_H
 742 #include <sys/statfs.h>
 743 #endif
 744 #ifdef HAVE_SYS_PARAM_H
 745 #include <sys/param.h>
 746 #endif
 747 #ifdef HAVE_SYS_MOUNT_H
 748 #include <sys/mount.h>
 749 #endif])
 750 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 751 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 752 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 753 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 754
 755 AC_STRUCT_DIRENT_D_TYPE
 756
 757 # Checks for libcharset
 758 AM_LANGINFO_CODESET
 759 gl_GLIBC21
 760
 761 # check additional type sizes
 762 AC_CHECK_SIZEOF(size_t)
 763
 764 dnl Try to figure out whether gsize should be long or int
 765 AC_MSG_CHECKING([for the appropriate definition for size_t])
 766
 767 case $ac_cv_sizeof_size_t in
 768   $ac_cv_sizeof_short)
 769       glib_size_type=short
 770       ;;
 771   $ac_cv_sizeof_int)
 772       glib_size_type=int
 773       ;;
 774   $ac_cv_sizeof_long)
 775       glib_size_type=long
 776       ;;
 777   $ac_cv_sizeof_long_long)
 778       glib_size_type='long long'
 779       ;;
 780   $ac_cv_sizeof__int64)
 781       glib_size_type='__int64'
 782       ;;
 783   *)  AC_MSG_ERROR([No type matching size_t in size])
 784       ;;
 785 esac
 786
 787 dnl If int/long are the same size, we see which one produces
 788 dnl warnings when used in the location as size_t. (This matters
 789 dnl on AIX with xlc)
 790 dnl
 791 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 792        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 793   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 794 #if defined(_AIX) && !defined(__GNUC__)
 795 #pragma options langlvl=stdc89
 796 #endif
 797 #include <stddef.h>
 798 int main ()
 799 {
 800   size_t s = 1;
 801   unsigned int *size_int = &s;
 802   return (int)*size_int;
 803 }
 804     ]])],glib_size_type=int,
 805       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 806 #if defined(_AIX) && !defined(__GNUC__)
 807 #pragma options langlvl=stdc89
 808 #endif
 809 #include <stddef.h>
 810 int main ()
 811 {
 812    size_t s = 1;
 813    unsigned long *size_long = &s;
 814    return (int)*size_long;
 815 }
 816         ]])],glib_size_type=long)])
 817 ])
 818
 819 AC_MSG_RESULT(unsigned $glib_size_type)
 820
 821 AC_CHECK_SIZEOF(ssize_t)
 822
 823 dnl Try to figure out whether gssize should be long or int
 824 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 825
 826 case $ac_cv_sizeof_ssize_t in
 827   $ac_cv_sizeof_short)
 828       glib_ssize_type=short
 829       ;;
 830   $ac_cv_sizeof_int)
 831       glib_ssize_type=int
 832       ;;
 833   $ac_cv_sizeof_long)
 834       glib_ssize_type=long
 835       ;;
 836   $ac_cv_sizeof_long_long)
 837       glib_ssize_type='long long'
 838       ;;
 839   $ac_cv_sizeof__int64)
 840       glib_ssize_type='__int64'
 841       ;;
 842   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 843       ;;
 844 esac
 845
 846 dnl If int/long are the same size, we see which one produces
 847 dnl warnings when used in the location as ssize_t. (This matters
 848 dnl on Android where ssize_t is long and size_t is unsigned int)
 849 dnl
 850 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 851        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 852   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 853 #if defined(_AIX) && !defined(__GNUC__)
 854 #pragma options langlvl=stdc89
 855 #endif
 856 #include <stddef.h>
 857 #ifdef HAVE_INTTYPES_H
 858 # include <inttypes.h>
 859 #endif
 860 #ifdef HAVE_STDINT_H
 861 # include <stdint.h>
 862 #endif
 863 #include <sys/types.h>
 864 int main ()
 865 {
 866   ssize_t s = 1;
 867   int *size_int = &s;
 868   return (int)*size_int;
 869 }
 870     ]])],glib_ssize_type=int,
 871       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 872 #if defined(_AIX) && !defined(__GNUC__)
 873 #pragma options langlvl=stdc89
 874 #endif
 875 #include <stddef.h>
 876 #ifdef HAVE_INTTYPES_H
 877 # include <inttypes.h>
 878 #endif
 879 #ifdef HAVE_STDINT_H
 880 # include <stdint.h>
 881 #endif
 882 #include <sys/types.h>
 883 int main ()
 884 {
 885    ssize_t s = 1;
 886    long *size_long = &s;
 887    return (int)*size_long;
 888 }
 889         ]])],glib_ssize_type=long)])
 890 ])
 891
 892 AC_MSG_RESULT($glib_ssize_type)
 893
 894 # Check for some functions
 895 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 896 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
 897 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
 898 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
 899 AC_CHECK_FUNCS(splice)
 900 AC_CHECK_FUNCS(prlimit)
 901
 902 # To avoid finding a compatibility unusable statfs, which typically
 903 # successfully compiles, but warns to use the newer statvfs interface:
 904 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 905 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 906
 907 AC_MSG_CHECKING([whether to use statfs or statvfs])
 908 # Some systems have both statfs and statvfs, pick the most "native" for these
 909 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
 910    [
 911    # on solaris and irix, statfs doesn't even have the f_bavail field
 912    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
 913       [ac_cv_func_statfs=no],
 914    # else, at least on linux, statfs is the actual syscall
 915       [ac_cv_func_statvfs=no])
 916    ])
 917
 918 AS_IF([test x$ac_cv_func_statfs = xyes],
 919       [
 920          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
 921          AC_MSG_RESULT([statfs])
 922       ],
 923       [test x$ac_cv_func_statvfs = xyes],
 924       [
 925          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
 926          AC_MSG_RESULT([statvfs])
 927       ],
 928       [  AC_MSG_RESULT([neither])])
 929
 930 AC_CHECK_HEADERS(crt_externs.h)
 931 AC_CHECK_FUNCS(_NSGetEnviron)
 932
 933 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
 934
 935 # Internet address families
 936 if test $glib_native_win32 = yes; then
 937   glib_inet_includes=["
 938 #include <winsock2.h>
 939   "]
 940 else
 941   glib_inet_includes=["
 942 #include <sys/types.h>
 943 #include <sys/socket.h>
 944   "]
 945 fi
 946
 947 glib_failed=false
 948 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
 949 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
 950 # winsock defines this even though it doesn't support it
 951 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
 952 if $glib_failed ; then
 953   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
 954 fi
 955
 956 glib_failed=false
 957 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
 958 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
 959 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
 960 if $glib_failed ; then
 961   AC_MSG_ERROR([Could not determine values for MSG_* constants])
 962 fi
 963
 964 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
 965
 966 AS_IF([test $glib_native_win32 = yes], [
 967   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
 968   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
 969   # they aren't present at run-time (on Windows 2000).
 970   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
 971   AC_SUBST(WSPIAPI_INCLUDE)
 972 ], [
 973   # Android does not have C_IN in public headers, we define it wherever necessary
 974   AS_IF([test $glib_native_android != yes], [
 975     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
 976     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 977                                         #include <arpa/nameser.h>],
 978                                        [int qclass = C_IN;])],
 979                       [AC_MSG_RESULT([no])],
 980                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 981                                                            #include <arpa/nameser.h>
 982                                                            #include <arpa/nameser_compat.h>],
 983                                                           [int qclass = C_IN;])],
 984                                          [AC_MSG_RESULT([yes])
 985                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
 986                                          [AC_MSG_ERROR([could not compile test program either way])])])])
 987   AC_SUBST(NAMESER_COMPAT_INCLUDE)
 988
 989   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
 990   NETWORK_LIBS=""
 991   AC_MSG_CHECKING([for res_query])
 992   AC_TRY_LINK([#include <sys/types.h>
 993                #include <netinet/in.h>
 994                #include <arpa/nameser.h>
 995                #include <resolv.h>
 996               ],[
 997                res_query("test", 0, 0, (void *)0, 0);
 998               ],[AC_MSG_RESULT([yes])],
 999               [save_libs="$LIBS"
1000                LIBS="-lresolv $LIBS"
1001                AC_TRY_LINK([#include <sys/types.h>
1002                             #include <netinet/in.h>
1003                             #include <arpa/nameser.h>
1004                             #include <resolv.h>
1005                            ],[
1006                             res_query("test", 0, 0, (void *)0, 0);
1007                            ],[AC_MSG_RESULT([in -lresolv])
1008                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1009                            [LIBS="-lbind $save_libs"
1010                             AC_TRY_LINK([#include <resolv.h>],
1011                                         [res_query("test", 0, 0, (void *)0, 0);],
1012                                         [AC_MSG_RESULT([in -lbind])
1013                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1014                                         [AC_MSG_ERROR(not found)])])
1015                LIBS="$save_libs"])
1016   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1017                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1018                                         [AC_MSG_ERROR(Could not find socket())]))
1019   save_libs="$LIBS"
1020   LIBS="$LIBS $NETWORK_LIBS"
1021   AC_MSG_CHECKING([for res_init])
1022   AC_TRY_LINK([#include <sys/types.h>
1023                #include <netinet/in.h>
1024                #include <arpa/nameser.h>
1025                #include <resolv.h>
1026               ],[
1027                res_init();
1028               ],[AC_MSG_RESULT([yes])
1029                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1030               ],[AC_MSG_RESULT([no])])
1031   LIBS="$save_libs"
1032 ])
1033 AC_SUBST(NETWORK_LIBS)
1034
1035 AC_CHECK_HEADER([linux/netlink.h],
1036                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1037                 [#include <sys/socket.h>])
1038 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1039
1040 AC_CHECK_TYPE([struct ip_mreqn], [
1041               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1042               [#include <netinet/in.h>])
1043
1044 case $host in
1045   *-*-solaris* )
1046      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1047      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1048      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1049      ;;
1050 esac
1051
1052 dnl
1053 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1054 dnl
1055 AS_IF([test "$ac_cv_func_statfs" = yes], [
1056   AC_MSG_CHECKING([number of arguments to statfs()])
1057   AC_TRY_COMPILE([#include <unistd.h>
1058   #ifdef HAVE_SYS_PARAM_H
1059   #include <sys/param.h>
1060   #endif
1061   #ifdef HAVE_SYS_VFS_H
1062   #include <sys/vfs.h>
1063   #endif
1064   #ifdef HAVE_SYS_MOUNT_H
1065   #include <sys/mount.h>
1066   #endif
1067   #ifdef HAVE_SYS_STATFS_H
1068   #include <sys/statfs.h>
1069   #endif], [struct statfs st;
1070   statfs("/", &st);],[
1071     AC_MSG_RESULT([2])
1072     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1073     AC_TRY_COMPILE([#include <unistd.h>
1074   #ifdef HAVE_SYS_PARAM_H
1075   #include <sys/param.h>
1076   #endif
1077   #ifdef HAVE_SYS_VFS_H
1078   #include <sys/vfs.h>
1079   #endif
1080   #ifdef HAVE_SYS_MOUNT_H
1081   #include <sys/mount.h>
1082   #endif
1083   #ifdef HAVE_SYS_STATFS_H
1084   #include <sys/statfs.h>
1085   #endif], [struct statfs st;
1086   statfs("/", &st, sizeof (st), 0);],[
1087       AC_MSG_RESULT([4])
1088       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1089       AC_MSG_RESULT(unknown)
1090       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1091 ])
1092
1093 dnl
1094 dnl open takes O_DIRECTORY as an option
1095 dnl
1096 AC_MSG_CHECKING([open() option O_DIRECTORY])
1097 AC_TRY_COMPILE([#include <fcntl.h>
1098 #include <sys/types.h>
1099 #include <sys/stat.h>],
1100 [open(0, O_DIRECTORY, 0);],[
1101         AC_MSG_RESULT([yes])
1102         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1103         AC_MSG_RESULT([no])])
1104
1105 #
1106 # Check whether to use an included printf
1107 #
1108 AC_FUNC_VSNPRINTF_C99
1109 AC_FUNC_PRINTF_UNIX98
1110
1111 AC_ARG_ENABLE(included-printf,
1112               [AS_HELP_STRING([--enable-included-printf],
1113                               [use included printf [default=auto]])],
1114               enable_included_printf="$enableval")
1115
1116 need_included_printf=no
1117 if test "x$enable_included_printf" = "xyes" ; then
1118   need_included_printf=yes
1119 fi
1120 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1121   need_included_printf=yes
1122 fi
1123 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1124   need_included_printf=yes
1125 fi
1126 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1127    test -z "$glib_cv_long_long_format" ; then
1128   need_included_printf=yes
1129 fi
1130
1131 if test "x$enable_included_printf" = "xno" &&
1132    test "x$need_included_printf" = "xyes" ; then
1133   AC_MSG_ERROR([
1134 *** Your C library's printf doesn't appear to have the features that
1135 *** GLib needs, but you specified --enable-included-printf=no.])
1136 fi
1137
1138 enable_included_printf=$need_included_printf
1139
1140 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1141 AS_IF([test "$enable_included_printf" != "yes"], [
1142   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1143 ], [
1144   if test -z "$glib_cv_long_long_format" ; then
1145     glib_cv_long_long_format="ll"
1146   fi
1147   AC_DEFINE(HAVE_VASPRINTF,1)
1148 ])
1149
1150 # Checks needed for gnulib vasnprintf
1151 bh_C_SIGNED
1152 jm_AC_TYPE_LONG_LONG
1153 gt_TYPE_LONGDOUBLE
1154 gt_TYPE_WCHAR_T
1155 gt_TYPE_WINT_T
1156 AC_TYPE_SIZE_T
1157 AC_CHECK_TYPES(ptrdiff_t)
1158 jm_AC_TYPE_INTMAX_T
1159 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1160 AC_FUNC_SNPRINTF_C99
1161
1162 # Check if <sys/select.h> needs to be included for fd_set
1163 AC_MSG_CHECKING([for fd_set])
1164 AC_TRY_COMPILE([#include <sys/types.h>],
1165         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1166 AS_IF([test "$gtk_ok" = "yes"], [
1167     AC_MSG_RESULT([yes, found in sys/types.h])
1168 ], [
1169     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1170     if test "$gtk_ok" = "yes"; then
1171         # *** FIXME: give it a different name
1172         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1173         AC_MSG_RESULT([yes, found in sys/select.h])
1174     else
1175         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1176         AC_MSG_RESULT(no)
1177     fi
1178 ])
1179
1180 dnl Check for nl_langinfo and CODESET
1181 AC_LANG_SAVE
1182 AC_LANG_C
1183 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1184         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1185                        [char *codeset = nl_langinfo (CODESET);])],
1186                 [glib_cv_langinfo_codeset=yes],
1187                 [glib_cv_langinfo_codeset=no])])
1188 if test x$glib_cv_langinfo_codeset = xyes; then
1189   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1190 fi
1191
1192 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1193 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1194         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1195                  [char *str;
1196                  str = nl_langinfo (PM_STR);
1197                  str = nl_langinfo (D_T_FMT);
1198                  str = nl_langinfo (D_FMT);
1199                  str = nl_langinfo (T_FMT);
1200                  str = nl_langinfo (T_FMT_AMPM);
1201                  str = nl_langinfo (MON_1);
1202                  str = nl_langinfo (ABMON_12);
1203                  str = nl_langinfo (DAY_1);
1204                  str = nl_langinfo (ABDAY_7);])],
1205                 [glib_cv_langinfo_time=yes],
1206                 [glib_cv_langinfo_time=no])])
1207 if test x$glib_cv_langinfo_time = xyes; then
1208   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1209 fi
1210
1211 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1212 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1213         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1214                 [char *str;
1215                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1216                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1217                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1218                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1219                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1220                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1221                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1222                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1223                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1224                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1225                 [glib_cv_langinfo_outdigit=yes],
1226                 [glib_cv_langinfo_outdigit=no])])
1227 if test x$glib_cv_langinfo_outdigit = xyes; then
1228   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1229 fi
1230 AC_LANG_RESTORE
1231
1232 dnl ****************************************
1233 dnl *** posix_memalign                   ***
1234 dnl ****************************************
1235 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1236 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1237     glib_cv_compliant_posix_memalign=0
1238     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1239         AC_TRY_RUN([
1240                 #define _XOPEN_SOURCE 600
1241                 #include <stdlib.h> /* posix_memalign() should be defined here */
1242                 /* some systems break if #include <malloc.h> used */
1243                 static void test_memalign (size_t boundary, size_t size) {
1244                     void *mem = 0;
1245                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1246                         exit (1);
1247                     else
1248                       free (mem);
1249                 }
1250                 int main() {
1251                     test_memalign (  128,   128 - 2 * sizeof (void*));
1252                     test_memalign (  256,   256 - 2 * sizeof (void*));
1253                     test_memalign (  512,   512 - 2 * sizeof (void*));
1254                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1255                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1256                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1257                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1258                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1259                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1260                     exit (0); /* success */
1261                 }
1262                 ],
1263             [glib_cv_compliant_posix_memalign=1], [], [:])
1264       :
1265     fi
1266     ])
1267 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1268     AC_MSG_RESULT(yes)
1269     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1270 ], [
1271     AC_MSG_RESULT(no)
1272 ])
1273
1274
1275 dnl ****************************************
1276 dnl *** strlcpy/strlcat                  ***
1277 dnl ****************************************
1278 # Check for strlcpy
1279 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1280 AC_TRY_RUN([#include <stdlib.h>
1281 #include <string.h>
1282 int main() {
1283   char p[10];
1284   (void) strlcpy (p, "hi", 10);
1285   if (strlcat (p, "bye", 0) != 3)
1286     return 1;
1287   return 0;
1288 }], glib_cv_have_strlcpy=yes,
1289     glib_cv_have_strlcpy=no,
1290     glib_cv_have_strlcpy=no)])
1291 if test "$glib_cv_have_strlcpy" = "yes"; then
1292     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1293 fi
1294
1295
1296 dnl **********************
1297 dnl *** va_copy checks ***
1298 dnl **********************
1299 dnl we currently check for all three va_copy possibilities, so we get
1300 dnl all results in config.log for bug reports.
1301 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1302         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1303 #include <stdlib.h>
1304         void f (int i, ...) {
1305         va_list args1, args2;
1306         va_start (args1, i);
1307         va_copy (args2, args1);
1308         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1309           exit (1);
1310         va_end (args1); va_end (args2);
1311         }
1312         int main() {
1313           f (0, 42);
1314           return 0;
1315         }]])],
1316         [glib_cv_va_copy=yes],
1317         [glib_cv_va_copy=no])
1318 ])
1319 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1320         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1321 #include <stdlib.h>
1322         void f (int i, ...) {
1323         va_list args1, args2;
1324         va_start (args1, i);
1325         __va_copy (args2, args1);
1326         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1327           exit (1);
1328         va_end (args1); va_end (args2);
1329         }
1330         int main() {
1331           f (0, 42);
1332           return 0;
1333         }]])],
1334         [glib_cv___va_copy=yes],
1335         [glib_cv___va_copy=no])
1336 ])
1337
1338 if test "x$glib_cv_va_copy" = "xyes"; then
1339   g_va_copy_func=va_copy
1340 else if test "x$glib_cv___va_copy" = "xyes"; then
1341   g_va_copy_func=__va_copy
1342 fi
1343 fi
1344
1345 if test -n "$g_va_copy_func"; then
1346   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1347 fi
1348
1349 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1350         AC_TRY_RUN([#include <stdarg.h>
1351 #include <stdlib.h>
1352         void f (int i, ...) {
1353         va_list args1, args2;
1354         va_start (args1, i);
1355         args2 = args1;
1356         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1357           exit (1);
1358         va_end (args1); va_end (args2);
1359         }
1360         int main() {
1361           f (0, 42);
1362           return 0;
1363         }],
1364         [glib_cv_va_val_copy=yes],
1365         [glib_cv_va_val_copy=no],
1366         [glib_cv_va_val_copy=yes])
1367 ])
1368
1369 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1370   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1371 ])
1372
1373 dnl ***********************
1374 dnl *** g_module checks ***
1375 dnl ***********************
1376 G_MODULE_LIBS=
1377 G_MODULE_LIBS_EXTRA=
1378 G_MODULE_PLUGIN_LIBS=
1379 if test x"$glib_native_win32" = xyes; then
1380   dnl No use for this on Win32
1381   G_MODULE_LDFLAGS=
1382 else
1383   export SED
1384   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1385 fi
1386 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1387 G_MODULE_NEED_USCORE=0
1388 G_MODULE_BROKEN_RTLD_GLOBAL=0
1389 G_MODULE_HAVE_DLERROR=0
1390 dnl *** force native WIN32 shared lib loader
1391 if test -z "$G_MODULE_IMPL"; then
1392   case "$host" in
1393   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1394   esac
1395 fi
1396 dnl *** force native AIX library loader
1397 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1398 if test -z "$G_MODULE_IMPL"; then
1399   case "$host" in
1400   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1401   esac
1402 fi
1403 dnl *** dlopen() and dlsym() in system libraries
1404 AS_IF([ test -z "$G_MODULE_IMPL"], [
1405         AC_CHECK_FUNC(dlopen,
1406                       [AC_CHECK_FUNC(dlsym,
1407                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1408                       [])
1409 ])
1410 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1411 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1412         AC_CHECK_FUNC(NSLinkModule,
1413                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1414                        G_MODULE_NEED_USCORE=1],
1415                       [])
1416 ])
1417 dnl *** dlopen() and dlsym() in libdl
1418 AS_IF([ test -z "$G_MODULE_IMPL"], [
1419         AC_CHECK_LIB(dl, dlopen,
1420                      [AC_CHECK_LIB(dl, dlsym,
1421                                    [G_MODULE_LIBS=-ldl
1422                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1423                      [])
1424 ])
1425 dnl *** additional checks for G_MODULE_IMPL_DL
1426 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1427         LIBS_orig="$LIBS"
1428         LDFLAGS_orig="$LDFLAGS"
1429         LIBS="$G_MODULE_LIBS $LIBS"
1430         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1431 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1432         echo "void glib_plugin_test(void) { }" > plugin.c
1433         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1434                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1435         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1436                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1437                 -shrext ".o" -avoid-version plugin.lo \
1438                 -rpath /dont/care >/dev/null 2>&1
1439         eval `./libtool --config | grep ^objdir`
1440         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1441                 glib_cv_rtldglobal_broken,[
1442                 AC_TRY_RUN([
1443 #include <dlfcn.h>
1444 #ifndef RTLD_GLOBAL
1445 #  define RTLD_GLOBAL 0
1446 #endif
1447 #ifndef RTLD_LAZY
1448 #  define RTLD_LAZY 0
1449 #endif
1450 int glib_plugin_test;
1451 int main () {
1452     void *handle, *global, *local;
1453     global = &glib_plugin_test;
1454     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1455     if (!handle) return 0;
1456     local = dlsym (handle, "glib_plugin_test");
1457     return global == local;
1458 }                       ],
1459                         [glib_cv_rtldglobal_broken=no],
1460                         [glib_cv_rtldglobal_broken=yes],
1461                         [glib_cv_rtldglobal_broken=no])
1462                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1463                 rmdir ${objdir} 2>/dev/null
1464         ])
1465         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1466                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1467         else
1468                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1469         fi
1470 dnl *** check whether we need preceeding underscores
1471         AC_CACHE_CHECK([for preceeding underscore in symbols],
1472                 glib_cv_uscore,[
1473                 AC_TRY_RUN([#include <dlfcn.h>
1474                 int glib_underscore_test (void) { return 42; }
1475                 int main() {
1476                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1477                   handle = dlopen ((void*)0, 0);
1478                   if (handle) {
1479                     f1 = dlsym (handle, "glib_underscore_test");
1480                     f2 = dlsym (handle, "_glib_underscore_test");
1481                   } return (!f2 || f1);
1482                 }],
1483                         [glib_cv_uscore=yes],
1484                         [glib_cv_uscore=no],
1485                         [])
1486                 rm -f plugin.c plugin.$ac_objext plugin.lo
1487         ])
1488         GLIB_ASSERT_SET(glib_cv_uscore)
1489         if test "x$glib_cv_uscore" = "xyes"; then
1490                 G_MODULE_NEED_USCORE=1
1491         else
1492                 G_MODULE_NEED_USCORE=0
1493         fi
1494
1495         LDFLAGS="$LDFLAGS_orig"
1496 dnl *** check for having dlerror()
1497         AC_CHECK_FUNC(dlerror,
1498                 [G_MODULE_HAVE_DLERROR=1],
1499                 [G_MODULE_HAVE_DLERROR=0])
1500         LIBS="$LIBS_orig"
1501 ])
1502 dnl *** done, have we got an implementation?
1503 if test -z "$G_MODULE_IMPL"; then
1504         G_MODULE_IMPL=0
1505         G_MODULE_SUPPORTED=false
1506 else
1507         G_MODULE_SUPPORTED=true
1508 fi
1509
1510 AC_MSG_CHECKING(for the suffix of module shared libraries)
1511 export SED
1512 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1513 eval $shrext_cmds
1514 module=yes eval std_shrext=$shrext_cmds
1515 # chop the initial dot
1516 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1517 AC_MSG_RESULT(.$glib_gmodule_suffix)
1518 # any reason it may fail?
1519 if test "x$glib_gmodule_suffix" = x; then
1520         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1521 fi
1522
1523 AC_SUBST(G_MODULE_SUPPORTED)
1524 AC_SUBST(G_MODULE_IMPL)
1525 AC_SUBST(G_MODULE_LIBS)
1526 AC_SUBST(G_MODULE_LIBS_EXTRA)
1527 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1528 AC_SUBST(G_MODULE_LDFLAGS)
1529 AC_SUBST(G_MODULE_HAVE_DLERROR)
1530 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1531 AC_SUBST(G_MODULE_NEED_USCORE)
1532 AC_SUBST(GLIB_DEBUG_FLAGS)
1533
1534 dnl **********************
1535 dnl *** g_spawn checks ***
1536 dnl **********************
1537
1538 AC_MSG_CHECKING(for gspawn implementation)
1539 case "$host" in
1540   *-*-mingw*)
1541     GSPAWN=gspawn-win32.lo
1542     ;;
1543   *)
1544     GSPAWN=gspawn.lo
1545     ;;
1546 esac
1547 AC_MSG_RESULT($GSPAWN)
1548 AC_SUBST(GSPAWN)
1549
1550 dnl *************************
1551 dnl *** GIOChannel checks ***
1552 dnl *************************
1553
1554 AC_MSG_CHECKING(for GIOChannel implementation)
1555 case "$host" in
1556   *-*-mingw*)
1557     GIO=giowin32.lo
1558     ;;
1559   *)
1560     GIO=giounix.lo
1561     ;;
1562 esac
1563 AC_MSG_RESULT($GIO)
1564 AC_SUBST(GIO)
1565
1566 dnl *********************************
1567 dnl *** Directory for GIO modules ***
1568 dnl *********************************
1569
1570 AC_ARG_WITH(gio-module-dir,
1571            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1572                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1573            [],
1574            [with_gio_module_dir='${libdir}/gio/modules'])
1575 GIO_MODULE_DIR=$with_gio_module_dir
1576 AC_SUBST(GIO_MODULE_DIR)
1577
1578 dnl **********************************
1579 dnl *** Check for libselinux (GIO) ***
1580 dnl **********************************
1581 AC_ARG_ENABLE(selinux,
1582               AS_HELP_STRING([--disable-selinux],
1583                              [build without selinux support]))
1584 msg_selinux=no
1585 SELINUX_LIBS=
1586 AS_IF([ test "x$enable_selinux" != "xno"], [
1587
1588  AC_CHECK_LIB(selinux, is_selinux_enabled,
1589    [AC_CHECK_HEADERS(selinux/selinux.h,
1590      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1591        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1592         SELINUX_LIBS="-lselinux"
1593         msg_selinux=yes])
1594      ])
1595    ])
1596 ])
1597 AC_SUBST(SELINUX_LIBS)
1598
1599 dnl *****************************
1600 dnl ** Check for inotify (GIO) **
1601 dnl *****************************
1602 inotify_support=no
1603 AC_CHECK_HEADERS([sys/inotify.h],
1604 [
1605   AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1606 ])
1607
1608 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1609
1610 dnl ****************************
1611 dnl ** Check for kqueue (GIO) **
1612 dnl ****************************
1613 kqueue_support=no
1614 AC_CHECK_HEADERS([sys/event.h],
1615 [
1616         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1617 ])
1618
1619 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1620
1621 dnl ****************************
1622 dnl *** Checks for FAM (GIO) ***
1623 dnl ****************************
1624
1625 should_disable_fam=no
1626
1627 AC_ARG_ENABLE(fam,
1628               AS_HELP_STRING([--disable-fam],
1629                              [don't use fam for file system monitoring]),
1630                          [
1631                                 if test "x$enable_fam" = "xno"; then
1632                                         should_disable_fam=yes
1633                                 fi
1634                          ]
1635                          )
1636 fam_support=no
1637 FAM_LIBS=
1638 if test "x$should_disable_fam" = "xno"; then
1639 AC_CHECK_LIB(fam, FAMOpen,
1640   [AC_CHECK_HEADERS(fam.h,
1641     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1642      AC_CHECK_LIB(fam, FAMNoExists,
1643                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1644      FAM_LIBS="-lfam"]
1645      fam_support=yes,
1646     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1647   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1648 AC_SUBST(FAM_LIBS)
1649 fi
1650 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1651
1652
1653 dnl *****************************
1654 dnl *** Check for xattr (GIO) ***
1655 dnl *****************************
1656 AC_ARG_ENABLE(xattr,
1657               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1658 msg_xattr=no
1659 XATTR_LIBS=
1660 AS_IF([ test "x$enable_xattr" != "xno"], [
1661
1662 dnl either glibc or libattr can provide xattr support
1663
1664 dnl for both of them, we check for getxattr being in
1665 dnl the library and a valid xattr header.
1666
1667 dnl try glibc
1668  AC_CHECK_LIB(c, getxattr,
1669    [AC_CHECK_HEADERS(sys/xattr.h,
1670      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1671       msg_xattr=yes])
1672    ])
1673
1674   AS_IF([ test "x$msg_xattr" != "xyes"], [
1675 dnl   failure. try libattr
1676    AC_CHECK_LIB(attr, getxattr,
1677       [AC_CHECK_HEADERS(attr/xattr.h,
1678        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1679         XATTR_LIBS="-lattr"
1680         msg_xattr=yes])
1681       ])
1682   ])
1683
1684   AS_IF([ test "x$msg_xattr" = "xyes"], [
1685     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1686     AC_TRY_COMPILE([
1687       #include <stdio.h>
1688       #ifdef HAVE_SYS_TYPES_H
1689       #include <sys/types.h>
1690       #endif
1691       #ifdef HAVE_SYS_XATTR_H
1692       #include <sys/xattr.h>
1693       #elif HAVE_ATTR_XATTR_H
1694       #include <attr/xattr.h>
1695       #endif
1696     ],
1697     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1698     [
1699       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1700       AC_MSG_RESULT([yes])
1701     ],
1702     [AC_MSG_RESULT([no])]
1703     )
1704   ])
1705 ])
1706 AC_SUBST(XATTR_LIBS)
1707
1708 dnl ************************
1709 dnl *** check for libelf ***
1710 dnl ************************
1711 AC_ARG_ENABLE(libelf,
1712               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1713 AS_IF([ test "x$enable_libelf" != "xno"],[
1714 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1715 AS_IF([ test $have_libelf = maybe ], [
1716   glib_save_LIBS=$LIBS
1717   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1718   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1719   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1720   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1721   LIBS=$glib_save_LIBS
1722
1723   if test $have_libelf != no; then
1724     LIBELF_LIBS=-lelf
1725     have_libelf=yes
1726   fi
1727 ])
1728 ])
1729
1730 if test x$have_libelf = xyes; then
1731   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1732 fi
1733
1734 dnl ************************
1735 dnl *** check for libmount ***
1736 dnl ************************
1737
1738 dnl The fallback code doesn't really implement the same behaviors - e.g.
1739 dnl so on linux we want to require libmount unless specifically disabled
1740 dnl
1741 enable_libmount_default=${glib_os_linux:-no}
1742 AC_ARG_ENABLE(libmount,
1743               [AS_HELP_STRING([--enable-libmount],
1744                               [build with libmount support [default for Linux]])],,
1745               [enable_libmount=$enable_libmount_default])
1746 AS_IF([ test "x$enable_libmount" = "xyes"],[
1747 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.28], [have_libmount=yes], [have_libmount=maybe])
1748 AS_IF([ test $have_libmount = maybe ], [
1749   glib_save_LIBS=$LIBS
1750   AC_CHECK_HEADER([libmount/libmount.h], [:], [have_libmount=no])
1751   LIBS=$glib_save_LIBS
1752
1753   if test $have_libmount != no; then
1754     LIBMOUNT_LIBS=-lmount
1755     have_libmount=yes
1756   fi
1757 ])
1758 if test $have_libmount = no ; then
1759    AC_MSG_ERROR([*** Could not find libmount])
1760 fi
1761 ])
1762
1763 if test x$have_libmount = xyes; then
1764   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1765 fi
1766 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1767
1768 dnl ****************************************
1769 dnl *** platform dependent source checks ***
1770 dnl ****************************************
1771
1772 AC_MSG_CHECKING(for platform-dependent source)
1773 case "$host" in
1774   *-*-cygwin*|*-*-mingw*)
1775     PLATFORMDEP=gwin32.lo
1776     ;;
1777   *)
1778     PLATFORMDEP=
1779     ;;
1780 esac
1781 AC_MSG_RESULT($PLATFORMDEP)
1782 AC_SUBST(PLATFORMDEP)
1783
1784 AC_MSG_CHECKING([whether to compile timeloop])
1785 case "$host" in
1786   *-*-cygwin*|*-*-mingw*|*-*-minix)
1787     enable_timeloop=no
1788     ;;
1789   *)
1790     enable_timeloop=yes
1791     ;;
1792 esac
1793 AC_MSG_RESULT($enable_timeloop)
1794 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1795
1796 AC_MSG_CHECKING([if building for some Win32 platform])
1797 case "$host" in
1798   *-*-mingw*|*-*-cygwin*)
1799     platform_win32=yes
1800     ;;
1801   *)
1802     platform_win32=no
1803     ;;
1804 esac
1805 AC_MSG_RESULT($platform_win32)
1806 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1807
1808 dnl ***********************
1809 dnl *** g_thread checks ***
1810 dnl ***********************
1811
1812 AC_ARG_WITH(threads,
1813            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1814                            [specify a thread implementation to use])],
1815            [],
1816            [with_threads=yes])
1817
1818 dnl error and warning message
1819 dnl *************************
1820
1821 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1822
1823 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1824                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1825                 compilation now, but then your programs might not work.
1826                 Please provide information on how it is done on your system."
1827
1828 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1829                  "
1830
1831 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1832                   provide information on your thread implementation."
1833
1834 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1835                 functions will not be MT-safe during their first call because
1836                 there is no working 'getpwuid_r' on your system."
1837
1838 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1839                 because there is no 'localtime_r' on your system."
1840
1841 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1842                 linking threaded applications. As GLib cannot do that
1843                 automatically, you will get an linkg error everytime you are
1844                 not using the right compiler. In that case you have to relink
1845                 with the right compiler. Ususally just '_r' is appended
1846                 to the compiler name."
1847
1848 dnl determination of thread implementation
1849 dnl ***************************************
1850
1851 AC_MSG_CHECKING(for thread implementation)
1852
1853 have_threads=no
1854 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1855         AS_IF([ test "x$have_threads" = xno], [
1856                 AC_TRY_COMPILE([#include <pthread.h>],
1857                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1858                         have_threads=posix)
1859         ])
1860         # Tru64Unix requires -pthread to find pthread.h. See #103020
1861         if test "x$have_threads" = xno; then
1862                 glib_save_CPPFLAGS="$CPPFLAGS"
1863                 CPPFLAGS="$CPPFLAGS -pthread"
1864                 AC_TRY_COMPILE([#include <pthread.h>],
1865                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1866                        have_threads=posix)
1867                 CPPFLAGS="$glib_save_CPPFLAGS"
1868         fi
1869 ])
1870 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1871         case $host in
1872                 *-*-mingw*)
1873                 have_threads=win32
1874                 ;;
1875         esac
1876 fi
1877
1878 if test "x$have_threads" = xno; then
1879         AC_MSG_RESULT(none available)
1880         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1881 else
1882         AC_MSG_RESULT($have_threads)
1883 fi
1884
1885
1886 dnl determination of G_THREAD_CFLAGS
1887 dnl ********************************
1888
1889 G_THREAD_LIBS=
1890 G_THREAD_LIBS_EXTRA=
1891 G_THREAD_CFLAGS=
1892
1893 dnl
1894 dnl Test program for basic POSIX threads functionality
1895 dnl
1896 m4_define([glib_thread_test],[
1897 #include <pthread.h>
1898 int check_me = 0;
1899 void* func(void* data) {check_me = 42; return &check_me;}
1900 int main()
1901  { pthread_t t;
1902    void *ret;
1903    pthread_create (&t, $1, func, 0);
1904    pthread_join (t, &ret);
1905    return (check_me != 42 || ret != &check_me);
1906 }])
1907
1908 AS_IF([ test x"$have_threads" = xposix], [
1909   # First we test for posix, whether -pthread or -pthreads do the trick as
1910   # both CPPFLAG and LIBS.
1911   # One of them does for most gcc versions and some other platforms/compilers
1912   # too and could be considered as the canonical way to go.
1913   case $host in
1914     *-*-cygwin*|*-*-darwin*)
1915        # skip cygwin and darwin -pthread or -pthreads test
1916        ;;
1917     *-solaris*)
1918       # These compiler/linker flags work with both Sun Studio and gcc
1919       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1920       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1921       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1922       G_THREAD_LIBS="-lpthread -lthread"
1923       ;;
1924     *)
1925       for flag in pthread pthreads mt; do
1926         glib_save_CFLAGS="$CFLAGS"
1927         CFLAGS="$CFLAGS -$flag"
1928         AC_TRY_RUN(glib_thread_test(0),
1929                    glib_flag_works=yes,
1930                    glib_flag_works=no,
1931                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1932                                    glib_flag_works=yes,
1933                                    glib_flag_works=no)])
1934         CFLAGS="$glib_save_CFLAGS"
1935         if test $glib_flag_works = yes ; then
1936            G_THREAD_CFLAGS=-$flag
1937         G_THREAD_LIBS=-$flag
1938         break;
1939         fi
1940       done
1941        ;;
1942   esac
1943 ])
1944
1945 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1946
1947   # The canonical -pthread[s] does not work. Try something different.
1948
1949   case $host in
1950         *-aix*)
1951                 if test x"$GCC" = xyes; then
1952                         # GCC 3.0 and above needs -pthread.
1953                         # Should be coverd by the case above.
1954                         # GCC 2.x and below needs -mthreads
1955                         G_THREAD_CFLAGS="-mthreads"
1956                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1957                 else
1958                         # We are probably using the aix compiler. Normaly a
1959                         # program would have to be compiled with the _r variant
1960                         # of the corresponding compiler, but we as GLib cannot
1961                         # do that: but the good news is that for compiling the
1962                         # only difference is the added -D_THREAD_SAFE compile
1963                         # option. This is according to the "C for AIX User's
1964                         # Guide".
1965                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1966                 fi
1967                 ;;
1968         *-sysv5uw7*) # UnixWare 7
1969                 # We are not using gcc with -pthread. Catched above.
1970                 G_THREAD_CFLAGS="-Kthread"
1971                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1972                 ;;
1973         *-mingw*)
1974                 # No flag needed when using MSVCRT.DLL
1975                 G_THREAD_CFLAGS=""
1976                 ;;
1977         *)
1978                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1979                 ;;
1980   esac
1981 ])
1982
1983 # if we are not finding the localtime_r function, then we probably are
1984 # not using the proper multithread flag
1985
1986 glib_save_CPPFLAGS="$CPPFLAGS"
1987 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1988
1989 # First we test, whether localtime_r is declared in time.h
1990 # directly. Then we test whether a macro localtime_r exists, in
1991 # which case localtime_r in the test program is replaced and thus
1992 # if we still find localtime_r in the output, it is not defined as
1993 # a macro.
1994
1995 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1996   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1997                                                            localtime_r(a,b)],
1998                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1999
2000 CPPFLAGS="$glib_save_CPPFLAGS"
2001
2002 AC_MSG_CHECKING(thread related cflags)
2003 AC_MSG_RESULT($G_THREAD_CFLAGS)
2004 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2005
2006 dnl determination of G_THREAD_LIBS
2007 dnl ******************************
2008
2009 AS_IF([test x$have_threads = xposix], [
2010           glib_save_CPPFLAGS="$CPPFLAGS"
2011           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2012           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2013             case $host in
2014               *-aix*)
2015                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2016                 # probably using the aix compiler.
2017                 AC_MSG_WARN($AIX_COMPILE_INFO)
2018                 ;;
2019               *)
2020                 G_THREAD_LIBS=error
2021                 glib_save_LIBS="$LIBS"
2022                 for thread_lib in "" pthread pthread32 pthreads thread; do
2023                         if test x"$thread_lib" = x; then
2024                                 add_thread_lib=""
2025                                 IN=""
2026                         else
2027                                 add_thread_lib="-l$thread_lib"
2028                                 IN=" in -l$thread_lib"
2029                         fi
2030                         if test x"$have_threads" = xposix; then
2031                                 defattr=0
2032                         else
2033                                 defattr=pthread_attr_default
2034                         fi
2035
2036                         LIBS="$add_thread_lib $glib_save_LIBS"
2037
2038                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2039                         AC_TRY_RUN(glib_thread_test($defattr),
2040                                    glib_result=yes,
2041                                    glib_result=no,
2042                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2043                                                    glib_result=yes,
2044                                                    glib_result=no)])
2045                         AC_MSG_RESULT($glib_result)
2046
2047                         if test "$glib_result" = "yes" ; then
2048                           G_THREAD_LIBS="$add_thread_lib"
2049                           break
2050                         fi
2051                 done
2052                 if test "x$G_THREAD_LIBS" = xerror; then
2053                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2054                 fi
2055                 LIBS="$glib_save_LIBS"
2056                 ;;
2057             esac
2058           ])
2059
2060           g_threads_impl="POSIX"
2061           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2062           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2063           CPPFLAGS="$glib_save_CPPFLAGS"
2064 ], [test x$have_threads = xwin32], [
2065            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2066            g_threads_impl="WIN32"
2067 ], [
2068            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2069            g_threads_impl="NONE"
2070            G_THREAD_LIBS=error
2071 ])
2072 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2073 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2074 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2075
2076 if test "x$G_THREAD_LIBS" = xerror; then
2077         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2078 fi
2079
2080 AC_MSG_CHECKING(thread related libraries)
2081 AC_MSG_RESULT($G_THREAD_LIBS)
2082
2083 dnl check for mt safe function variants and some posix functions
2084 dnl ************************************************************
2085
2086 glib_save_LIBS="$LIBS"
2087 # we are not doing the following for now, as this might require glib
2088 # to always be linked with the thread libs on some platforms.
2089 # LIBS="$LIBS $G_THREAD_LIBS"
2090 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2091
2092 LIBS="$G_THREAD_LIBS $LIBS"
2093 AS_IF([ test x"$have_threads" = xposix], [
2094         glib_save_CPPFLAGS="$CPPFLAGS"
2095         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2096         # This is not AC_CHECK_FUNC to also work with function
2097         # name mangling in header files.
2098         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2099         AC_LINK_IFELSE(
2100             [AC_LANG_PROGRAM(
2101                 [#include <pthread.h>],
2102                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2103             [AC_MSG_RESULT(yes)
2104              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2105                 [Have function pthread_attr_setstacksize])],
2106             [AC_MSG_RESULT(no)])
2107         AC_MSG_CHECKING(for pthread_condattr_setclock)
2108         AC_LINK_IFELSE(
2109             [AC_LANG_PROGRAM(
2110                 [#include <pthread.h>],
2111                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2112             [AC_MSG_RESULT(yes)
2113              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2114                 [Have function pthread_condattr_setclock])],
2115             [AC_MSG_RESULT(no)])
2116         AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2117         AC_LINK_IFELSE(
2118             [AC_LANG_PROGRAM(
2119                 [#include <pthread.h>],
2120                 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2121             [AC_MSG_RESULT(yes)
2122              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2123                 [Have function pthread_cond_timedwait_relative_np])],
2124             [AC_MSG_RESULT(no)])
2125         dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2126         AC_MSG_CHECKING(for pthread_setname_np(const char*))
2127         AC_LINK_IFELSE(
2128             [AC_LANG_PROGRAM(
2129                 [#include <pthread.h>],
2130                 [pthread_setname_np("example")])],
2131             [AC_MSG_RESULT(yes)
2132              AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2133                 [Have function pthread_setname_np(const char*)])],
2134             [AC_MSG_RESULT(no)])
2135         dnl Sets thread names on Solaris 11.3 & higher
2136         AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2137         AC_LINK_IFELSE(
2138             [AC_LANG_PROGRAM(
2139                 [#include <pthread.h>],
2140                 [pthread_setname_np(pthread_self(), "example")])],
2141             [AC_MSG_RESULT(yes)
2142              AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2143                 [Have function pthread_setname_np(pthread_t, const char*)])],
2144             [AC_MSG_RESULT(no)])
2145         CPPFLAGS="$glib_save_CPPFLAGS"
2146 ])
2147
2148 LIBS="$glib_save_LIBS"
2149
2150 # now spit out all the warnings.
2151 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2152         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2153 fi
2154 if test "$ac_cv_func_localtime_r" != "yes"; then
2155         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2156 fi
2157
2158 #
2159 # Hack to deal with:
2160 #
2161 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2162 #     building shared libraries with linux.
2163 #  b) FreeBSD doesn't do this either.
2164 #
2165 case $host in
2166   *android*)
2167     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2168     ;;
2169   *-*-freebsd*|*-*-linux*)
2170     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2171     ;;
2172   *)
2173     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2174     ;;
2175 esac
2176
2177 AC_SUBST(G_THREAD_CFLAGS)
2178 AC_SUBST(G_THREAD_LIBS)
2179 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2180 AC_SUBST(G_THREAD_LIBS_EXTRA)
2181
2182 AC_CHECK_FUNCS(clock_gettime, [], [
2183   AC_CHECK_LIB(rt, clock_gettime, [
2184     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2185     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2186   ])
2187 ])
2188
2189
2190 dnl ************************
2191 dnl *** g_atomic_* tests ***
2192 dnl ************************
2193
2194 dnl We need to decide at configure time if GLib will use real atomic
2195 dnl operations ("lock free") or emulated ones with a mutex.  This is
2196 dnl because we must put this information in glibconfig.h so we know if
2197 dnl it is safe or not to inline using compiler intrinsics directly from
2198 dnl the header.
2199 dnl
2200 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2201 dnl user is interested in knowing if they can use the atomic ops across
2202 dnl processes.
2203 dnl
2204 dnl We can currently support the atomic ops natively when building GLib
2205 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2206 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2207 dnl we are using GCC (and not mingw*).
2208 dnl
2209 dnl Note that the atomic ops are only available with GCC on x86 when
2210 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2211 dnl not available but would be available given the right flags, we want
2212 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2213 dnl that then to silently fall back on emulated atomic ops just because
2214 dnl the user had the wrong build environment.
2215
2216 dnl We may add other compilers here in the future...
2217
2218 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2219   case $host in
2220     *-*-mingw*)
2221       glib_cv_g_atomic_lock_free=yes
2222       ;;
2223     *)
2224       AC_TRY_LINK([],
2225                      [volatile int atomic = 2;\
2226                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2227                      [glib_cv_g_atomic_lock_free=yes],
2228                      [glib_cv_g_atomic_lock_free=no])
2229       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2230         SAVE_CFLAGS="${CFLAGS}"
2231         CFLAGS="-march=i486"
2232         AC_TRY_LINK([],
2233                        [volatile int atomic = 2;\
2234                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2235                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2236                        [])
2237         CFLAGS="${SAVE_CFLAGS}"
2238       fi
2239       ;;
2240   esac])
2241
2242
2243 case $host in
2244   *-*-mingw*)
2245     ;;
2246   *)
2247     # Some compilers support atomic operations but do not define
2248     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2249     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2250       AC_TRY_LINK([],
2251                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2252                      [],
2253                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2254     fi
2255     ;;
2256  esac
2257
2258 dnl We need a more robust approach here...
2259 case $host_cpu in
2260   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2261     glib_memory_barrier_needed=no
2262     ;;
2263   sparc*|alpha*|powerpc*|ia64)
2264     glib_memory_barrier_needed=yes
2265     ;;
2266   *)
2267     glib_memory_barrier_needed=yes
2268     ;;
2269 esac
2270
2271 dnl ************************
2272 dnl ** Check for futex(2) **
2273 dnl ************************
2274 AC_CACHE_CHECK(for futex(2) system call,
2275     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2276 #include <linux/futex.h>
2277 #include <sys/syscall.h>
2278 #include <unistd.h>
2279 ],[
2280   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2281 ])],glib_cv_futex=yes,glib_cv_futex=no))
2282 if test x"$glib_cv_futex" = xyes; then
2283   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2284 fi
2285
2286 AC_CACHE_CHECK(for eventfd(2) system call,
2287     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2288 #include <sys/eventfd.h>
2289 #include <unistd.h>
2290 ],[
2291   eventfd (0, EFD_CLOEXEC);
2292 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2293 if test x"$glib_cv_eventfd" = x"yes"; then
2294   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2295 fi
2296 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2297
2298 dnl ****************************************
2299 dnl *** GLib POLL* compatibility defines ***
2300 dnl ****************************************
2301
2302 glib_poll_includes=["
2303 #include <sys/types.h>
2304 #include <poll.h>
2305 "]
2306
2307 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2308    test $ac_cv_func_poll = yes ], [
2309   glib_failed=false
2310   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2311   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2312   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2313   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2314   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2315   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2316   if $glib_failed ; then
2317     AC_MSG_ERROR([Could not determine values for POLL* constants])
2318   fi
2319 ], [
2320   glib_cv_value_POLLIN=1
2321   glib_cv_value_POLLOUT=4
2322   glib_cv_value_POLLPRI=2
2323   glib_cv_value_POLLERR=8
2324   glib_cv_value_POLLHUP=16
2325   glib_cv_value_POLLNVAL=32
2326 ])
2327
2328 AC_MSG_CHECKING([for broken poll])
2329 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2330         #include <stdlib.h>
2331         #include <fcntl.h>
2332         #include <poll.h>
2333         int main(void) {
2334           struct pollfd fds[1];
2335           int fd;
2336           fd = open("/dev/null", 1);
2337           fds[0].fd = fd;
2338           fds[0].events = POLLIN;
2339           fds[0].revents = 0;
2340           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2341                 exit(1);  /* Does not work for devices -- fail */
2342           }
2343           exit(0);
2344         }]])],
2345   [broken_poll=no],
2346   [broken_poll=yes
2347    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2348   [broken_poll="no (cross compiling)"])
2349 AC_MSG_RESULT($broken_poll)
2350
2351 dnl *********************
2352 dnl *** GRegex checks ***
2353 dnl *********************
2354
2355 PCRE_REQUIRED_VERSION=8.13
2356
2357 # Check if we should use the internal or the system-supplied pcre
2358 AC_ARG_WITH(pcre,
2359             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2360                             [whether to use system PCRE [default=system]])],
2361             [],
2362             [with_pcre=system])
2363
2364 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2365
2366 AS_IF([ test "x$with_pcre" = xsystem], [
2367   PKG_CHECK_MODULES(PCRE,
2368                     libpcre >= $PCRE_REQUIRED_VERSION)
2369   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2370                   glib_save_CFLAGS="$CFLAGS"
2371                   glib_save_LIBS="$LIBS"
2372                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2373                   AC_TRY_RUN([#include <pcre.h>
2374                               int main () {
2375                                 int support;
2376                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2377                                 if (!support)
2378                                   return 1;
2379                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2380                                 if (!support)
2381                                   return 1;
2382                                 return 0;
2383                               }],
2384                   glib_cv_pcre_has_unicode=yes,
2385                   glib_cv_pcre_has_unicode=no,
2386                   glib_cv_pcre_has_unicode=yes)
2387                   CFLAGS="$glib_save_CFLAGS"
2388                   LIBS="$glib_save_LIBS"
2389       ])
2390   if test "$glib_cv_pcre_has_unicode" = "no"; then
2391     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2392   fi
2393   AC_SUBST(PCRE_CFLAGS)
2394   AC_SUBST(PCRE_LIBS)
2395   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2396   PCRE_REQUIRES=libpcre
2397   AC_SUBST(PCRE_REQUIRES)
2398 ], [
2399   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2400   AS_IF([ test x"$GCC" = xyes], [
2401     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2402     save_CFLAGS="$CFLAGS"
2403     CFLAGS="$CFLAGS -Wno-pointer-sign"
2404     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2405                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2406     CFLAGS="$save_CFLAGS"
2407   ])
2408 ])
2409 AC_SUBST(PCRE_WARN_CFLAGS)
2410
2411 dnl **********************
2412 dnl *** Win32 API libs ***
2413 dnl **********************
2414
2415 case $host in
2416   *-*-cygwin*)
2417         G_LIBS_EXTRA="-luser32 -lkernel32"
2418     ;;
2419   *-*-mingw*)
2420         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2421     ;;
2422   *)
2423         G_LIBS_EXTRA=""
2424     ;;
2425 esac
2426 AC_SUBST(G_LIBS_EXTRA)
2427
2428 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2429 dnl since we need it for g_iconv()
2430
2431 AC_MSG_CHECKING([for EILSEQ])
2432 AC_TRY_COMPILE([
2433 #include <errno.h>
2434 ],
2435 [
2436 int error = EILSEQ;
2437 ], have_eilseq=yes, have_eilseq=no);
2438 AC_MSG_RESULT($have_eilseq)
2439
2440 dnl Add a conditional we can use when cross-compiling, so we avoid running
2441 dnl binaries
2442 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2443
2444 dnl **************************
2445 dnl *** Checks for gtk-doc ***
2446 dnl **************************
2447 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2448 # it on it's own line.
2449 m4_ifdef([GTK_DOC_CHECK], [
2450 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2451 ],[
2452 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2453 ])
2454
2455 AC_ARG_ENABLE(man,
2456               [AS_HELP_STRING([--enable-man],
2457                               [generate man pages [default=auto]])],,
2458               enable_man=maybe)
2459
2460 AS_IF([test "$enable_man" != no], [
2461   AC_PATH_PROG([XSLTPROC], [xsltproc])
2462   AS_IF([test -z "$XSLTPROC"], [
2463     AS_IF([test "$enable_man" = yes], [
2464       AC_MSG_ERROR([xsltproc is required for --enable-man])
2465     ])
2466     enable_man=no
2467   ])
2468 ])
2469
2470 AS_IF([ test "$enable_man" != no ], [
2471   dnl check for DocBook DTD in the local catalog
2472   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2473      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2474   AS_IF([test "$have_docbook_dtd" != yes], [
2475     AS_IF([test "$enable_man" = yes ], [
2476       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2477     ])
2478     enable_man=no
2479   ])
2480 ])
2481
2482 AS_IF([test "$enable_man" != no], [
2483   dnl check for DocBook XSL stylesheets in the local catalog
2484   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2485      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2486   AS_IF([ test "$have_docbook_style" != yes ], [
2487     AS_IF([ test "$enable_man" = yes ], [
2488       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2489     ])
2490     enable_man=no
2491   ])
2492 ])
2493
2494 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2495
2496 AC_MSG_CHECKING([whether to generate man pages])
2497 AS_IF([ test "$enable_man" != no ], [
2498   AC_MSG_RESULT([yes])
2499 ], [
2500   AC_MSG_RESULT([no])
2501 ])
2502
2503 dnl
2504 dnl Tracing
2505 dnl
2506
2507 AC_ARG_ENABLE([dtrace],
2508              [AS_HELP_STRING([--enable-dtrace],
2509                               [include tracing support for dtrace])])
2510 have_dtrace=no
2511 AC_MSG_CHECKING([whether to include dtrace tracing support])
2512 AS_IF([ test "x$enable_dtrace" != xno], [
2513   if test x$glib_have_carbon = xyes; then
2514     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2515   else
2516     AC_MSG_RESULT([yes])
2517     AC_CHECK_PROGS(DTRACE, dtrace)
2518     if test -z "$DTRACE"; then
2519       if test "x$enable_dtrace" = xyes; then
2520         AC_MSG_ERROR([dtrace not found])
2521       fi
2522     else
2523       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2524                       [if test "x$enable_dtrace" = xyes; then
2525                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2526                        fi])
2527     fi
2528   fi
2529 ], [
2530   AC_MSG_RESULT([no])
2531 ])
2532 if test "x$have_dtrace" = xyes; then
2533   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2534 fi
2535 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2536
2537 AC_MSG_CHECKING([whether to include systemtap tracing support])
2538 AC_ARG_ENABLE([systemtap],
2539              [AS_HELP_STRING([--enable-systemtap],
2540                               [include tracing support for systemtap])])
2541 have_systemtap=no
2542 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2543   have_systemtap=yes
2544 fi
2545 AC_MSG_RESULT(${have_systemtap})
2546
2547 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2548
2549 AC_ARG_WITH([tapset-install-dir],
2550             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2551                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2552             [if test "x${withval}" = x; then
2553                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2554              else
2555                ABS_TAPSET_DIR="${withval}"
2556               fi],
2557             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2558 AC_SUBST(ABS_TAPSET_DIR)
2559
2560 dnl ************************************
2561 dnl *** Enable lcov coverage reports ***
2562 dnl ************************************
2563
2564 AC_ARG_ENABLE(coverage,
2565   AS_HELP_STRING([--enable-coverage],
2566                  [enable coverage testing with gcov]),
2567   [use_gcov=$enableval], [use_gcov=no])
2568
2569 AS_IF([ test "x$use_gcov" = "xyes"], [
2570   dnl we need gcc:
2571   if test "$GCC" != "yes"; then
2572     AC_MSG_ERROR([GCC is required for --enable-coverage])
2573   fi
2574
2575   dnl Check if ccache is being used
2576   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2577   case `$SHTOOL path $CC` in
2578     *ccache*[)] gcc_ccache=yes;;
2579     *[)] gcc_ccache=no;;
2580   esac
2581
2582   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2583     AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2584   fi
2585
2586   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2587   AC_CHECK_PROG(LTP, lcov, lcov)
2588   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2589
2590   AS_IF([ test "$LTP" ], [
2591     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2592       glib_cv_ltp_version=invalid
2593       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2594       for ltp_check_version in $ltp_version_list; do
2595         if test "$ltp_version" = "$ltp_check_version"; then
2596           glib_cv_ltp_version="$ltp_check_version (ok)"
2597         fi
2598       done
2599     ])
2600   ], [
2601     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2602     AC_MSG_ERROR([$ltp_msg])
2603   ])
2604
2605   case $glib_cv_ltp_version in
2606     ""|invalid[)]
2607       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2608       AC_MSG_ERROR([$ltp_msg])
2609       LTP="exit 0;"
2610       ;;
2611   esac
2612
2613   if test -z "$LTP_GENHTML"; then
2614     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2615   fi
2616
2617   dnl Remove all optimization flags from CFLAGS
2618   changequote({,})
2619   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2620   changequote([,])
2621
2622   dnl Add the special gcc flags
2623   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2624   LDFLAGS="$LDFLAGS -lgcov"
2625 ])
2626
2627 dnl ******************************
2628 dnl *** output the whole stuff ***
2629 dnl ******************************
2630
2631 dnl this section will only be run if config.status is invoked with no
2632 dnl arguments, or with "glib/glibconfig.h" as an argument.
2633 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2634 [
2635         outfile=glib/glibconfig.h-tmp
2636         cat > $outfile <<\_______EOF
2637 /* glibconfig.h
2638  *
2639  * This is a generated file.  Please modify 'configure.ac'
2640  */
2641
2642 #ifndef __GLIBCONFIG_H__
2643 #define __GLIBCONFIG_H__
2644
2645 #include <glib/gmacros.h>
2646
2647 _______EOF
2648
2649         echo '#include <limits.h>' >> $outfile
2650         echo '#include <float.h>' >> $outfile
2651         if test x$glib_values_h = xyes; then
2652           echo '#include <values.h>' >> $outfile
2653         fi
2654         if test "$glib_header_alloca_h" = "yes"; then
2655           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2656         fi
2657         if test x$glib_included_printf != xyes; then
2658           echo "
2659 /* Specifies that GLib's g_print*() functions wrap the
2660  * system printf functions.  This is useful to know, for example,
2661  * when using glibc's register_printf_function().
2662  */" >> $outfile
2663           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2664         fi
2665
2666         cat >> $outfile <<_______EOF
2667
2668 G_BEGIN_DECLS
2669
2670 #define G_MINFLOAT      FLT_MIN
2671 #define G_MAXFLOAT      FLT_MAX
2672 #define G_MINDOUBLE     DBL_MIN
2673 #define G_MAXDOUBLE     DBL_MAX
2674 #define G_MINSHORT      SHRT_MIN
2675 #define G_MAXSHORT      SHRT_MAX
2676 #define G_MAXUSHORT     USHRT_MAX
2677 #define G_MININT        INT_MIN
2678 #define G_MAXINT        INT_MAX
2679 #define G_MAXUINT       UINT_MAX
2680 #define G_MINLONG       LONG_MIN
2681 #define G_MAXLONG       LONG_MAX
2682 #define G_MAXULONG      ULONG_MAX
2683
2684 _______EOF
2685
2686
2687         ### this should always be true in a modern C/C++ compiler
2688         ### and is statically asserted by glib-init.c
2689         cat >>$outfile <<_______EOF
2690 typedef signed char gint8;
2691 typedef unsigned char guint8;
2692 _______EOF
2693
2694
2695         if test -n "$gint16"; then
2696           cat >>$outfile <<_______EOF
2697 typedef signed $gint16 gint16;
2698 typedef unsigned $gint16 guint16;
2699 #define G_GINT16_MODIFIER $gint16_modifier
2700 #define G_GINT16_FORMAT $gint16_format
2701 #define G_GUINT16_FORMAT $guint16_format
2702 _______EOF
2703         fi
2704
2705
2706         if test -n "$gint32"; then
2707           cat >>$outfile <<_______EOF
2708 typedef signed $gint32 gint32;
2709 typedef unsigned $gint32 guint32;
2710 #define G_GINT32_MODIFIER $gint32_modifier
2711 #define G_GINT32_FORMAT $gint32_format
2712 #define G_GUINT32_FORMAT $guint32_format
2713 _______EOF
2714         fi
2715
2716         cat >>$outfile <<_______EOF
2717 #define G_HAVE_GINT64 1          /* deprecated, always true */
2718
2719 ${glib_extension}typedef signed $gint64 gint64;
2720 ${glib_extension}typedef unsigned $gint64 guint64;
2721
2722 #define G_GINT64_CONSTANT(val)  $gint64_constant
2723 #define G_GUINT64_CONSTANT(val) $guint64_constant
2724 _______EOF
2725
2726         if test x$gint64_format != x ; then
2727           cat >>$outfile <<_______EOF
2728 #define G_GINT64_MODIFIER $gint64_modifier
2729 #define G_GINT64_FORMAT $gint64_format
2730 #define G_GUINT64_FORMAT $guint64_format
2731 _______EOF
2732         else
2733           cat >>$outfile <<_______EOF
2734 #undef G_GINT64_MODIFIER
2735 #undef G_GINT64_FORMAT
2736 #undef G_GUINT64_FORMAT
2737 _______EOF
2738         fi
2739
2740         cat >>$outfile <<_______EOF
2741
2742 #define GLIB_SIZEOF_VOID_P $glib_void_p
2743 #define GLIB_SIZEOF_LONG   $glib_long
2744 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2745 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2746
2747 _______EOF
2748
2749         cat >>$outfile <<_______EOF
2750 typedef signed $glib_ssize_type_define gssize;
2751 typedef unsigned $glib_size_type_define gsize;
2752 #define G_GSIZE_MODIFIER $gsize_modifier
2753 #define G_GSSIZE_MODIFIER $gssize_modifier
2754 #define G_GSIZE_FORMAT $gsize_format
2755 #define G_GSSIZE_FORMAT $gssize_format
2756
2757 #define G_MAXSIZE       G_MAXU$glib_msize_type
2758 #define G_MINSSIZE      G_MIN$glib_mssize_type
2759 #define G_MAXSSIZE      G_MAX$glib_mssize_type
2760
2761 typedef gint64 goffset;
2762 #define G_MINOFFSET     G_MININT64
2763 #define G_MAXOFFSET     G_MAXINT64
2764
2765 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2766 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2767 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2768
2769 #define G_POLLFD_FORMAT $g_pollfd_format
2770
2771 _______EOF
2772
2773         if test -z "$glib_unknown_void_p"; then
2774           cat >>$outfile <<_______EOF
2775
2776 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2777 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2778
2779 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2780 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2781
2782 typedef signed $glib_intptr_type_define gintptr;
2783 typedef unsigned $glib_intptr_type_define guintptr;
2784
2785 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2786 #define G_GINTPTR_FORMAT        $gintptr_format
2787 #define G_GUINTPTR_FORMAT       $guintptr_format
2788 _______EOF
2789         else
2790           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2791         fi
2792
2793
2794
2795         cat >>$outfile <<_______EOF
2796 #ifndef G_DISABLE_DEPRECATED
2797 #define g_ATEXIT(proc)  (atexit (proc))
2798 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2799 #endif
2800 $glib_defines
2801 $glib_os
2802 $glib_static_compilation
2803
2804 $glib_vacopy
2805
2806 _______EOF
2807
2808         if test x$g_have_iso_c_varargs = xyes ; then
2809                 cat >>$outfile <<_______EOF
2810 #ifndef __cplusplus
2811 # define G_HAVE_ISO_VARARGS 1
2812 #endif
2813 _______EOF
2814         fi
2815         if test x$g_have_iso_cxx_varargs = xyes ; then
2816                 cat >>$outfile <<_______EOF
2817 #ifdef __cplusplus
2818 # define G_HAVE_ISO_VARARGS 1
2819 #endif
2820 _______EOF
2821         fi
2822         if test x$g_have_gnuc_varargs = xyes ; then
2823                 cat >>$outfile <<_______EOF
2824
2825 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2826  * is passed ISO vararg support is turned off, and there is no work
2827  * around to turn it on, so we unconditionally turn it off.
2828  */
2829 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2830 #  undef G_HAVE_ISO_VARARGS
2831 #endif
2832
2833 #define G_HAVE_GNUC_VARARGS 1
2834 _______EOF
2835         fi
2836
2837         case x$g_stack_grows in
2838         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2839         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2840         esac
2841
2842
2843         echo >>$outfile
2844         if test x$g_have_eilseq = xno; then
2845                 cat >>$outfile <<_______EOF
2846 #ifndef EILSEQ
2847 /* On some pre-C99 systems, EILSEQ is not defined.
2848  * The correspondence between this and the corresponding definition
2849  * in libiconv is essential.
2850  */
2851 #  define EILSEQ ENOENT
2852 #endif
2853 _______EOF
2854
2855         fi
2856
2857         if test x$g_have_gnuc_visibility = xyes; then
2858                 cat >>$outfile <<_______EOF
2859 #define G_HAVE_GNUC_VISIBILITY 1
2860 _______EOF
2861         fi
2862                 cat >>$outfile <<_______EOF
2863 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2864 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2865 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2866 #define G_GNUC_INTERNAL __hidden
2867 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2868 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2869 #else
2870 #define G_GNUC_INTERNAL
2871 #endif
2872 _______EOF
2873
2874         echo >>$outfile
2875         cat >>$outfile <<_______EOF
2876 #define G_THREADS_ENABLED
2877 #define G_THREADS_IMPL_$g_threads_impl_def
2878 _______EOF
2879
2880         if test x"$g_memory_barrier_needed" != xno; then
2881           echo >>$outfile
2882           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2883         fi
2884         if test x"$g_atomic_lock_free" = xyes; then
2885           echo >>$outfile
2886           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2887         fi
2888         echo >>$outfile
2889         g_bit_sizes="16 32 64"
2890         for bits in $g_bit_sizes; do
2891           cat >>$outfile <<_______EOF
2892 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2893 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2894 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2895 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2896 _______EOF
2897         done
2898
2899         cat >>$outfile <<_______EOF
2900 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2901 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2902 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2903 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2904 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2905 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2906 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2907 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2908 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
2909 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
2910 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
2911 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
2912 #define G_BYTE_ORDER $g_byte_order
2913
2914 #define GLIB_SYSDEF_POLLIN =$g_pollin
2915 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2916 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2917 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2918 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2919 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2920
2921 #define G_MODULE_SUFFIX "$g_module_suffix"
2922
2923 typedef $g_pid_type GPid;
2924 #define G_PID_FORMAT $g_pid_format
2925
2926 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2927 #define GLIB_SYSDEF_AF_INET $g_af_inet
2928 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2929
2930 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2931 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2932 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2933
2934 G_END_DECLS
2935
2936 #endif /* __GLIBCONFIG_H__ */
2937 _______EOF
2938
2939
2940         if cmp -s $outfile glib/glibconfig.h; then
2941           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
2942           rm -f $outfile
2943         else
2944           mv $outfile glib/glibconfig.h
2945         fi
2946 ],[
2947
2948 # Note that if two cases are the same, case goes with the first one.
2949 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2950 # on variable expansion in case labels.  Look at the generated config.status
2951 # for a hint.
2952
2953 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2954   glib_header_alloca_h="$ac_cv_working_alloca_h"
2955 else
2956   glib_header_alloca_h="$ac_cv_header_alloca_h"
2957 fi
2958
2959 if test x$enable_included_printf = xyes ; then
2960   glib_included_printf=yes
2961 fi
2962
2963 case 2 in
2964 $ac_cv_sizeof_short)
2965   gint16=short
2966   gint16_modifier='"h"'
2967   gint16_format='"hi"'
2968   guint16_format='"hu"'
2969   ;;
2970 $ac_cv_sizeof_int)
2971   gint16=int
2972   gint16_modifier='""'
2973   gint16_format='"i"'
2974   guint16_format='"u"'
2975   ;;
2976 esac
2977 case 4 in
2978 $ac_cv_sizeof_short)
2979   gint32=short
2980   gint32_modifier='"h"'
2981   gint32_format='"hi"'
2982   guint32_format='"hu"'
2983   ;;
2984 $ac_cv_sizeof_int)
2985   gint32=int
2986   gint32_modifier='""'
2987   gint32_format='"i"'
2988   guint32_format='"u"'
2989   ;;
2990 $ac_cv_sizeof_long)
2991   gint32=long
2992   gint32_modifier='"l"'
2993   gint32_format='"li"'
2994   guint32_format='"lu"'
2995   ;;
2996 esac
2997 case 8 in
2998 $ac_cv_sizeof_int)
2999   gint64=int
3000   gint64_modifier='""'
3001   gint64_format='"i"'
3002   guint64_format='"u"'
3003   glib_extension=
3004   gint64_constant='(val)'
3005   guint64_constant='(val)'
3006   ;;
3007 $ac_cv_sizeof_long)
3008   gint64=long
3009   gint64_modifier='"l"'
3010   gint64_format='"li"'
3011   guint64_format='"lu"'
3012   glib_extension=
3013   gint64_constant='(val##L)'
3014   guint64_constant='(val##UL)'
3015   ;;
3016 $ac_cv_sizeof_long_long)
3017   gint64='long long'
3018   if test -n "$glib_cv_long_long_format"; then
3019     gint64_modifier='"'$glib_cv_long_long_format'"'
3020     gint64_format='"'$glib_cv_long_long_format'i"'
3021     guint64_format='"'$glib_cv_long_long_format'u"'
3022   fi
3023   glib_extension='G_GNUC_EXTENSION '
3024   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3025   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3026   ;;
3027 $ac_cv_sizeof___int64)
3028   gint64='__int64'
3029   if test -n "$glib_cv_long_long_format"; then
3030     gint64_modifier='"'$glib_cv_long_long_format'"'
3031     gint64_format='"'$glib_cv_long_long_format'i"'
3032     guint64_format='"'$glib_cv_long_long_format'u"'
3033   fi
3034   glib_extension=
3035   gint64_constant='(val##i64)'
3036   guint64_constant='(val##ui64)'
3037   ;;
3038 esac
3039 glib_size_t=$ac_cv_sizeof_size_t
3040 glib_ssize_t=$ac_cv_sizeof_ssize_t
3041 glib_size_type_define="$glib_size_type"
3042 glib_ssize_type_define="$glib_ssize_type"
3043 glib_void_p=$ac_cv_sizeof_void_p
3044 glib_long=$ac_cv_sizeof_long
3045
3046 case "$glib_size_type" in
3047 short)
3048   gsize_modifier='"h"'
3049   gsize_format='"hu"'
3050   glib_msize_type='SHRT'
3051   ;;
3052 int)
3053   gsize_modifier='""'
3054   gsize_format='"u"'
3055   glib_msize_type='INT'
3056   ;;
3057 long)
3058   gsize_modifier='"l"'
3059   gsize_format='"lu"'
3060   glib_msize_type='LONG'
3061   ;;
3062 "long long"|__int64)
3063   gsize_modifier='"I64"'
3064   gsize_format='"I64u"'
3065   glib_msize_type='INT64'
3066   ;;
3067 esac
3068
3069 case "$glib_ssize_type" in
3070 short)
3071   gssize_modifier='"h"'
3072   gssize_format='"hi"'
3073   glib_mssize_type='SHRT'
3074   ;;
3075 int)
3076   gssize_modifier='""'
3077   gssize_format='"i"'
3078   glib_mssize_type='INT'
3079   ;;
3080 long)
3081   gssize_modifier='"l"'
3082   gssize_format='"li"'
3083   glib_mssize_type='LONG'
3084   ;;
3085 "long long"|__int64)
3086   gssize_modifier='"I64"'
3087   gssize_format='"I64i"'
3088   glib_mssize_type='INT64'
3089   ;;
3090 esac
3091
3092 gintbits=`expr $ac_cv_sizeof_int \* 8`
3093 glongbits=`expr $ac_cv_sizeof_long \* 8`
3094 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3095 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3096
3097 case $ac_cv_sizeof_void_p in
3098 $ac_cv_sizeof_int)
3099   glib_intptr_type_define=int
3100   gintptr_modifier='""'
3101   gintptr_format='"i"'
3102   guintptr_format='"u"'
3103   glib_gpi_cast='(gint)'
3104   glib_gpui_cast='(guint)'
3105   ;;
3106 $ac_cv_sizeof_long)
3107   glib_intptr_type_define=long
3108   gintptr_modifier='"l"'
3109   gintptr_format='"li"'
3110   guintptr_format='"lu"'
3111   glib_gpi_cast='(glong)'
3112   glib_gpui_cast='(gulong)'
3113   ;;
3114 $ac_cv_sizeof_long_long)
3115   glib_intptr_type_define='long long'
3116   gintptr_modifier='"I64"'
3117   gintptr_format='"I64i"'
3118   guintptr_format='"I64u"'
3119   glib_gpi_cast='(gint64)'
3120   glib_gpui_cast='(guint64)'
3121   ;;
3122 $ac_cv_sizeof___int64)
3123   glib_intptr_type_define=__int64
3124   gintptr_modifier='"I64"'
3125   gintptr_format='"I64i"'
3126   guintptr_format='"I64u"'
3127   glib_gpi_cast='(gint64)'
3128   glib_gpui_cast='(guint64)'
3129   ;;
3130 *)
3131   glib_unknown_void_p=yes
3132   ;;
3133 esac
3134
3135
3136 glib_defines="
3137 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3138 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3139 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3140 "
3141
3142 case xyes in
3143 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3144 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3145 *)                      glib_vacopy=''
3146 esac
3147
3148 if test x$glib_cv_va_val_copy = xno; then
3149   glib_vacopy="\$glib_vacopy
3150 #define G_VA_COPY_AS_ARRAY 1"
3151 fi
3152
3153 g_have_gnuc_varargs=$g_have_gnuc_varargs
3154 g_have_iso_c_varargs=$g_have_iso_c_varargs
3155 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3156
3157 g_have_gnuc_visibility=$g_have_gnuc_visibility
3158 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3159
3160 if test x$ac_cv_c_bigendian = xyes; then
3161   g_byte_order=G_BIG_ENDIAN
3162   g_bs_native=BE
3163   g_bs_alien=LE
3164 else
3165   g_byte_order=G_LITTLE_ENDIAN
3166   g_bs_native=LE
3167   g_bs_alien=BE
3168 fi
3169
3170 g_pollin=$glib_cv_value_POLLIN
3171 g_pollout=$glib_cv_value_POLLOUT
3172 g_pollpri=$glib_cv_value_POLLPRI
3173 g_pollhup=$glib_cv_value_POLLHUP
3174 g_pollerr=$glib_cv_value_POLLERR
3175 g_pollnval=$glib_cv_value_POLLNVAL
3176
3177 # If a family is not found on the system, define that family to
3178 # a negative value, picking a different one for each undefined
3179 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3180 # This is needed because glib-mkenums doesn't handle optional
3181 # values in enums, and thus we have to have all existing values
3182 # defined in the enum.
3183 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3184   g_af_unix=$glib_cv_value_AF_UNIX
3185 else
3186   g_af_unix=-1
3187 fi
3188 g_af_inet=$glib_cv_value_AF_INET
3189 g_af_inet6=$glib_cv_value_AF_INET6
3190
3191 g_msg_peek=$glib_cv_value_MSG_PEEK
3192 g_msg_oob=$glib_cv_value_MSG_OOB
3193 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3194
3195 g_stack_grows=$glib_cv_stack_grows
3196
3197 g_have_eilseq=$have_eilseq
3198
3199 g_threads_impl_def=$g_threads_impl
3200
3201 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3202 g_memory_barrier_needed="$glib_memory_barrier_needed"
3203 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3204
3205 g_module_suffix="$glib_gmodule_suffix"
3206 g_pid_type="$glib_pid_type"
3207 g_pid_format="\"$glib_pid_format\""
3208 g_pollfd_format="\"$glib_pollfd_format\""
3209
3210 case $host in
3211   *-*-cygwin*)
3212     glib_os="#define G_OS_UNIX
3213 #define G_PLATFORM_WIN32
3214 #define G_WITH_CYGWIN"
3215     ;;
3216   *-*-mingw*)
3217     glib_os="#define G_OS_WIN32
3218 #define G_PLATFORM_WIN32"
3219     ;;
3220   *)
3221     glib_os="#define G_OS_UNIX"
3222     ;;
3223 esac
3224 glib_static_compilation=""
3225 if test x$glib_win32_static_compilation = xyes; then
3226   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3227 #define GOBJECT_STATIC_COMPILATION 1"
3228 fi
3229 ])
3230
3231 # Redo enough to get guint32 and guint64 for the alignment checks below
3232 case 4 in
3233 $ac_cv_sizeof_short)
3234   gint32=short
3235   ;;
3236 $ac_cv_sizeof_int)
3237   gint32=int
3238   ;;
3239 $ac_cv_sizeof_long)
3240   gint32=long
3241   ;;
3242 esac
3243 case 8 in
3244 $ac_cv_sizeof_int)
3245   gint64=int
3246   ;;
3247 $ac_cv_sizeof_long)
3248   gint64=long
3249   ;;
3250 $ac_cv_sizeof_long_long)
3251   gint64='long long'
3252   ;;
3253 $ac_cv_sizeof___int64)
3254   gint64='__int64'
3255   ;;
3256 esac
3257
3258 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3259 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3260 typedef unsigned $gint32 guint32;])
3261 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3262 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3263 typedef unsigned $gint64 guint64;])
3264 AC_CHECK_TYPE([unsigned long])
3265 AC_CHECK_ALIGNOF([unsigned long])
3266
3267 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3268 #
3269 # 1.2.14 required for dbus_message_set_serial
3270 PKG_CHECK_MODULES(DBUS1,
3271      dbus-1 >= 1.2.14,
3272      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3273      have_dbus1=no)
3274 AC_SUBST(DBUS1_CFLAGS)
3275 AC_SUBST(DBUS1_LIBS)
3276 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3277
3278 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3279 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3280
3281 # Check whether MSVC toolset is explicitly set
3282 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3283 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3284
3285 dnl
3286 dnl Check for -Bsymbolic-functions linker flag used to avoid
3287 dnl intra-library PLT jumps, if available.
3288 dnl
3289
3290 AC_ARG_ENABLE(Bsymbolic,
3291               [AS_HELP_STRING([--disable-Bsymbolic],
3292                               [avoid linking with -Bsymbolic])],,
3293               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3294                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3295                LDFLAGS=-Wl,-Bsymbolic-functions
3296                LIBS=
3297                AC_TRY_LINK([], [return 0],
3298                            AC_MSG_RESULT(yes)
3299                            enable_Bsymbolic=yes,
3300                            AC_MSG_RESULT(no)
3301                            enable_Bsymbolic=no)
3302                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3303
3304 if test "x${enable_Bsymbolic}" = "xyes"; then
3305   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3306 fi
3307
3308 dnl
3309 dnl Check for -z,nodelete linker flag: the type system assumes that
3310 dnl libgobject stays loaded for the lifetime of the process.
3311 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3312 dnl we also try to check for the --fatal-warnings linker flag if
3313 dnl auto-detecting.
3314 dnl
3315
3316 AC_ARG_ENABLE([znodelete],
3317               [AS_HELP_STRING([--disable-znodelete],
3318                               [avoid linking with -z,nodelete])],,
3319               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3320                AC_MSG_CHECKING([for --fatal-warnings linker flag])
3321                LDFLAGS=-Wl,--fatal-warnings
3322                LIBS=
3323                AC_TRY_LINK([], [return 0],
3324                            AC_MSG_RESULT(yes)
3325                            [ldflags_fatal=-Wl,--fatal-warnings],
3326                            AC_MSG_RESULT(no)
3327                            ldflags_fatal=)
3328                AC_MSG_CHECKING([for -z,nodelete linker flag])
3329                LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3330                AC_TRY_LINK([], [return 0],
3331                            AC_MSG_RESULT(yes)
3332                            enable_znodelete=yes,
3333                            AC_MSG_RESULT(no)
3334                            enable_znodelete=no)
3335                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3336
3337 if test "x${enable_znodelete}" = "xyes"; then
3338   GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3339 fi
3340
3341 AC_SUBST(GLIB_LINK_FLAGS)
3342
3343 dnl
3344 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3345 dnl visibility attributes for symbol export control
3346 dnl
3347 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3348 case "$host" in
3349   *-*-mingw*)
3350     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3351     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3352               [defines how to decorate public symbols while building])
3353     CFLAGS="${CFLAGS} -fvisibility=hidden"
3354     ;;
3355   *)
3356     dnl on other compilers, check if we can do -fvisibility=hidden
3357     SAVED_CFLAGS="${CFLAGS}"
3358     CFLAGS="-fvisibility=hidden"
3359     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3360     AC_TRY_COMPILE([], [return 0],
3361                    AC_MSG_RESULT(yes)
3362                    enable_fvisibility_hidden=yes,
3363                    AC_MSG_RESULT(no)
3364                    enable_fvisibility_hidden=no)
3365     CFLAGS="${SAVED_CFLAGS}"
3366
3367     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3368       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3369                 [defines how to decorate public symbols while building])
3370       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3371     ])
3372     ;;
3373 esac
3374 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3375
3376 dnl Compiler flags; macro originates from systemd
3377 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3378 AC_ARG_ENABLE(compile-warnings,
3379               [AS_HELP_STRING([--disable-compile-warnings],
3380                               [Don't use builtin compiler warnings])],,
3381                               enable_compile_warnings=yes)
3382 AS_IF([test "x$enable_compile_warnings" = xyes], [
3383   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3384    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3385    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3386    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3387    -Werror=format=2 -Werror=missing-include-dirs])
3388 ])
3389 AC_SUBST(GLIB_WARN_CFLAGS)
3390
3391 #
3392 # Define variables corresponding to the correct include paths to use for
3393 # in-tree building.
3394 #
3395
3396 # for config.h:
3397 config_h_INCLUDES='-I$(top_builddir)'
3398 AC_SUBST(config_h_INCLUDES)
3399
3400 # glib:
3401 #   config.h
3402 #   $(top_builddir)/glib: for glibconfig.h
3403 #   $(top_srcdir)/glib:   for glib.h
3404 #   $(top_srcdir):        for everything
3405 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3406 AC_SUBST(glib_INCLUDES)
3407
3408 # gobject:
3409 #   same as glib
3410 gobject_INCLUDES='$(glib_INCLUDES)'
3411 AC_SUBST(gobject_INCLUDES)
3412
3413 # gmodule:
3414 #   glib includes
3415 #   $(top_srcdir)/gmodule: for gmodule.h
3416 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3417 AC_SUBST(gmodule_INCLUDES)
3418
3419 # gio:
3420 #   same as gmodule
3421 gio_INCLUDES='$(gmodule_INCLUDES)'
3422 AC_SUBST(gio_INCLUDES)
3423
3424
3425 AC_CONFIG_FILES([
3426 glib-2.0.pc
3427 gmodule-2.0.pc
3428 gmodule-export-2.0.pc
3429 gmodule-no-export-2.0.pc
3430 gthread-2.0.pc
3431 gobject-2.0.pc
3432 gio-2.0.pc
3433 gio-unix-2.0.pc
3434 gio-windows-2.0.pc
3435 glib-zip
3436 glib-gettextize
3437 Makefile
3438 build/Makefile
3439 build/win32/Makefile
3440 build/win32/dirent/Makefile
3441 win32/Makefile
3442 win32/vs9/Makefile
3443 win32/vs9/glib-version-paths.vsprops
3444 win32/vs10/Makefile
3445 win32/vs10/glib-version-paths.props
3446 win32/vs11/Makefile
3447 win32/vs12/Makefile
3448 win32/vs14/Makefile
3449 win32/vs15/Makefile
3450 glib/Makefile
3451 glib/libcharset/Makefile
3452 glib/gnulib/Makefile
3453 glib/pcre/Makefile
3454 glib/update-pcre/Makefile
3455 glib/tests/Makefile
3456 gmodule/Makefile
3457 gmodule/gmoduleconf.h
3458 gobject/Makefile
3459 gobject/glib-mkenums
3460 gobject/tests/Makefile
3461 gthread/Makefile
3462 gio/Makefile
3463 gio/gdbus-2.0/codegen/Makefile
3464 gio/gdbus-2.0/codegen/config.py
3465 gio/gnetworking.h
3466 gio/xdgmime/Makefile
3467 gio/inotify/Makefile
3468 gio/kqueue/Makefile
3469 gio/fam/Makefile
3470 gio/win32/Makefile
3471 gio/tests/Makefile
3472 gio/tests/gdbus-object-manager-example/Makefile
3473 gio/tests/services/Makefile
3474 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3475 gio/tests/modules/Makefile
3476 po/Makefile.in
3477 docs/Makefile
3478 docs/reference/Makefile
3479 docs/reference/glib/Makefile
3480 docs/reference/glib/version.xml
3481 docs/reference/gobject/Makefile
3482 docs/reference/gobject/version.xml
3483 docs/reference/gio/Makefile
3484 docs/reference/gio/version.xml
3485 tests/Makefile
3486 tests/gobject/Makefile
3487 tests/refcount/Makefile
3488 m4macros/Makefile
3489 ])
3490
3491 AC_CONFIG_COMMANDS([chmod-scripts],
3492 [chmod 0755 glib-zip
3493 chmod 0755 glib-gettextize
3494 chmod 0755 gobject/glib-mkenums])
3495
3496 # we want to invoke this macro solely so that the config.status script
3497 # and automake generated makefiles know about these generated files.
3498 # They are only needed to distcheck the package
3499 if false; then
3500   AC_CONFIG_FILES([
3501     INSTALL
3502     README
3503     config.h.win32
3504     glib/glibconfig.h.win32
3505     glib/makefile.msc
3506     glib/glib.rc
3507     gmodule/makefile.msc
3508     gmodule/gmodule.rc
3509     gobject/makefile.msc
3510     gobject/gobject.rc
3511     gthread/makefile.msc
3512     gthread/gthread.rc
3513     gio/gio.rc
3514     tests/makefile.msc
3515   ])
3516 fi
3517
3518 AC_OUTPUT