configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.13.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 1300, 0, 1300)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.13.0.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for gobject-introspection
 158 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 159
 160 dnl check for documentation tools
 161 GTK_DOC_CHECK([1.12])
 162 AG_GST_PLUGIN_DOCS([1.12])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 LT_LIB_M
 168 AC_SUBST(LIBM)
 169
 170 dnl check for pthreads
 171 AX_PTHREAD
 172
 173 dnl *** checks for header files ***
 174
 175 dnl check if we have ANSI C header files
 176 AC_HEADER_STDC
 177
 178 dnl check for GCC specific SSE headers
 179 dnl these are used by the speex resampler code
 180 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 181
 182 dnl also check which architecture we're on for building files with intrinsics
 183 dnl separately
 184 AC_CHECK_DECLS([__i386__], [HAVE_X86=1])
 185 AC_CHECK_DECLS([__x86_64__], [HAVE_X86=1])
 186
 187 dnl check for -m* compiler flags too
 188 SSE_CFLAGS="-msse"
 189 SSE2_CFLAGS="-msse2"
 190 SSE41_CFLAGS="-msse4.1"
 191
 192 AS_COMPILER_FLAG([$SSE_CFLAGS], [HAVE_SSE=1], [HAVE_SSE=0])
 193 AS_COMPILER_FLAG([$SSE2_CFLAGS], [HAVE_SSE2=1], [HAVE_SSE2=0])
 194 AS_COMPILER_FLAG([$SSE41_CFLAGS], [HAVE_SSE41=1], [HAVE_SSE41=0])
 195
 196 AM_CONDITIONAL(HAVE_X86, [test "x${HAVE_X86}" = "x1"])
 197
 198 AC_DEFINE_UNQUOTED(HAVE_SSE, [$HAVE_SSE], [SSE support is enabled])
 199 AC_DEFINE_UNQUOTED(HAVE_SSE2, [$HAVE_SSE2], [SSE2 support is enabled])
 200 AC_DEFINE_UNQUOTED(HAVE_SSE41, [$HAVE_SSE41], [SSE4.1 support is enabled])
 201
 202 AC_SUBST(SSE_CFLAGS)
 203 AC_SUBST(SSE2_CFLAGS)
 204 AC_SUBST(SSE41_CFLAGS)
 205
 206 dnl used in gst/tcp
 207 AC_CHECK_HEADERS([sys/socket.h],
 208   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 209 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 210
 211 dnl used in gst-libs/gst/rtsp
 212 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 213 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 214 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 215   WIN32_LIBS="-lws2_32"
 216   AC_SUBST(WIN32_LIBS)
 217 fi
 218
 219 dnl used in gst-libs/gst/pbutils and associated unit test
 220 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 221
 222 dnl checks for ARM NEON support
 223 dnl this instruction set is used by the speex resampler code
 224 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 225 AC_LINK_IFELSE([
 226 AC_LANG_PROGRAM([[
 227   #include <arm_neon.h>
 228   int32x4_t testfunc(int16_t *a, int16_t *b) {
 229       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 230       return vmull_s16(vld1_s16(a), vld1_s16(b));
 231   }
 232 ]])],
 233 [
 234   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 235   AC_MSG_RESULT(yes)
 236 ],
 237 [
 238   AC_MSG_RESULT(no)
 239 ])
 240
 241 dnl also, Windows does not have long long
 242 AX_CREATE_STDINT_H
 243
 244 dnl *** checks for functions ***
 245 AC_CHECK_FUNCS([localtime_r gmtime_r])
 246
 247 dnl *** checks for math functions ***
 248 LIBS_SAVE=$LIBS
 249 LIBS="$LIBS $LIBM"
 250 AC_CHECK_FUNCS(log2)
 251 LIBS=$LIBS_SAVE
 252
 253 dnl *** checks for types/defines ***
 254
 255 dnl *** checks for structures ***
 256
 257 dnl *** checks for compiler characteristics ***
 258
 259 dnl *** checks for library functions ***
 260
 261 dnl check for fseeko()
 262 AC_FUNC_FSEEKO
 263
 264 dnl Check for fast float to int casting as defined in C99
 265 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 266 save_libs=$LIBS
 267 LIBS="$LIBS $LIBM"
 268 AC_C99_FUNC_LRINT
 269 AC_C99_FUNC_LRINTF
 270 LIBS=$save_libs
 271
 272 dnl Check for a way to display the function name in debug output
 273 AG_GST_CHECK_FUNCTION
 274
 275 dnl *** checks for dependency libraries ***
 276
 277 dnl GLib
 278 GLIB_REQ=2.40.0
 279 AG_GST_GLIB_CHECK([$GLIB_REQ])
 280
 281 ORC_CHECK([0.4.24])
 282
 283 dnl checks for gstreamer
 284 dnl uninstalled is selected preferentially -- see pkg-config(1)
 285 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 286 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 287 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 288 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 289 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 290 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 291
 292 dnl Check for documentation xrefs
 293 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 294 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 295 AC_SUBST(GLIB_PREFIX)
 296 AC_SUBST(GST_PREFIX)
 297
 298 dnl GTK is optional and only used in examples
 299 HAVE_GTK=no
 300 HAVE_GTK_X11=no
 301 HAVE_GDK_PIXBUF=no
 302 GTK_REQ=3.10
 303 if test "x$BUILD_EXAMPLES" = "xyes"; then
 304   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 305   dnl some examples need gtk+-x11
 306   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 307   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 308   AC_SUBST(GTK_LIBS)
 309   AC_SUBST(GTK_CFLAGS)
 310
 311   PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0, HAVE_GDK_PIXBUF=yes, HAVE_GDK_PIXBUF=no)
 312   AC_SUBST(GDK_PIXBUF_LIBS)
 313   AC_SUBST(GDK_PIXBUF_CFLAGS)
 314 fi
 315 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 316 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 317 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 318 AM_CONDITIONAL(HAVE_GDK_PIXBUF, test "x$HAVE_GDK_PIXBUF" = "xyes")
 319
 320 HAVE_QT=no
 321 HAVE_QT_MOC=no
 322 dnl QT is optional and only used in examples
 323 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 324   HAVE_QT=yes
 325 ], [
 326   HAVE_QT=no
 327 ])
 328 if test "x$HAVE_QT" = "xyes"; then
 329   AC_CHECK_TOOL(QT_MOC, moc)
 330   AC_MSG_CHECKING([for Qt5 moc])
 331   mocversion=`$QT_MOC -v 2>&1`
 332   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 333   if test x"$mocversiongrep" != x"$mocversion"; then
 334     AC_MSG_RESULT([no])
 335     # moc was not the qt5 one, try with moc-qt5
 336     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 337     AC_MSG_CHECKING([for Qt5 moc-qt5])
 338     mocversion=`$QT_MOC -v 2>&1`
 339     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 340     if test x"$mocversiongrep" != x"$mocversion"; then
 341       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 342       AC_MSG_CHECKING([for qtchooser])
 343       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 344       mocversion=`$qt5tooldir/moc -v 2>&1`
 345       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 346       if test x"$mocversiongrep" != x"$mocversion"; then
 347         # no valid moc found
 348         QT_MOC="no"
 349       else
 350         QT_MOC=$qt5tooldir/moc
 351       fi
 352     else
 353       QT_MOC=$QT_MOC
 354     fi
 355   fi
 356   AC_SUBST(QT_MOC)
 357   AC_MSG_RESULT([$QT_MOC])
 358 fi
 359 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 360 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 361
 362 dnl chck for linux headers needed by the joystick seek example
 363 AC_COMPILE_IFELSE(
 364 [
 365   AC_LANG_PROGRAM([
 366     #include <linux/input.h>
 367     #include <linux/joystick.h>
 368   ],[
 369     struct js_event js;
 370     js.type = JS_EVENT_AXIS;
 371   ])
 372 ], [
 373   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 374 ], [
 375   HAVE_LINUX_JOYSTICK_HEADERS="no"
 376 ])
 377 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 378
 379 dnl Check for -Bsymbolic-functions linker flag used to avoid
 380 dnl intra-library PLT jumps, if available.
 381 AC_ARG_ENABLE(Bsymbolic,
 382               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 383               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 384                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 385                LDFLAGS=-Wl,-Bsymbolic-functions
 386                LIBS=
 387                AC_TRY_LINK([], [return 0],
 388                            AC_MSG_RESULT(yes)
 389                            enable_Bsymbolic=yes,
 390                            AC_MSG_RESULT(no)
 391                            enable_Bsymbolic=no)
 392                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 393
 394
 395 dnl *** set variables based on configure arguments ***
 396
 397 dnl set license and copyright notice
 398 GST_LICENSE="LGPL"
 399 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 400 AC_SUBST(GST_LICENSE)
 401
 402 dnl set location of plugin directory
 403 AG_GST_SET_PLUGINDIR
 404
 405 dnl set release date/time
 406 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 407   ["${srcdir}/gst-plugins-base.doap"],
 408   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 409
 410 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 411 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 412 if test x$enable_static = xyes -a x$enable_shared = xno; then
 413   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 414 fi
 415
 416 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 417 dnl make sure it doesn't complain about unused variables if debugging is disabled
 418 NO_WARNINGS=""
 419 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 420
 421 dnl define an ERROR_CFLAGS Makefile variable
 422 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 423 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 424     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 425     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 426     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 427     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 428
 429 dnl define an ERROR_CXXFLAGS Makefile variable
 430 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 431     -Wmissing-declarations -Wredundant-decls -Wundef
 432     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 433     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 434     -Wno-multichar $NO_WARNINGS])
 435
 436 dnl define correct level for debugging messages
 437 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 438
 439 dnl used in examples
 440 AG_GST_DEFAULT_ELEMENTS
 441
 442 dnl needed for encoding-target
 443 GST_DATADIR="$GST_PREFIX/share"
 444 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 445 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 446
 447 dnl behaviour of speex based audio resampler
 448 AC_MSG_CHECKING(which audio resample format to use for integer)
 449 AC_ARG_WITH([audioresample_format],
 450         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 451         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 452 AC_MSG_RESULT($ac_cv_audioresample_format)
 453 case $ac_cv_audioresample_format in
 454   int)
 455     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 456     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 457   ;;
 458   float)
 459     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 460     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 461   ;;
 462   auto)
 463     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 464     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 465 esac
 466
 467 dnl Check for mmap (needed by allocators library)
 468 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 469
 470 dnl *** plug-ins to include ***
 471
 472 dnl these are all the gst plug-ins, compilable without additional libs
 473 AG_GST_CHECK_PLUGIN(adder)
 474 AG_GST_CHECK_PLUGIN(app)
 475 AG_GST_CHECK_PLUGIN(audioconvert)
 476 AG_GST_CHECK_PLUGIN(audiorate)
 477 AG_GST_CHECK_PLUGIN(audiotestsrc)
 478 AG_GST_CHECK_PLUGIN(encoding)
 479 AG_GST_CHECK_PLUGIN(videoconvert)
 480 AG_GST_CHECK_PLUGIN(gio)
 481 AG_GST_CHECK_PLUGIN(playback)
 482 AG_GST_CHECK_PLUGIN(audioresample)
 483 AG_GST_CHECK_PLUGIN(rawparse)
 484 AG_GST_CHECK_PLUGIN(subparse)
 485 AG_GST_CHECK_PLUGIN(tcp)
 486 AG_GST_CHECK_PLUGIN(typefind)
 487 AG_GST_CHECK_PLUGIN(videotestsrc)
 488 AG_GST_CHECK_PLUGIN(videorate)
 489 AG_GST_CHECK_PLUGIN(videoscale)
 490 AG_GST_CHECK_PLUGIN(volume)
 491
 492 dnl iso-codes is optional, used by libgsttag
 493 AC_ARG_ENABLE(iso-codes,
 494 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 495 [case "${enableval}" in
 496   yes) enable_iso_codes=yes ;;
 497   no)  enable_iso_codes=no ;;
 498   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 499 esac
 500 ],
 501 [enable_iso_codes=yes]) dnl Default value
 502
 503 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 504 if test "x$enable_iso_codes" = "xyes"; then
 505   AC_MSG_RESULT([yes])
 506   have_iso_codes=no
 507   AC_MSG_CHECKING([whether iso-codes are available on this system])
 508   if $PKG_CONFIG iso-codes; then
 509     AC_MSG_RESULT([yes])
 510     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 511     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 512       AC_MSG_RESULT([yes])
 513       AC_MSG_CHECKING([for iso-codes prefix])
 514       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 515       if test -d "$ISO_CODES_PREFIX"; then
 516         AC_MSG_RESULT([yes])
 517         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 518         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 519         ISO_639_DOMAIN="iso_639"
 520         AC_MSG_CHECKING([ISO_639_DOMAIN])
 521         AC_MSG_RESULT([$ISO_639_DOMAIN])
 522         have_iso_codes=yes
 523         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 524         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 525         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 526         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 527       else
 528         AC_MSG_RESULT([no])
 529       fi
 530     else
 531       AC_MSG_RESULT([no])
 532     fi
 533   else
 534     AC_MSG_RESULT([no])
 535   fi
 536   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 537 else
 538   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 539   AM_CONDITIONAL(USE_ISO_CODES, false)
 540 fi
 541
 542 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 543 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 544 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 545   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 546       HAVE_ZLIB="yes"
 547     ], [
 548       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 549         HAVE_ZLIB="yes"
 550         ZLIB_LIBS="-lz"
 551         AC_SUBST(ZLIB_LIBS)
 552       ])
 553     ])
 554 ])
 555
 556 dnl *** sys plug-ins ***
 557
 558 echo
 559 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 560 echo
 561
 562 dnl *** X11 ***
 563 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 564 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 565                   [ximagesink], [
 566   AG_GST_PKG_CHECK_MODULES(X, x11)
 567 ])
 568
 569 dnl Check for Xv extension
 570 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 571 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 572                   [xvimagesink], [
 573   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 574 ])
 575
 576 dnl check for X Shm
 577 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 578 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 579   if test x$HAVE_X = xyes; then
 580     PKG_CHECK_MODULES(XSHM, xext, [
 581       AC_CHECK_LIB(Xext, XShmAttach, [
 582         HAVE_XSHM="yes"
 583       ], [
 584         HAVE_XSHM="no"
 585         XSHM_LIBS=""
 586       ], [ $X_LIBS ])
 587     ], [
 588       HAVE_XSHM="no"
 589     ])
 590   fi
 591 ], , [
 592   AC_SUBST(HAVE_XSHM)
 593   AC_SUBST(XSHM_LIBS)
 594 ])
 595
 596 dnl *** ext plug-ins ***
 597 dnl keep this list sorted alphabetically !
 598
 599 if test "x$BUILD_EXTERNAL" = "xyes"; then
 600
 601 echo
 602 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 603 echo
 604
 605 dnl *** alsa ***
 606 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 607 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 608   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 609     HAVE_ALSA="yes"
 610     AC_SUBST(ALSA_CFLAGS)
 611     AC_SUBST(ALSA_LIBS)
 612   ], [
 613     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 614   ])
 615 ])
 616
 617 dnl *** CDParanoia ***
 618 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 619 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 620 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 621   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 622     HAVE_CDPARANOIA="yes"
 623   ], [
 624     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 625                         cdda_open, -lm,
 626                         cdda_interface.h,
 627                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 628                         HEADER_DIR="no"
 629                         FOUND_CDPARANOIA="yes")
 630     if test "x$FOUND_CDPARANOIA" != "xyes";
 631     then
 632       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 633                           cdda_open, -lm,
 634                           cdda/cdda_interface.h,
 635                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 636                           HEADER_DIR="yes"
 637                           FOUND_CDPARANOIA="yes")
 638     fi
 639     if test "x$HEADER_DIR" = "xyes";
 640     then
 641       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 642                          defined if cdda headers are in a cdda/ directory)
 643     fi
 644     if test "x$FOUND_CDPARANOIA" = "xyes";
 645     then
 646       AC_CHECK_LIB(cdda_paranoia,
 647                    paranoia_cachemodel_size,
 648                    : ,
 649                    HAVE_CDPARANOIA=no,
 650                  [-lcdda_interface])
 651     fi
 652
 653     AC_SUBST(CDPARANOIA_LIBS)
 654   ])
 655 ])
 656 dnl FIXME : add second check somehow if that is necessary
 657 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 658 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 659
 660 dnl *** ivorbis ***
 661 dnl AM_PATH_IVORBIS only takes two options
 662 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 663 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 664   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 665   if test $HAVE_IVORBIS = no
 666   then
 667     IVORBIS_LIBS=
 668     IVORBIS_CFLAGS=
 669     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 670       [IVORBIS_LIBS=-lvorbisidec
 671       HAVE_IVORBIS=yes
 672       case $host in
 673       arm-*-*)
 674         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 675       esac
 676       ],
 677       HAVE_IVORBIS=no)
 678     AC_SUBST(IVORBIS_LIBS)
 679     AC_SUBST(IVORBIS_CFLAGS)
 680   else
 681     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 682       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 683       USE_TREMOLO=no)
 684   fi
 685 ])
 686
 687 dnl *** libvisual ***
 688 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 689 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 690   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 691   if test x$HAVE_LIBVISUAL = xyes; then
 692     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 693   fi
 694   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 695   if test x$LIBVIS_PLUGINSDIR != x; then
 696     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 697         "$LIBVIS_PLUGINSDIR",
 698         [directory in which the detected libvisual's plugins are located])
 699   fi
 700 ])
 701
 702 dnl *** ogg ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 704 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 705   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 706 ])
 707
 708 dnl *** Opus ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 710 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 711   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 712           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 713           HAVE_OPUS="yes"
 714   ], [
 715           HAVE_OPUS="no"
 716   ])
 717   AC_SUBST(OPUS_CFLAGS)
 718   AC_SUBST(OPUS_LIBS)
 719 ])
 720
 721 dnl *** pango ***
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 723 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 724   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 725 ])
 726
 727 dnl *** theora ***
 728 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 729 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 730   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 731 ])
 732
 733 dnl *** vorbis ***
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 735 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 736   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 737 ])
 738
 739 if test "x$HAVE_VORBIS" = "xyes"; then
 740   ac_cflags_save="$CFLAGS"
 741   AC_COMPILE_IFELSE([
 742     AC_LANG_PROGRAM([[
 743 #include <vorbis/codec.h>
 744                      ]],[[
 745 vorbis_dsp_state *v;
 746
 747 vorbis_synthesis_restart (v);
 748                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 749   if test "x$HAVE_VSR" = "xyes"; then
 750     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 751                        [defined if vorbis_synthesis_restart is present])
 752   fi
 753   CFLAGS="$ac_cflags_save"
 754 fi
 755
 756 else
 757
 758 dnl not building plugins with external dependencies,
 759 dnl but we still need to set the conditionals
 760 AM_CONDITIONAL(USE_ALSA, false)
 761 AM_CONDITIONAL(USE_CDPARANOIA, false)
 762 AM_CONDITIONAL(USE_IVORBIS, false)
 763 AM_CONDITIONAL(USE_LIBVISUAL, false)
 764 AM_CONDITIONAL(USE_OGG, false)
 765 AM_CONDITIONAL(USE_OPUS, false)
 766 AM_CONDITIONAL(USE_PANGO, false)
 767 AM_CONDITIONAL(USE_THEORA, false)
 768 AM_CONDITIONAL(USE_VORBIS, false)
 769
 770 fi dnl of EXT plugins
 771
 772 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 773 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 774     HAVE_GIO_UNIX_2_0="yes",
 775     HAVE_GIO_UNIX_2_0="no")
 776 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 777
 778 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 779
 780 dnl Overview:
 781 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 782 dnl GST_*:              flags shared by built objects to link against GStreamer
 783 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 784 dnl                          (compare to other modules) or for i18n
 785 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 786 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 787 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 788 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 789
 790 dnl GST_OPTION_CFLAGS
 791 if test "x$USE_DEBUG" = xyes; then
 792    PROFILE_CFLAGS="-g"
 793 fi
 794 AC_SUBST(PROFILE_CFLAGS)
 795
 796 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 797   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 798   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 799 else
 800   DEPRECATED_CFLAGS=""
 801 fi
 802 AC_SUBST(DEPRECATED_CFLAGS)
 803
 804 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 805 dnl at make time with e.g. make ERROR_CFLAGS=""
 806 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 807 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 808 AC_SUBST(GST_OPTION_CFLAGS)
 809 AC_SUBST(GST_OPTION_CXXFLAGS)
 810
 811 dnl our libraries need to be versioned correctly
 812 AC_SUBST(GST_LT_LDFLAGS)
 813
 814 dnl GST_PLUGINS_BASE_CFLAGS
 815 dnl prefer internal headers to already installed ones
 816 dnl also add builddir include for enumtypes and marshal
 817 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 818 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 819
 820 dnl FIXME: do we want to rename to GST_ALL_* ?
 821 dnl add GST_OPTION_CFLAGS, but overridable
 822 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 823 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 824 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 825 AC_SUBST(GST_CFLAGS)
 826 AC_SUBST(GST_CXXFLAGS)
 827 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 828 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 829 AC_SUBST(GST_LIBS)
 830
 831 dnl LDFLAGS really should only contain flags, not libs - they get added before
 832 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 833 GST_ALL_LDFLAGS="-no-undefined"
 834 if test "x${enable_Bsymbolic}" = "xyes"; then
 835   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 836 fi
 837 AC_SUBST(GST_ALL_LDFLAGS)
 838
 839 dnl GST_LIB_LDFLAGS
 840 dnl linker flags shared by all libraries
 841 dnl LDFLAGS modifier defining exported symbols from built libraries
 842 dnl (export _gst_foo but not __gst_foo)
 843 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 844 AC_SUBST(GST_LIB_LDFLAGS)
 845
 846 dnl this really should only contain flags, not libs - they get added before
 847 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 848 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 849 AC_SUBST(GST_PLUGIN_LDFLAGS)
 850
 851 dnl *** output files ***
 852
 853 $MKDIR_P tests/check/orc
 854
 855 AC_CONFIG_FILES(
 856 Makefile
 857 gst/Makefile
 858 gst/adder/Makefile
 859 gst/app/Makefile
 860 gst/audioconvert/Makefile
 861 gst/audiorate/Makefile
 862 gst/audioresample/Makefile
 863 gst/audiotestsrc/Makefile
 864 gst/encoding/Makefile
 865 gst/videoconvert/Makefile
 866 gst/gio/Makefile
 867 gst/pbtypes/Makefile
 868 gst/playback/Makefile
 869 gst/rawparse/Makefile
 870 gst/subparse/Makefile
 871 gst/tcp/Makefile
 872 gst/typefind/Makefile
 873 gst/videotestsrc/Makefile
 874 gst/videorate/Makefile
 875 gst/videoscale/Makefile
 876 gst/volume/Makefile
 877 sys/Makefile
 878 sys/ximage/Makefile
 879 sys/xvimage/Makefile
 880 ext/Makefile
 881 ext/alsa/Makefile
 882 ext/cdparanoia/Makefile
 883 ext/libvisual/Makefile
 884 ext/ogg/Makefile
 885 ext/opus/Makefile
 886 ext/pango/Makefile
 887 ext/theora/Makefile
 888 ext/vorbis/Makefile
 889 gst-libs/Makefile
 890 gst-libs/gst/Makefile
 891 gst-libs/gst/allocators/Makefile
 892 gst-libs/gst/audio/Makefile
 893 gst-libs/gst/app/Makefile
 894 gst-libs/gst/fft/Makefile
 895 gst-libs/gst/riff/Makefile
 896 gst-libs/gst/rtp/Makefile
 897 gst-libs/gst/rtsp/Makefile
 898 gst-libs/gst/sdp/Makefile
 899 gst-libs/gst/tag/Makefile
 900 gst-libs/gst/pbutils/Makefile
 901 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 902 gst-libs/gst/video/Makefile
 903 tools/Makefile
 904 pkgconfig/Makefile
 905 pkgconfig/gstreamer-allocators.pc
 906 pkgconfig/gstreamer-allocators-uninstalled.pc
 907 pkgconfig/gstreamer-audio.pc
 908 pkgconfig/gstreamer-audio-uninstalled.pc
 909 pkgconfig/gstreamer-app.pc
 910 pkgconfig/gstreamer-app-uninstalled.pc
 911 pkgconfig/gstreamer-fft.pc
 912 pkgconfig/gstreamer-fft-uninstalled.pc
 913 pkgconfig/gstreamer-pbutils.pc
 914 pkgconfig/gstreamer-pbutils-uninstalled.pc
 915 pkgconfig/gstreamer-riff.pc
 916 pkgconfig/gstreamer-riff-uninstalled.pc
 917 pkgconfig/gstreamer-rtp.pc
 918 pkgconfig/gstreamer-rtp-uninstalled.pc
 919 pkgconfig/gstreamer-rtsp.pc
 920 pkgconfig/gstreamer-rtsp-uninstalled.pc
 921 pkgconfig/gstreamer-sdp.pc
 922 pkgconfig/gstreamer-sdp-uninstalled.pc
 923 pkgconfig/gstreamer-tag.pc
 924 pkgconfig/gstreamer-tag-uninstalled.pc
 925 pkgconfig/gstreamer-video.pc
 926 pkgconfig/gstreamer-video-uninstalled.pc
 927 pkgconfig/gstreamer-plugins-base.pc
 928 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 929 tests/Makefile
 930 tests/check/Makefile
 931 tests/examples/Makefile
 932 tests/examples/app/Makefile
 933 tests/examples/audio/Makefile
 934 tests/examples/decodebin_next/Makefile
 935 tests/examples/dynamic/Makefile
 936 tests/examples/encoding/Makefile
 937 tests/examples/fft/Makefile
 938 tests/examples/gio/Makefile
 939 tests/examples/overlay/Makefile
 940 tests/examples/seek/Makefile
 941 tests/examples/snapshot/Makefile
 942 tests/examples/playback/Makefile
 943 tests/examples/playrec/Makefile
 944 tests/files/Makefile
 945 tests/icles/Makefile
 946 tests/icles/playback/Makefile
 947 docs/Makefile
 948 docs/libs/Makefile
 949 docs/plugins/Makefile
 950 docs/version.entities
 951 po/Makefile.in
 952 common/Makefile
 953 common/m4/Makefile
 954 m4/Makefile
 955 )
 956 AC_OUTPUT
 957
 958 AG_GST_OUTPUT_PLUGINS
 959 ORC_OUTPUT
 960