configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.13.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 1300, 0, 1300)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.13.0.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for gobject-introspection
 158 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 159
 160 dnl check for documentation tools
 161 GTK_DOC_CHECK([1.12])
 162 AG_GST_PLUGIN_DOCS([1.12])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 LT_LIB_M
 168 AC_SUBST(LIBM)
 169
 170 dnl check for pthreads
 171 AX_PTHREAD
 172
 173 dnl *** checks for header files ***
 174
 175 dnl check if we have ANSI C header files
 176 AC_HEADER_STDC
 177
 178 dnl check for GCC specific SSE headers
 179 dnl these are used by the speex resampler code
 180 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 181
 182 dnl also check which architecture we're on for building files with intrinsics
 183 dnl separately
 184 AC_CHECK_DECLS([__i386__], [HAVE_X86=1])
 185 AC_CHECK_DECLS([__x86_64__], [HAVE_X86=1])
 186
 187 dnl check for -m* compiler flags too
 188 SSE_CFLAGS="-msse"
 189 SSE2_CFLAGS="-msse2"
 190 SSE41_CFLAGS="-msse4.1"
 191
 192 AS_COMPILER_FLAG([$SSE_CFLAGS], [HAVE_SSE=1], [HAVE_SSE=0])
 193 AS_COMPILER_FLAG([$SSE2_CFLAGS], [HAVE_SSE2=1], [HAVE_SSE2=0])
 194 AS_COMPILER_FLAG([$SSE41_CFLAGS], [HAVE_SSE41=1], [HAVE_SSE41=0])
 195
 196 AM_CONDITIONAL(HAVE_X86, [test "x${HAVE_X86}" = "x1"])
 197
 198 AC_DEFINE_UNQUOTED(HAVE_SSE, [$HAVE_SSE], [SSE support is enabled])
 199 AC_DEFINE_UNQUOTED(HAVE_SSE2, [$HAVE_SSE2], [SSE2 support is enabled])
 200 AC_DEFINE_UNQUOTED(HAVE_SSE41, [$HAVE_SSE41], [SSE4.1 support is enabled])
 201
 202 AC_SUBST(SSE_CFLAGS)
 203 AC_SUBST(SSE2_CFLAGS)
 204 AC_SUBST(SSE41_CFLAGS)
 205
 206 dnl used in gst/tcp
 207 AC_CHECK_HEADERS([sys/socket.h],
 208   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 209 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 210
 211 dnl used in gst-libs/gst/rtsp
 212 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 213 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 214 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 215   WIN32_LIBS="-lws2_32"
 216   AC_SUBST(WIN32_LIBS)
 217 fi
 218
 219 dnl used in gst-libs/gst/pbutils and associated unit test
 220 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 221
 222 dnl checks for ARM NEON support
 223 dnl this instruction set is used by the speex resampler code
 224 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 225 AC_LINK_IFELSE([
 226 AC_LANG_PROGRAM([[
 227   #include <arm_neon.h>
 228   int32x4_t testfunc(int16_t *a, int16_t *b) {
 229       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 230       return vmull_s16(vld1_s16(a), vld1_s16(b));
 231   }
 232 ]])],
 233 [
 234   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 235   AC_MSG_RESULT(yes)
 236 ],
 237 [
 238   AC_MSG_RESULT(no)
 239 ])
 240
 241 dnl also, Windows does not have long long
 242 AX_CREATE_STDINT_H
 243
 244 dnl *** checks for functions ***
 245 AC_CHECK_FUNCS([localtime_r gmtime_r])
 246
 247 dnl *** checks for math functions ***
 248 LIBS_SAVE=$LIBS
 249 LIBS="$LIBS $LIBM"
 250 AC_CHECK_FUNCS(log2)
 251 LIBS=$LIBS_SAVE
 252
 253 dnl *** checks for types/defines ***
 254
 255 dnl *** checks for structures ***
 256
 257 dnl *** checks for compiler characteristics ***
 258
 259 dnl *** checks for library functions ***
 260
 261 dnl check for fseeko()
 262 AC_FUNC_FSEEKO
 263
 264 dnl Check for fast float to int casting as defined in C99
 265 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 266 save_libs=$LIBS
 267 LIBS="$LIBS $LIBM"
 268 AC_C99_FUNC_LRINT
 269 AC_C99_FUNC_LRINTF
 270 LIBS=$save_libs
 271
 272 dnl Check for a way to display the function name in debug output
 273 AG_GST_CHECK_FUNCTION
 274
 275 dnl *** checks for dependency libraries ***
 276
 277 dnl GLib
 278 GLIB_REQ=2.40.0
 279 AG_GST_GLIB_CHECK([$GLIB_REQ])
 280
 281 ORC_CHECK([0.4.24])
 282
 283 dnl checks for gstreamer
 284 dnl uninstalled is selected preferentially -- see pkg-config(1)
 285 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 286 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 287 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 288 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 289 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 290 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 291
 292 dnl Check for documentation xrefs
 293 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 294 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 295 AC_SUBST(GLIB_PREFIX)
 296 AC_SUBST(GST_PREFIX)
 297
 298 dnl GTK is optional and only used in examples
 299 HAVE_GTK=no
 300 HAVE_GTK_X11=no
 301 GTK_REQ=3.10
 302 if test "x$BUILD_EXAMPLES" = "xyes"; then
 303   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 304   dnl some examples need gtk+-x11
 305   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 306   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 307   AC_SUBST(GTK_LIBS)
 308   AC_SUBST(GTK_CFLAGS)
 309 fi
 310 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 311 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 312 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 313
 314 HAVE_QT=no
 315 HAVE_QT_MOC=no
 316 dnl QT is optional and only used in examples
 317 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 318   HAVE_QT=yes
 319 ], [
 320   HAVE_QT=no
 321 ])
 322 if test "x$HAVE_QT" = "xyes"; then
 323   AC_CHECK_TOOL(QT_MOC, moc)
 324   AC_MSG_CHECKING([for Qt5 moc])
 325   mocversion=`$QT_MOC -v 2>&1`
 326   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 327   if test x"$mocversiongrep" != x"$mocversion"; then
 328     AC_MSG_RESULT([no])
 329     # moc was not the qt5 one, try with moc-qt5
 330     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 331     AC_MSG_CHECKING([for Qt5 moc-qt5])
 332     mocversion=`$QT_MOC -v 2>&1`
 333     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 334     if test x"$mocversiongrep" != x"$mocversion"; then
 335       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 336       AC_MSG_CHECKING([for qtchooser])
 337       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 338       mocversion=`$qt5tooldir/moc -v 2>&1`
 339       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 340       if test x"$mocversiongrep" != x"$mocversion"; then
 341         # no valid moc found
 342         QT_MOC="no"
 343       else
 344         QT_MOC=$qt5tooldir/moc
 345       fi
 346     else
 347       QT_MOC=$QT_MOC
 348     fi
 349   fi
 350   AC_SUBST(QT_MOC)
 351   AC_MSG_RESULT([$QT_MOC])
 352 fi
 353 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 354 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 355
 356 dnl chck for linux headers needed by the joystick seek example
 357 AC_COMPILE_IFELSE(
 358 [
 359   AC_LANG_PROGRAM([
 360     #include <linux/input.h>
 361     #include <linux/joystick.h>
 362   ],[
 363     struct js_event js;
 364     js.type = JS_EVENT_AXIS;
 365   ])
 366 ], [
 367   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 368 ], [
 369   HAVE_LINUX_JOYSTICK_HEADERS="no"
 370 ])
 371 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 372
 373 dnl Check for -Bsymbolic-functions linker flag used to avoid
 374 dnl intra-library PLT jumps, if available.
 375 AC_ARG_ENABLE(Bsymbolic,
 376               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 377               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 378                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 379                LDFLAGS=-Wl,-Bsymbolic-functions
 380                LIBS=
 381                AC_TRY_LINK([], [return 0],
 382                            AC_MSG_RESULT(yes)
 383                            enable_Bsymbolic=yes,
 384                            AC_MSG_RESULT(no)
 385                            enable_Bsymbolic=no)
 386                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 387
 388
 389 dnl *** set variables based on configure arguments ***
 390
 391 dnl set license and copyright notice
 392 GST_LICENSE="LGPL"
 393 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 394 AC_SUBST(GST_LICENSE)
 395
 396 dnl set location of plugin directory
 397 AG_GST_SET_PLUGINDIR
 398
 399 dnl set release date/time
 400 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 401   ["${srcdir}/gst-plugins-base.doap"],
 402   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 403
 404 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 405 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 406 if test x$enable_static = xyes -a x$enable_shared = xno; then
 407   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 408 fi
 409
 410 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 411 dnl make sure it doesn't complain about unused variables if debugging is disabled
 412 NO_WARNINGS=""
 413 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 414
 415 dnl define an ERROR_CFLAGS Makefile variable
 416 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 417 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 418     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 419     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 420     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 421     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 422
 423 dnl define an ERROR_CXXFLAGS Makefile variable
 424 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 425     -Wmissing-declarations -Wredundant-decls -Wundef
 426     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 427     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 428     -Wno-multichar $NO_WARNINGS])
 429
 430 dnl define correct level for debugging messages
 431 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 432
 433 dnl used in examples
 434 AG_GST_DEFAULT_ELEMENTS
 435
 436 dnl needed for encoding-target
 437 GST_DATADIR="$GST_PREFIX/share"
 438 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 439 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 440
 441 dnl behaviour of speex based audio resampler
 442 AC_MSG_CHECKING(which audio resample format to use for integer)
 443 AC_ARG_WITH([audioresample_format],
 444         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 445         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 446 AC_MSG_RESULT($ac_cv_audioresample_format)
 447 case $ac_cv_audioresample_format in
 448   int)
 449     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 450     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 451   ;;
 452   float)
 453     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 454     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 455   ;;
 456   auto)
 457     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 458     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 459 esac
 460
 461 dnl Check for mmap (needed by allocators library)
 462 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 463
 464 dnl *** plug-ins to include ***
 465
 466 dnl these are all the gst plug-ins, compilable without additional libs
 467 AG_GST_CHECK_PLUGIN(adder)
 468 AG_GST_CHECK_PLUGIN(app)
 469 AG_GST_CHECK_PLUGIN(audioconvert)
 470 AG_GST_CHECK_PLUGIN(audiorate)
 471 AG_GST_CHECK_PLUGIN(audiotestsrc)
 472 AG_GST_CHECK_PLUGIN(encoding)
 473 AG_GST_CHECK_PLUGIN(videoconvert)
 474 AG_GST_CHECK_PLUGIN(gio)
 475 AG_GST_CHECK_PLUGIN(playback)
 476 AG_GST_CHECK_PLUGIN(audioresample)
 477 AG_GST_CHECK_PLUGIN(rawparse)
 478 AG_GST_CHECK_PLUGIN(subparse)
 479 AG_GST_CHECK_PLUGIN(tcp)
 480 AG_GST_CHECK_PLUGIN(typefind)
 481 AG_GST_CHECK_PLUGIN(videotestsrc)
 482 AG_GST_CHECK_PLUGIN(videorate)
 483 AG_GST_CHECK_PLUGIN(videoscale)
 484 AG_GST_CHECK_PLUGIN(volume)
 485
 486 dnl iso-codes is optional, used by libgsttag
 487 AC_ARG_ENABLE(iso-codes,
 488 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 489 [case "${enableval}" in
 490   yes) enable_iso_codes=yes ;;
 491   no)  enable_iso_codes=no ;;
 492   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 493 esac
 494 ],
 495 [enable_iso_codes=yes]) dnl Default value
 496
 497 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 498 if test "x$enable_iso_codes" = "xyes"; then
 499   AC_MSG_RESULT([yes])
 500   have_iso_codes=no
 501   AC_MSG_CHECKING([whether iso-codes are available on this system])
 502   if $PKG_CONFIG iso-codes; then
 503     AC_MSG_RESULT([yes])
 504     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 505     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 506       AC_MSG_RESULT([yes])
 507       AC_MSG_CHECKING([for iso-codes prefix])
 508       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 509       if test -d "$ISO_CODES_PREFIX"; then
 510         AC_MSG_RESULT([yes])
 511         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 512         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 513         ISO_639_DOMAIN="iso_639"
 514         AC_MSG_CHECKING([ISO_639_DOMAIN])
 515         AC_MSG_RESULT([$ISO_639_DOMAIN])
 516         have_iso_codes=yes
 517         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 518         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 519         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 520         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 521       else
 522         AC_MSG_RESULT([no])
 523       fi
 524     else
 525       AC_MSG_RESULT([no])
 526     fi
 527   else
 528     AC_MSG_RESULT([no])
 529   fi
 530   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 531 else
 532   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 533   AM_CONDITIONAL(USE_ISO_CODES, false)
 534 fi
 535
 536 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 537 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 538 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 539   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 540       HAVE_ZLIB="yes"
 541     ], [
 542       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 543         HAVE_ZLIB="yes"
 544         ZLIB_LIBS="-lz"
 545         AC_SUBST(ZLIB_LIBS)
 546       ])
 547     ])
 548 ])
 549
 550 dnl *** sys plug-ins ***
 551
 552 echo
 553 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 554 echo
 555
 556 dnl *** X11 ***
 557 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 558 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 559                   [ximagesink], [
 560   AG_GST_PKG_CHECK_MODULES(X, x11)
 561 ])
 562
 563 dnl Check for Xv extension
 564 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 565 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 566                   [xvimagesink], [
 567   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 568 ])
 569
 570 dnl check for X Shm
 571 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 572 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 573   if test x$HAVE_X = xyes; then
 574     PKG_CHECK_MODULES(XSHM, xext, [
 575       AC_CHECK_LIB(Xext, XShmAttach, [
 576         HAVE_XSHM="yes"
 577       ], [
 578         HAVE_XSHM="no"
 579         XSHM_LIBS=""
 580       ], [ $X_LIBS ])
 581     ], [
 582       HAVE_XSHM="no"
 583     ])
 584   fi
 585 ], , [
 586   AC_SUBST(HAVE_XSHM)
 587   AC_SUBST(XSHM_LIBS)
 588 ])
 589
 590 dnl *** ext plug-ins ***
 591 dnl keep this list sorted alphabetically !
 592
 593 if test "x$BUILD_EXTERNAL" = "xyes"; then
 594
 595 echo
 596 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 597 echo
 598
 599 dnl *** alsa ***
 600 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 601 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 602   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 603     HAVE_ALSA="yes"
 604     AC_SUBST(ALSA_CFLAGS)
 605     AC_SUBST(ALSA_LIBS)
 606   ], [
 607     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 608   ])
 609 ])
 610
 611 dnl *** CDParanoia ***
 612 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 613 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 614 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 615   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 616     HAVE_CDPARANOIA="yes"
 617   ], [
 618     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 619                         cdda_open, -lm,
 620                         cdda_interface.h,
 621                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 622                         HEADER_DIR="no"
 623                         FOUND_CDPARANOIA="yes")
 624     if test "x$FOUND_CDPARANOIA" != "xyes";
 625     then
 626       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 627                           cdda_open, -lm,
 628                           cdda/cdda_interface.h,
 629                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 630                           HEADER_DIR="yes"
 631                           FOUND_CDPARANOIA="yes")
 632     fi
 633     if test "x$HEADER_DIR" = "xyes";
 634     then
 635       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 636                          defined if cdda headers are in a cdda/ directory)
 637     fi
 638     if test "x$FOUND_CDPARANOIA" = "xyes";
 639     then
 640       AC_CHECK_LIB(cdda_paranoia,
 641                    paranoia_cachemodel_size,
 642                    : ,
 643                    HAVE_CDPARANOIA=no,
 644                  [-lcdda_interface])
 645     fi
 646
 647     AC_SUBST(CDPARANOIA_LIBS)
 648   ])
 649 ])
 650 dnl FIXME : add second check somehow if that is necessary
 651 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 652 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 653
 654 dnl *** ivorbis ***
 655 dnl AM_PATH_IVORBIS only takes two options
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 657 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 658   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 659   if test $HAVE_IVORBIS = no
 660   then
 661     IVORBIS_LIBS=
 662     IVORBIS_CFLAGS=
 663     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 664       [IVORBIS_LIBS=-lvorbisidec
 665       HAVE_IVORBIS=yes
 666       case $host in
 667       arm-*-*)
 668         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 669       esac
 670       ],
 671       HAVE_IVORBIS=no)
 672     AC_SUBST(IVORBIS_LIBS)
 673     AC_SUBST(IVORBIS_CFLAGS)
 674   else
 675     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 676       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 677       USE_TREMOLO=no)
 678   fi
 679 ])
 680
 681 dnl *** libvisual ***
 682 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 683 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 684   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 685   if test x$HAVE_LIBVISUAL = xyes; then
 686     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 687   fi
 688   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 689   if test x$LIBVIS_PLUGINSDIR != x; then
 690     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 691         "$LIBVIS_PLUGINSDIR",
 692         [directory in which the detected libvisual's plugins are located])
 693   fi
 694 ])
 695
 696 dnl *** ogg ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 698 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 699   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 700 ])
 701
 702 dnl *** Opus ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 704 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 705   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 706           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 707           HAVE_OPUS="yes"
 708   ], [
 709           HAVE_OPUS="no"
 710   ])
 711   AC_SUBST(OPUS_CFLAGS)
 712   AC_SUBST(OPUS_LIBS)
 713 ])
 714
 715 dnl *** pango ***
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 717 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 718   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 719 ])
 720
 721 dnl *** theora ***
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 723 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 724   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 725 ])
 726
 727 dnl *** vorbis ***
 728 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 729 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 730   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 731 ])
 732
 733 if test "x$HAVE_VORBIS" = "xyes"; then
 734   ac_cflags_save="$CFLAGS"
 735   AC_COMPILE_IFELSE([
 736     AC_LANG_PROGRAM([[
 737 #include <vorbis/codec.h>
 738                      ]],[[
 739 vorbis_dsp_state *v;
 740
 741 vorbis_synthesis_restart (v);
 742                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 743   if test "x$HAVE_VSR" = "xyes"; then
 744     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 745                        [defined if vorbis_synthesis_restart is present])
 746   fi
 747   CFLAGS="$ac_cflags_save"
 748 fi
 749
 750 else
 751
 752 dnl not building plugins with external dependencies,
 753 dnl but we still need to set the conditionals
 754 AM_CONDITIONAL(USE_ALSA, false)
 755 AM_CONDITIONAL(USE_CDPARANOIA, false)
 756 AM_CONDITIONAL(USE_IVORBIS, false)
 757 AM_CONDITIONAL(USE_LIBVISUAL, false)
 758 AM_CONDITIONAL(USE_OGG, false)
 759 AM_CONDITIONAL(USE_OPUS, false)
 760 AM_CONDITIONAL(USE_PANGO, false)
 761 AM_CONDITIONAL(USE_THEORA, false)
 762 AM_CONDITIONAL(USE_VORBIS, false)
 763
 764 fi dnl of EXT plugins
 765
 766 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 767 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 768     HAVE_GIO_UNIX_2_0="yes",
 769     HAVE_GIO_UNIX_2_0="no")
 770 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 771
 772 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 773
 774 dnl Overview:
 775 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 776 dnl GST_*:              flags shared by built objects to link against GStreamer
 777 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 778 dnl                          (compare to other modules) or for i18n
 779 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 780 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 781 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 782 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 783
 784 dnl GST_OPTION_CFLAGS
 785 if test "x$USE_DEBUG" = xyes; then
 786    PROFILE_CFLAGS="-g"
 787 fi
 788 AC_SUBST(PROFILE_CFLAGS)
 789
 790 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 791   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 792   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 793 else
 794   DEPRECATED_CFLAGS=""
 795 fi
 796 AC_SUBST(DEPRECATED_CFLAGS)
 797
 798 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 799 dnl at make time with e.g. make ERROR_CFLAGS=""
 800 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 801 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 802 AC_SUBST(GST_OPTION_CFLAGS)
 803 AC_SUBST(GST_OPTION_CXXFLAGS)
 804
 805 dnl our libraries need to be versioned correctly
 806 AC_SUBST(GST_LT_LDFLAGS)
 807
 808 dnl GST_PLUGINS_BASE_CFLAGS
 809 dnl prefer internal headers to already installed ones
 810 dnl also add builddir include for enumtypes and marshal
 811 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 812 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 813
 814 dnl FIXME: do we want to rename to GST_ALL_* ?
 815 dnl add GST_OPTION_CFLAGS, but overridable
 816 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 817 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 818 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 819 AC_SUBST(GST_CFLAGS)
 820 AC_SUBST(GST_CXXFLAGS)
 821 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 822 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 823 AC_SUBST(GST_LIBS)
 824
 825 dnl LDFLAGS really should only contain flags, not libs - they get added before
 826 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 827 GST_ALL_LDFLAGS="-no-undefined"
 828 if test "x${enable_Bsymbolic}" = "xyes"; then
 829   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 830 fi
 831 AC_SUBST(GST_ALL_LDFLAGS)
 832
 833 dnl GST_LIB_LDFLAGS
 834 dnl linker flags shared by all libraries
 835 dnl LDFLAGS modifier defining exported symbols from built libraries
 836 dnl (export _gst_foo but not __gst_foo)
 837 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 838 AC_SUBST(GST_LIB_LDFLAGS)
 839
 840 dnl this really should only contain flags, not libs - they get added before
 841 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 842 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 843 AC_SUBST(GST_PLUGIN_LDFLAGS)
 844
 845 dnl *** output files ***
 846
 847 $MKDIR_P tests/check/orc
 848
 849 AC_CONFIG_FILES(
 850 Makefile
 851 gst/Makefile
 852 gst/adder/Makefile
 853 gst/app/Makefile
 854 gst/audioconvert/Makefile
 855 gst/audiorate/Makefile
 856 gst/audioresample/Makefile
 857 gst/audiotestsrc/Makefile
 858 gst/encoding/Makefile
 859 gst/videoconvert/Makefile
 860 gst/gio/Makefile
 861 gst/pbtypes/Makefile
 862 gst/playback/Makefile
 863 gst/rawparse/Makefile
 864 gst/subparse/Makefile
 865 gst/tcp/Makefile
 866 gst/typefind/Makefile
 867 gst/videotestsrc/Makefile
 868 gst/videorate/Makefile
 869 gst/videoscale/Makefile
 870 gst/volume/Makefile
 871 sys/Makefile
 872 sys/ximage/Makefile
 873 sys/xvimage/Makefile
 874 ext/Makefile
 875 ext/alsa/Makefile
 876 ext/cdparanoia/Makefile
 877 ext/libvisual/Makefile
 878 ext/ogg/Makefile
 879 ext/opus/Makefile
 880 ext/pango/Makefile
 881 ext/theora/Makefile
 882 ext/vorbis/Makefile
 883 gst-libs/Makefile
 884 gst-libs/gst/Makefile
 885 gst-libs/gst/allocators/Makefile
 886 gst-libs/gst/audio/Makefile
 887 gst-libs/gst/app/Makefile
 888 gst-libs/gst/fft/Makefile
 889 gst-libs/gst/riff/Makefile
 890 gst-libs/gst/rtp/Makefile
 891 gst-libs/gst/rtsp/Makefile
 892 gst-libs/gst/sdp/Makefile
 893 gst-libs/gst/tag/Makefile
 894 gst-libs/gst/pbutils/Makefile
 895 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 896 gst-libs/gst/video/Makefile
 897 tools/Makefile
 898 pkgconfig/Makefile
 899 pkgconfig/gstreamer-allocators.pc
 900 pkgconfig/gstreamer-allocators-uninstalled.pc
 901 pkgconfig/gstreamer-audio.pc
 902 pkgconfig/gstreamer-audio-uninstalled.pc
 903 pkgconfig/gstreamer-app.pc
 904 pkgconfig/gstreamer-app-uninstalled.pc
 905 pkgconfig/gstreamer-fft.pc
 906 pkgconfig/gstreamer-fft-uninstalled.pc
 907 pkgconfig/gstreamer-pbutils.pc
 908 pkgconfig/gstreamer-pbutils-uninstalled.pc
 909 pkgconfig/gstreamer-riff.pc
 910 pkgconfig/gstreamer-riff-uninstalled.pc
 911 pkgconfig/gstreamer-rtp.pc
 912 pkgconfig/gstreamer-rtp-uninstalled.pc
 913 pkgconfig/gstreamer-rtsp.pc
 914 pkgconfig/gstreamer-rtsp-uninstalled.pc
 915 pkgconfig/gstreamer-sdp.pc
 916 pkgconfig/gstreamer-sdp-uninstalled.pc
 917 pkgconfig/gstreamer-tag.pc
 918 pkgconfig/gstreamer-tag-uninstalled.pc
 919 pkgconfig/gstreamer-video.pc
 920 pkgconfig/gstreamer-video-uninstalled.pc
 921 pkgconfig/gstreamer-plugins-base.pc
 922 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 923 tests/Makefile
 924 tests/check/Makefile
 925 tests/examples/Makefile
 926 tests/examples/app/Makefile
 927 tests/examples/audio/Makefile
 928 tests/examples/decodebin_next/Makefile
 929 tests/examples/dynamic/Makefile
 930 tests/examples/encoding/Makefile
 931 tests/examples/fft/Makefile
 932 tests/examples/gio/Makefile
 933 tests/examples/overlay/Makefile
 934 tests/examples/seek/Makefile
 935 tests/examples/snapshot/Makefile
 936 tests/examples/playback/Makefile
 937 tests/examples/playrec/Makefile
 938 tests/files/Makefile
 939 tests/icles/Makefile
 940 tests/icles/playback/Makefile
 941 docs/Makefile
 942 docs/libs/Makefile
 943 docs/plugins/Makefile
 944 docs/version.entities
 945 po/Makefile.in
 946 common/Makefile
 947 common/m4/Makefile
 948 m4/Makefile
 949 )
 950 AC_OUTPUT
 951
 952 AG_GST_OUTPUT_PLUGINS
 953 ORC_OUTPUT
 954