configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.6.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 601, 0, 601)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.6.1
  50 GSTPB_REQ=1.6.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.17])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 AC_ARG_ENABLE(pcmdump, AC_HELP_STRING([--enable-pcmdump], [pcm dump]),
 254   [
 255     case "${enableval}" in
 256       yes) PCM_DUMP_ENABLE=yes ;;
 257       no)  PCM_DUMP_ENABLE=no ;;
 258       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-pcmdump) ;;
 259     esac
 260   ],
 261   [PCM_DUMP_ENABLE=no])
 262 AM_CONDITIONAL([PCM_DUMP_ENABLE], [test "x$PCM_DUMP_ENABLE" = "xyes"])
 263
 264 if test "x$PCM_DUMP_ENABLE" = "xyes"; then
 265 PKG_CHECK_MODULES(VCONF, vconf)
 266 AC_SUBST(VCONF_CFLAGS)
 267 AC_SUBST(VCONF_LIBS)
 268 fi
 269
 270 dnl *** set variables based on configure arguments ***
 271
 272 dnl set license and copyright notice
 273 GST_LICENSE="LGPL"
 274 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 275 AC_SUBST(GST_LICENSE)
 276
 277 dnl set location of plugin directory
 278 AG_GST_SET_PLUGINDIR
 279
 280 dnl set release date/time
 281 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 282   ["${srcdir}/gst-plugins-good.doap"],
 283   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 284
 285 dnl build static plugins or not
 286 AC_MSG_CHECKING([whether to build static plugins or not])
 287 AC_ARG_ENABLE(
 288   static-plugins,
 289   AC_HELP_STRING(
 290     [--enable-static-plugins],
 291     [build static plugins @<:@default=no@:>@]),
 292   [AS_CASE(
 293     [$enableval], [no], [], [yes], [],
 294     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 295   [enable_static_plugins=no])
 296 AC_MSG_RESULT([$enable_static_plugins])
 297 if test "x$enable_static_plugins" = xyes; then
 298   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 299     [Define if static plugins should be built])
 300   GST_PLUGIN_LIBTOOLFLAGS=""
 301 else
 302   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 303 fi
 304 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 305 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 306
 307 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 308 dnl make sure it doesn't complain about unused variables if debugging is disabled
 309 NO_WARNINGS=""
 310 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 311
 312 dnl define an ERROR_CFLAGS Makefile variable
 313 dnl -Wundef: too many broken headers
 314 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 315       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 316       -Wwrite-strings -Wold-style-definition -Waggregate-return
 317       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 318       -Wnested-externs $NO_WARNINGS])
 319
 320 dnl define an ERROR_CXXFLAGS Makefile variable
 321 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 322         -Wmissing-declarations -Wredundant-decls
 323         -Wwrite-strings
 324         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 325         $NO_WARNINGS])
 326
 327 dnl define an ERROR_OBJCFLAGS Makefile variable
 328 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 329       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 330       -Wwrite-strings -Wold-style-definition
 331       -Winit-self -Wmissing-include-dirs -Wno-multichar
 332       -Wnested-externs $NO_WARNINGS])
 333
 334 dnl define correct level for debugging messages
 335 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 336
 337 dnl used in examples
 338 AG_GST_DEFAULT_ELEMENTS
 339
 340 dnl *** plug-ins to include ***
 341
 342 dnl these are all the gst plug-ins, compilable without additional libs
 343 dnl videofilter is at the top because others depend on it
 344 AG_GST_CHECK_PLUGIN(alpha)
 345 AG_GST_CHECK_PLUGIN(apetag)
 346 AG_GST_CHECK_PLUGIN(audiofx)
 347 AG_GST_CHECK_PLUGIN(audioparsers)
 348 AG_GST_CHECK_PLUGIN(auparse)
 349 AG_GST_CHECK_PLUGIN(autodetect)
 350 AG_GST_CHECK_PLUGIN(avi)
 351 AG_GST_CHECK_PLUGIN(cutter)
 352 AG_GST_CHECK_PLUGIN(debugutils)
 353 AG_GST_CHECK_PLUGIN(deinterlace)
 354 AG_GST_CHECK_PLUGIN(dtmf)
 355 AG_GST_CHECK_PLUGIN(effectv)
 356 AG_GST_CHECK_PLUGIN(equalizer)
 357 AG_GST_CHECK_PLUGIN(flv)
 358 AG_GST_CHECK_PLUGIN(flx)
 359 AG_GST_CHECK_PLUGIN(goom)
 360 AG_GST_CHECK_PLUGIN(goom2k1)
 361 AG_GST_CHECK_PLUGIN(icydemux)
 362 AG_GST_CHECK_PLUGIN(id3demux)
 363 AG_GST_CHECK_PLUGIN(imagefreeze)
 364 AG_GST_CHECK_PLUGIN(interleave)
 365 AG_GST_CHECK_PLUGIN(isomp4)
 366 AG_GST_CHECK_PLUGIN(law)
 367 AG_GST_CHECK_PLUGIN(level)
 368 AG_GST_CHECK_PLUGIN(matroska)
 369 AG_GST_CHECK_PLUGIN(monoscope)
 370 AG_GST_CHECK_PLUGIN(multifile)
 371 AG_GST_CHECK_PLUGIN(multipart)
 372 AG_GST_CHECK_PLUGIN(replaygain)
 373 AG_GST_CHECK_PLUGIN(rtp)
 374 AG_GST_CHECK_PLUGIN(rtpmanager)
 375 AG_GST_CHECK_PLUGIN(rtsp)
 376 AG_GST_CHECK_PLUGIN(shapewipe)
 377 AG_GST_CHECK_PLUGIN(smpte)
 378 AG_GST_CHECK_PLUGIN(spectrum)
 379 AG_GST_CHECK_PLUGIN(udp)
 380 AG_GST_CHECK_PLUGIN(videobox)
 381 AG_GST_CHECK_PLUGIN(videocrop)
 382 AG_GST_CHECK_PLUGIN(videofilter)
 383 AG_GST_CHECK_PLUGIN(videomixer)
 384 AG_GST_CHECK_PLUGIN(wavenc)
 385 AG_GST_CHECK_PLUGIN(wavparse)
 386 AG_GST_CHECK_PLUGIN(y4m)
 387
 388 dnl disable experimental plug-ins
 389 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 390   AG_GST_DISABLE_PLUGIN(monoscope)
 391 fi
 392
 393 dnl *** sys plug-ins ***
 394
 395 echo
 396 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 397 echo
 398
 399 dnl DirectSound
 400 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 401 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 402   HAVE_DIRECTSOUND="no"
 403   save_CFLAGS="$CFLAGS"
 404   save_LDFLAGS="$LDFLAGS"
 405   save_LIBS="$LIBS"
 406   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 407   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 408   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 409   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 410   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 411 #include <windows.h>
 412 #include <dxerr9.h>
 413 #include <dsound.h>
 414 ]], [[
 415   DXGetErrorString9 (0);
 416   DirectSoundCreate(NULL, NULL, NULL);
 417   CLSIDFromString(NULL, NULL);
 418 ]])
 419 ],
 420     [HAVE_DIRECTSOUND="yes"],
 421     [HAVE_DIRECTSOUND="no"])
 422   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 423   CFLAGS=$save_CFLAGS
 424   LDFLAGS=$save_LDFLAGS
 425   LIBS=$save_LIBS
 426
 427   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 428     dnl this is much more than we want
 429     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 430     AC_SUBST(DIRECTSOUND_CFLAGS)
 431     AC_SUBST(DIRECTSOUND_LDFLAGS)
 432     AC_SUBST(DIRECTSOUND_LIBS)
 433   fi
 434   AC_SUBST(HAVE_DIRECTSOUND)
 435 ])
 436
 437 dnl *** Win32 WaveOut ***
 438 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 439 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 440   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 441 ])
 442
 443 dnl *** OSS audio *** (Linux, *BSD)
 444 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 445 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 446  HAVE_OSS="yes"
 447 dnl Linux and newer BSD versions :
 448  AC_CHECK_HEADER(sys/soundcard.h, [
 449    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 450    ] , [
 451 dnl Some old BSD versions and also newer OpenBSD versions :
 452    AC_CHECK_HEADER(soundcard.h, [
 453      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 454      ], [
 455   dnl Some old BSD versions :
 456      AC_CHECK_HEADER(machine/soundcard.h, [
 457        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 458          [Define if OSS includes are in /machine/])
 459        ], [
 460        HAVE_OSS="no"
 461      ])
 462    ])
 463  ])
 464 ])
 465
 466 dnl *** oss4 ***
 467 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 468 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 469   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 470   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 471       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 472       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 473 ])
 474
 475 dnl *** Sun Audio ***
 476 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 477 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 478   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 479 ])
 480
 481 dnl *** OSX Audio ***
 482 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 483 HAVE_IOS="no"
 484 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 485   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 486     [HAVE_OSX_AUDIO="yes"],
 487     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 488     [
 489       HAVE_OSX_AUDIO="yes"
 490       HAVE_IOS="yes"
 491     ], [
 492       HAVE_OSX_AUDIO="no"
 493       HAVE_IOS="no"
 494     ])]
 495   )
 496 ])
 497 if test "x$HAVE_IOS" = "xyes"; then
 498   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 499 fi
 500 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 501
 502 dnl *** OS X video ***
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 504 HAVE_OSX_VIDEO="no"
 505 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 506   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 507
 508   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 509   dnl also require Snow Leopard or newer
 510
 511   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 512         #include <AvailabilityMacros.h>
 513         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 514         #error Too old OSX version
 515         #endif
 516       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 517 ])
 518
 519 dnl *** Video 4 Linux 2 ***
 520 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 521 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 522 HAVE_GST_V4L2=no
 523 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 524   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 525   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 526   [
 527     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 528     [
 529       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 530     ])
 531   ])
 532   if test "x$HAVE_VIDEODEV" = "xno"; then
 533      AC_MSG_WARN([video4linux2 was not found])
 534   fi
 535 ])
 536
 537 # Optional gudev for device probing
 538 AC_ARG_WITH([gudev],
 539   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 540   [],
 541   [with_gudev=check])
 542 if test x$HAVE_GST_V4L2 = xyes; then
 543   if test x$with_gudev != xno; then
 544     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 545       [ AC_DEFINE(HAVE_GUDEV, 1,
 546           [Whether gudev is available for device detection])
 547       ],
 548       [true])
 549   fi
 550 fi
 551
 552 AC_SUBST(GUDEV_CFLAGS)
 553 AC_SUBST(GUDEV_LIBS)
 554
 555 # Make libv4l2 non-automagic
 556 AC_ARG_WITH([libv4l2],
 557   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 558   [],
 559   [with_libv4l2=check])
 560 if test x$HAVE_GST_V4L2 = xyes; then
 561   if test x$with_libv4l2 != xno; then
 562       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 563           [ have_libv4l2=yes
 564             AC_DEFINE(HAVE_LIBV4L2, 1,
 565                 [Whether libv4l2 is available for video buffer conversion])
 566           ], [
 567           have_libv4l2=no
 568           ])
 569   else
 570     have_libv4l2=no
 571   fi
 572 fi
 573
 574 dnl Check for X11
 575 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 576 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 577                   [ximagesrc], [
 578   AG_GST_CHECK_X
 579
 580   if test "x$HAVE_X" = "xyes"
 581   then
 582     dnl check for Xfixes
 583     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 584     if test "x$HAVE_XFIXES" = "xyes"
 585     then
 586         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 587     fi
 588     AC_SUBST(XFIXES_LIBS)
 589     AC_SUBST(XFIXES_CFLAGS)
 590
 591     dnl check for Xdamage
 592     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 593     if test "x$HAVE_XDAMAGE" = "xyes"
 594     then
 595         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 596     fi
 597     AC_SUBST(XDAMAGE_LIBS)
 598     AC_SUBST(XDAMAGE_CFLAGS)
 599   fi
 600 ])
 601
 602 dnl FIXME: this should be rolled into the test above, it's just an additional
 603 dnl feature of the ximagesrc plug-in
 604 dnl This is the same as in gst-plugins-base
 605 dnl check for X Shm
 606 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 607 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 608   if test x$HAVE_X = xyes; then
 609     AC_CHECK_LIB(Xext, XShmAttach,
 610                  HAVE_XSHM="yes", HAVE_XSHM="no",
 611                  $X_LIBS)
 612     if test "x$HAVE_XSHM" = "xyes"; then
 613       XSHM_LIBS="-lXext"
 614     else
 615       dnl On AIX, it is in XextSam instead, but we still need -lXext
 616       AC_CHECK_LIB(XextSam, XShmAttach,
 617                    HAVE_XSHM="yes", HAVE_XSHM="no",
 618                    $X_LIBS)
 619       if test "x$HAVE_XSHM" = "xyes"; then
 620         XSHM_LIBS="-lXext -lXextSam"
 621       fi
 622     fi
 623   fi
 624 ], ,[
 625   AC_SUBST(HAVE_XSHM)
 626   AC_SUBST(XSHM_LIBS)
 627 ])
 628
 629 dnl *** ext plug-ins ***
 630 dnl keep this list sorted alphabetically !
 631
 632 if test "x$BUILD_EXTERNAL" = "xyes"; then
 633
 634 echo
 635 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 636 echo
 637
 638 dnl *** aalib ***
 639 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 640 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 641   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 642 ])
 643
 644 dnl *** cairo ***
 645 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 646 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 647   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 648 ])
 649
 650 dnl *** FLAC ***
 651 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 652 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 653   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 654 ])
 655
 656 dnl *** GDK pixbuf ***
 657 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 658 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 659   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 660 ])
 661
 662 dnl *** Jack ***
 663 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 664 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 665   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 666   AC_SUBST(JACK_CFLAGS)
 667   AC_SUBST(JACK_LIBS)
 668
 669   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 670   if test x$HAVE_JACK_0_120_1 = xyes; then
 671     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 672   fi
 673   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 674   if test x$HAVE_JACK_1_9_7 = xyes; then
 675     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 676   fi
 677
 678 ])
 679
 680 dnl *** jpeg ***
 681 dnl FIXME: we could use header checks here as well IMO
 682 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 683 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 684   AC_ARG_WITH(jpeg-mmx,
 685     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 686   OLD_LIBS="$LIBS"
 687   if test x$with_jpeg_mmx != x; then
 688     LIBS="$LIBS -L$with_jpeg_mmx"
 689   fi
 690   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 691   JPEG_LIBS="$LIBS -ljpeg-mmx"
 692   LIBS="$OLD_LIBS"
 693   if test x$HAVE_JPEG != xyes; then
 694     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 695     JPEG_LIBS="-ljpeg"
 696   fi
 697   AC_SUBST(JPEG_LIBS)
 698 ])
 699
 700 dnl *** libcaca ***
 701 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 702 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 703   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 704 ])
 705
 706 dnl *** libdv ***
 707 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 708 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 709   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 710 ])
 711
 712 dnl *** libpng ***
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 714 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 715   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 716 ])
 717
 718 dnl *** pulseaudio ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 720 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 721
 722   dnl used in ext/pulse/pulseutil.c
 723   AC_CHECK_HEADERS([process.h])
 724
 725   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 726 ])
 727
 728 dnl *** dv1394 ***
 729 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 730 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 731   dnl first test for libraw1394 >= 2.0.0
 732   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 733   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 734   dnl now see how far we got
 735   if test x$HAVE_RAW1394 = xyes && \
 736      test x$HAVE_LIBIEC61883 = xyes; then
 737        AG_GST_CHECK_LIBHEADER(AVC1394,
 738         avc1394, avc1394_send_command, $RAW1394_LIBS,
 739         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 740        AG_GST_CHECK_LIBHEADER(ROM1394,
 741         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 742         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 743        if test x$HAVE_AVC1394 = xyes && \
 744           test x$HAVE_AVC1394 = xyes && \
 745           test x$HAVE_ROM1394 = xyes; then
 746           HAVE_DV1394=yes
 747           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 748           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 749           AC_SUBST(DV1394_CFLAGS)
 750           AC_SUBST(DV1394_LIBS)
 751         fi
 752   else
 753        if test x$HAVE_RAW1394 = xno; then
 754           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 755           AG_GST_CHECK_LIBHEADER(AVC1394,
 756            avc1394, avc1394_send_command, $RAW1394_LIBS,
 757            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 758           AG_GST_CHECK_LIBHEADER(ROM1394,
 759            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 760            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 761           if test x$HAVE_RAW1394 = xyes && \
 762              test x$HAVE_AVC1394 = xyes && \
 763              test x$HAVE_ROM1394 = xyes; then
 764              HAVE_DV1394=yes
 765              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 766              DV1394_CFLAGS="$RAW1394_CFLAGS"
 767              if test x$HAVE_LIBIEC61883 = xyes; then
 768                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 769                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 770              fi
 771              AC_SUBST(DV1394_CFLAGS)
 772              AC_SUBST(DV1394_LIBS)
 773            fi
 774          fi
 775   fi
 776 ])
 777 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 778
 779 dnl *** shout2 ***
 780 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 781 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 782   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 783 ])
 784
 785 dnl *** soup ***
 786 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 787 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 788   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.40, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 789   AC_SUBST(SOUP_CFLAGS)
 790   AC_SUBST(SOUP_LIBS)
 791 ])
 792
 793 dnl *** speex ***
 794 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 795 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 796   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 797 ])
 798
 799 dnl *** taglib ***
 800 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 801 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 802   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 803   if test "x$HAVE_CXX" != "xyes"; then
 804     USE_TAGLIB=false
 805     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 806   else
 807     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 808     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 809         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 810       ], [
 811         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 812     ])
 813     AC_SUBST(TAGLIB_CXXFLAGS)
 814   fi
 815 ])
 816
 817 dnl *** vpx ***
 818 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 819 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 820   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 821   HAVE_VP8=no
 822   HAVE_VP9=no
 823
 824   if test $HAVE_VPX = "yes"; then
 825     OLD_LIBS="$LIBS"
 826     OLD_CFLAGS="$CFLAGS"
 827     CFLAGS="$CFLAGS $VPX_CFLAGS"
 828     LIBS="$LIBS $VPX_LIBS"
 829     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 830       HAVE_VP8=yes
 831       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 832     ])
 833     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 834       HAVE_VP8=yes
 835       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 836     ])
 837
 838     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 839       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 840         HAVE_VP9=yes
 841         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 842       ])
 843       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 844         HAVE_VP9=yes
 845         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 846       ])
 847     ], [true])
 848     LIBS="$OLD_LIBS"
 849     CFLAGS="$OLD_CFLAGS"
 850   fi
 851   AC_SUBST(VPX_LIBS)
 852   AC_SUBST(VPX_CFLAGS)
 853 ])
 854
 855 dnl *** wavpack ***
 856 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 857 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 858   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 859 ])
 860
 861 dnl *** qtdemux & matroska prefer to have zlib ***
 862 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 863 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 864   AG_GST_CHECK_LIBHEADER(ZLIB,
 865     z, uncompress,, zlib.h, [
 866     HAVE_ZLIB="yes"
 867     ZLIB_LIBS="-lz"
 868     AC_SUBST(ZLIB_LIBS)
 869   ])
 870 ])
 871
 872 dnl *** matroska prefers to have bz2 ***
 873 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 874 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 875   save_LIBS=$LIBS
 876   LIBS="$LIBS -lbz2"
 877   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 878   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 879   AC_MSG_RESULT($HAVE_BZ2)
 880   LIBS=$save_LIBS
 881   if test "x$HAVE_BZ2" = "xyes"; then
 882     BZ2_LIBS="-lbz2"
 883   fi
 884   AC_SUBST(BZ2_LIBS)
 885 ])
 886
 887 else
 888
 889 dnl not building plugins with external dependencies,
 890 dnl but we still need to set the conditionals
 891 AM_CONDITIONAL(USE_AALIB, false)
 892 AM_CONDITIONAL(USE_BZ2, false)
 893 AM_CONDITIONAL(USE_CAIRO, false)
 894 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 895 AM_CONDITIONAL(USE_DV1394, false)
 896 AM_CONDITIONAL(USE_FLAC, false)
 897 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 898 AM_CONDITIONAL(USE_JACK, false)
 899 AM_CONDITIONAL(USE_JPEG, false)
 900 AM_CONDITIONAL(USE_LIBCACA, false)
 901 AM_CONDITIONAL(USE_LIBDV, false)
 902 AM_CONDITIONAL(USE_LIBIEC61883, false)
 903 AM_CONDITIONAL(USE_LIBPNG, false)
 904 AM_CONDITIONAL(USE_OSS, false)
 905 AM_CONDITIONAL(USE_OSS4, false)
 906 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 907 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 908 AM_CONDITIONAL(USE_PULSE, false)
 909 AM_CONDITIONAL(USE_SHOUT2, false)
 910 AM_CONDITIONAL(USE_SOUP, false)
 911 AM_CONDITIONAL(USE_SPEEX, false)
 912 AM_CONDITIONAL(USE_SUNAUDIO, false)
 913 AM_CONDITIONAL(USE_TAGLIB, false)
 914 AM_CONDITIONAL(USE_VPX, false)
 915 AM_CONDITIONAL(USE_WAVEFORM, false)
 916 AM_CONDITIONAL(USE_WAVPACK, false)
 917 AM_CONDITIONAL(USE_X, false)
 918 AM_CONDITIONAL(USE_XSHM, false)
 919 AM_CONDITIONAL(USE_ZLIB, false)
 920
 921 fi dnl of EXT plugins
 922
 923 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 924
 925 dnl Overview:
 926 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 927 dnl GST_*:              flags shared by all built objects
 928 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 929 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 930 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 931 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 932
 933 dnl GST_OPTION_CFLAGS
 934 if test "x$USE_DEBUG" = xyes; then
 935    PROFILE_CFLAGS="-g"
 936 fi
 937 AC_SUBST(PROFILE_CFLAGS)
 938
 939 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 940   dnl Define _only_ for git (not pre-releases or releases)
 941   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 942 else
 943   DEPRECATED_CFLAGS=""
 944 fi
 945 AC_SUBST(DEPRECATED_CFLAGS)
 946
 947 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 948 dnl at make time with e.g. make ERROR_CFLAGS=""
 949 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 950 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 951 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 952 AC_SUBST(GST_OPTION_CFLAGS)
 953 AC_SUBST(GST_OPTION_CXXFLAGS)
 954 AC_SUBST(GST_OPTION_OBJCFLAGS)
 955
 956 dnl our libraries need to be versioned correctly
 957 AC_SUBST(GST_LT_LDFLAGS)
 958
 959 dnl FIXME: do we want to rename to GST_ALL_* ?
 960 dnl prefer internal headers to already installed ones
 961 dnl also add builddir include for enumtypes and marshal
 962 dnl add ERROR_CFLAGS, but overridable
 963 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 964 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 965 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 966 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 967 AC_SUBST(GST_CFLAGS)
 968 AC_SUBST(GST_CXXFLAGS)
 969 AC_SUBST(GST_OBJCFLAGS)
 970 AC_SUBST(GST_LIBS)
 971
 972 dnl LDFLAGS really should only contain flags, not libs - they get added before
 973 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 974 GST_ALL_LDFLAGS="-no-undefined"
 975 AC_SUBST(GST_ALL_LDFLAGS)
 976
 977 dnl this really should only contain flags, not libs - they get added before
 978 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 979 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 980 AC_SUBST(GST_PLUGIN_LDFLAGS)
 981
 982 dnl *** output files ***
 983
 984 $MKDIR_P tests/check/orc
 985
 986 dnl keep this alphabetic per directory, please
 987 AC_CONFIG_FILES(
 988 Makefile
 989 gst/Makefile
 990 gst/alpha/Makefile
 991 gst/apetag/Makefile
 992 gst/audiofx/Makefile
 993 gst/audioparsers/Makefile
 994 gst/auparse/Makefile
 995 gst/autodetect/Makefile
 996 gst/avi/Makefile
 997 gst/cutter/Makefile
 998 gst/deinterlace/Makefile
 999 gst/dtmf/Makefile
1000 gst/debugutils/Makefile
1001 gst/effectv/Makefile
1002 gst/equalizer/Makefile
1003 gst/flv/Makefile
1004 gst/goom/Makefile
1005 gst/goom2k1/Makefile
1006 gst/id3demux/Makefile
1007 gst/icydemux/Makefile
1008 gst/imagefreeze/Makefile
1009 gst/interleave/Makefile
1010 gst/isomp4/Makefile
1011 gst/law/Makefile
1012 gst/level/Makefile
1013 gst/matroska/Makefile
1014 gst/monoscope/Makefile
1015 gst/multifile/Makefile
1016 gst/multipart/Makefile
1017 gst/replaygain/Makefile
1018 gst/rtp/Makefile
1019 gst/rtpmanager/Makefile
1020 gst/rtsp/Makefile
1021 gst/shapewipe/Makefile
1022 gst/smpte/Makefile
1023 gst/spectrum/Makefile
1024 gst/udp/Makefile
1025 gst/videobox/Makefile
1026 gst/videocrop/Makefile
1027 gst/videofilter/Makefile
1028 gst/videomixer/Makefile
1029 gst/wavenc/Makefile
1030 gst/wavparse/Makefile
1031 gst/flx/Makefile
1032 gst/y4m/Makefile
1033 ext/Makefile
1034 ext/aalib/Makefile
1035 ext/cairo/Makefile
1036 ext/dv/Makefile
1037 ext/flac/Makefile
1038 ext/gdk_pixbuf/Makefile
1039 ext/jack/Makefile
1040 ext/jpeg/Makefile
1041 ext/libcaca/Makefile
1042 ext/libpng/Makefile
1043 ext/pulse/Makefile
1044 ext/raw1394/Makefile
1045 ext/shout2/Makefile
1046 ext/soup/Makefile
1047 ext/speex/Makefile
1048 ext/taglib/Makefile
1049 ext/vpx/Makefile
1050 ext/wavpack/Makefile
1051 sys/Makefile
1052 sys/directsound/Makefile
1053 sys/oss/Makefile
1054 sys/oss4/Makefile
1055 sys/osxaudio/Makefile
1056 sys/osxvideo/Makefile
1057 sys/sunaudio/Makefile
1058 sys/v4l2/Makefile
1059 sys/waveform/Makefile
1060 sys/ximage/Makefile
1061 po/Makefile.in
1062 tests/Makefile
1063 tests/check/Makefile
1064 tests/examples/Makefile
1065 tests/examples/audiofx/Makefile
1066 tests/examples/cairo/Makefile
1067 tests/examples/equalizer/Makefile
1068 tests/examples/jack/Makefile
1069 tests/examples/level/Makefile
1070 tests/examples/pulse/Makefile
1071 tests/examples/rtp/Makefile
1072 tests/examples/shapewipe/Makefile
1073 tests/examples/spectrum/Makefile
1074 tests/examples/v4l2/Makefile
1075 tests/files/Makefile
1076 tests/icles/Makefile
1077 common/Makefile
1078 common/m4/Makefile
1079 m4/Makefile
1080 docs/Makefile
1081 docs/plugins/Makefile
1082 docs/version.entities
1083 pkgconfig/Makefile
1084 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1085 gst-plugins-good.spec
1086 )
1087
1088 dnl Create the config.h file for Visual Studio builds
1089 dnl Beware of spaces and /'s in some of the shell variable contents.
1090 sed \
1091     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1092     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1093     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1094     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1095     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1096     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1097     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1098     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1099     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1100     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1101     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1102     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1103     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1104     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1105     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1106     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1107     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1108     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1109     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1110     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1111     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1112     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1113     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1114     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1115     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1116     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1117     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1118     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1119     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1120     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1121     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1122     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1123     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1124     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1125     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1126     config.h.in >win32/common/config.h-new
1127
1128 AC_OUTPUT
1129
1130 AG_GST_OUTPUT_PLUGINS
1131 ORC_OUTPUT
1132