configure.ac

   1 # clutter package version number, (as distinct from shared library version)
   2 # An odd micro number indicates in-progress development from Git
   3 # An even micro number indicates a released version
   4 #
   5 # Making a point release:
   6 # - increase clutter_micro_version to the next even number
   7 # - increase clutter_interface_age to the next even number
   8 # After the release:
   9 # - increase clutter_micro_version to the next odd number
  10 # - increase clutter_interface_version to the next odd number
  11 m4_define([clutter_major_version], [1])
  12 m4_define([clutter_minor_version], [9])
  13 m4_define([clutter_micro_version], [1])
  14
  15 # • for stable releases: increase the interface age by 1 for each release;
  16 #   if the API changes, set to 0. interface_age and binary_age are used to
  17 #   create the soname of the shared object:
  18 #
  19 #  (<minor> * 100 + <micro>) - <interface_age>
  20 #
  21 # this allows using the same soname for different micro-releases in case
  22 # no API was added or deprecated. for instance:
  23 #
  24 #   clutter 1.2.0  -> 100 * 2 + 0  = 200, interface age = 0 -> 200
  25 #   clutter 1.2.2  -> 100 * 2 + 2  = 202, interface age = 2 -> 200
  26 #   clutter 1.2.4  -> 100 * 2 + 4  = 204, interface age = 4 -> 200
  27 #   [ API addition, deprecation ]
  28 #   clutter 1.2.6  -> 100 * 2 + 6  = 206, interface age = 0 -> 206
  29 #   clutter 1.2.8  -> 100 * 2 + 8  = 208, interface age = 2 -> 206
  30 #   clutter 1.2.10 -> 100 * 2 + 10 = 210, interface age = 4 -> 206
  31 #   ...
  32 #
  33 # • for development releases: keep clutter_interface_age to 0
  34 m4_define([clutter_interface_age], [0])
  35
  36 m4_define([clutter_binary_age], [m4_eval(100 * clutter_minor_version + clutter_micro_version)])
  37
  38 m4_define([clutter_release_status],
  39           [m4_if(m4_eval(clutter_micro_version % 2), [1], [git],
  40                  [m4_if(m4_eval(clutter_minor_version % 2), [1], [snapshot],
  41                                                                  [release])])])
  42
  43 m4_define([clutter_version], [clutter_major_version.clutter_minor_version.clutter_micro_version])
  44
  45 # change this only when breaking the API
  46 m4_define([clutter_api_version], [1.0])
  47
  48 AC_PREREQ([2.63])
  49
  50 AC_INIT([clutter],
  51         [clutter_version],
  52         [http://bugzilla.gnome.org/enter_bug.cgi?product=clutter],
  53         [clutter],
  54         [http://www.clutter-project.org])
  55
  56 AC_CONFIG_SRCDIR([clutter/clutter.h])
  57 AC_CONFIG_HEADERS([config.h])
  58 AC_CONFIG_AUX_DIR([build])
  59 AC_CONFIG_MACRO_DIR([build/autotools])
  60
  61 AM_INIT_AUTOMAKE([1.11 foreign -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  62 AM_SILENT_RULES([yes])
  63
  64 AC_SUBST([CLUTTER_MAJOR_VERSION],  [clutter_major_version])
  65 AC_SUBST([CLUTTER_MINOR_VERSION],  [clutter_minor_version])
  66 AC_SUBST([CLUTTER_MICRO_VERSION],  [clutter_micro_version])
  67 AC_SUBST([CLUTTER_VERSION],        [clutter_version])
  68 AC_SUBST([CLUTTER_API_VERSION],    [clutter_api_version])
  69 AC_SUBST([CLUTTER_API_VERSION_AM], [$CLUTTER_MAJOR_VERSION\_0])
  70 AC_SUBST([CLUTTER_RELEASE_STATUS], [clutter_release_status])
  71
  72 m4_define([lt_current],  [m4_eval(100 * clutter_minor_version + clutter_micro_version - clutter_interface_age)])
  73 m4_define([lt_revision], [clutter_interface_age])
  74 m4_define([lt_age],      [m4_eval(clutter_binary_age - clutter_interface_age)])
  75 CLUTTER_LT_CURRENT=lt_current
  76 CLUTTER_LT_REV=lt_revision
  77 CLUTTER_LT_AGE=lt_age
  78 CLUTTER_LT_VERSION="$CLUTTER_LT_CURRENT:$CLUTTER_LT_REV:$CLUTTER_LT_AGE"
  79 CLUTTER_LT_LDFLAGS="-version-info $CLUTTER_LT_VERSION"
  80 AC_SUBST([CLUTTER_LT_CURRENT],  [lt_current])
  81 AC_SUBST([CLUTTER_LT_REVISION], [lt_revision])
  82 AC_SUBST([CLUTTER_LT_VERSION],  [$CLUTTER_LT_VERSION])
  83
  84 AC_PROG_SED
  85
  86 dnl = Preliminary platform checks =============================================
  87
  88 AC_CANONICAL_HOST
  89
  90 platform_win32=no
  91 platform_quartz=no
  92 platform_linux=no
  93
  94 AC_MSG_CHECKING([if building for some Win32 platform])
  95 AS_CASE([$host],
  96         [*-*-mingw*|*-*-cygwin*],
  97         [
  98           CLUTTER_LT_LDFLAGS="$CLUTTER_LT_LDFLAGS -no-undefined"
  99           platform_win32=yes
 100         ],
 101
 102         []
 103 )
 104 AC_MSG_RESULT([$platform_win32])
 105
 106 AM_CONDITIONAL(OS_WIN32, [test "$platform_win32" = "yes"])
 107
 108 AC_CHECK_HEADER([OpenGL/gl.h], [platform_quartz=yes], [platform_quartz=no])
 109 AM_CONDITIONAL(OS_QUARTZ, [test "$platform_quartz" = "yes"])
 110
 111 AC_CHECK_HEADER([GL/glx.h], [platform_glx=yes], [platform_glx=no])
 112 AC_CHECK_LIB([GL], [glXCreateContext], [platform_glx=yes], [platform_glx=no])
 113 AM_CONDITIONAL(OS_GLX, [test "$platform_glx" = "yes"])
 114
 115 AC_SUBST(CLUTTER_LT_LDFLAGS)
 116
 117 AC_CACHE_SAVE
 118
 119 dnl = Dependencies =========================================================
 120
 121 # Checks for programs.
 122 AM_PROG_CC_C_O
 123
 124 # require libtool >= 2.2
 125 LT_PREREQ([2.2.6])
 126 LT_INIT([disable-static])
 127
 128 # Checks for header files.
 129 AC_HEADER_STDC
 130
 131 # required versions for dependencies
 132 m4_define([glib_req_version],           [2.31.0])
 133 m4_define([cogl_req_version],           [1.9.1])
 134 m4_define([json_glib_req_version],      [0.12.0])
 135 m4_define([atk_req_version],            [2.1.5])
 136 m4_define([cairo_req_version],          [1.10])
 137 m4_define([pango_req_version],          [1.20])
 138 m4_define([gi_req_version],             [0.9.5])
 139 m4_define([uprof_req_version],          [0.3])
 140 m4_define([gtk_doc_req_version],        [1.15])
 141 m4_define([xfixes_req_version],         [3])
 142 m4_define([xcomposite_req_version],     [0.4])
 143 m4_define([gdk_req_version],            [3.0.0])
 144
 145 AC_SUBST([GLIB_REQ_VERSION],       [glib_req_version])
 146 AC_SUBST([COGL_REQ_VERSION],       [cogl_req_version])
 147 AC_SUBST([JSON_GLIB_REQ_VERSION],  [json_glib_req_version])
 148 AC_SUBST([ATK_REQ_VERSION],        [atk_req_version])
 149 AC_SUBST([CAIRO_REQ_VERSION],      [cairo_req_version])
 150 AC_SUBST([PANGO_REQ_VERSION],      [pango_req_version])
 151 AC_SUBST([GI_REQ_VERSION],         [gi_req_version])
 152 AC_SUBST([UPROF_REQ_VERSION],      [uprof_req_version])
 153 AC_SUBST([GTK_DOC_REQ_VERSION],    [gtk_doc_req_version])
 154 AC_SUBST([XFIXES_REQ_VERSION],     [xfixes_req_version])
 155 AC_SUBST([XCOMPOSITE_REQ_VERSION], [xcomposite_req_version])
 156 AC_SUBST([GDK_REQ_VERSION],        [gdk_req_version])
 157
 158 # Checks for typedefs, structures, and compiler characteristics.
 159 AM_PATH_GLIB_2_0([glib_req_version],
 160                  [],
 161                  [AC_MSG_ERROR([glib-2.0 is required])],
 162                  [gobject gthread gmodule-no-export])
 163
 164 # Check for -Bsymbolic-functions to avoid intra-library PLT jumps
 165 AC_ARG_ENABLE([Bsymbolic],
 166               [AS_HELP_STRING([--disable-Bsymbolic],
 167                               [Avoid linking with -Bsymbolic])],
 168               [],
 169               [
 170                 saved_LDFLAGS="${LDFLAGS}"
 171                 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 172                 LDFLAGS=-Wl,-Bsymbolic-functions
 173                 AC_TRY_LINK([], [int main (void) { return 0; }],
 174                             [
 175                               AC_MSG_RESULT([yes])
 176                               enable_Bsymbolic=yes
 177                             ],
 178                             [
 179                               AC_MSG_RESULT([no])
 180                               enable_Bsymbolic=no
 181                             ])
 182                 LDFLAGS="${saved_LDFLAGS}"
 183               ])
 184
 185 AS_IF([test "x$enable_Bsymbolic" = "xyes"], [CLUTTER_LINK_FLAGS=-Wl[,]-Bsymbolic-functions])
 186 AC_SUBST(CLUTTER_LINK_FLAGS)
 187
 188 AC_CACHE_SAVE
 189
 190 dnl ========================================================================
 191
 192 FLAVOUR_LIBS=""
 193 FLAVOUR_CFLAGS=""
 194 CLUTTER_BACKENDS=""
 195
 196 experimental_backend=no
 197
 198 # base dependencies for core
 199 CLUTTER_BASE_PC_FILES="cogl-1.0 >= $COGL_REQ_VERSION cairo-gobject >= $CAIRO_REQ_VERSION atk >= $ATK_REQ_VERSION pangocairo >= $PANGO_REQ_VERSION cogl-pango-1.0 json-glib-1.0 >= $JSON_GLIB_REQ_VERSION"
 200
 201 # backend specific pkg-config files
 202 BACKEND_PC_FILES=""
 203
 204 dnl === Clutter windowing system backend ======================================
 205
 206 AC_ARG_ENABLE([x11-backend],
 207               [AS_HELP_STRING([--enable-x11-backend=@<:@yes/no@:>@], [Enable the X11 backend (default=check)])],
 208               [enable_x11=$enableval],
 209               [enable_x11=check])
 210 AC_ARG_ENABLE([win32-backend],
 211               [AS_HELP_STRING([--enable-win32-backend=@<:@yes/no@:>@], [Enable the Windows backend (default=check)])],
 212               [enable_win32=$enableval],
 213               [enable_win32=check])
 214 AC_ARG_ENABLE([quartz-backend],
 215               [AS_HELP_STRING([--enable-quartz-backend=@<:@yes/no@:>@], [Enable the OS X backend (default=check)])],
 216               [enable_osx=$enableval],
 217               [enable_osx=check])
 218 AC_ARG_ENABLE([gdk-backend],
 219               [AS_HELP_STRING([--enable-gdk-backend=@<:@yes/no@:>@], [Enable the GDK backend (default=check)])],
 220               [enable_gdk=$enableval],
 221               [enable_gdk=check])
 222 AC_ARG_ENABLE([wayland-backend],
 223               [AS_HELP_STRING([--enable-wayland-backend=@<:@yes/no@:>@], [Enable the Wayland client backend (default=no)])],
 224               [enable_wayland=$enableval],
 225               [enable_wayland=no])
 226 AC_ARG_ENABLE([egl-backend],
 227               [AS_HELP_STRING([--enable-egl-backend=@<:@yes/no@:>@], [Enable the EGL framebuffer backend (default=no)])],
 228               [enable_egl=$enableval],
 229               [enable_egl=no])
 230 AC_ARG_ENABLE([cex100-backend],
 231               [AS_HELP_STRING([--enable-cex100-backend=@<:@yes/no@:>@], [Enable the CEx100 backend (default=no)])],
 232               [enable_cex100=$enableval],
 233               [enable_cex100=no])
 234
 235 dnl Define default values
 236 AS_IF([test "x$enable_x11" = "xcheck"],
 237       [
 238         AS_IF([test "x$platform_glx" = "xyes"], [enable_x11=yes], [enable_x11=no])
 239       ])
 240
 241 AS_IF([test "x$enable_win32" = "xcheck"],
 242       [
 243         AS_IF([test "x$platform_win32" = "xyes"], [enable_win32=yes], [enable_win32=no])
 244       ])
 245
 246 AS_IF([test "x$enable_osx" = "xcheck"],
 247       [
 248         AS_IF([test "x$platform_quartz" = "xyes"], [enable_osx=yes], [enable_osx=no])
 249       ])
 250
 251 AS_IF([test "x$enable_gdk" = "xcheck"],
 252       [
 253         PKG_CHECK_EXISTS([gdk-3.0 >= gdk_req_version], [enable_gdk=yes], [enable_gdk=no])
 254       ])
 255
 256 dnl Per-backend rules
 257 AS_IF([test "x$enable_x11" = "xyes"],
 258       [
 259         CLUTTER_BACKENDS="$CLUTTER_BACKENDS x11"
 260
 261         SUPPORT_X11=1
 262         SUPPORT_GLX=1
 263         SUPPORT_COGL=1
 264
 265         # Mesa 7.3 added a GL pkg-config file, finally, but if a pkg-config
 266         # file isn't found just add -lGL and hope for the best.
 267         PKG_CHECK_EXISTS([gl],
 268                          [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"],
 269                          [FLAVOUR_LIBS="$FLAVOUR_LIBS -lGL"])
 270
 271         # We might fall back to DRM for sync-to-vblank on GLX
 272         PKG_CHECK_EXISTS([libdrm],
 273                          [
 274                            AC_DEFINE([HAVE_DRM], [1], [Have libdrm support])
 275                            BACKEND_PC_FILES="$BACKEND_PC_FILES libdrm"
 276                          ],
 277                          [])
 278
 279         # we use fontconfig API and pango-fc when the fontconfig
 280         # configuration changes
 281         PKG_CHECK_EXISTS([pangoft2],
 282                          [
 283                            AC_DEFINE([HAVE_PANGO_FT2], [1], [Supports PangoFt2])
 284                            BACKEND_PC_FILES="$BACKEND_PC_FILES pangoft2"
 285                          ],
 286                          [])
 287
 288         AC_DEFINE([HAVE_CLUTTER_GLX], [1], [Have the GLX backend])
 289       ])
 290
 291 AS_IF([test "x$enable_gdk" = "xyes"],
 292       [
 293         CLUTTER_BACKENDS="$CLUTTER_BACKENDS gdk"
 294
 295         SUPPORT_GDK=1
 296         SUPPORT_COGL=1
 297
 298         BACKEND_PC_FILES="$BACKEND_PC_FILES gdk-3.0"
 299         PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 300       ])
 301
 302 AS_IF([test "x$enable_wayland" = "xyes"],
 303       [
 304         CLUTTER_BACKENDS="$CLUTTER_BACKENDS wayland"
 305
 306         experimental_backend="yes"
 307
 308         SUPPORT_WAYLAND=1
 309         SUPPORT_EVDEV=1
 310
 311         PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 312         PKG_CHECK_EXISTS([egl], [BACKEND_PC_FILES="$BACKEND_PC_FILES egl"], [])
 313         PKG_CHECK_EXISTS([wayland-client xkbcommon],
 314                          [BACKEND_PC_FILES="$BACKEND_PC_FILES wayland-client xkbcommon"],
 315                          [])
 316
 317         AC_DEFINE([HAVE_CLUTTER_WAYLAND], [1], [Have the Wayland backend])
 318       ])
 319
 320 AS_IF([test "x$enable_cex100" = "xyes"],
 321       [
 322         CLUTTER_BACKENDS="$CLUTTER_BACKENDS cex100"
 323
 324         SUPPORT_COGL=1
 325         SUPPORT_EGL_PLATFORM_GDL=1
 326
 327         have_gdl=no
 328         AC_CHECK_HEADERS([libgdl.h], [have_gdl=yes])
 329
 330         AS_IF([test "x$have_gdl" = "xno"],
 331               [
 332                 AC_CHECK_HEADERS([CE4100/libgdl.h],
 333                                  [
 334                                    FLAVOUR_CFLAGS="-I/usr/include/CE4100"
 335                                    have_gdl=yes
 336                                    CLUTTER_CEX100_LIBGDL_PREFIX=CE4100/
 337                                  ])
 338               ])
 339
 340         AS_IF([test "x$have_gdl" = "xno"],
 341               [AC_MSG_ERROR([libgdl.h not found but the CEx100 backend has been explicitly enabled])])
 342
 343         AC_SUBST(CLUTTER_CEX100_LIBGDL_PREFIX)
 344
 345         FLAVOUR_LIBS="$FLAVOUR_LIBS -lgdl"
 346
 347         AC_DEFINE([CLUTTER_EGL_BACKEND_CEX100], [1], [Use CEX100 EGL backend])
 348         AC_DEFINE([CLUTTER_EGL_BACKEND_GENERIC], [1], [Use Generic EGL backend])
 349         AC_DEFINE([HAVE_CLUTTER_EGL], [1], [Have the EGL backend])
 350       ])
 351
 352 AS_IF([test "x$enable_egl" = "xyes"],
 353       [
 354         CLUTTER_BACKENDS="$CLUTTER_BACKENDS egl"
 355
 356         SUPPORT_EGL=1
 357         SUPPORT_COGL=1
 358
 359         # if Mesa has support for egl, we can use it as well
 360         PKG_CHECK_EXISTS([egl],
 361                          [
 362                            BACKEND_PC_FILES="$BACKEND_PC_FILES egl"
 363                          ],
 364                          [])
 365
 366         FLAVOUR_LIBS="$FLAVOUR_LIBS $TSLIB_LIBS $EVDEV_LIBS"
 367         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $TSLIB_CFLAGS $EVDEV_CFLAGS"
 368
 369         AC_DEFINE([CLUTTER_EGL_BACKEND_GENERIC], [1], [Use Generic EGL backend])
 370
 371         AC_DEFINE([HAVE_CLUTTER_EGL], [1], [Have the EGL backend])
 372       ])
 373
 374 AS_IF([test "x$enable_osx" = "xyes"],
 375       [
 376         CLUTTER_BACKENDS="$CLUTTER_BACKENDS osx"
 377
 378         AC_DEFINE([HAVE_CLUTTER_OSX], [1], [Have the OSX backend])
 379
 380         FLAVOUR_LIBS="$FLAVOUR_LIBS -framework Cocoa -framework OpenGL"
 381
 382         SUPPORT_OSX=1
 383       ])
 384
 385 AS_IF([test "x$enable_win32" = "xyes"],
 386       [
 387         CLUTTER_BACKENDS="$CLUTTER_BACKENDS win32"
 388
 389         AC_DEFINE([HAVE_CLUTTER_WIN32], [1], [Have the Win32 backend])
 390
 391         FLAVOUR_LIBS="$FLAVOUR_LIBS -lopengl32 -lgdi32 -lwinmm"
 392         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS -D_WIN32_WINNT=0x0500"
 393
 394         AC_CHECK_TOOL(WINDRES, [windres], [AC_MSG_ERROR([*** windres is required])])
 395
 396         SUPPORT_WIN32=1
 397       ])
 398
 399 AS_IF([test "x$CLUTTER_BACKENDS" = "x"],
 400       [
 401         AC_MSG_ERROR([No backend enabled. You need to enable at least one backend.])
 402       ])
 403
 404 # additional input backends
 405
 406 AC_ARG_ENABLE([tslib-input],
 407               [AS_HELP_STRING([--enable-tslib-input=@<:@yes/no@:>@], [Enable TSLib for input events (default=no)])],
 408               [enable_tslib=$enableval],
 409               [enable_tslib=no])
 410 AC_ARG_ENABLE([evdev-input],
 411               [AS_HELP_STRING([--with-evdev=@<:@yes/no@:>@], [Enable evdev for input events (default=yes)])],
 412               [enable_evdev=$enableval],
 413               [enable_evdev=yes])
 414
 415 AS_IF([test "x$enable_tslib" = "xyes"],
 416       [
 417         PKG_CHECK_MODULES(TSLIB, [tslib-1.0], [have_tslib=yes], [have_tslib=no])
 418         AS_IF([test "x$have_tslib" = "xyes"],
 419               [
 420                 AC_DEFINE([HAVE_TSLIB], [1], [Have tslib for touchscreen handling])
 421                 SUPPORT_TSLIB=1
 422               ])
 423       ])
 424
 425 AS_IF([test "x$enable_evdev" = "xyes"],
 426       [
 427         PKG_CHECK_MODULES(EVDEV, [gudev-1.0 xkbcommon], [have_evdev=yes], [have_evdev=no])
 428         AS_IF([test "x$have_evdev" = "xyes"],
 429               [
 430                 AC_DEFINE([HAVE_EVDEV], [1], [Have evdev support for input handling])
 431                 SUPPORT_EVDEV=1
 432               ])
 433       ])
 434
 435 # conditionals for use in automake files...
 436 AM_CONDITIONAL(SUPPORT_GLX,     [test "x$SUPPORT_GLX" = "x1"])
 437 AM_CONDITIONAL(SUPPORT_X11,     [test "x$SUPPORT_X11" = "x1"])
 438 AM_CONDITIONAL(SUPPORT_GDK,     [test "x$SUPPORT_GDK" = "x1"])
 439 AM_CONDITIONAL(SUPPORT_EGL,     [test "x$SUPPORT_EGL" = "x1"])
 440 AM_CONDITIONAL(SUPPORT_OSX,     [test "x$SUPPORT_OSX" = "x1"])
 441 AM_CONDITIONAL(SUPPORT_WIN32,   [test "x$SUPPORT_WIN32" = "x1"])
 442 AM_CONDITIONAL(SUPPORT_CEX100,  [test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"])
 443 AM_CONDITIONAL(SUPPORT_WAYLAND, [test "x$SUPPORT_WAYLAND" = "x1"])
 444 AM_CONDITIONAL(SUPPORT_STUB,    [test "x$SUPPORT_WIN32" = "x1" -o \
 445                                       "x$SUPPORT_OSX" = "x1" -o \
 446                                       "x$SUPPORT_WAYLAND" = "x1"])
 447
 448 AM_CONDITIONAL(USE_COGL,  [test "x$SUPPORT_COGL" = "x1"])
 449 AM_CONDITIONAL(USE_TSLIB, [test "x$have_tslib" = "xyes"])
 450 AM_CONDITIONAL(USE_EVDEV, [test "x$have_evdev" = "xyes"])
 451 AM_CONDITIONAL(USE_GLD,   [test "x$have_gdl" = "xyes"])
 452
 453 dnl Instead of using AM_CFLAGS to ensure
 454 dnl COGL_ENABLE_EXPERIMENTAL_2_0_API is defined while compiling clutter
 455 dnl and cogl code we use a define in config.h instead. This helps ensure
 456 dnl other tools such as glib-mkenums and gir-scanner don't end up
 457 dnl using the define also.
 458 AC_DEFINE([COGL_ENABLE_EXPERIMENTAL_2_0_API], [1], [Can use Cogl 2.0 API internally])
 459
 460 dnl strip leading spaces
 461 CLUTTER_BACKENDS=${CLUTTER_BACKENDS#* }
 462 AC_SUBST(CLUTTER_BACKENDS)
 463
 464 AC_CACHE_SAVE
 465
 466 dnl === Clutter configuration =================================================
 467
 468 CLUTTER_CONFIG_DEFINES=
 469
 470 # windowing systems
 471 AS_IF([test "x$SUPPORT_X11" = "x1"],
 472       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 473 #define CLUTTER_WINDOWING_X11 \"x11\"
 474 #define CLUTTER_INPUT_X11 \"x11\""])
 475 AS_IF([test "x$SUPPORT_GDK" = "x1"],
 476       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 477 #define CLUTTER_WINDOWING_GDK \"gdk\"
 478 #define CLUTTER_INPUT_GDK \"gdk\""])
 479 AS_IF([test "x$SUPPORT_GLX" = "x1"],
 480       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 481 #define CLUTTER_WINDOWING_GLX \"glx\""])
 482 AS_IF([test "x$SUPPORT_EGL" = "x1"],
 483       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 484 #define CLUTTER_WINDOWING_EGL \"eglnative\""])
 485 AS_IF([test "x$SUPPORT_WAYLAND" = "x1"],
 486       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 487 #define CLUTTER_WINDOWING_WAYLAND \"wayland\""])
 488 AS_IF([test "x$SUPPORT_OSX" = "x1"],
 489       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 490 #define CLUTTER_WINDOWING_OSX \"osx\"
 491 #define CLUTTER_INPUT_OSX \"osx\""])
 492 AS_IF([test "x$SUPPORT_WIN32" = "x1"],
 493       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 494 #define CLUTTER_WINDOWING_WIN32 \"win32\"
 495 #define CLUTTER_INPUT_WIN32 \"win32\""])
 496 AS_IF([test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"],
 497       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 498 #define CLUTTER_WINDOWING_CEX100 \"cex100\""])
 499 AS_IF([test "x$SUPPORT_EVDEV" = "x1"],
 500       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 501 #define CLUTTER_INPUT_EVDEV \"evdev\""])
 502 AS_IF([test "x$SUPPORT_TSLIB" = "x1"],
 503       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 504 #define CLUTTER_INPUT_TSLIB \"tslib\""])
 505
 506 # the 'null' input backend is special
 507 CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 508 #define CLUTTER_INPUT_NULL \"null\""
 509
 510 AC_SUBST([CLUTTER_CONFIG_DEFINES])
 511
 512 dnl === Clutter substitutions kept for backwards compatibility ================
 513 AC_SUBST([CLUTTER_WINSYS],       [deprecated])
 514 AC_SUBST([CLUTTER_WINSYS_BASE],  [deprecated])
 515 AC_SUBST([CLUTTER_STAGE_TYPE],   [deprecated])
 516 AC_SUBST([CLUTTER_SONAME_INFIX], [deprecated])
 517 AC_SUBST([CLUTTER_FLAVOUR],      [deprecated])
 518 AC_SUBST([CLUTTER_COGL],         [deprecated])
 519 AC_SUBST([COGL_DRIVER],          [deprecated])
 520
 521 dnl === Image loading backend =================================================
 522 IMAGE_PC_FILES=""
 523
 524 dnl === X11 checks, only for X11-based backends ===============================
 525 X11_PC_FILES=""
 526 X11_EXTS=""
 527 x11_tests=no
 528
 529 AS_IF([test "x$SUPPORT_X11" = "x1"],
 530       [
 531         # base X11 includes and libraries
 532         AC_MSG_CHECKING([for X11])
 533
 534         # start with pkg-config
 535         PKG_CHECK_EXISTS([x11], [have_x11=yes], [have_x11=no])
 536         AS_IF([test "x$have_x11" = "xyes"],
 537               [
 538                 X11_PC_FILES="x11"
 539
 540                 # we actually need to ask for CFLAGS and LIBS
 541                 X11_CFLAGS=`$PKG_CONFIG --cflags $X11_PC_FILES`
 542                 X11_LIBS=`$PKG_CONFIG --libs $X11_PC_FILES`
 543
 544                 AC_MSG_RESULT([found])
 545               ],
 546               [
 547                 # no pkg-config, let's go old school
 548                 AC_PATH_X
 549
 550                 AS_IF([test "x$no_x" = "xyes"],
 551                       [AC_MSG_ERROR([No X11 Libraries found])],
 552                       [
 553                         AS_IF([test "x$x_includes" != "xNONE" && test -n "$x_includes"],
 554                               [X11_CFLAGS=-I`echo $x_includes | sed -e "s/:/ -I/g"`])
 555
 556                         AS_IF([test "x$x_libraries" != "xNONE" && test -n "$x_libraries"],
 557                               [X11_LIBS=-L`echo $x_libraries | sed -e "s/:/ -L/g"`])
 558
 559                         AC_MSG_RESULT([found])
 560                       ]
 561                 )
 562               ]
 563         )
 564
 565         # XEXT (required)
 566         AC_MSG_CHECKING([for XEXT extension])
 567         PKG_CHECK_EXISTS([xext], [have_xext=yes], [have_xext=no])
 568         AS_IF([test "x$have_xext" = "xyes"],
 569               [
 570                 AC_DEFINE(HAVE_XEXT, [1], [Define to 1 if we have the XEXT X extension])
 571
 572                 X11_LIBS="$X11_LIBS -lXext"
 573                 X11_PC_FILES="$X11_PC_FILES xext"
 574                 X11_EXTS="$X11_EXTS xext"
 575
 576                 AC_MSG_RESULT([found])
 577               ],
 578               [AC_MSG_ERROR([Not found])]
 579         )
 580
 581         # XFIXES (required)
 582         AC_MSG_CHECKING([for XFIXES extension >= $XFIXES_REQ_VERSION])
 583         PKG_CHECK_EXISTS([xfixes >= $XFIXES_REQ_VERSION], [have_xfixes=yes], [have_xfixes=no])
 584         AS_IF([test "x$have_xfixes" = "xyes"],
 585               [
 586                 AC_DEFINE(HAVE_XFIXES, [1], [Define to 1 if we have the XFIXES X extension])
 587
 588                 X11_LIBS="$X11_LIBS -lXfixes"
 589                 X11_PC_FILES="$X11_PC_FILES xfixes >= $XFIXES_REQ_VERSION"
 590                 X11_EXTS="$X11_EXTS xfixes"
 591
 592                 AC_MSG_RESULT([found])
 593               ],
 594               [AC_MSG_ERROR([Not found])]
 595         )
 596
 597         # XDAMAGE (required)
 598         AC_MSG_CHECKING([for XDAMAGE extension])
 599         PKG_CHECK_EXISTS([xdamage], [have_xdamage=yes], [have_xdamage=no])
 600         AS_IF([test "x$have_xdamage" = "xyes"],
 601               [
 602                 AC_DEFINE(HAVE_XDAMAGE, [1], [Define to 1 if we have the XDAMAGE X extension])
 603
 604                 X11_LIBS="$X11_LIBS -lXdamage"
 605                 X11_PC_FILES="$X11_PC_FILES xdamage"
 606                 X11_EXTS="$X11_EXTS xdamage"
 607
 608                 AC_MSG_RESULT([found])
 609               ],
 610               [AC_MSG_ERROR([not found])]
 611         )
 612
 613         # XCOMPOSITE (optional)
 614         AC_MSG_CHECKING([for XCOMPOSITE extension >= $XCOMPOSITE_REQ_VERSION])
 615         PKG_CHECK_EXISTS([xcomposite >= $XCOMPOSITE_REQ_VERSION], [have_xcomposite=yes], [have_xcomposite=no])
 616         AS_IF([test "x$have_xcomposite" = "xyes"],
 617               [
 618                 AC_DEFINE(HAVE_XCOMPOSITE, [1], [Define to 1 if we have the XCOMPOSITE X extension])
 619
 620                 X11_LIBS="$X11_LIBS -lXcomposite"
 621                 X11_PC_FILES="$X11_PC_FILES xcomposite >= $XCOMPOSITE_REQ_VERSION"
 622                 X11_EXTS="$X11_EXTS xcomposite"
 623
 624                 AC_MSG_RESULT([found])
 625               ],
 626               [AC_MSG_ERROR([not found])]
 627         )
 628
 629         # X Generic Extensions (optional)
 630         clutter_save_CPPFLAGS="$CPPFLAGS"
 631         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 632
 633         clutter_save_LIBS="$LIBS"
 634         LIBS="$LIBS $X11_LIBS"
 635
 636         have_xge=no
 637         AC_CHECK_FUNC([XGetEventData],
 638                       [
 639                         AC_DEFINE([HAVE_XGE], [1], [Define to 1 if X Generic Extensions is available])
 640                         have_xge=yes
 641                         X11_EXTS="$X11_EXTS xge"
 642                       ])
 643
 644         CPPFLAGS="$clutter_save_CPPFLAGS"
 645         LIBS="$clutter_save_LIBS"
 646
 647         # XI (optional)
 648         AC_ARG_ENABLE([xinput],
 649                       [AS_HELP_STRING([--enable-xinput], [Use the XI X extension])],
 650                       [],
 651                       [enable_xinput=yes])
 652
 653         AS_IF([test "x$enable_xinput" = "xyes"],
 654               [
 655                 PKG_CHECK_EXISTS([xi], [have_xinput=yes], [have_xinput=no])
 656               ],
 657               [
 658                 have_xinput=no
 659               ])
 660
 661         AS_CASE([$have_xinput],
 662
 663                 [yes],
 664                 [
 665                   AC_CHECK_HEADERS([X11/extensions/XInput2.h],
 666                                    [
 667                                      have_xinput2=yes
 668                                      AC_DEFINE([HAVE_XINPUT_2],
 669                                                [1],
 670                                                [Define to 1 if XI2 is available])
 671                                    ],
 672                                    [
 673                                      have_xinput2=no
 674                                      AC_DEFINE([HAVE_XINPUT],
 675                                                [1],
 676                                                [Define to 1 if XInput is available])
 677                                    ])
 678
 679                   X11_LIBS="$X11_LIBS $XINPUT_LIBS"
 680                   X11_PC_FILES="$X11_PC_FILES xi"
 681                   X11_EXTS="$X11_EXTS xi"
 682                 ],
 683
 684                 [no],
 685                 [have_xinput2=no],
 686
 687                 [*],
 688                 [AC_MSG_ERROR([Invalid argument for --enable-xinput])]
 689         )
 690
 691         # XKB
 692         clutter_save_CPPFLAGS="$CPPFLAGS"
 693         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 694
 695         clutter_save_LIBS="$LIBS"
 696         LIBS="$LIBS $X11_LIBS"
 697
 698         have_xkb=no
 699         AC_CHECK_FUNC([XkbQueryExtension],
 700                       [
 701                         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
 702                         have_xkb=yes
 703
 704                         X11_EXTS="$X11_EXTS xkb"
 705                       ])
 706
 707         CPPFLAGS="$clutter_save_CPPFLAGS"
 708         LIBS="$clutter_save_LIBS"
 709
 710         x11_tests=yes
 711         BACKEND_PC_FILES="$BACKEND_PC_FILES $X11_PC_FILES"
 712         FLAVOUR_LIBS="$FLAVOUR_LIBS $X11_LIBS"
 713         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $X11_CFLAGS"
 714       ]
 715 )
 716
 717 AM_CONDITIONAL([BUILD_XI2], [test "x$have_xinput2" = "xyes"])
 718 AM_CONDITIONAL([X11_TESTS], [test "x$x11_tests" = "xyes"])
 719
 720 X11_EXTS=${X11_EXTS#* }
 721
 722 AC_CACHE_SAVE
 723
 724 dnl === Enable debug level ====================================================
 725
 726 m4_define([debug_default], [m4_if(m4_eval(clutter_minor_version % 2), [1], [yes], [minimum])])
 727 AC_ARG_ENABLE([debug],
 728               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 729                               [Control Clutter debugging level @<:@default=]debug_default[@:>@])],
 730               [],
 731               [enable_debug=debug_default])
 732
 733 AS_CASE([$enable_debug],
 734
 735         [yes],
 736         [
 737           test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 738           CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG"
 739         ],
 740
 741         [minimum],
 742         [CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"],
 743
 744         [no],
 745         [CLUTTER_DEBUG_CFLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"],
 746
 747         [AC_MSG_ERROR([Unknown argument for --enable-debug])]
 748 )
 749
 750 AC_SUBST(CLUTTER_DEBUG_CFLAGS)
 751
 752 dnl === Enable deprecation guards ==================================================
 753
 754 m4_define([deprecated_default],
 755           [m4_if(m4_eval(clutter_minor_version % 2),
 756                  [1],
 757                  [no],
 758                  [yes])])
 759
 760 AC_ARG_ENABLE([deprecated],
 761               [AS_HELP_STRING([--enable-deprecated=@<:@no/yes@:>@],
 762                               [Whether deprecated symbols should be disabled when compiling Clutter @<:@default=]deprecated_default[@:>@])],
 763               [],
 764               [enable_deprecated=deprecated_default])
 765
 766 AS_CASE([$enable_deprecated],
 767
 768         [no],
 769         [
 770           CLUTTER_DEPRECATED_CFLAGS="-DG_DISABLE_SINGLE_INCLUDES -DCOGL_DISABLE_DEPRECATED"
 771         ],
 772
 773         [yes],
 774         [
 775           CLUTTER_DEPRECATED_CFLAGS="-DGLIB_DISABLE_DEPRECATION_WARNINGS -DCLUTTER_DISABLE_DEPRECATION_WARNINGS"
 776         ],
 777
 778         [AC_MSG_ERROR([Unknown argument for --enable-deprecated])]
 779 )
 780
 781 AC_SUBST([CLUTTER_DEPRECATED_CFLAGS])
 782
 783
 784 dnl === Conformance test suite ================================================
 785
 786 AC_ARG_ENABLE([conformance],
 787               [AS_HELP_STRING([--enable-conformance=@<:@no/yes@:>@],
 788                               [Build conformance test suite @<:@default=yes@:>@])],
 789               [],
 790               [enable_conformance=yes])
 791
 792 AM_CONDITIONAL([BUILD_TESTS], [test "x$enable_conformance" = "xyes"])
 793
 794 dnl === Profiling =============================================================
 795
 796 m4_define([profile_default], [no])
 797 AC_ARG_ENABLE(profile,
 798               AS_HELP_STRING([--enable-profile=@<:@no/yes@:>@],
 799                              [Turn on profiling support. yes; All profiling probe points are compiled in and may be runtime enabled. no; No profiling support will built into clutter.  @<:@default=no@:>@]),
 800               [],
 801               [enable_profile=profile_default])
 802
 803 AS_CASE([$enable_profile],
 804
 805         [yes],
 806         [
 807           AS_IF([test "x$GCC" = "xyes"],
 808                 [
 809                   PKG_CHECK_MODULES([PROFILE_DEP], [uprof-0.3])
 810                   CLUTTER_PROFILE_CFLAGS="-DCLUTTER_ENABLE_PROFILE $PROFILE_DEP_CFLAGS"
 811                   CLUTTER_PROFILE_LDFLAGS="$PROFILE_DEP_LIBS"
 812
 813                   AS_IF([test "x$enable_debug" = "xyes"], [CLUTTER_PROFILE_CFLAGS+=" -DUPROF_DEBUG"])
 814                 ],
 815                 [
 816                   AC_MSG_ERROR([--enable-profile is currently only supported if using GCC])
 817                 ])
 818         ],
 819
 820         [no],
 821         [
 822           CLUTTER_PROFILE_CFLAGS=""
 823           CLUTTER_PROFILE_LDFLAGS=""
 824         ],
 825
 826         [*], [AC_MSG_ERROR([Invalid value for --enable-profile])]
 827 )
 828 AM_CONDITIONAL(PROFILE, test "x$enable_profile" != "xno")
 829 AC_SUBST(CLUTTER_PROFILE_CFLAGS)
 830 AC_SUBST(CLUTTER_PROFILE_LDFLAGS)
 831
 832 dnl === Coverage report =======================================================
 833
 834 AC_PATH_PROG([GCOV], [gcov], [enable_gcov=no])
 835
 836 AC_MSG_CHECKING([whether to build with gcov testing])
 837
 838 AC_ARG_ENABLE([gcov],
 839               [AS_HELP_STRING([--enable-gcov],
 840                               [Whether to enable coverage testing (requires gcc
 841 and gcov)])],
 842               [],
 843               [enable_gcov=no])
 844
 845 AS_IF([test "x$enable_gcov" = "xyes" && test "x$GCC" = "xyes"],
 846       [
 847         AS_IF([test "x$enable_conformance" = "xno"],
 848               [AC_MSG_WARN([Conformance test suite is disabled, the coverage report will be incomplete])],
 849               [AC_MSG_RESULT([yes])]
 850         )
 851
 852         GCOV_CFLAGS="-g -O0 -fprofile-arcs -ftest-coverage"
 853         GCOV_LDFLAGS="-lgcov"
 854       ],
 855       [AC_MSG_RESULT([no])]
 856 )
 857
 858 AM_CONDITIONAL([GCOV_ENABLED], [test "x$enable_gcov" = "xyes"])
 859 AC_SUBST([GCOV_CFLAGS])
 860 AC_SUBST([GCOV_LDFLAGS])
 861
 862 dnl === Enable strict compiler flags ==========================================
 863
 864 # use strict compiler flags only when building from git; the rules for
 865 # distcheck will take care of turning this on when making a release
 866 m4_define([maintainer_flags_default], [m4_if(m4_eval(clutter_micro_version % 2), [1], [yes], [no])])
 867 AC_ARG_ENABLE([maintainer-flags],
 868               [AS_HELP_STRING([--enable-maintainer-flags=@<:@no/yes/error@:>@],
 869                               [Use strict compiler flags @<:@default=]maintainer_flags_default[@:>@])],
 870               [],
 871               [enable_maintainer_flags=maintainer_flags_default])
 872
 873 MAINTAINER_COMPILER_FLAGS="-Wall -Wshadow -Wcast-align -Wuninitialized
 874                            -Wno-strict-aliasing -Wempty-body -Wformat
 875                            -Wformat-security -Winit-self
 876                            -Wdeclaration-after-statement -Wvla
 877                            -Wpointer-arith"
 878
 879 AS_CASE([$enable_maintainer_flags],
 880         [yes],
 881         [
 882           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 883         ],
 884
 885         [no],
 886         [
 887         ],
 888
 889         [error],
 890         [
 891           MAINTAINER_COMPILER_FLAGS="$MAINTAINER_COMPILER_FLAGS -Werror"
 892           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 893         ],
 894
 895         [*],
 896         [AC_MSG_ERROR([Invalid option for --enable-maintainer-flags])]
 897 )
 898
 899 # strip leading spaces
 900 MAINTAINER_CFLAGS=${MAINTAINER_CFLAGS#*  }
 901 AC_SUBST(MAINTAINER_CFLAGS)
 902
 903 dnl === Dependencies, compiler flags and linker libraries =====================
 904 # strip leading space
 905 BACKEND_PC_FILES=${BACKEND_PC_FILES#* }
 906
 907 CLUTTER_REQUIRES="$CLUTTER_BASE_PC_FILES $IMAGE_PC_FILES $BACKEND_PC_FILES"
 908 PKG_CHECK_MODULES(CLUTTER_DEPS, [$CLUTTER_REQUIRES])
 909 AC_SUBST(CLUTTER_REQUIRES)
 910
 911 CLUTTER_CFLAGS="$FLAVOUR_CFLAGS $CLUTTER_DEPS_CFLAGS $CLUTTER_PROFILE_CFLAGS $GLIB_CFLAGS"
 912 CLUTTER_LIBS="$FLAVOUR_LIBS $CLUTTER_DEPS_LIBS $CLUTTER_PROFILE_LDFLAGS $GLIB_LIBS"
 913 AC_SUBST(CLUTTER_CFLAGS)
 914 AC_SUBST(CLUTTER_LIBS)
 915
 916
 917 dnl === GObject-Introspection check ===========================================
 918
 919 GOBJECT_INTROSPECTION_CHECK([gi_req_version])
 920
 921 dnl === GTK Doc check =========================================================
 922
 923 GTK_DOC_CHECK([gtk_doc_req_version], [--flavour no-tmpl])
 924
 925 # we don't want to build the documentation from a Git clone unless we
 926 # explicitly tell configure to do so; this allows avoiding to recurse into
 927 # the documentation directory when building Clutter inside Poky for a
 928 # target device that doesn't have gtk-doc installed. for reference
 929 # see: http://bugzilla.openedhand.com/show_bug.cgi?id=1047
 930 #
 931 # we use autogen.sh as it exists only inside the Git clones, and it
 932 # is not packaged into tarballs.
 933 AM_CONDITIONAL([BUILD_GTK_DOC], [test "x$enable_gtk_doc" = "xyes" || test ! -f "autogen.sh"])
 934
 935 # prefixes for fixing gtk-doc references
 936 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
 937 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 938 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
 939 COGL_PREFIX="`$PKG_CONFIG --variable=prefix cogl-1.0`"
 940 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
 941 AC_SUBST(CAIRO_PREFIX)
 942 AC_SUBST(GLIB_PREFIX)
 943 AC_SUBST(PANGO_PREFIX)
 944 AC_SUBST(COGL_PREFIX)
 945 AC_SUBST(ATK_PREFIX)
 946
 947 dnl === Manual ================================================================
 948
 949 AC_ARG_ENABLE([docs],
 950               [AS_HELP_STRING([--enable-docs=@<:@no/yes@:>@],
 951                               [Build optional documentation; requires xsltproc and jw.])],
 952               [enable_docs=$enableval],
 953               [enable_docs=no])
 954
 955 enable_pdfs=no
 956 AS_IF([test "x$enable_docs" = "xyes"],
 957       [
 958         AC_PATH_PROG(JW, [jw], [no])
 959         AS_IF([test "x$JW" = "xno"],
 960               [
 961                 AC_MSG_WARN([jw not found; pdf generation has been disabled])
 962               ],
 963               [enable_pdfs=yes])
 964
 965         AC_PATH_PROG(XSLTPROC, [xsltproc], [no])
 966         AS_IF([test "x$XSLTPROC" = "xno"],
 967               [
 968                 AC_MSG_ERROR([xsltproc not found])
 969               ])
 970       ]
 971 )
 972
 973 AM_CONDITIONAL(ENABLE_DOCS, [test "x$enable_docs" = "xyes"])
 974 AM_CONDITIONAL(ENABLE_PDFS, [test "x$enable_pdfs" = "xyes"])
 975
 976 dnl === I18N ==================================================================
 977
 978 AM_GNU_GETTEXT_VERSION([0.17])
 979 AM_GNU_GETTEXT([external])
 980
 981 GETTEXT_PACKAGE="clutter-1.0"
 982 AC_SUBST(GETTEXT_PACKAGE)
 983 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
 984                    ["$GETTEXT_PACKAGE"],
 985                    [The prefix for our gettext translation domains.])
 986 AS_ALL_LINGUAS
 987
 988 dnl ===========================================================================
 989
 990 AC_CONFIG_FILES([
 991         Makefile
 992
 993         README
 994
 995         build/Makefile
 996         build/autotools/Makefile
 997         build/mingw/Makefile
 998
 999         clutter/Makefile
1000         clutter/clutter-config.h
1001         clutter/clutter-version.h
1002         clutter/clutter-$CLUTTER_API_VERSION.pc:clutter/clutter.pc.in
1003
1004         clutter/cally/cally-$CLUTTER_API_VERSION.pc:clutter/cally/cally.pc.in
1005
1006         clutter/cex100/clutter-cex100.h
1007
1008         tests/Makefile
1009         tests/accessibility/Makefile
1010         tests/conform/Makefile
1011         tests/conform/test-launcher.sh
1012         tests/data/Makefile
1013         tests/interactive/Makefile
1014         tests/interactive/wrapper.sh
1015         tests/micro-bench/Makefile
1016         tests/performance/Makefile
1017
1018         doc/Makefile
1019         doc/reference/Makefile
1020         doc/reference/clutter/Makefile
1021         doc/reference/clutter/clutter-docs.xml
1022         doc/reference/cally/Makefile
1023         doc/reference/cally/cally-docs.xml
1024         doc/common/Makefile
1025         doc/cookbook/Makefile
1026         doc/cookbook/clutter-cookbook.xml
1027         doc/cookbook/examples/Makefile
1028
1029         po/Makefile.in
1030 ])
1031
1032 AC_OUTPUT
1033
1034 dnl === Summary ===============================================================
1035
1036 echo ""
1037 echo "Clutter - $VERSION (${CLUTTER_RELEASE_STATUS})"
1038
1039 # Global flags
1040 echo ""
1041 echo " • Global:"
1042 echo "        Prefix: ${prefix}"
1043 echo "        Libdir: ${libdir}"
1044 echo "        Sysconfdir: ${sysconfdir}"
1045
1046 # Compiler/Debug related flags
1047 echo ""
1048 echo " • Compiler options:"
1049 echo "        Clutter debug level: ${enable_debug}"
1050 echo "        Compiler flags: ${CFLAGS} ${MAINTAINER_CFLAGS}"
1051 echo "        Profiling enabled: ${enable_profile}"
1052 echo "        Enable coverage tests: ${enable_gcov}"
1053 echo "        Enable deprecated symbols: ${enable_deprecated}"
1054
1055 # Documentation
1056 echo ""
1057 echo " • Documentation:"
1058 echo "        Build API Reference: ${enable_gtk_doc}"
1059 echo "        Build Additional Documentation: ${enable_docs} (Generate PDF: ${enable_pdfs})"
1060
1061 # Miscellaneous
1062 echo ""
1063 echo " • Extra:"
1064 echo "        Build introspection data: ${enable_introspection}"
1065 echo "        Build conformance test suite: ${enable_conformance}"
1066 echo "        Build X11-specific tests: ${x11_tests}"
1067
1068 # Clutter backend related flags
1069 echo ""
1070 echo " • Clutter Backends:"
1071
1072 if test "x$experimental_backend" = "xno"; then
1073 echo "        Windowing systems: ${CLUTTER_BACKENDS}"
1074 else
1075 echo "        Windowing systems: ${CLUTTER_BACKENDS} (WARNING: Experimental backends enabled)"
1076 fi
1077
1078 if test "x$SUPPORT_X11" = "x1"; then
1079 echo ""
1080 echo "     - X11 backend options:"
1081 echo "        Enabled extensions: ${X11_EXTS}"
1082 echo "        Build X11-specific tests: ${x11_tests}"
1083 fi
1084
1085 if test "x$SUPPORT_EGL" = "x1"; then
1086 echo ""
1087 echo "     - EGL backend options:"
1088 echo "        Enable TSLib: ${have_tslib}"
1089 echo "        Enable evdev: ${have_evdev}"
1090 echo "        Enable GDL: ${have_gdl}"
1091 fi
1092
1093 echo ""
1094
1095 # General warning about experimental features
1096 if test "x$experimental_backend" = "xyes"; then
1097 echo ""
1098 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1099 echo "*WARNING* *WARNING* *WARNING* *WARNING* *WARNING* *WARNING* *WARNING*"
1100 echo ""
1101 echo "  The stability of your build might be affected by one or more"
1102 echo "  experimental backends or experimental and unsupported features"
1103 echo ""
1104 echo "*WARNING* *WARNING* *WARNING* *WARNING* *WARNING* *WARNING* *WARNING*"
1105 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1106 echo ""
1107 fi