configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_rev], m4_eval(v_maj + v_min))
  16 m4_define([lt_cur], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver.beta2], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_ISC_POSIX
  28 AC_GNU_SOURCE
  29
  30 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  31 AM_CONFIG_HEADER([config.h])
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33
  34 AC_LIBTOOL_WIN32_DLL
  35 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  36 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  37 AC_PROG_LIBTOOL
  38
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  41 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  42 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  43 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  44 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  45 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  46 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  47 version_info="lt_rev:lt_cur:lt_age"
  48 release_info="v_rel"
  49 AC_SUBST(version_info)
  50 AC_SUBST(release_info)
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  53 VMAJ=v_maj
  54 AC_SUBST(VMAJ)
  55
  56 ### Needed information
  57
  58 requirement_eina=""
  59
  60 case "$host_os" in
  61    mingw32ce*)
  62       MODULE_ARCH="$host_os-$host_cpu"
  63       ;;
  64    *)
  65       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  66       ;;
  67 esac
  68 AC_SUBST(MODULE_ARCH)
  69 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  70
  71 case "$host_os" in
  72    mingw*)
  73       MODULE_EXT=".dll"
  74       ;;
  75    *)
  76       MODULE_EXT=".so"
  77       ;;
  78 esac
  79
  80 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  81
  82 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  83 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  84 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  85 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  86
  87 EFL_CHECK_THREADS(
  88    [
  89     if test "x${_efl_have_posix_threads}" = "xyes" ; then
  90        have_threads="POSIX"
  91     else
  92        if test "x${_efl_have_win32_threads}" = "xyes" ; then
  93           have_threads="Win32"
  94        else
  95           have_threads="no"
  96        fi
  97     fi
  98    ],
  99    [have_threads="no"])
 100 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 101
 102 ### Additional options to configure
 103
 104 # Magic debug
 105 AC_ARG_ENABLE([magic-debug],
 106    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 107    [
 108     if test "x${enableval}" = "xyes" ; then
 109        have_magic_debug="yes"
 110     else
 111        have_magic_debug="no"
 112     fi
 113    ],
 114    [have_magic_debug="yes"])
 115
 116 AC_MSG_CHECKING([whether magic debug is enable])
 117 AC_MSG_RESULT([${have_magic_debug}])
 118
 119 if test "x${have_magic_debug}" = "xyes" ; then
 120    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 121 fi
 122 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 123
 124 # Valgrind
 125 want_valgrind="auto"
 126 have_valgrind="no"
 127
 128 AC_MSG_CHECKING(whether to enable build with valgrind)
 129 AC_ARG_ENABLE(valgrind,
 130   AC_HELP_STRING([--enable-valgrind], [improve valgrind support by hinting it of our memory usages, having it to report proper mempool leaks.]),
 131   [want_valgrind=$enableval]
 132 )
 133 AC_MSG_RESULT($want_valgrind)
 134
 135 if test "x${want_valgrind}" = "xyes" -o "x${want_valgrind}" = "xauto"; then
 136     PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
 137         [
 138          requirement_eina="valgrind ${requirement_eina}"
 139          have_valgrind="yes"
 140         ],
 141         [
 142          AC_DEFINE(NVALGRIND, 1, [Valgrind support disabled])
 143          if test "x$want_valgrind" = "xyes"; then
 144             AC_MSG_ERROR([Valgrind >= 2.4.0 is required)])
 145          fi
 146         ]
 147     )
 148 else
 149     AC_DEFINE(NVALGRIND, 1, [Valgrind support disabled])
 150 fi
 151
 152 # Safety checks (avoid crashes on wrong api usage)
 153 AC_ARG_ENABLE(safety-checks,
 154    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 155    [
 156     if test "x${enableval}" = "xyes" ; then
 157        have_safety_checks="yes"
 158     else
 159        have_safety_checks="no"
 160     fi
 161    ],
 162    [have_safety_checks="yes"])
 163
 164 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 165 AC_MSG_RESULT($have_safety_checks)
 166
 167 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 168 if test "x$have_safety_checks" = "xyes"; then
 169   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 170   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 171 fi
 172 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 173
 174 with_max_log_level="<unset>"
 175 AC_ARG_WITH(internal-maximum-log-level,
 176    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 177                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 178    [
 179     if test "x${withval}" != "xno"; then
 180        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
 181           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 182           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 183           with_max_log_level="${withval}"
 184        else
 185           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 186        fi
 187     fi
 188     ], [:])
 189
 190 AC_ARG_ENABLE([amalgamation],
 191    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 192    [if test "x${enableval}" = "xyes"; then
 193        do_amalgamation="yes"
 194     else
 195        do_amalgamation="no"
 196     fi
 197    ],
 198    [do_amalgamation="no"]
 199 )
 200 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 201
 202 # Choose best memory pool
 203 AC_ARG_ENABLE([default-mempool],
 204    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 205    [
 206     if test "x${enableval}" = "xyes"; then
 207        have_default_mempool="yes"
 208     else
 209        have_default_mempool="no"
 210     fi
 211    ],
 212    [have_default_mempool="no"]
 213 )
 214 AC_MSG_CHECKING([whether to use default mempool allocator])
 215 AC_MSG_RESULT([${have_default_mempool}])
 216
 217 if test "x${have_default_mempool}" = "xyes" ; then
 218    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 219 fi
 220 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 221
 222 # Report stringshare usage
 223 AC_ARG_ENABLE([stringshare-usage],
 224    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 225    [
 226     if test "x${enableval}" = "xyes"; then
 227        have_stringshare_usage="yes"
 228     else
 229        have_stringshare_usage="no"
 230     fi
 231    ],
 232    [have_stringshare_usage="no"]
 233 )
 234 AC_MSG_CHECKING([whether to report stringshare usage])
 235 AC_MSG_RESULT([${have_stringshare_usage}])
 236
 237 if test "x${have_stringshare_usage}" = "xyes"; then
 238    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 239 fi
 240
 241 # Check if we want to benchmark on real data
 242 enable_benchmark_e17="no"
 243 AC_ARG_ENABLE([e17],
 244    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 245    [
 246     if test "x${enableval}" = "xyes" ; then
 247        enable_benchmark_e17="yes"
 248     else
 249        enable_benchmark_e17="no"
 250     fi
 251    ],
 252    [enable_benchmark_e17="no"])
 253
 254 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 255 AC_MSG_RESULT([${enable_benchmark_e17}])
 256
 257 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 258
 259
 260 ### Checks for programs
 261 AC_PROG_CC
 262
 263 # pkg-config
 264 PKG_PROG_PKG_CONFIG
 265
 266 # Check whether pkg-config supports Requires.private
 267 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 268    pkgconfig_requires_private="Requires.private"
 269 else
 270    pkgconfig_requires_private="Requires"
 271 fi
 272 AC_SUBST(pkgconfig_requires_private)
 273
 274 # doxygen program for documentation building
 275
 276 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 277
 278
 279 ### Checks for libraries
 280
 281 # Evil library for compilation on Windows CE
 282
 283 EFL_EINA_BUILD=""
 284 case "$host_os" in
 285    mingw*)
 286       PKG_CHECK_MODULES([EVIL], [evil])
 287       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed])
 288       requirement_eina="evil"
 289       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 290    ;;
 291 esac
 292 AC_SUBST(EFL_EINA_BUILD)
 293
 294 # Check ememoa memory pool library
 295
 296 AC_ARG_ENABLE([ememoa],
 297    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 298    [
 299     if test "x${enableval}" = "xyes" ; then
 300        enable_ememoa="yes"
 301     else
 302        enable_ememoa="no"
 303     fi
 304    ],
 305    [enable_ememoa="yes"]
 306 )
 307 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 308 AC_MSG_RESULT([$enable_ememoa])
 309
 310 if test "x${enable_ememoa}" = "xyes" ; then
 311    PKG_CHECK_MODULES([EMEMOA],
 312       [ememoa >= 0.0.26 ],
 313       [enable_ememoa="yes"],
 314       [enable_ememoa="no"]
 315    )
 316 fi
 317
 318
 319 ### Checks for header files
 320 AC_HEADER_ASSERT
 321 AC_HEADER_DIRENT
 322 AC_HEADER_TIME
 323
 324
 325 ### Checks for types
 326 AC_CHECK_HEADER([inttypes.h],
 327                 [EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"])
 328 AC_SUBST(EINA_CONFIGURE_HAVE_INTTYPES_H)
 329
 330 AC_CHECK_HEADER([stdint.h],
 331                 [EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"])
 332 AC_SUBST(EINA_CONFIGURE_HAVE_STDINT_H)
 333
 334 AC_CHECK_SIZEOF(wchar_t)
 335 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 336 AC_SUBST(EINA_SIZEOF_WCHAR_T)
 337
 338 ### Checks for structures
 339
 340
 341 ### Checks for compiler characteristics
 342 AC_C_CONST
 343 AC_C_BIGENDIAN
 344 AC_C_INLINE
 345 AC_C___ATTRIBUTE__
 346 AC_PROG_CC_STDC
 347
 348 have_win32="no"
 349 EINA_CPPFLAGS=""
 350 EINA_CFLAGS=""
 351 case "$host_os" in
 352    mingw32ce*)
 353       EINA_CPPFLAGS="-D_WIN32_WCE=0x0420"
 354       EINA_CFLAGS="${EVIL_CFLAGS}"
 355       have_win32="yes"
 356       ;;
 357    mingw*)
 358       EINA_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 359       EINA_CFLAGS="${EVIL_CFLAGS}"
 360       have_win32="yes"
 361       ;;
 362 esac
 363 AM_CONDITIONAL([EINA_HAVE_WIN32], [test "x$have_win32" = "xyes"])
 364
 365 m4_ifdef([v_mic],
 366    [
 367     EFL_COMPILER_FLAG([-Wall])
 368     EFL_COMPILER_FLAG([-W])
 369    ])
 370
 371 EFL_COMPILER_FLAG([-Wshadow])
 372
 373 AC_SUBST(EINA_CPPFLAGS)
 374 AC_SUBST(EINA_CFLAGS)
 375
 376
 377 ### Checks for linker characteristics
 378 EINA_LIBS=
 379 lt_enable_auto_import=""
 380 case "${host_os}" in
 381    mingw*)
 382       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 383       lt_enable_auto_import="-Wl,--enable-auto-import"
 384    ;;
 385    dragonfly*|openbsd*)
 386       EINA_LIBS="-lm"
 387    ;;
 388    freebsd*|netbsd*)
 389       EINA_LIBS="-lrt -lm"
 390    ;;
 391    darwin*)
 392       EINA_LIBS="-lm"
 393    ;;
 394    cygwin*)
 395       EINA_LIBS="-ldl -lm"
 396    ;;
 397    *)
 398       EINA_LIBS="-ldl -lrt -lm"
 399    ;;
 400 esac
 401 AC_SUBST(EINA_LIBS)
 402 AC_SUBST(lt_enable_auto_import)
 403
 404 EFL_LINKER_FLAG([-fno-strict-aliasing])
 405
 406
 407 ### Checks for library functions
 408 AC_FUNC_ALLOCA
 409 AC_CHECK_FUNCS(strlcpy)
 410
 411 #dlopen and dladdr
 412 dlopen_libs=""
 413 case "$host_os" in
 414    mingw*)
 415 # managed by evil
 416       AC_DEFINE(HAVE_DLADDR)
 417       ;;
 418    *)
 419       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 420       if test "x${res}" = "xyes" ; then
 421          AC_CHECK_FUNCS([dladdr], [AC_DEFINE(HAVE_DLADDR)])
 422       else
 423          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 424          if test "x${res}" = "xyes" ; then
 425             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE(HAVE_DLADDR)])
 426             dlopen_libs="-ldl"
 427          else
 428             AC_MSG_ERROR([Cannot find dlopen])
 429          fi
 430       fi
 431       ;;
 432 esac
 433 AC_SUBST(dlopen_libs)
 434
 435 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 436
 437 # iconv library
 438 have_iconv="no"
 439 AC_ARG_WITH([iconv-link],
 440    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 441    [
 442     LIBS="$withval $LIBS"
 443     have_iconv="yes"
 444    ])
 445
 446 AC_MSG_CHECKING(for explicit iconv link options)
 447 if test "x${iconv_libs}" = "x" ; then
 448    AC_MSG_RESULT([no explicit iconv link option])
 449 else
 450    AC_MSG_RESULT([$iconv_libs])
 451 fi
 452
 453 if test "x${have_iconv}" = "xno" ; then
 454    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 455
 456    if test "x${have_iconv}" = "xyes" ; then
 457       AC_MSG_CHECKING([whether iconv() is in libc])
 458
 459       AC_LINK_IFELSE(
 460          [AC_LANG_PROGRAM(
 461              [[
 462 #include <stdlib.h>
 463 #include <iconv.h>
 464              ]],
 465              [[
 466 iconv_t ic;
 467 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 468              ]])],
 469          [have_iconv="yes"],
 470          [have_iconv="no"])
 471
 472       AC_MSG_RESULT([${have_iconv}])
 473    fi
 474
 475    if test "x${have_iconv}" = "xno" ; then
 476       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 477
 478       LIBS_save="${LIBS}"
 479       LIBS="-liconv $LIBS"
 480       AC_LINK_IFELSE(
 481          [AC_LANG_PROGRAM(
 482              [[
 483 #include <stdlib.h>
 484 #include <iconv.h>
 485              ]],
 486              [[
 487 iconv_t ic;
 488 size_t count;
 489 count = iconv(ic, NULL, NULL, NULL, NULL);
 490              ]])],
 491          [have_iconv="yes"],
 492          [
 493           have_iconv="no"
 494           LIBS=${LIBS_save}
 495          ])
 496
 497       AC_MSG_RESULT([${have_iconv}])
 498    fi
 499
 500    if test "x${have_iconv}" = "xno" ; then
 501       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 502
 503       LIBS_save="${LIBS}"
 504       LIBS="-liconv_plug $LIBS"
 505       AC_LINK_IFELSE(
 506          [AC_LANG_PROGRAM(
 507              [[
 508 #include <stdlib.h>
 509 #include <iconv.h>
 510              ]],
 511              [[
 512 iconv_t ic;
 513 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 514              ]])],
 515          [have_iconv="yes"],
 516          [
 517           have_iconv="no"
 518           LIBS=${LIBS_save}
 519          ])
 520
 521       AC_MSG_RESULT([${have_iconv}])
 522    fi
 523 fi
 524
 525 if test "x${have_iconv}" = "xyes" ; then
 526    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 527 fi
 528
 529 #check for dirfd API presence
 530 have_dirfd="no"
 531 AC_CHECK_FUNCS([dirfd], [have_dirfd="yes"], [])
 532 if test "x${dirfd}" = "xyes"; then
 533    AC_DEFINE(HAVE_DIRFD)
 534 fi
 535 AC_CHECK_FUNCS([openat], [AC_DEFINE(HAVE_OPENAT)], [])
 536 AC_CHECK_FUNCS([statat], [AC_DEFINE(HAVE_STATAT)], [])
 537 AC_CHECK_FUNCS([fpathconf], [AC_DEFINE(HAVE_FPATHCONF)], [])
 538
 539 ### Modules
 540
 541 if test "x${have_default_mempool}" = "xyes" ; then
 542    enable_chained_pool="no"
 543    enable_pass_through="static"
 544 else
 545    enable_chained_pool="static"
 546    enable_pass_through="no"
 547 fi
 548
 549 enable_one_big="static"
 550
 551 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 552 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 553 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 554 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 555 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 556 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 557 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 558
 559 ### Make the debug preprocessor configurable
 560
 561 ### Unit tests, coverage and benchmarking
 562
 563 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 564
 565 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 566 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 567 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 568 if test "x$enable_coverage" = "xyes" ; then
 569    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 570 fi
 571
 572 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 573 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 574
 575 AC_SUBST(requirement_eina)
 576
 577 ### Create the .pc.in file according to the major version
 578 #cat > ${srcdir}/eina-${VMAJ}.pc.in << EOF
 579 #prefix=@prefix@
 580 #exec_prefix=@exec_prefix@
 581 #libdir=@libdir@
 582 #includedir=@includedir@
 583 #
 584 #Name: Eina
 585 #Description: A Library that implements fast data types and miscellaneous tools
 586 #Requires:
 587 #Version: @VERSION@
 588 #Libs: -L${libdir} -leina
 589 #Libs.private: -ldl
 590 #Cflags: -I${includedir}/eina-@VMAJ@ -I${includedir}/eina-@VMAJ@/eina
 591 #EOF
 592
 593 AC_CONFIG_FILES([
 594 Makefile
 595 eina.pc
 596 eina.spec
 597 doc/Makefile
 598 src/Makefile
 599 src/include/Makefile
 600 src/include/eina_config.h
 601 src/lib/Makefile
 602 src/modules/Makefile
 603 src/modules/mp/Makefile
 604 src/modules/mp/chained_pool/Makefile
 605 src/modules/mp/ememoa_fixed/Makefile
 606 src/modules/mp/ememoa_unknown/Makefile
 607 src/modules/mp/pass_through/Makefile
 608 src/modules/mp/fixed_bitmap/Makefile
 609 src/modules/mp/buddy/Makefile
 610 src/modules/mp/one_big/Makefile
 611 src/tests/Makefile
 612 ])
 613
 614 AC_OUTPUT
 615
 616 #####################################################################
 617 ## Info
 618
 619 echo
 620 echo
 621 echo
 622 echo "------------------------------------------------------------------------"
 623 echo "$PACKAGE $VERSION"
 624 echo "------------------------------------------------------------------------"
 625 echo
 626 echo
 627 echo "Configuration Options Summary:"
 628 echo
 629 echo "  Magic debug..........: ${have_magic_debug}"
 630 echo "  Safety checks........: ${have_safety_checks}"
 631 echo "  Maximum log level....: ${with_max_log_level}"
 632 echo "  Report string usage..: ${have_stringshare_usage}"
 633 echo "  Valgrind support.....: ${have_valgrind}"
 634 echo "  Default mempool......: ${have_default_mempool}"
 635 echo "  Thread Support.......: ${have_threads}"
 636 if test "${have_threads}" = "POSIX" ; then
 637 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 638 echo "    debug usage........: ${have_debug_threads}"
 639 fi
 640 echo "  Amalgamation.........: ${do_amalgamation}"
 641 echo "  Iconv support........: ${have_iconv}"
 642 echo "  File dirfd...........: ${have_dirfd}"
 643 echo
 644 echo "  Documentation........: ${build_doc}"
 645 echo "  Tests................: ${enable_tests}"
 646 echo "  Coverage.............: ${enable_coverage}"
 647 echo "  Benchmark............: ${enable_benchmark}"
 648 if test "x${enable_benchmark}" = "xyes" ; then
 649 echo "    Glib...............: ${enable_benchmark_glib}"
 650 echo "    E17 real data......: ${enable_benchmark_e17}"
 651 fi
 652 echo
 653 echo "  CPU Specific Extensions:"
 654 echo "    MMX................: ${have_mmx}"
 655 echo "    SSE................: ${have_sse}"
 656 echo "    SSE2...............: ${have_sse2}"
 657 echo "    ALTIVEC............: ${have_altivec}"
 658 echo
 659 echo "  Memory pools:"
 660 echo "    Chained pool.......: ${enable_chained_pool}"
 661 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 662 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 663 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 664 echo "    Pass through.......: ${enable_pass_through}"
 665 echo "    Buddy..............: ${enable_buddy}"
 666 echo "    One big............: ${enable_one_big}"
 667 echo
 668 echo "Compilation............: make (or gmake)"
 669 echo "  CPPFLAGS.............: $CPPFLAGS"
 670 echo "  CFLAGS...............: $CFLAGS"
 671 echo "  LDFLAGS..............: $LDFLAGS"
 672 echo
 673 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 674 echo "  prefix...............: $prefix"
 675 echo
 676 EFL_FORM_VOLTRON