configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.21.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 15, 0, 15)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.10.21.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AC_HELP_STRING([--with-install-plugins-helper],
  90     [specify path of helper script to call to install plugins]),
  91   [
  92     case "${withval}" in
  93       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  95       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  96     esac
  97   ],
  98   [
  99     dnl Default value
 100     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 101   ]
 102 )
 103 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 104 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 105     [plugin install helper script])
 106 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 107
 108 AG_GST_ARG_WITH_PLUGINS
 109
 110 AG_GST_ARG_ENABLE_EXTERNAL
 111
 112 AG_GST_ARG_ENABLE_EXPERIMENTAL
 113
 114 dnl *** checks for platform ***
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130
 131 dnl check if the compiler supports '-c' and '-o' options
 132 AM_PROG_CC_C_O
 133
 134 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 135 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl libm, for sin() etc.
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used in gst/ffmpegcolorspace/mem.c
 154 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 155 AC_CHECK_HEADERS([malloc.h])
 156
 157 dnl used in gst/subparse/gstsubparse.c
 158 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 159 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 160
 161 if test "x$HAVE_REGEX_H" = "xyes"; then
 162   ac_cppflags_save="$CPPFLAGS"
 163   CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 164   AC_COMPILE_IFELSE(
 165     AC_LANG_PROGRAM([
 166 #include <libxml/HTMLparser.h>
 167                      ],[
 168 #ifndef LIBXML_HTML_ENABLED
 169 #error libxml2 has no HTML support
 170 #endif /* LIBXML_HTML_ENABLED */
 171                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 172   CPPFLAGS="$ac_cppflags_save"
 173 else
 174   HAVE_LIBXML_HTML="no"
 175 fi
 176 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/rtsp
 184 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 185 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 186   WIN32_LIBS="-lws2_32"
 187   AC_SUBST(WIN32_LIBS)
 188 fi
 189
 190 dnl check for hstrerror, for gst-libs/gst/rtsp
 191 save_libs="$LIBS"
 192 AC_CHECK_FUNC(hstrerror, ,
 193     AC_CHECK_LIB(resolv, hstrerror, ,
 194         [AC_DEFINE(NO_HSTRERROR, 1,
 195              [Define if you have no native hstrerror() function.])]))
 196 HSTRERROR_LIBS=$LIBS
 197 AC_SUBST(HSTRERROR_LIBS)
 198 LIBS="$save_libs"
 199
 200 dnl used in gst-libs/gst/pbutils and associated unit test
 201 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 202
 203 dnl ffmpegcolorspace includes _stdint.h
 204 dnl also, Windows does not have long long
 205 AX_CREATE_STDINT_H
 206
 207 dnl *** checks for functions ***
 208 AC_CHECK_FUNCS([localtime_r gmtime_r])
 209
 210 dnl *** checks for types/defines ***
 211
 212 dnl Check for FIONREAD ioctl declaration
 213 dnl used in gst/tcp
 214 GST_CHECK_FIONREAD
 215
 216 dnl *** checks for structures ***
 217
 218 dnl *** checks for compiler characteristics ***
 219
 220 dnl make sure we can use "inline" from C code
 221 AC_C_INLINE
 222
 223 dnl *** checks for library functions ***
 224
 225 dnl check for fseeko()
 226 AC_FUNC_FSEEKO
 227
 228 dnl Check for fast float to int casting as defined in C99
 229 dnl used in gst-libs/gst/floatcast/floatcast.h
 230 save_libs=$LIBS
 231 LIBS="$LIBS $LIBM"
 232 AC_C99_FUNC_LRINT
 233 AC_C99_FUNC_LRINTF
 234 LIBS=$save_libs
 235
 236 dnl Check for a way to display the function name in debug output
 237 AG_GST_CHECK_FUNCTION
 238
 239 dnl *** checks for dependency libraries ***
 240
 241 dnl GLib is required
 242 AG_GST_GLIB_CHECK([2.12])
 243
 244 dnl liboil is required
 245 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 246 if test "x$HAVE_LIBOIL" != "xyes"; then
 247   AC_ERROR([liboil-0.3.14 or later is required])
 248 fi
 249
 250 dnl checks for gstreamer
 251 dnl uninstalled is selected preferentially -- see pkg-config(1)
 252 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 253 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 254 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 255 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 256 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 257 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 258
 259 dnl Check for documentation xrefs
 260 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 261 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 262 AC_SUBST(GLIB_PREFIX)
 263 AC_SUBST(GST_PREFIX)
 264
 265 dnl GTK is optional and only used in examples
 266 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.12.0, HAVE_GTK=yes, HAVE_GTK=no)
 267 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 268
 269 dnl some examples need gtk+-x11
 270 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.12.0,
 271     HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 272 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 273
 274 dnl *** set variables based on configure arguments ***
 275
 276 dnl set license and copyright notice
 277 GST_LICENSE="LGPL"
 278 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 279 AC_SUBST(GST_LICENSE)
 280
 281 dnl set location of plugin directory
 282 AG_GST_SET_PLUGINDIR
 283
 284 dnl define an ERROR_CFLAGS Makefile variable
 285 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 286
 287 dnl define correct level for debugging messages
 288 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 289
 290 dnl used in examples
 291 AG_GST_DEFAULT_ELEMENTS
 292
 293 dnl *** plug-ins to include ***
 294
 295 dnl these are all the gst plug-ins, compilable without additional libs
 296 AG_GST_CHECK_PLUGIN(adder)
 297 AG_GST_CHECK_PLUGIN(audioconvert)
 298 AG_GST_CHECK_PLUGIN(audiorate)
 299 AG_GST_CHECK_PLUGIN(audiotestsrc)
 300 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 301 AG_GST_CHECK_PLUGIN(gdp)
 302 AG_GST_CHECK_PLUGIN(playback)
 303 AG_GST_CHECK_PLUGIN(speexresample)
 304 AG_GST_CHECK_PLUGIN(subparse)
 305 AG_GST_CHECK_PLUGIN(tcp)
 306 AG_GST_CHECK_PLUGIN(typefind)
 307 AG_GST_CHECK_PLUGIN(videotestsrc)
 308 AG_GST_CHECK_PLUGIN(videorate)
 309 AG_GST_CHECK_PLUGIN(videoscale)
 310 AG_GST_CHECK_PLUGIN(volume)
 311
 312 dnl check for gstreamer core features (subsystems)
 313 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 314 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 315 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 316
 317 dnl disable plug-ins that require libxml2's HTML support if it is not available
 318 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 319   AG_GST_DISABLE_PLUGIN(subparse)
 320 fi
 321
 322 dnl disable plug-ins that require sys/socket.h if it is not available
 323 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 324   AG_GST_DISABLE_PLUGIN(tcp)
 325 fi
 326
 327 dnl *** sys plug-ins ***
 328
 329 echo
 330 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 331 echo
 332
 333 dnl *** X11 ***
 334 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 335 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 336                   [ximagesink], [
 337   AC_PATH_XTRA
 338   ac_cflags_save="$CFLAGS"
 339   ac_cppflags_save="$CPPFLAGS"
 340   CFLAGS="$CFLAGS $X_CFLAGS"
 341   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 342
 343   dnl now try to find the HEADER
 344   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 345
 346   if test "x$HAVE_X" = "xno"
 347   then
 348     AC_MSG_NOTICE([cannot find X11 development files])
 349   else
 350     dnl this is much more than we want
 351     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 352     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 353     dnl it does not add the libs; therefore we add them here
 354     X_LIBS="$X_LIBS -lX11"
 355     AC_SUBST(X_CFLAGS)
 356     AC_SUBST(X_LIBS)
 357   fi
 358   AC_SUBST(HAVE_X)
 359   CFLAGS="$ac_cflags_save"
 360   CPPFLAGS="$ac_cppflags_save"
 361 ])
 362
 363 dnl Check for Xv extension
 364 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 365 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 366                   [xvimagesink], [
 367   AG_GST_CHECK_XV
 368 ])
 369
 370 dnl check for X Shm
 371 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 372 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 373   if test x$HAVE_X = xyes; then
 374     AC_CHECK_LIB(Xext, XShmAttach,
 375                  HAVE_XSHM="yes", HAVE_XSHM="no",
 376                  $X_LIBS)
 377     if test "x$HAVE_XSHM" = "xyes"; then
 378       XSHM_LIBS="-lXext"
 379     else
 380       dnl On AIX, it is in XextSam instead, but we still need -lXext
 381       AC_CHECK_LIB(XextSam, XShmAttach,
 382                    HAVE_XSHM="yes", HAVE_XSHM="no",
 383                    $X_LIBS)
 384       if test "x$HAVE_XSHM" = "xyes"; then
 385         XSHM_LIBS="-lXext -lXextSam"
 386       fi
 387     fi
 388   fi
 389 ], , [
 390   AC_SUBST(HAVE_XSHM)
 391   AC_SUBST(XSHM_LIBS)
 392 ])
 393
 394 dnl v4l/v4l2 checks have been moved down because they require X
 395
 396 dnl *** Video 4 Linux ***
 397 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 398 dnl renamed to GST_V4L in accordance with V4L2 below
 399 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 400 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 401   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 402 #include <sys/types.h>
 403 #define _LINUX_TIME_H
 404 #define __user
 405 #include <linux/videodev.h>
 406   ])
 407
 408   dnl we can build v4l without Xv, but then we won't have XOverlay support
 409   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 410   then
 411     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 412     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 413   fi
 414 ])
 415
 416 dnl *** ext plug-ins ***
 417 dnl keep this list sorted alphabetically !
 418
 419 if test "x$BUILD_EXTERNAL" = "xyes"; then
 420
 421 echo
 422 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 423 echo
 424
 425 dnl *** alsa ***
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 427 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 428   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 429     HAVE_ALSA="yes"
 430     AC_SUBST(ALSA_CFLAGS)
 431     AC_SUBST(ALSA_LIBS)
 432   ], [
 433     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 434   ])
 435 ])
 436
 437 dnl *** CDParanoia ***
 438 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 439 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 440   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 441                       cdda_open, -lm,
 442                       cdda_interface.h,
 443                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 444                       HEADER_DIR="no"
 445                       FOUND_CDPARANOIA="yes")
 446   if test "x$FOUND_CDPARANOIA" != "xyes";
 447   then
 448     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 449                         cdda_open, -lm,
 450                         cdda/cdda_interface.h,
 451                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 452                         HEADER_DIR="yes"
 453                         FOUND_CDPARANOIA="yes")
 454   fi
 455   if test "x$HEADER_DIR" = "xyes";
 456   then
 457     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 458                        defined if cdda headers are in a cdda/ directory)
 459   fi
 460   AC_SUBST(CDPARANOIA_LIBS)
 461 ])
 462 dnl FIXME : add second check somehow if that is necessary
 463 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 464 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 465
 466 dnl *** GNOME VFS ***
 467 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 468 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 469   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 470 ])
 471
 472 dnl *** libgio ***
 473 USE_GIO=$BUILD_EXPERIMENTAL
 474 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 475 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 476   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, HAVE_GIO="yes", [
 477     HAVE_GIO="no"
 478     AC_MSG_RESULT(no)
 479   ])
 480   AC_SUBST(GIO_CFLAGS)
 481   AC_SUBST(GIO_LIBS)
 482   AC_SUBST(GIO_LDFLAGS)
 483 ])
 484
 485 dnl *** libvisual ***
 486 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 487 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 488   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 489   if test $HAVE_LIBVISUAL = no
 490   then
 491     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 492   fi
 493 ])
 494
 495 dnl *** ogg ***
 496 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 497 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 498   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 499   if test $HAVE_OGG = no
 500   then
 501     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 502     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 503   fi
 504 ])
 505
 506 dnl *** pango ***
 507 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 508 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 509   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 510 ])
 511
 512 dnl *** theora ***
 513 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 514 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 515   dnl theora uses pkg-config version incorrectly, for pkg-config:
 516   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 517   dnl theoraenc and theoradec appeared in 1.0beta3
 518
 519   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 520   if test x$HAVE_THEORA = xno; then
 521     AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 522   fi
 523 ])
 524
 525 dnl *** vorbis ***
 526 dnl AM_PATH_VORBIS only takes two options
 527 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 528 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 529   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 530   if test $HAVE_VORBIS = no
 531   then
 532     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 533     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 534   fi
 535 ])
 536
 537 if test "x$HAVE_VORBIS" = "xyes"; then
 538   ac_cflags_save="$CFLAGS"
 539   AC_COMPILE_IFELSE(
 540     AC_LANG_PROGRAM([
 541 #include <vorbis/codec.h>
 542                      ],[
 543 vorbis_dsp_state *v;
 544
 545 vorbis_synthesis_restart (v);
 546                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 547   if test "x$HAVE_VSR" = "xyes"; then
 548     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 549                        [defined if vorbis_synthesis_restart is present])
 550   fi
 551   CFLAGS="$ac_cflags_save"
 552 fi
 553
 554 else
 555
 556 dnl not building plugins with external dependencies,
 557 dnl but we still need to set the conditionals
 558 AM_CONDITIONAL(USE_ALSA, false)
 559 AM_CONDITIONAL(USE_CDPARANOIA, false)
 560 AM_CONDITIONAL(USE_GNOME_VFS, false)
 561 AM_CONDITIONAL(USE_GIO, false)
 562 AM_CONDITIONAL(USE_LIBVISUAL, false)
 563 AM_CONDITIONAL(USE_OGG, false)
 564 AM_CONDITIONAL(USE_PANGO, false)
 565 AM_CONDITIONAL(USE_THEORA, false)
 566 AM_CONDITIONAL(USE_VORBIS, false)
 567
 568 fi dnl of EXT plugins
 569
 570 dnl seeking needs freetype, so check for it here
 571 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 572   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 573 ])
 574 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 575 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 576 AC_SUBST(FT2_CFLAGS)
 577 AC_SUBST(FT2_LIBS)
 578
 579 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 580
 581 dnl Overview:
 582 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 583 dnl GST_*:              flags shared by built objects to link against GStreamer
 584 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 585 dnl                          (compare to other modules) or for i18n
 586 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 587 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 588 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 589 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 590
 591 dnl GST_OPTION_CFLAGS
 592 if test "x$USE_DEBUG" = xyes; then
 593    PROFILE_CFLAGS="-g"
 594 fi
 595 AC_SUBST(PROFILE_CFLAGS)
 596
 597 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 598   dnl Define _only_ during CVS (not pre-releases or releases)
 599   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 600 else
 601   DEPRECATED_CFLAGS=""
 602 fi
 603 AC_SUBST(DEPRECATED_CFLAGS)
 604
 605 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 606 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 607 AC_SUBST(GST_OPTION_CFLAGS)
 608
 609 dnl our libraries need to be versioned correctly
 610 AC_SUBST(GST_LT_LDFLAGS)
 611
 612 dnl GST_PLUGINS_BASE_CFLAGS
 613 dnl prefer internal headers to already installed ones
 614 dnl also add builddir include for enumtypes and marshal
 615 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 616 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 617
 618 dnl FIXME: do we want to rename to GST_ALL_* ?
 619 dnl add GST_OPTION_CFLAGS, but overridable
 620 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 621 AC_SUBST(GST_CFLAGS)
 622 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 623 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 624 AC_SUBST(GST_LIBS)
 625
 626 dnl LDFLAGS really should only contain flags, not libs - they get added before
 627 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 628 GST_ALL_LDFLAGS="-no-undefined"
 629 AC_SUBST(GST_ALL_LDFLAGS)
 630
 631 dnl GST_LIB_LDFLAGS
 632 dnl linker flags shared by all libraries
 633 dnl LDFLAGS modifier defining exported symbols from built libraries
 634 dnl (export _gst_foo but not __gst_foo)
 635 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 636 AC_SUBST(GST_LIB_LDFLAGS)
 637
 638 dnl this really should only contain flags, not libs - they get added before
 639 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 640 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 641 AC_SUBST(GST_PLUGIN_LDFLAGS)
 642
 643 dnl *** output files ***
 644
 645 AC_CONFIG_FILES(
 646 Makefile
 647 gst-plugins-base.spec
 648 gst/Makefile
 649 gst/adder/Makefile
 650 gst/audioconvert/Makefile
 651 gst/audiorate/Makefile
 652 gst/audiotestsrc/Makefile
 653 gst/ffmpegcolorspace/Makefile
 654 gst/gdp/Makefile
 655 gst/playback/Makefile
 656 gst/speexresample/Makefile
 657 gst/subparse/Makefile
 658 gst/tcp/Makefile
 659 gst/typefind/Makefile
 660 gst/videotestsrc/Makefile
 661 gst/videorate/Makefile
 662 gst/videoscale/Makefile
 663 gst/volume/Makefile
 664 sys/Makefile
 665 sys/ximage/Makefile
 666 sys/xvimage/Makefile
 667 sys/v4l/Makefile
 668 ext/Makefile
 669 ext/alsa/Makefile
 670 ext/cdparanoia/Makefile
 671 ext/gnomevfs/Makefile
 672 ext/gio/Makefile
 673 ext/libvisual/Makefile
 674 ext/ogg/Makefile
 675 ext/pango/Makefile
 676 ext/theora/Makefile
 677 ext/vorbis/Makefile
 678 gst-libs/Makefile
 679 gst-libs/gst/Makefile
 680 gst-libs/gst/audio/Makefile
 681 gst-libs/gst/cdda/Makefile
 682 gst-libs/gst/fft/Makefile
 683 gst-libs/gst/floatcast/Makefile
 684 gst-libs/gst/interfaces/Makefile
 685 gst-libs/gst/netbuffer/Makefile
 686 gst-libs/gst/riff/Makefile
 687 gst-libs/gst/rtp/Makefile
 688 gst-libs/gst/rtsp/Makefile
 689 gst-libs/gst/sdp/Makefile
 690 gst-libs/gst/tag/Makefile
 691 gst-libs/gst/pbutils/Makefile
 692 gst-libs/gst/video/Makefile
 693 tools/Makefile
 694 win32/common/config.h
 695 pkgconfig/Makefile
 696 pkgconfig/gstreamer-audio.pc
 697 pkgconfig/gstreamer-audio-uninstalled.pc
 698 pkgconfig/gstreamer-cdda.pc
 699 pkgconfig/gstreamer-cdda-uninstalled.pc
 700 pkgconfig/gstreamer-fft.pc
 701 pkgconfig/gstreamer-fft-uninstalled.pc
 702 pkgconfig/gstreamer-floatcast.pc
 703 pkgconfig/gstreamer-floatcast-uninstalled.pc
 704 pkgconfig/gstreamer-interfaces.pc
 705 pkgconfig/gstreamer-interfaces-uninstalled.pc
 706 pkgconfig/gstreamer-netbuffer.pc
 707 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 708 pkgconfig/gstreamer-pbutils.pc
 709 pkgconfig/gstreamer-pbutils-uninstalled.pc
 710 pkgconfig/gstreamer-riff.pc
 711 pkgconfig/gstreamer-riff-uninstalled.pc
 712 pkgconfig/gstreamer-rtp.pc
 713 pkgconfig/gstreamer-rtp-uninstalled.pc
 714 pkgconfig/gstreamer-rtsp.pc
 715 pkgconfig/gstreamer-rtsp-uninstalled.pc
 716 pkgconfig/gstreamer-sdp.pc
 717 pkgconfig/gstreamer-sdp-uninstalled.pc
 718 pkgconfig/gstreamer-tag.pc
 719 pkgconfig/gstreamer-tag-uninstalled.pc
 720 pkgconfig/gstreamer-video.pc
 721 pkgconfig/gstreamer-video-uninstalled.pc
 722 pkgconfig/gstreamer-plugins-base.pc
 723 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 724 tests/Makefile
 725 tests/check/Makefile
 726 tests/examples/Makefile
 727 tests/examples/dynamic/Makefile
 728 tests/examples/seek/Makefile
 729 tests/examples/volume/Makefile
 730 tests/examples/snapshot/Makefile
 731 tests/icles/Makefile
 732 docs/Makefile
 733 docs/design/Makefile
 734 docs/libs/Makefile
 735 docs/plugins/Makefile
 736 docs/version.entities
 737 po/Makefile.in
 738 common/Makefile
 739 common/m4/Makefile
 740 m4/Makefile
 741 )
 742 AC_OUTPUT
 743
 744 AG_GST_OUTPUT_PLUGINS