configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.11.4,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 8, 0, 8)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.11.1
  58
  59 dnl *** autotools stuff ****
  60
  61 dnl allow for different autotools
  62 AS_AUTOTOOLS_ALTERNATE
  63
  64 dnl Add parameters for aclocal
  65 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  66
  67 dnl set up gettext
  68 dnl the version check needs to stay here because autopoint greps for it
  69 AM_GNU_GETTEXT_VERSION([0.11.5])
  70 AM_GNU_GETTEXT([external])
  71 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  72
  73 dnl *** check for arguments to configure ***
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 dnl let distro override plugin install helper path
  87 AC_ARG_WITH(install-plugins-helper,
  88   AC_HELP_STRING([--with-install-plugins-helper],
  89     [specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107
 108 dnl these are all the gst plug-ins, compilable without additional libs
 109 GST_PLUGINS_ALL="\
 110         adder \
 111         audioconvert \
 112         audiorate \
 113         audioresample \
 114         audiotestsrc \
 115         ffmpegcolorspace \
 116         gdp \
 117         playback \
 118         typefind \
 119         videotestsrc \
 120         videorate \
 121         videoscale \
 122         volume \
 123         "
 124 AC_SUBST(GST_PLUGINS_ALL)
 125
 126 GST_PLUGINS_SELECTED=""
 127
 128 AC_ARG_WITH(plugins,
 129     AC_HELP_STRING([--with-plugins],
 130       [comma-separated list of plug-ins to compile]),
 131     [for i in `echo $withval | tr , ' '`; do
 132         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 133         then
 134             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 135         else
 136             echo "plug-in $i not recognized, ignoring..."
 137         fi
 138     done],
 139     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 140
 141 AC_SUBST(GST_PLUGINS_SELECTED)
 142
 143 dnl ext plug-ins; plug-ins that have external dependencies
 144 AG_GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 145   [HAVE_EXTERNAL=yes], enabled,
 146   [
 147     AC_MSG_NOTICE(building external plug-ins)
 148     BUILD_EXTERNAL="yes"
 149   ],[
 150     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 151     BUILD_EXTERNAL="no"
 152   ])
 153 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 154
 155 dnl *** checks for platform ***
 156
 157 dnl * hardware/architecture *
 158
 159 dnl common/m4/gst-arch.m4
 160 dnl check CPU type
 161 AG_GST_ARCH
 162
 163 dnl *** checks for programs ***
 164
 165 dnl find a compiler
 166 AC_PROG_CC
 167
 168 dnl determine c++ compiler
 169 AC_PROG_CXX
 170 dnl determine if c++ is available on this system
 171 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 172
 173 dnl determine c++ preprocessor
 174 dnl FIXME: do we need this ?
 175 AC_PROG_CXXCPP
 176
 177 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 178 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 179
 180 dnl check for documentation tools
 181 GTK_DOC_CHECK([1.3])
 182 AS_PATH_PYTHON([2.1])
 183 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 184
 185 dnl *** checks for libraries ***
 186
 187 dnl For interactive UNIX (a Sun thing)
 188 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 189 AC_ISC_POSIX
 190
 191 dnl libm, for sin() etc.
 192 AC_CHECK_LIBM
 193 AC_SUBST(LIBM)
 194
 195 dnl *** checks for header files ***
 196
 197 dnl check if we have ANSI C header files
 198 AC_HEADER_STDC
 199
 200 dnl used in gst/ffmpegcolorspace/mem.c
 201 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 202 AC_CHECK_HEADERS([malloc.h])
 203
 204 dnl used in gst/subparse/gstsubparse.c
 205 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 206 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 207
 208 dnl used in gst/tcp
 209 AC_CHECK_HEADERS([sys/socket.h],
 210   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 211 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 212
 213 dnl used in gst-libs/gst/pbutils and associated unit test
 214 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 215
 216 dnl ffmpegcolorspace includes _stdint.h
 217 dnl also, Windows does not have long long
 218 AX_CREATE_STDINT_H
 219
 220 dnl *** checks for functions ***
 221 AC_CHECK_FUNCS([localtime_r])
 222
 223 dnl *** checks for types/defines ***
 224
 225 dnl Check for FIONREAD ioctl declaration
 226 dnl used in gst/tcp
 227 GST_CHECK_FIONREAD
 228
 229 dnl *** checks for structures ***
 230
 231 dnl *** checks for compiler characteristics ***
 232
 233 dnl make sure we can use "inline" from C code
 234 AC_C_INLINE
 235
 236 dnl *** checks for library functions ***
 237
 238 dnl Check for fast float to int casting as defined in C99
 239 dnl used in gst-libs/gst/floatcast/floatcast.h
 240 AC_C99_FUNC_LRINT
 241 AC_C99_FUNC_LRINTF
 242
 243 dnl Check for a way to display the function name in debug output
 244 AG_GST_CHECK_FUNCTION
 245
 246 dnl *** checks for dependency libraries ***
 247
 248 dnl GLib is required
 249 AG_GST_GLIB_CHECK([2.6])
 250
 251 dnl liboil is required
 252 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 253 if test "x$HAVE_LIBOIL" != "xyes"
 254 then
 255   AC_ERROR([liboil-0.3.8 or later is required])
 256 fi
 257
 258 dnl checks for gstreamer
 259 dnl uninstalled is selected preferentially -- see pkg-config(1)
 260 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 261 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 262 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 263 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 264 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 265
 266 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 267 dnl check for "check", unit testing library/header
 268 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 269 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 270
 271 dnl Check for documentation xrefs
 272 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 273 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 274 AC_SUBST(GLIB_PREFIX)
 275 AC_SUBST(GST_PREFIX)
 276
 277 dnl GTK is optional and used in examples
 278 HAVE_GTK=NO
 279 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 280 if test "x$HAVE_GTK_22" = "xyes"; then
 281   HAVE_GTK=yes
 282   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 283   AC_SUBST(GTK_VERSION)
 284   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 285   AC_SUBST(GTK_BASE_DIR)
 286 else
 287   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 288 fi
 289 if test "x$HAVE_GTK_20" = "xyes"; then
 290   HAVE_GTK=yes
 291 fi
 292 GTK_CFLAGS=$GTK2_CFLAGS
 293 GTK_LIBS=$GTK2_LIBS
 294 AC_SUBST(GTK_LIBS)
 295 AC_SUBST(GTK_CFLAGS)
 296 AC_SUBST(HAVE_GTK)
 297 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 298
 299 dnl *** set variables based on configure arguments ***
 300
 301 dnl set license and copyright notice
 302 GST_LICENSE="LGPL"
 303 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 304 AC_SUBST(GST_LICENSE)
 305
 306 dnl set location of plugin directory
 307 AG_GST_SET_PLUGINDIR
 308
 309 dnl define an ERROR_CFLAGS Makefile variable
 310 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 311
 312 dnl define correct level for debugging messages
 313 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 314
 315 dnl used in examples
 316 AG_GST_DEFAULT_ELEMENTS
 317
 318 dnl *** sys plug-ins ***
 319
 320 echo
 321 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 322 echo
 323
 324 dnl *** X11 ***
 325 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 326 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 327                   [ximagesink], [
 328   AC_PATH_XTRA
 329   ac_cflags_save="$CFLAGS"
 330   ac_cppflags_save="$CPPFLAGS"
 331   CFLAGS="$CFLAGS $X_CFLAGS"
 332   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 333
 334   dnl now try to find the HEADER
 335   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 336
 337   if test "x$HAVE_X" = "xno"
 338   then
 339     AC_MSG_NOTICE([cannot find X11 development files])
 340   else
 341     dnl this is much more than we want
 342     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 343     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 344     dnl it does not add the libs; therefore we add them here
 345     X_LIBS="$X_LIBS -lX11"
 346     AC_SUBST(X_CFLAGS)
 347     AC_SUBST(X_LIBS)
 348   fi
 349   AC_SUBST(HAVE_X)
 350   CFLAGS="$ac_cflags_save"
 351   CPPFLAGS="$ac_cppflags_save"
 352 ])
 353
 354 dnl Check for Xv extension
 355 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 356 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 357                   [xvimagesink], [
 358   AG_GST_CHECK_XV
 359 ])
 360
 361 dnl check for X Shm
 362 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 363 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 364   if test x$HAVE_X = xyes; then
 365     AC_CHECK_LIB(Xext, XShmAttach,
 366                  HAVE_XSHM="yes", HAVE_XSHM="no",
 367                  $X_LIBS)
 368     if test "x$HAVE_XSHM" = "xyes"; then
 369       XSHM_LIBS="-lXext"
 370     else
 371       dnl On AIX, it is in XextSam instead, but we still need -lXext
 372       AC_CHECK_LIB(XextSam, XShmAttach,
 373                    HAVE_XSHM="yes", HAVE_XSHM="no",
 374                    $X_LIBS)
 375       if test "x$HAVE_XSHM" = "xyes"; then
 376         XSHM_LIBS="-lXext -lXextSam"
 377       fi
 378     fi
 379   fi
 380 ], , [
 381   AC_SUBST(HAVE_XSHM)
 382   AC_SUBST(XSHM_LIBS)
 383 ])
 384
 385 dnl v4l/v4l2 checks have been moved down because they require X
 386
 387 dnl *** Video 4 Linux ***
 388 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 389 dnl renamed to GST_V4L in accordance with V4L2 below
 390 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 391 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 392   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 393 #include <sys/types.h>
 394 #define _LINUX_TIME_H
 395 #define __user
 396 #include <linux/videodev.h>
 397   ])
 398
 399   dnl we can build v4l without Xv, but then we won't have XOverlay support
 400   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 401   then
 402     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 403     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 404   fi
 405 ])
 406
 407 dnl *** ext plug-ins ***
 408 dnl keep this list sorted alphabetically !
 409
 410 if test "x$BUILD_EXTERNAL" = "xyes"; then
 411
 412 echo
 413 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 414 echo
 415
 416 dnl *** alsa ***
 417 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 418 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 419   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 420     HAVE_ALSA="yes"
 421     AC_SUBST(ALSA_CFLAGS)
 422     AC_SUBST(ALSA_LIBS)
 423   ], [
 424     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 425   ])
 426 ])
 427
 428 dnl *** CDParanoia ***
 429 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 430 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 431   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 432                       cdda_open, -lm,
 433                       cdda_interface.h,
 434                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 435                       HEADER_DIR="no"
 436                       FOUND_CDPARANOIA="yes")
 437   if test "x$FOUND_CDPARANOIA" != "xyes";
 438   then
 439     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 440                         cdda_open, -lm,
 441                         cdda/cdda_interface.h,
 442                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 443                         HEADER_DIR="yes"
 444                         FOUND_CDPARANOIA="yes")
 445   fi
 446   if test "x$HEADER_DIR" = "xyes";
 447   then
 448     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 449                        defined if cdda headers are in a cdda/ directory)
 450   fi
 451   AC_SUBST(CDPARANOIA_LIBS)
 452 ])
 453 dnl FIXME : add second check somehow if that is necessary
 454 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 455 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 456
 457 dnl *** GNOME VFS ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 459 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 460   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 461 ])
 462
 463 dnl *** libvisual ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 465 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 466   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 467   if test $HAVE_LIBVISUAL = no
 468   then
 469     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 470   fi
 471 ])
 472
 473 dnl *** ogg ***
 474 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 475 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 476   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 477   if test $HAVE_OGG = no
 478   then
 479     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 480     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 481   fi
 482 ])
 483
 484 dnl *** pango ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 486 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 487   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 488 ])
 489
 490 dnl *** theora ***
 491 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 492 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 493   AG_GST_PKG_CHECK_MODULES(THEORA, theora)
 494   if test $HAVE_THEORA = no
 495   then
 496     AG_GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
 497     AC_SUBST(THEORA_LIBS)
 498   fi
 499 ])
 500
 501 dnl *** vorbis ***
 502 dnl AM_PATH_VORBIS only takes two options
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 504 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 505   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 506   if test $HAVE_VORBIS = no
 507   then
 508     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 509     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 510   fi
 511 ])
 512
 513 if test "x$HAVE_VORBIS" = "xyes"; then
 514   ac_cflags_save="$CFLAGS"
 515   dnl FIXME: does this work on non-gcc? -- Company
 516   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 517   CFLAGS="-Wall -Werror"
 518   AC_COMPILE_IFELSE(
 519     AC_LANG_PROGRAM([
 520 #include <vorbis/codec.h>
 521                      ],[
 522 vorbis_dsp_state *v;
 523
 524 vorbis_synthesis_restart (v);
 525                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 526   if test "x$HAVE_VSR" = "xyes"; then
 527     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 528                        [defined if vorbis_synthesis_restart is present])
 529   fi
 530   CFLAGS="$ac_cflags_save"
 531 fi
 532
 533 else
 534
 535 dnl not building plugins with external dependencies,
 536 dnl but we still need to set the conditionals
 537 AM_CONDITIONAL(USE_ALSA, false)
 538 AM_CONDITIONAL(USE_CDPARANOIA, false)
 539 AM_CONDITIONAL(USE_GNOME_VFS, false)
 540 AM_CONDITIONAL(USE_LIBVISUAL, false)
 541 AM_CONDITIONAL(USE_OGG, false)
 542 AM_CONDITIONAL(USE_PANGO, false)
 543 AM_CONDITIONAL(USE_THEORA, false)
 544 AM_CONDITIONAL(USE_VORBIS, false)
 545
 546 fi dnl of EXT plugins
 547
 548 dnl seeking needs freetype, so check for it here
 549 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 550   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 551 ])
 552 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 553 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 554 AC_SUBST(FT2_CFLAGS)
 555 AC_SUBST(FT2_LIBS)
 556
 557 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 558
 559 dnl Overview:
 560 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 561 dnl GST_*:              flags shared by built objects to link against GStreamer
 562 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 563 dnl                          (compare to other modules) or for i18n
 564 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 565 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 566 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 567 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 568
 569 dnl GST_OPTION_CFLAGS
 570 if test "x$USE_DEBUG" = xyes; then
 571    PROFILE_CFLAGS="-g"
 572 fi
 573 AC_SUBST(PROFILE_CFLAGS)
 574
 575 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 576 AC_SUBST(DEPRECATED_CFLAGS)
 577
 578 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 579 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 580 AC_SUBST(GST_OPTION_CFLAGS)
 581
 582 dnl our libraries need to be versioned correctly
 583 AC_SUBST(GST_LT_LDFLAGS)
 584
 585 dnl GST_PLUGINS_BASE_CFLAGS
 586 dnl prefer internal headers to already installed ones
 587 dnl also add builddir include for enumtypes and marshal
 588 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 589 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 590
 591 dnl FIXME: do we want to rename to GST_ALL_* ?
 592 dnl add GST_OPTION_CFLAGS, but overridable
 593 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 594 AC_SUBST(GST_CFLAGS)
 595 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 596 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 597 AC_SUBST(GST_LIBS)
 598
 599 dnl LDFLAGS really should only contain flags, not libs - they get added before
 600 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 601 GST_ALL_LDFLAGS="-no-undefined"
 602 AC_SUBST(GST_ALL_LDFLAGS)
 603
 604 dnl GST_LIB_LDFLAGS
 605 dnl linker flags shared by all libraries
 606 dnl LDFLAGS modifier defining exported symbols from built libraries
 607 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 608 AC_SUBST(GST_LIB_LDFLAGS)
 609
 610 dnl this really should only contain flags, not libs - they get added before
 611 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 612 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 613 AC_SUBST(GST_PLUGIN_LDFLAGS)
 614
 615 dnl *** output files ***
 616
 617 AC_CONFIG_FILES(
 618 Makefile
 619 gst-plugins-base.spec
 620 gst/Makefile
 621 gst/adder/Makefile
 622 gst/audioconvert/Makefile
 623 gst/audiorate/Makefile
 624 gst/audioresample/Makefile
 625 gst/audiotestsrc/Makefile
 626 gst/ffmpegcolorspace/Makefile
 627 gst/gdp/Makefile
 628 gst/playback/Makefile
 629 gst/subparse/Makefile
 630 gst/tcp/Makefile
 631 gst/typefind/Makefile
 632 gst/videotestsrc/Makefile
 633 gst/videorate/Makefile
 634 gst/videoscale/Makefile
 635 gst/volume/Makefile
 636 sys/Makefile
 637 sys/ximage/Makefile
 638 sys/xvimage/Makefile
 639 sys/v4l/Makefile
 640 ext/Makefile
 641 ext/alsa/Makefile
 642 ext/cdparanoia/Makefile
 643 ext/gnomevfs/Makefile
 644 ext/libvisual/Makefile
 645 ext/ogg/Makefile
 646 ext/pango/Makefile
 647 ext/theora/Makefile
 648 ext/vorbis/Makefile
 649 gst-libs/Makefile
 650 gst-libs/gst/Makefile
 651 gst-libs/gst/audio/Makefile
 652 gst-libs/gst/cdda/Makefile
 653 gst-libs/gst/floatcast/Makefile
 654 gst-libs/gst/interfaces/Makefile
 655 gst-libs/gst/netbuffer/Makefile
 656 gst-libs/gst/riff/Makefile
 657 gst-libs/gst/rtp/Makefile
 658 gst-libs/gst/tag/Makefile
 659 gst-libs/gst/pbutils/Makefile
 660 gst-libs/gst/video/Makefile
 661 tools/Makefile
 662 win32/common/config.h
 663 pkgconfig/Makefile
 664 pkgconfig/gstreamer-plugins-base.pc
 665 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 666 tests/Makefile
 667 tests/check/Makefile
 668 tests/examples/Makefile
 669 tests/examples/seek/Makefile
 670 tests/examples/volume/Makefile
 671 tests/icles/Makefile
 672 docs/Makefile
 673 docs/design/Makefile
 674 docs/libs/Makefile
 675 docs/plugins/Makefile
 676 docs/version.entities
 677 po/Makefile.in
 678 common/Makefile
 679 common/m4/Makefile
 680 m4/Makefile
 681 )
 682 AC_OUTPUT
 683
 684 AG_GST_OUTPUT_PLUGINS