configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of PulseAudio.
   7 #
   8 # Copyright 2004-2006 Lennart Poettering
   9 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
  10 #
  11 # PulseAudio is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU Lesser General Public License as published by
  13 # the Free Software Foundation; either version 2 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # PulseAudio is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  19 # General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public License
  22 # along with PulseAudio; if not, write to the Free Software Foundation,
  23 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  24
  25 AC_PREREQ(2.57)
  26
  27 m4_define(PA_MAJOR, [0])
  28 m4_define(PA_MINOR, [9])
  29 m4_define(PA_MICRO, [7])
  30
  31 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  32 AC_CONFIG_SRCDIR([src/daemon/main.c])
  33 AC_CONFIG_HEADERS([config.h])
  34 AM_INIT_AUTOMAKE([foreign -Wall])
  35
  36 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  37 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/pulseaudio/])
  38
  39 AC_SUBST(PA_API_VERSION, 10)
  40 AC_SUBST(PA_PROTOCOL_VERSION, 11)
  41
  42 AC_SUBST(LIBPULSE_VERSION_INFO, [3:0:3])
  43 AC_SUBST(LIBPULSECORE_VERSION_INFO, [4:0:0])
  44 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:0:0])
  45 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:0:1])
  46 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:2:0])
  47
  48 AC_CANONICAL_HOST
  49
  50 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  51    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  52    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  53 fi
  54
  55 #### Platform hacks ####
  56
  57 case $host in
  58    *-*-solaris* )
  59       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  60       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  61       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  62       ;;
  63 esac
  64
  65 #### Checks for programs. ####
  66
  67 # CC
  68
  69 AC_PROG_CC
  70 AM_PROG_CC_C_O
  71 AC_PROG_GCC_TRADITIONAL
  72 AC_GNU_SOURCE
  73
  74 # M4
  75
  76 AC_PATH_PROG([M4], [m4 gm4], [no])
  77 if test "x$M4" = xno ; then
  78    AC_MSG_ERROR([m4 missing])
  79 fi
  80
  81 # GCC flags
  82
  83 test_gcc_flag() {
  84     AC_LANG_CONFTEST([int main(int argc, char*argv[]) {}])
  85     $CC -c conftest.c $CFLAGS -o conftest.o > /dev/null 2> /dev/null
  86     ret=$?
  87     rm -f conftest.o
  88     return $ret
  89 }
  90
  91 # If using GCC specify some additional parameters
  92 if test "x$GCC" = "xyes" ; then
  93
  94     # We use gnu99 instead of c99 because many have interpreted the standard
  95     # in a way that int64_t isn't defined on non-64 bit platforms.
  96     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"
  97
  98     for flag in $DESIRED_FLAGS ; do
  99         AC_MSG_CHECKING([whether $CC accepts $flag])
 100         if test_gcc_flag $flag ; then
 101            CFLAGS="$CFLAGS $flag"
 102            AC_MSG_RESULT([yes])
 103         else
 104            AC_MSG_RESULT([no])
 105         fi
 106     done
 107 fi
 108
 109 AC_MSG_CHECKING([whether $CC knows __sync_bool_compare_and_swap()])
 110 AC_LANG_CONFTEST([int main() { int a = 4; __sync_bool_compare_and_swap(&a, 4, 5); }])
 111 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 112 ret=$?
 113 rm -f conftest.o conftest
 114 if test $ret -eq 0 ; then
 115     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 116     AC_MSG_RESULT([yes])
 117 else
 118     AC_MSG_RESULT([no])
 119 fi
 120
 121 AC_MSG_CHECKING([whether $CC knows __thread])
 122 AC_LANG_CONFTEST([static __thread int a = 6; int main() { a = 5; }])
 123 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 124 ret=$?
 125 rm -f conftest.o conftest
 126 if test $ret -eq 0 ; then
 127     AC_DEFINE([HAVE_TLS_BUILTIN], 1, [Have __thread().])
 128     AC_MSG_RESULT([yes])
 129 else
 130     AC_MSG_RESULT([no])
 131 fi
 132
 133 AC_MSG_CHECKING([whether $CC knows _Bool])
 134 AC_LANG_CONFTEST([int main() { _Bool b; }])
 135 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 136 ret=$?
 137 rm -f conftest.o conftest
 138 if test $ret -eq 0 ; then
 139     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 140     AC_MSG_RESULT([yes])
 141 else
 142     AC_MSG_RESULT([no])
 143 fi
 144
 145 #### libtool stuff ####
 146
 147 AC_LTDL_ENABLE_INSTALL
 148 AC_LIBLTDL_INSTALLABLE
 149 AC_LIBTOOL_DLOPEN
 150 AC_LIBTOOL_WIN32_DLL
 151 AC_PROG_LIBTOOL
 152 AC_SUBST(LTDLINCL)
 153 AC_SUBST(LIBLTDL)
 154 AC_CONFIG_SUBDIRS(libltdl)
 155
 156 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 157     AC_MSG_ERROR([[
 158
 159         *** Cannot find the libltdl development files.
 160         *** Maybe you need to install the libltdl-dev package.
 161         ]])
 162 fi
 163
 164 #### Determine build environment ####
 165
 166 os_is_win32=0
 167
 168 case "$host_os" in
 169         mingw*)
 170         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 171         os_is_win32=1
 172                 ;;
 173         esac
 174
 175 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 176
 177 ###################################
 178 #   Basic environment checks      #
 179 ###################################
 180
 181 #### Checks for header files. ####
 182
 183 # ISO
 184 AC_HEADER_STDC
 185
 186 # POSIX
 187 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 188     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 189     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 190     syslog.h sys/dl.h dlfcn.h])
 191 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 192                  [#include <sys/types.h>
 193                   #if HAVE_NETINET_IN_H
 194                   # include <netinet/in.h>
 195                   #endif
 196                   #if HAVE_NETINET_IN_SYSTM_H
 197                   # include <netinet/in_systm.h>
 198                   #endif
 199                  ])
 200 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 201 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 202
 203 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 204 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 205
 206 # Linux
 207 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 208
 209 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 210
 211 AC_CHECK_HEADERS([sys/prctl.h])
 212
 213 # Solaris
 214 AC_CHECK_HEADERS([sys/filio.h])
 215
 216 # Windows
 217 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 218
 219 # Other
 220 AC_CHECK_HEADERS([sys/ioctl.h])
 221 AC_CHECK_HEADERS([byteswap.h])
 222
 223 #### Typdefs, structures, etc. ####
 224
 225 AC_C_CONST
 226 AC_C_BIGENDIAN
 227 AC_TYPE_PID_T
 228 AC_TYPE_SIZE_T
 229 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 230     [Define ssize_t if it is not done by the standard libs.])])
 231 AC_TYPE_OFF_T
 232 AC_TYPE_SIGNAL
 233 AC_TYPE_UID_T
 234
 235 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 236 HAVE_SIGXCPU=1
 237 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 238 ], [HAVE_SIGXCPU=0])
 239 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 240
 241 # Solaris lacks this
 242 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 243     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 244         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 245
 246 #### Check for libs ####
 247
 248 # ISO
 249 AC_SEARCH_LIBS([pow], [m])
 250
 251 # POSIX
 252 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 253 AC_SEARCH_LIBS([dlopen], [dl])
 254 AC_SEARCH_LIBS([shm_open], [rt])
 255
 256 # BSD
 257 AC_SEARCH_LIBS([connect], [socket])
 258
 259 # Non-standard
 260
 261 # This magic is needed so we do not needlessly add static libs to the win32
 262 # build, disabling its ability to make dlls.
 263 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 264
 265 #### Check for functions ####
 266
 267 # ISO
 268 AC_CHECK_FUNCS([lrintf strtof])
 269
 270 # POSIX
 271 AC_FUNC_FORK
 272 AC_FUNC_GETGROUPS
 273 AC_FUNC_SELECT_ARGTYPES
 274 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 275     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 276     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 277     sigaction sleep sysconf])
 278 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 279
 280 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 281
 282 # X/OPEN
 283 AC_CHECK_FUNCS([readlink])
 284
 285 # SUSv2
 286 AC_CHECK_FUNCS([ctime_r usleep])
 287
 288 # SUSv3
 289 AC_CHECK_FUNCS([strerror_r])
 290
 291 # BSD
 292 AC_CHECK_FUNCS([lstat])
 293
 294 # Non-standard
 295
 296 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 297
 298 #### POSIX threads ####
 299
 300 ACX_PTHREAD
 301
 302 AC_MSG_CHECKING([for PTHREAD_PRIO_INHERIT])
 303 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
 304 #include <pthread.h>
 305 int main() { int i = PTHREAD_PRIO_INHERIT; }]])])
 306 $PTHREAD_CC conftest.c $PTHREAD_CFLAGS $CFLAGS $PTHREAD_LIBS -o conftest > /dev/null 2> /dev/null
 307 ret=$?
 308 rm -f conftest.o conftest
 309
 310 if test $ret -eq 0 ; then
 311     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 312     AC_MSG_RESULT([yes])
 313 else
 314     AC_MSG_RESULT([no])
 315 fi
 316
 317
 318 #### Large File-Support (LFS) ####
 319
 320 AC_SYS_LARGEFILE
 321
 322 # Check for open64 to know if the current system does have open64() and similar functions
 323 AC_CHECK_FUNCS([open64])
 324
 325 #### [lib]iconv ####
 326
 327 AM_ICONV
 328
 329 ###################################
 330 #      External libraries         #
 331 ###################################
 332
 333 #### X11 (optional) ####
 334
 335 HAVE_X11=0
 336
 337 # The macro tests the host, not the build target
 338 if test "x$os_is_win32" != "x1" ; then
 339     AC_PATH_XTRA
 340     test "x$no_x" != "xyes" && HAVE_X11=1
 341 fi
 342
 343 AC_SUBST(HAVE_X11)
 344 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 345 if test "x$HAVE_X11" = "x1" ; then
 346     AC_DEFINE([HAVE_X11], 1, [Have X11])
 347 fi
 348
 349 #### Capabilities (optional) ####
 350
 351 CAP_LIBS=''
 352
 353 AC_ARG_WITH(
 354         [caps],
 355         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 356
 357 if test "x${with_caps}" != "xno"; then
 358     AC_SEARCH_LIBS([cap_init], [cap], [], [
 359                     if test "x${with_caps}" = "xyes" ; then
 360                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 361                     fi])
 362     AC_CHECK_HEADERS([sys/capability.h], [], [
 363                     if test "x${with_caps}" = "xyes" ; then
 364                         AC_MSG_ERROR([*** POSIX caps headers not found])
 365                     fi])
 366 fi
 367
 368 #### pkg-config ####
 369
 370 # Check for pkg-config manually first, as if its not installed the
 371 # PKG_PROG_PKG_CONFIG macro won't be defined.
 372 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 373
 374 if test x"$have_pkg_config" = "xno"; then
 375     AC_MSG_ERROR(pkg-config is required to install this program)
 376 fi
 377
 378 PKG_PROG_PKG_CONFIG
 379
 380 #### Sound file ####
 381
 382 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 383 AC_SUBST(LIBSNDFILE_CFLAGS)
 384 AC_SUBST(LIBSNDFILE_LIBS)
 385
 386 #### atomic-ops ###
 387
 388 AC_CHECK_HEADERS([atomic_ops.h], [], [
 389 AC_MSG_ERROR([*** libatomic-ops headers not found])
 390 ])
 391
 392 # Win32 does not need the lib and breaks horribly if we try to include it
 393 if test "x$os_is_win32" != "x1" ; then
 394     LIBS="$LIBS -latomic_ops"
 395 fi
 396
 397 #### Libsamplerate support (optional) ####
 398
 399 AC_ARG_ENABLE([samplerate],
 400     AC_HELP_STRING([--disable-samplerate], [Disable optional libsamplerate support]),
 401         [
 402             case "${enableval}" in
 403                 yes) samplerate=yes ;;
 404                 no) samplerate=no ;;
 405                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 406             esac
 407         ],
 408         [samplerate=auto])
 409
 410 if test "x${samplerate}" != xno ; then
 411     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 412         HAVE_LIBSAMPLERATE=1,
 413         [
 414             HAVE_LIBSAMPLERATE=0
 415             if test "x$samplerate" = xyes ; then
 416                 AC_MSG_ERROR([*** Libsamplerate not found])
 417             fi
 418         ])
 419 else
 420     HAVE_LIBSAMPLERATE=0
 421 fi
 422
 423 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 424    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 425 fi
 426
 427 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 428 AC_SUBST(LIBSAMPLERATE_LIBS)
 429 AC_SUBST(HAVE_LIBSAMPLERATE)
 430 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 431
 432 #### OSS support (optional) ####
 433
 434 AC_ARG_ENABLE([oss],
 435     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 436         [
 437             case "${enableval}" in
 438                 yes) oss=yes ;;
 439                 no) oss=no ;;
 440                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 441             esac
 442         ],
 443         [oss=auto])
 444
 445 if test "x${oss}" != xno ; then
 446     AC_CHECK_HEADERS([sys/soundcard.h],
 447         [
 448             HAVE_OSS=1
 449             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 450         ],
 451         [
 452             HAVE_OSS=0
 453             if test "x$oss" = xyes ; then
 454                 AC_MSG_ERROR([*** OSS support not found])
 455             fi
 456         ])
 457 else
 458     HAVE_OSS=0
 459 fi
 460
 461 AC_SUBST(HAVE_OSS)
 462 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 463
 464
 465 #### ALSA support (optional) ####
 466
 467 AC_ARG_ENABLE([alsa],
 468     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 469         [
 470             case "${enableval}" in
 471                 yes) alsa=yes ;;
 472                 no) alsa=no ;;
 473                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 474             esac
 475         ],
 476         [alsa=auto])
 477
 478 if test "x${alsa}" != xno ; then
 479     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 480         [
 481             HAVE_ALSA=1
 482             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 483         ],
 484         [
 485             HAVE_ALSA=0
 486             if test "x$alsa" = xyes ; then
 487                 AC_MSG_ERROR([*** ALSA support not found])
 488             fi
 489         ])
 490 else
 491     HAVE_ALSA=0
 492 fi
 493
 494 AC_SUBST(ASOUNDLIB_CFLAGS)
 495 AC_SUBST(ASOUNDLIB_LIBS)
 496 AC_SUBST(HAVE_ALSA)
 497 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 498
 499 #### Solaris audio support (optional) ####
 500
 501 AC_ARG_ENABLE([solaris],
 502     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 503         [
 504             case "${enableval}" in
 505                 yes) solaris=yes ;;
 506                 no) solaris=no ;;
 507                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 508             esac
 509         ],
 510         [solaris=auto])
 511
 512 if test "x${solaris}" != xno ; then
 513     AC_CHECK_HEADERS([sys/audio.h],
 514         [
 515             HAVE_SOLARIS=1
 516             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 517         ],
 518         [
 519             HAVE_SOLARIS=0
 520             if test "x$solaris" = xyes ; then
 521                 AC_MSG_ERROR([*** Solaris audio support not found])
 522             fi
 523         ])
 524 else
 525     HAVE_SOLARIS=0
 526 fi
 527
 528 AC_SUBST(HAVE_SOLARIS)
 529 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 530
 531 #### GLib 2 support (optional) ####
 532
 533 AC_ARG_ENABLE([glib2],
 534     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 535         [
 536             case "${enableval}" in
 537                 yes) glib2=yes ;;
 538                 no) glib2=no ;;
 539                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 540             esac
 541         ],
 542         [glib2=auto])
 543
 544 if test "x${glib2}" != xno ; then
 545     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 546         HAVE_GLIB20=1,
 547         [
 548             HAVE_GLIB20=0
 549             if test "x$glib2" = xyes ; then
 550                 AC_MSG_ERROR([*** GLib 2 support not found])
 551             fi
 552         ])
 553 else
 554     HAVE_GLIB20=0
 555 fi
 556
 557 AC_SUBST(GLIB20_CFLAGS)
 558 AC_SUBST(GLIB20_LIBS)
 559 AC_SUBST(HAVE_GLIB20)
 560 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 561
 562 #### GConf support (optional) ####
 563
 564 AC_ARG_ENABLE([gconf],
 565     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 566         [
 567             case "${enableval}" in
 568                 yes) gconf=yes ;;
 569                 no) gconf=no ;;
 570                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 571             esac
 572         ],
 573         [glib=auto])
 574
 575 if test "x${gconf}" != xno ; then
 576     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 577         HAVE_GCONF=1,
 578         [
 579             HAVE_GCONF=0
 580             if test "x$gconf" = xyes ; then
 581                 AC_MSG_ERROR([*** GConf support not found])
 582             fi
 583         ])
 584 else
 585     HAVE_GCONF=0
 586 fi
 587
 588 AC_SUBST(GCONF_CFLAGS)
 589 AC_SUBST(GCONF_LIBS)
 590 AC_SUBST(HAVE_GCONF)
 591 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 592
 593 #### Avahi support (optional) ####
 594
 595 AC_ARG_ENABLE([avahi],
 596     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 597         [
 598             case "${enableval}" in
 599                 yes) avahi=yes ;;
 600                 no) avahi=no ;;
 601                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 602             esac
 603         ],
 604         [avahi=auto])
 605
 606 if test "x${avahi}" != xno ; then
 607     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 608         HAVE_AVAHI=1,
 609         [
 610                 HAVE_AVAHI=0
 611                 if test "x$avahi" = xyes ; then
 612                         AC_MSG_ERROR([*** Avahi support not found])
 613                 fi
 614         ])
 615 else
 616     HAVE_AVAHI=0
 617 fi
 618
 619 AC_SUBST(AVAHI_CFLAGS)
 620 AC_SUBST(AVAHI_LIBS)
 621 AC_SUBST(HAVE_AVAHI)
 622 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 623
 624 ### LIBOIL ####
 625
 626 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 627 AC_SUBST(LIBOIL_CFLAGS)
 628 AC_SUBST(LIBOIL_LIBS)
 629
 630 ### JACK (optional) ####
 631
 632 AC_ARG_ENABLE([jack],
 633     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 634         [
 635             case "${enableval}" in
 636                 yes) jack=yes ;;
 637                 no) jack=no ;;
 638                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 639             esac
 640         ],
 641         [jack=auto])
 642
 643 if test "x${jack}" != xno ; then
 644     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 645         HAVE_JACK=1,
 646         [
 647             HAVE_JACK=0
 648             if test "x$jack" = xyes ; then
 649                 AC_MSG_ERROR([*** JACK support not found])
 650             fi
 651         ])
 652 else
 653     HAVE_JACK=0
 654 fi
 655
 656 AC_SUBST(JACK_CFLAGS)
 657 AC_SUBST(JACK_LIBS)
 658 AC_SUBST(HAVE_JACK)
 659 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 660
 661 #### Async DNS support (optional) ####
 662
 663 AC_ARG_ENABLE([asyncns],
 664     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 665         [
 666             case "${enableval}" in
 667                 yes) asyncns=yes ;;
 668                 no) asyncns=no ;;
 669                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 670             esac
 671         ],
 672         [asyncns=auto])
 673
 674 if test "x${asyncns}" != xno ; then
 675     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 676         HAVE_LIBASYNCNS=1,
 677         [
 678             HAVE_LIBASYNCNS=0
 679             if test "x$asyncns" = xyes ; then
 680                 AC_MSG_ERROR([*** Async DNS support not found])
 681             fi
 682         ])
 683 else
 684     HAVE_LIBASYNCNS=0
 685 fi
 686
 687 AC_SUBST(LIBASYNCNS_CFLAGS)
 688 AC_SUBST(LIBASYNCNS_LIBS)
 689 AC_SUBST(HAVE_LIBASYNCNS)
 690 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 691
 692 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 693    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 694 fi
 695
 696 #### TCP wrappers (optional) ####
 697
 698 AC_ARG_ENABLE([tcpwrap],
 699     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 700         [
 701             case "${enableval}" in
 702                 yes) tcpwrap=yes ;;
 703                 no) tcpwrap=no ;;
 704                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 705             esac
 706         ],
 707         [tcpwrap=auto])
 708
 709 if test "x${tcpwrap}" != xno ; then
 710     ACX_LIBWRAP
 711     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 712         AC_MSG_ERROR([*** TCP wrappers support not found])
 713     fi
 714 else
 715     LIBWRAP_LIBS=
 716 fi
 717
 718 AC_SUBST(LIBWRAP_LIBS)
 719
 720 #### LIRC support (optional) ####
 721
 722 AC_ARG_ENABLE([lirc],
 723     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 724         [
 725             case "${enableval}" in
 726                 yes) lirc=yes ;;
 727                 no) lirc=no ;;
 728                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 729             esac
 730         ],
 731         [lirc=auto])
 732
 733 if test "x${lirc}" != xno ; then
 734     ACX_LIRC
 735     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 736         AC_MSG_ERROR([*** LIRC support not found])
 737     fi
 738 else
 739     HAVE_LIRC=0
 740 fi
 741
 742 AC_SUBST(LIRC_CFLAGS)
 743 AC_SUBST(LIRC_LIBS)
 744 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 745
 746 #### HAL support (optional) ####
 747
 748 AC_ARG_ENABLE([hal],
 749     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 750         [
 751             case "${enableval}" in
 752                 yes) hal=yes ;;
 753                 no) hal=no ;;
 754                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 755             esac
 756         ],
 757         [hal=auto])
 758 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 759     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 760         HAVE_HAL=1,
 761         [
 762             HAVE_HAL=0
 763             if test "x$hal" = xyes ; then
 764                 AC_MSG_ERROR([*** HAL support not found])
 765             fi
 766         ])
 767 else
 768     HAVE_HAL=0
 769 fi
 770
 771 AC_SUBST(HAL_CFLAGS)
 772 AC_SUBST(HAL_LIBS)
 773 AC_SUBST(HAVE_HAL)
 774 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 775
 776 #### D-Bus support (optional) ####
 777
 778 AC_ARG_ENABLE([dbus],
 779     AC_HELP_STRING([--disable-dbus], [Disable optional D-Bus support]),
 780         [
 781             case "${enableval}" in
 782                 yes) dbus=yes ;;
 783                 no) dbus=no ;;
 784                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 785             esac
 786         ],
 787         [dbus=auto])
 788
 789 if test "x$HAVE_HAL" = x1 ; then
 790    dbus=yes
 791 fi
 792
 793 if test "x${dbus}" != xno ; then
 794
 795     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 796         [
 797             HAVE_DBUS=1
 798             saved_LIBS="$LIBS"
 799             LIBS="$LIBS $DBUS_LIBS"
 800             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 801             LIBS="$saved_LIBS"
 802             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 803         ],
 804         [
 805             HAVE_DBUS=0
 806             if test "x$dbus" = xyes ; then
 807                 AC_MSG_ERROR([*** D-Bus support not found])
 808             fi
 809         ])
 810 else
 811     HAVE_DBUS=0
 812 fi
 813
 814 AC_SUBST(DBUS_CFLAGS)
 815 AC_SUBST(DBUS_LIBS)
 816 AC_SUBST(HAVE_DBUS)
 817 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 818
 819 #### PulseAudio system group & user  #####
 820
 821 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
 822 if test -z "$with_system_user" ; then
 823     PA_SYSTEM_USER=pulse
 824 else
 825     PA_SYSTEM_USER=$with_system_user
 826 fi
 827 AC_SUBST(PA_SYSTEM_USER)
 828 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
 829
 830 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
 831 if test -z "$with_system_group" ; then
 832     PA_SYSTEM_GROUP=pulse
 833 else
 834     PA_SYSTEM_GROUP=$with_system_group
 835 fi
 836 AC_SUBST(PA_SYSTEM_GROUP)
 837 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
 838
 839 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
 840 if test -z "$with_realtime_group" ; then
 841     PA_REALTIME_GROUP=pulse-rt
 842 else
 843     PA_REALTIME_GROUP=$with_realtime_group
 844 fi
 845 AC_SUBST(PA_REALTIME_GROUP)
 846 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
 847
 848 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
 849 if test -z "$with_access_group" ; then
 850     PA_ACCESS_GROUP=pulse-access
 851 else
 852     PA_ACCESS_GROUP=$with_access_group
 853 fi
 854 AC_SUBST(PA_ACCESS_GROUP)
 855 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
 856
 857 #### PulseAudio system runtime dir ####
 858 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
 859 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
 860
 861 ###################################
 862 #            Output               #
 863 ###################################
 864
 865 AC_ARG_ENABLE(
 866         [static-bins],
 867         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 868         [STATIC_BINS=1], [STATIC_BINS=0])
 869 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 870
 871 AC_ARG_WITH(
 872         [preopen-mods],
 873         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 874         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 875 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 876 if test "x$PREOPEN_MODS" != "xall" ; then
 877     tmpLIBS=""
 878     for mod in $PREOPEN_MODS; do
 879         tmpLIBS="$tmpLIBS module-$mod.la"
 880     done
 881     PREOPEN_MODS="$tmpLIBS"
 882     AC_SUBST(PREOPEN_MODS)
 883 fi
 884
 885 AC_ARG_WITH(
 886         [module-dir],
 887         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
 888         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
 889
 890 AC_SUBST(modlibexecdir)
 891
 892 AC_ARG_ENABLE(
 893         [force-preopen],
 894         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 895         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 896 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 897
 898 AC_CONFIG_FILES([
 899 Makefile
 900 src/Makefile
 901 libpulse.pc
 902 libpulse-simple.pc
 903 libpulse-browse.pc
 904 libpulse-mainloop-glib.pc
 905 doxygen/Makefile
 906 doxygen/doxygen.conf
 907 src/pulse/version.h
 908 ])
 909 AC_OUTPUT
 910
 911 # ==========================================================================
 912 ENABLE_X11=no
 913 if test "x$HAVE_X11" = "x1" ; then
 914    ENABLE_X11=yes
 915 fi
 916
 917 ENABLE_OSS=no
 918 if test "x$HAVE_OSS" = "x1" ; then
 919    ENABLE_OSS=yes
 920 fi
 921
 922 ENABLE_ALSA=no
 923 if test "x$HAVE_ALSA" = "x1" ; then
 924    ENABLE_ALSA=yes
 925 fi
 926
 927 ENABLE_SOLARIS=no
 928 if test "x$HAVE_SOLARIS" = "x1" ; then
 929    ENABLE_SOLARIS=yes
 930 fi
 931
 932 ENABLE_GLIB20=no
 933 if test "x$HAVE_GLIB20" = "x1" ; then
 934    ENABLE_GLIB20=yes
 935 fi
 936
 937 ENABLE_GCONF=no
 938 if test "x$HAVE_GCONF" = "x1" ; then
 939    ENABLE_GCONF=yes
 940 fi
 941
 942 ENABLE_AVAHI=no
 943 if test "x$HAVE_AVAHI" = "x1" ; then
 944    ENABLE_AVAHI=yes
 945 fi
 946
 947 ENABLE_JACK=no
 948 if test "x$HAVE_JACK" = "x1" ; then
 949    ENABLE_JACK=yes
 950 fi
 951
 952 ENABLE_LIBASYNCNS=no
 953 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
 954    ENABLE_LIBASYNCNS=yes
 955 fi
 956
 957 ENABLE_LIRC=no
 958 if test "x$HAVE_LIRC" = "x1" ; then
 959    ENABLE_LIRC=yes
 960 fi
 961
 962 ENABLE_HAL=no
 963 if test "x$HAVE_HAL" = "x1" ; then
 964    ENABLE_HAL=yes
 965 fi
 966
 967 ENABLE_TCPWRAP=no
 968 if test "x${LIBWRAP_LIBS}" != x ; then
 969    ENABLE_TCPWRAP=yes
 970 fi
 971
 972 ENABLE_LIBSAMPLERATE=no
 973 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
 974    ENABLE_LIBSAMPLERATE=yes
 975 fi
 976
 977 echo "
 978  ---{ $PACKAGE_NAME $VERSION }---
 979
 980     prefix:                 ${prefix}
 981     sysconfdir:             ${sysconfdir}
 982     localstatedir:          ${localstatedir}
 983     System Runtime Path:    ${PA_SYSTEM_RUNTIME_PATH}
 984     Compiler:               ${CC}
 985     CFLAGS:                 ${CFLAGS}
 986     Have X11:               ${ENABLE_X11}
 987     Enable OSS:             ${ENABLE_OSS}
 988     Enable Alsa:            ${ENABLE_ALSA}
 989     Enable Solaris:         ${ENABLE_SOLARIS}
 990     Enable GLib 2.0:        ${ENABLE_GLIB20}
 991     Enable GConf:           ${ENABLE_GCONF}
 992     Enable Avahi:           ${ENABLE_AVAHI}
 993     Enable Jack:            ${ENABLE_JACK}
 994     Enable Async DNS:       ${ENABLE_LIBASYNCNS}
 995     Enable LIRC:            ${ENABLE_LIRC}
 996     Enable HAL:             ${ENABLE_HAL}
 997     Enable TCP Wrappers:    ${ENABLE_TCPWRAP}
 998     Enable libsamplerate:   ${ENABLE_LIBSAMPLERATE}
 999     System User:            ${PA_SYSTEM_USER}
1000     System Group:           ${PA_SYSTEM_GROUP}
1001     Realtime Group:         ${PA_REALTIME_GROUP}
1002     Access Group:           ${PA_ACCESS_GROUP}
1003 "