configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Ugly Plug-ins, 1.1.0.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-ugly)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER(config.h)
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 AS_LIBTOOL(GST, 2, 0, 2)
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=1.1.0
  51 GSTPB_REQ=1.1.0
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION(0.17)
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-ugly-$GST_API_VERSION])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 dnl *** checks for platform ***
  89
  90 dnl * hardware/architecture *
  91
  92 dnl common/m4/gst-arch.m4
  93 dnl check CPU type
  94 AG_GST_ARCH
  95
  96 dnl Determine endianness
  97 AC_C_BIGENDIAN
  98
  99 dnl *** checks for programs ***
 100
 101 dnl find a compiler
 102 AC_PROG_CC
 103 AC_PROG_CC_STDC
 104
 105 dnl determine c++ compiler
 106 AC_PROG_CXX
 107 dnl determine if c++ is available on this system
 108 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 109
 110 dnl check if the compiler supports '-c' and '-o' options
 111 AM_PROG_CC_C_O
 112
 113 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 114 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 115
 116 dnl check if the compiler supports do while(0) macros
 117 AG_GST_CHECK_DOWHILE_MACROS
 118
 119 dnl check for documentation tools
 120 GTK_DOC_CHECK([1.12])
 121 AG_GST_PLUGIN_DOCS([1.12])
 122
 123 dnl *** checks for libraries ***
 124
 125 dnl check for libm, for sin()
 126 LT_LIB_M
 127 AC_SUBST(LIBM)
 128
 129 dnl *** checks for header files ***
 130
 131 dnl used by ext/a52dec
 132 AX_CREATE_STDINT_H
 133
 134 dnl Check for malloc.h
 135 AC_CHECK_HEADERS([malloc.h])
 136
 137 dnl *** checks for types/defines ***
 138
 139 dnl *** checks for structures ***
 140
 141 dnl *** checks for compiler characteristics ***
 142
 143 dnl *** checks for library functions ***
 144
 145 dnl Check for a way to display the function name in debug output
 146 AG_GST_CHECK_FUNCTION
 147
 148 dnl *** checks for dependency libraries ***
 149
 150 dnl GLib is required
 151 GLIB_REQ=2.32.0
 152 AG_GST_GLIB_CHECK([$GLIB_REQ])
 153
 154 ORC_CHECK([0.4.16])
 155
 156 dnl checks for gstreamer
 157 dnl uninstalled is selected preferentially -- see pkg-config(1)
 158 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 159 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 160 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 161 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 162 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 163
 164 dnl Check for documentation xrefs
 165 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 166 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 167 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 168 AC_SUBST(GLIB_PREFIX)
 169 AC_SUBST(GST_PREFIX)
 170 AC_SUBST(GSTPB_PREFIX)
 171
 172 dnl *** set variables based on configure arguments ***
 173
 174 dnl set license and copyright notice
 175 GST_LICENSE="LGPL"
 176 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 177 AC_SUBST(GST_LICENSE)
 178
 179 dnl set location of plugin directory
 180 AG_GST_SET_PLUGINDIR
 181
 182 dnl set release date/time
 183 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 184   ["${srcdir}/gst-plugins-ugly.doap"],
 185   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 186
 187 dnl define an ERROR_CFLAGS Makefile variable
 188 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 189     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 190     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 191     -Winit-self -Wmissing-include-dirs -Waddress
 192     -Waggregate-return -Wno-multichar -Wnested-externs ])
 193
 194 dnl define an ERROR_CXXFLAGS Makefile variable
 195 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 196     -Wmissing-declarations -Wredundant-decls
 197     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 198     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 199     -Wno-multichar])
 200
 201 dnl define correct level for debugging messages
 202 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 203
 204 dnl used in examples
 205 AG_GST_DEFAULT_ELEMENTS
 206
 207 dnl *** plug-ins to include ***
 208
 209 dnl Non ported plugins (non-dependant, then dependant)
 210 dnl Make sure you have a space before and after all plugins
 211 GST_PLUGINS_NONPORTED=" "
 212 AC_SUBST(GST_PLUGINS_NONPORTED)
 213
 214 dnl these are all the gst plug-ins, compilable without additional libs
 215 AG_GST_CHECK_PLUGIN(asfdemux)
 216 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 217 AG_GST_CHECK_PLUGIN(dvdsub)
 218 AG_GST_CHECK_PLUGIN(xingmux)
 219 AG_GST_CHECK_PLUGIN(realmedia)
 220
 221 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 222
 223 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 224   WIN32_LIBS="-lws2_32"
 225   AC_SUBST(WIN32_LIBS)
 226 fi
 227
 228 dnl *** ext plug-ins ***
 229 dnl keep this list sorted alphabetically !
 230
 231 if test "x$BUILD_EXTERNAL" = "xyes"; then
 232
 233 echo
 234 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 235 echo
 236
 237 dnl *** a52dec ***
 238 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 239 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 240   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 241 ])
 242
 243 dnl *** amr-nb ***
 244 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 245 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 246   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, [
 247     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrnb; then
 248       AC_DEFINE(HAVE_OPENCORE_AMRNB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrnb])
 249     fi
 250     HAVE_AMRNB="yes"
 251   ], [
 252     HAVE_AMRNB="no"
 253   ])
 254   AC_SUBST(AMRNB_CFLAGS)
 255   AC_SUBST(AMRNB_LIBS)
 256 ])
 257
 258 dnl *** amr-wb dec ***
 259 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 260 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 261   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, [
 262     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrwb; then
 263       AC_DEFINE(HAVE_OPENCORE_AMRWB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrwb])
 264     fi
 265     HAVE_AMRWB="yes"
 266   ], [
 267     HAVE_AMRWB="no"
 268   ])
 269   AC_SUBST(AMRWB_CFLAGS)
 270   AC_SUBST(AMRWB_LIBS)
 271 ])
 272
 273 dnl *** cdio ***
 274 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 275 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 276   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 277 ])
 278
 279 dnl *** dvdread ***
 280 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 281 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 282   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 283   AC_SUBST(DVDREAD_LIBS)
 284 ])
 285
 286 dnl *** lame ***
 287 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 288 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 289   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 290   [
 291     HAVE_LAME="yes"
 292     LAME_LIBS="-lmp3lame $LIBM"
 293     dnl is lame presets available
 294     LAME_CFLAGS=""
 295     AC_TRY_COMPILE([#include <lame/lame.h>], [ int preset = MEDIUM ],
 296       [LAME_CFLAGS="-DGSTLAME_PRESET"],
 297       [LAME_CFLAGS=""]
 298     )
 299     AC_TRY_COMPILE([#include <lame/lame.h>], [
 300         void *ptr = &lame_set_VBR_quality
 301       ],
 302       [LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],
 303       [LAME_CFLAGS="$LAME_CFLAGS"]
 304     )
 305   AC_SUBST(LAME_CFLAGS)
 306   AC_SUBST(LAME_LIBS)
 307   ])
 308 ])
 309
 310 dnl *** mad ***
 311 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 312 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 313
 314   dnl check with pkg-config first
 315   AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 316   MAD_LIBS="$MAD_LIBS"
 317   if test "x$HAVE_MAD" = "xno"; then
 318     dnl fall back to oldskool detection
 319     AC_CHECK_HEADER(mad.h, [
 320       AC_CHECK_LIB(mad, mad_decoder_finish,
 321         HAVE_MAD="yes" MAD_LIBS="-lmad")
 322     ])
 323   fi
 324 ])
 325 AC_SUBST(MAD_LIBS)
 326
 327 dnl *** mpeg2dec ***
 328 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 329 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 330   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 331 ])
 332
 333 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 334 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 335 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 336   GST_PATH_SIDPLAY()
 337 ])
 338
 339 dnl *** twolame ***
 340 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 341 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 342   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 343       HAVE_TWOLAME="yes"], [
 344       HAVE_TWOLAME="no"
 345   ])
 346   AC_SUBST(TWOLAME_CFLAGS)
 347   AC_SUBST(TWOLAME_LIBS)
 348 ])
 349
 350 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 351 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 352 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 353   AG_GST_PKG_CHECK_MODULES(X264, x264 >= 0.120.0)
 354 ])
 355
 356 else
 357
 358 dnl not building plugins with external dependencies,
 359 dnl but we still need to set the conditionals
 360
 361 AM_CONDITIONAL(USE_A52DEC, false)
 362 AM_CONDITIONAL(USE_AMRNB, false)
 363 AM_CONDITIONAL(USE_AMRWB, false)
 364 AM_CONDITIONAL(USE_CDIO, false)
 365 AM_CONDITIONAL(USE_DVDREAD, false)
 366 AM_CONDITIONAL(USE_LAME, false)
 367 AM_CONDITIONAL(USE_MAD, false)
 368 AM_CONDITIONAL(USE_MPEG2DEC, false)
 369 AM_CONDITIONAL(USE_SIDPLAY, false)
 370 AM_CONDITIONAL(USE_TWOLAME, false)
 371 AM_CONDITIONAL(USE_X264, false)
 372
 373 fi dnl of EXT plugins
 374
 375 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 376
 377 dnl Overview:
 378 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 379 dnl GST_*:              flags shared by built objects to link against GStreamer
 380 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 381 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 382 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 383 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 384
 385 dnl GST_OPTION_CFLAGS
 386 if test "x$USE_DEBUG" = xyes; then
 387    PROFILE_CFLAGS="-g"
 388 fi
 389 AC_SUBST(PROFILE_CFLAGS)
 390
 391 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 392   dnl Define _only_ during CVS (not pre-releases or releases)
 393   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 394 else
 395   DEPRECATED_CFLAGS=""
 396 fi
 397 AC_SUBST(DEPRECATED_CFLAGS)
 398
 399 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 400 dnl at make time with e.g. make ERROR_CFLAGS=""
 401 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 402 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 403 AC_SUBST(GST_OPTION_CFLAGS)
 404 AC_SUBST(GST_OPTION_CXXFLAGS)
 405
 406 dnl FIXME: do we want to rename to GST_ALL_* ?
 407 dnl prefer internal headers to already installed ones
 408 dnl also add builddir include for enumtypes and marshal
 409 dnl add GST_OPTION_CFLAGS, but overridable
 410 GST_CFLAGS="$GST_CFLAGS"
 411 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 412 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 413 AC_SUBST(GST_CFLAGS)
 414 AC_SUBST(GST_CXXFLAGS)
 415 AC_SUBST(GST_LIBS)
 416
 417 dnl LDFLAGS really should only contain flags, not libs - they get added before
 418 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 419 GST_ALL_LDFLAGS="-no-undefined"
 420 AC_SUBST(GST_ALL_LDFLAGS)
 421
 422 dnl this really should only contain flags, not libs - they get added before
 423 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 424 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 425 AC_SUBST(GST_PLUGIN_LDFLAGS)
 426
 427 dnl *** output files ***
 428
 429 AC_CONFIG_FILES(
 430 Makefile
 431 common/Makefile
 432 common/m4/Makefile
 433 gst-libs/Makefile
 434 gst-libs/gst/Makefile
 435 gst/Makefile
 436 gst/asfdemux/Makefile
 437 gst/dvdlpcmdec/Makefile
 438 gst/dvdsub/Makefile
 439 gst/realmedia/Makefile
 440 gst/xingmux/Makefile
 441 ext/Makefile
 442 ext/a52dec/Makefile
 443 ext/amrnb/Makefile
 444 ext/amrwbdec/Makefile
 445 ext/cdio/Makefile
 446 ext/dvdread/Makefile
 447 ext/lame/Makefile
 448 ext/mad/Makefile
 449 ext/mpeg2dec/Makefile
 450 ext/sidplay/Makefile
 451 ext/twolame/Makefile
 452 ext/x264/Makefile
 453 docs/Makefile
 454 docs/plugins/Makefile
 455 docs/version.entities
 456 tests/Makefile
 457 tests/check/Makefile
 458 m4/Makefile
 459 po/Makefile.in
 460 pkgconfig/Makefile
 461 pkgconfig/gstreamer-plugins-ugly-uninstalled.pc
 462 gst-plugins-ugly.spec
 463 )
 464
 465 dnl Create the config.h file for Visual Studio builds
 466 dnl Beware of spaces and /'s in some of the shell variable contents.
 467 sed \
 468     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 469     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 470     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 471     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 472     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 473     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 474     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 475     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 476     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 477     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 478     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 479     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 480     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 481     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 482     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 483     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 484     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 485     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 486     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 487     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 488     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 489     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 490     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 491     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 492     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 493     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 494     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 495     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 496     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 497     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 498     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 499     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 500     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 501     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 502     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 503     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 504     config.h.in >win32/common/config.h-new
 505
 506 AC_OUTPUT
 507
 508 AG_GST_OUTPUT_PLUGINS
 509
 510 ORC_OUTPUT