configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.28.3,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.32.2
  58 GSTPB_REQ=0.10.32.2
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for gconftool-2
 134 dnl this macro defines an am conditional, so it needs to be run always
 135 AM_GCONF_SOURCE_2
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl check for libm, for sin()
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used by ext/wavpack
 154 AX_CREATE_STDINT_H
 155
 156 dnl used in gst/rtp/gstasteriskh263.c
 157 AC_CHECK_HEADERS([netinet/in.h])
 158 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 159 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 160
 161 dnl used in gst/udp
 162 AC_CHECK_HEADERS([sys/time.h])
 163
 164 dnl *** checks for types/defines ***
 165
 166 dnl Check for FIONREAD ioctl declaration.  This check is needed
 167 dnl for the UDP plugin to build on Solaris
 168 GST_CHECK_FIONREAD
 169
 170 dnl *** checks for structures ***
 171
 172 dnl *** checks for compiler characteristics ***
 173
 174 dnl check if we have GCC inline-asm
 175 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 176 if test x$HAVE_GCC_ASM = xyes ; then
 177   AC_DEFINE(HAVE_GCC_ASM, 1,
 178     [Define if compiler supports gcc inline assembly])
 179 fi
 180 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 181
 182 dnl *** checks for library functions ***
 183
 184 LIBS_SAVE=$LIBS
 185 LIBS="$LIBS $LIBM"
 186 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 187 LIBS=$LIBS_SAVE
 188
 189 dnl Check whether isinf() is defined by math.h
 190 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 191     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 192 if test "$ac_cv_have_isinf" = "yes"
 193 then
 194     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 195 fi
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198 AC_FUNC_MMAP
 199 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 200
 201 dnl Check for mmap (needed by electricfence plugin)
 202
 203 AC_CHECK_TYPE([struct ip_mreqn], [
 204               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 205               [#include <netinet/in.h>])
 206
 207 dnl *** checks for dependency libraries ***
 208
 209 dnl GLib is required
 210 AG_GST_GLIB_CHECK([2.20])
 211
 212 dnl Orc
 213 ORC_CHECK([0.4.11])
 214
 215 dnl checks for gstreamer
 216 dnl uninstalled is selected preferentially -- see pkg-config(1)
 217 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 222 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 223
 224 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 225 if test -z $GST_TOOLS_DIR; then
 226   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 227 fi
 228 AC_SUBST(GST_TOOLS_DIR)
 229
 230 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 231 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 232
 233 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 234
 235 dnl Check for documentation xrefs
 236 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 237 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 238 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 239 AC_SUBST(GLIB_PREFIX)
 240 AC_SUBST(GST_PREFIX)
 241 AC_SUBST(GSTPB_PREFIX)
 242
 243 dnl GTK is optional and used in examples
 244 HAVE_GTK=no
 245 GTK2_REQ=2.14.0
 246 GTK3_REQ=2.91.3
 247 if test "x$BUILD_EXAMPLES" = "xyes"; then
 248   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 249   AC_ARG_WITH([gtk],
 250     AC_HELP_STRING([--with-gtk=3.0|2.0],
 251                    [which gtk+ version to compile against (default: 2.0)]),
 252     [case "$with_gtk" in
 253         2.0) GTK_REQ=$GTK2_REQ ;;
 254         3.0) GTK_REQ=$GTK3_REQ ;;
 255         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 256     esac],
 257     [with_gtk=2.0
 258      GTK_REQ=$GTK2_REQ])
 259   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 260   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 261   dnl some examples need gtk+-x11
 262   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 263   AC_SUBST(GTK_LIBS)
 264   AC_SUBST(GTK_CFLAGS)
 265 fi
 266 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 267 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 268
 269 dnl should we install schemas ?
 270 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 271 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 272   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 273   if test x$GCONFTOOL = xno; then
 274     AC_MSG_WARN(Not installing GConf schemas)
 275     HAVE_GCONFTOOL="no"
 276   else
 277     HAVE_GCONFTOOL="yes"
 278   fi
 279   AC_SUBST(HAVE_GCONFTOOL)
 280 ])
 281
 282 dnl *** set variables based on configure arguments ***
 283
 284 dnl set license and copyright notice
 285 GST_LICENSE="LGPL"
 286 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 287 AC_SUBST(GST_LICENSE)
 288
 289 dnl set location of plugin directory
 290 AG_GST_SET_PLUGINDIR
 291
 292 dnl set release date/time
 293 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 294   ["${srcdir}/gst-plugins-good.doap"],
 295   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 296
 297 dnl define an ERROR_CFLAGS Makefile variable
 298 dnl -Wundef: too many broken headers
 299 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 300   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 301         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 302         -Wwrite-strings -Wold-style-definition -Waggregate-return
 303         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 304         -Wnested-externs ])
 305 else
 306   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 307   dnl doesn't understand all warning flags that the C compiler knows about
 308   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 309   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 310         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 311         -Wwrite-strings -Wold-style-definition
 312         -Winit-self -Wmissing-include-dirs -Wno-multichar
 313         -Wnested-externs ])
 314 fi
 315
 316 dnl define an ERROR_CXXFLAGS Makefile variable
 317 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 318         -Wmissing-declarations -Wredundant-decls
 319         -Wwrite-strings
 320         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 321
 322 dnl define correct level for debugging messages
 323 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 324
 325 dnl used in examples
 326 AG_GST_DEFAULT_ELEMENTS
 327
 328 dnl *** plug-ins to include ***
 329
 330 dnl these are all the gst plug-ins, compilable without additional libs
 331 dnl videofilter is at the top because others depend on it
 332 AG_GST_CHECK_PLUGIN(videofilter)
 333 AG_GST_CHECK_PLUGIN(alpha)
 334 AG_GST_CHECK_PLUGIN(apetag)
 335 AG_GST_CHECK_PLUGIN(audiofx)
 336 AG_GST_CHECK_PLUGIN(audioparsers)
 337 AG_GST_CHECK_PLUGIN(auparse)
 338 AG_GST_CHECK_PLUGIN(autodetect)
 339 AG_GST_CHECK_PLUGIN(avi)
 340 AG_GST_CHECK_PLUGIN(cutter)
 341 AG_GST_CHECK_PLUGIN(debugutils)
 342 AG_GST_CHECK_PLUGIN(deinterlace)
 343 AG_GST_CHECK_PLUGIN(effectv)
 344 AG_GST_CHECK_PLUGIN(equalizer)
 345 AG_GST_CHECK_PLUGIN(flv)
 346 AG_GST_CHECK_PLUGIN(id3demux)
 347 AG_GST_CHECK_PLUGIN(icydemux)
 348 AG_GST_CHECK_PLUGIN(interleave)
 349 AG_GST_CHECK_PLUGIN(flx)
 350 AG_GST_CHECK_PLUGIN(goom)
 351 AG_GST_CHECK_PLUGIN(goom2k1)
 352 AG_GST_CHECK_PLUGIN(imagefreeze)
 353 AG_GST_CHECK_PLUGIN(law)
 354 AG_GST_CHECK_PLUGIN(level)
 355 AG_GST_CHECK_PLUGIN(matroska)
 356 AG_GST_CHECK_PLUGIN(monoscope)
 357 AG_GST_CHECK_PLUGIN(multifile)
 358 AG_GST_CHECK_PLUGIN(multipart)
 359 AG_GST_CHECK_PLUGIN(quicktime)
 360 AG_GST_CHECK_PLUGIN(replaygain)
 361 AG_GST_CHECK_PLUGIN(rtp)
 362 AG_GST_CHECK_PLUGIN(rtpmanager)
 363 AG_GST_CHECK_PLUGIN(rtsp)
 364 AG_GST_CHECK_PLUGIN(shapewipe)
 365 AG_GST_CHECK_PLUGIN(smpte)
 366 AG_GST_CHECK_PLUGIN(spectrum)
 367 AG_GST_CHECK_PLUGIN(udp)
 368 AG_GST_CHECK_PLUGIN(videobox)
 369 AG_GST_CHECK_PLUGIN(videocrop)
 370 AG_GST_CHECK_PLUGIN(videomixer)
 371 AG_GST_CHECK_PLUGIN(wavenc)
 372 AG_GST_CHECK_PLUGIN(wavparse)
 373 AG_GST_CHECK_PLUGIN(y4m)
 374
 375 dnl *** checks for socket and nsl libraries ***
 376 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 377
 378 dnl disable gst plugins we might not be able to build on this
 379 dnl platform: udp and rtsp (ugly but minimally invasive)
 380 dnl FIXME: maybe move to sys
 381 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 382 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 383
 384 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 385   AG_GST_DISABLE_PLUGIN(udp)
 386   AG_GST_DISABLE_PLUGIN(rtsp)
 387 fi
 388
 389 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 390   WIN32_LIBS="-lws2_32"
 391   AC_SUBST(WIN32_LIBS)
 392 fi
 393
 394 dnl disable experimental plug-ins
 395 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 396   AG_GST_DISABLE_PLUGIN(monoscope)
 397 fi
 398
 399 dnl *** sys plug-ins ***
 400
 401 echo
 402 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 403 echo
 404
 405 dnl DirectSound
 406 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 407 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 408   HAVE_DIRECTSOUND="no"
 409   save_CFLAGS="$CFLAGS"
 410   save_LDFLAGS="$LDFLAGS"
 411   save_LIBS="$LIBS"
 412   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 413   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 414   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 415   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 416   AC_LINK_IFELSE([
 417 #include <windows.h>
 418 #include <dxerr9.h>
 419 #include <dsound.h>
 420
 421 int main ()
 422 {
 423   DXGetErrorString9 (0);
 424   DirectSoundCreate(NULL, NULL, NULL);
 425
 426   return 0;
 427 }
 428 ],
 429     [HAVE_DIRECTSOUND="yes"],
 430     [HAVE_DIRECTSOUND="no"])
 431   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 432   CFLAGS=$save_CFLAGS
 433   LDFLAGS=$save_LDFLAGS
 434   LIBS=$save_LIBS
 435
 436   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 437     dnl this is much more than we want
 438     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 439     AC_SUBST(DIRECTSOUND_CFLAGS)
 440     AC_SUBST(DIRECTSOUND_LDFLAGS)
 441     AC_SUBST(DIRECTSOUND_LIBS)
 442   fi
 443   AC_SUBST(HAVE_DIRECTSOUND)
 444 ])
 445
 446 dnl *** OSS audio *** (Linux, *BSD)
 447 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 448 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 449  HAVE_OSS="yes"
 450 dnl Linux and newer BSD versions :
 451  AC_CHECK_HEADER(sys/soundcard.h, [
 452    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 453    ] , [
 454 dnl Some old BSD versions and also newer OpenBSD versions :
 455    AC_CHECK_HEADER(soundcard.h, [
 456      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 457      ], [
 458   dnl Some old BSD versions :
 459      AC_CHECK_HEADER(machine/soundcard.h, [
 460        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 461          [Define if OSS includes are in /machine/])
 462        ], [
 463        HAVE_OSS="no"
 464      ])
 465    ])
 466  ])
 467 ])
 468
 469 dnl *** oss4 ***
 470 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 471 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 472   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 473   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 474       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 475       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 476 ])
 477
 478 dnl *** Sun Audio ***
 479 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 480 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 481   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 482 ])
 483
 484 dnl *** OSX Audio ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 486 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 487   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 488 ])
 489
 490 dnl *** OS X video ***
 491 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 492 HAVE_OSX_VIDEO="no"
 493 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 494   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 495 ])
 496 dnl in case header OpenGL/gl.h is found on other platforms
 497 case "$host" in
 498   *-*darwin*)
 499     dnl do nothing
 500     ;;
 501   *)
 502     HAVE_OSX_VIDEO="no"
 503     ;;
 504 esac
 505
 506
 507 dnl *** Video 4 Linux 2 ***
 508 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 509 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 510 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 511 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 512   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 513   AC_TRY_COMPILE([
 514 #include <sys/types.h>
 515 #ifdef __sun /* Solaris */
 516 #include <sys/types.h>
 517 #include <sys/videodev2.h>
 518 #else /* Linux */
 519 #include <linux/types.h>
 520 #define _LINUX_TIME_H
 521 #define __user
 522 #include <linux/videodev2.h>
 523 #endif
 524 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 525 #error too early v4l2 version or no v4l2 at all
 526 #endif
 527     ], [
 528 return 0;
 529     ], [
 530       HAVE_GST_V4L2="yes"
 531       AC_MSG_RESULT(yes)
 532     ], [
 533       HAVE_GST_V4L2="no"
 534       AC_MSG_RESULT(no)
 535
 536       HAVE_VIDEODEV=no
 537       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 538       [
 539         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 540       ])
 541
 542       if test "x$HAVE_VIDEODEV" = "xyes"; then
 543         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 544         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 545       else
 546         AC_MSG_WARN([video4linux2 was not found])
 547       fi
 548     ])
 549
 550   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 551     dnl check for missing v4l2_buffer declaration (see #135919)
 552     MISSING_DECL=0
 553     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 554     AC_TRY_COMPILE([
 555 #include <sys/types.h>
 556 #ifdef __sun /* Solaris */
 557 #include <sys/types.h>
 558 #include <sys/videodev2.h>
 559 #else /* Linux */
 560 #include <linux/types.h>
 561 #define _LINUX_TIME_H
 562 #define __user
 563 #include <linux/videodev2.h>
 564 #endif
 565     ],[
 566 struct v4l2_buffer buf;
 567 buf.index = 0;
 568 return 0;
 569     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 570     if [ test x$MISSING_DECL = x1 ]; then
 571       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 572     fi
 573
 574     dnl check for XOverlay libraries
 575     AG_GST_CHECK_XV
 576   fi
 577 ])
 578
 579 # Optional gudev for device probing
 580 AC_ARG_WITH([gudev],
 581   AC_HELP_STRING([--with-gudev],
 582     [device detection with gudev]),
 583   [],
 584   [with_gudev=check])
 585 if test x$HAVE_GST_V4L2 = xyes; then
 586   if test x$with_gudev != xno; then
 587       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 588           [ have_gudev=yes
 589             AC_DEFINE(HAVE_GUDEV, 1,
 590                [Whether gudev is available for device detection])
 591             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 592           ], [
 593           have_gudev=no
 594           ])
 595   else
 596     have_gudev=no
 597   fi
 598 fi
 599 AC_SUBST(GUDEV_CFLAGS)
 600 AC_SUBST(GUDEV_LIBS)
 601
 602 # Make libv4l2 non-automagic
 603 AC_ARG_WITH([libv4l2],
 604   AC_HELP_STRING([--with-libv4l2],
 605     [support video buffer conversion using libv4l2]),
 606   [],
 607   [with_libv4l2=check])
 608 if test x$HAVE_GST_V4L2 = xyes; then
 609   if test x$with_libv4l2 != xno; then
 610       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 611           [ have_libv4l2=yes
 612             AC_DEFINE(HAVE_LIBV4L2, 1,
 613                 [Whether libv4l2 is available for video buffer conversion])
 614           ], [
 615           have_libv4l2=no
 616           ])
 617   else
 618     have_libv4l2=no
 619   fi
 620 fi
 621
 622 dnl Check for X11
 623 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 624 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 625                   [ximagesrc], [
 626   AC_PATH_XTRA
 627
 628   dnl now try to find the HEADER
 629   ac_cflags_save="$CFLAGS"
 630   ac_cppflags_save="$CPPFLAGS"
 631   CFLAGS="$CFLAGS $X_CFLAGS"
 632   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 633   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 634
 635   if test "x$HAVE_X" = "xno"
 636   then
 637     AC_MSG_NOTICE([cannot find X11 development files])
 638   else
 639     dnl this is much more than we want
 640     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 641     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 642     dnl it does not add the libs; therefore we add them here
 643     X_LIBS="$X_LIBS -lX11"
 644     AC_SUBST(X_CFLAGS)
 645     AC_SUBST(X_LIBS)
 646
 647     dnl check for Xfixes
 648     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 649     if test "x$HAVE_XFIXES" = "xyes"
 650     then
 651         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 652     fi
 653     AC_SUBST(XFIXES_LIBS)
 654     AC_SUBST(XFIXES_CFLAGS)
 655
 656     dnl check for Xdamage
 657     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 658     if test "x$HAVE_XDAMAGE" = "xyes"
 659     then
 660         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 661     fi
 662     AC_SUBST(XDAMAGE_LIBS)
 663     AC_SUBST(XDAMAGE_CFLAGS)
 664   fi
 665   AC_SUBST(HAVE_X)
 666   CFLAGS="$ac_cflags_save"
 667   CPPFLAGS="$ac_cppflags_save"
 668 ])
 669
 670 dnl FIXME: this should be rolled into the test above, it's just an additional
 671 dnl feature of the ximagesrc plug-in
 672 dnl This is the same as in gst-plugins-base
 673 dnl check for X Shm
 674 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 675 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 676   if test x$HAVE_X = xyes; then
 677     AC_CHECK_LIB(Xext, XShmAttach,
 678                  HAVE_XSHM="yes", HAVE_XSHM="no",
 679                  $X_LIBS)
 680     if test "x$HAVE_XSHM" = "xyes"; then
 681       XSHM_LIBS="-lXext"
 682     else
 683       dnl On AIX, it is in XextSam instead, but we still need -lXext
 684       AC_CHECK_LIB(XextSam, XShmAttach,
 685                    HAVE_XSHM="yes", HAVE_XSHM="no",
 686                    $X_LIBS)
 687       if test "x$HAVE_XSHM" = "xyes"; then
 688         XSHM_LIBS="-lXext -lXextSam"
 689       fi
 690     fi
 691   fi
 692 ], ,[
 693   AC_SUBST(HAVE_XSHM)
 694   AC_SUBST(XSHM_LIBS)
 695 ])
 696
 697 dnl for V4L2, we also need to know if we have XVIDEO
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 699 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 700                   [], [
 701   AG_GST_CHECK_XV
 702 ])
 703
 704 dnl *** ext plug-ins ***
 705 dnl keep this list sorted alphabetically !
 706
 707 if test "x$BUILD_EXTERNAL" = "xyes"; then
 708
 709 echo
 710 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 711 echo
 712
 713 dnl *** aalib ***
 714 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 715 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 716   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 717   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 718 ])
 719
 720 dnl *** annodex ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 722 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 723   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 724 ])
 725
 726 dnl *** cairo ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 728 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 729   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 730 ])
 731
 732 dnl *** cairo-gobject ***
 733 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 734 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 735   [Cairo graphics rendering gobject bindings], cairooverlay, [
 736   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 737 ])
 738
 739 dnl **** ESound ****
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 741 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 742   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 743   if test $HAVE_ESD = no
 744   then
 745     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 746     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 747   fi
 748 ])
 749
 750 dnl *** FLAC ***
 751 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 752 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 753   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 754 ])
 755
 756 dnl *** GConf ***
 757 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 758 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 759   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 760 ])
 761
 762 dnl *** GDK pixbuf ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 764 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 765   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 766 ])
 767
 768 dnl *** HAL ***
 769 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 770 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 771   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 772 ])
 773
 774 dnl *** Jack ***
 775 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 776 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 777   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 778   AC_SUBST(JACK_CFLAGS)
 779   AC_SUBST(JACK_LIBS)
 780
 781   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 782   if test x$HAVE_JACK_0_120_1 = xyes; then
 783     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 784   fi
 785   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 786   if test x$HAVE_JACK_1_9_7 = xyes; then
 787     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 788   fi
 789
 790 ])
 791
 792 dnl *** jpeg ***
 793 dnl FIXME: we could use header checks here as well IMO
 794 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 795 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 796   AC_ARG_WITH(jpeg-mmx,
 797     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 798   OLD_LIBS="$LIBS"
 799   if test x$with_jpeg_mmx != x; then
 800     LIBS="$LIBS -L$with_jpeg_mmx"
 801   fi
 802   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 803   JPEG_LIBS="$LIBS -ljpeg-mmx"
 804   LIBS="$OLD_LIBS"
 805   if test x$HAVE_JPEG != xyes; then
 806     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 807     JPEG_LIBS="-ljpeg"
 808   fi
 809   AC_SUBST(JPEG_LIBS)
 810 ])
 811
 812 dnl *** libcaca ***
 813 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 814 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 815   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 816   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 817   if test "x$HAVE_LIBCACA" != "xyes"; then
 818     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 819     dnl see if it compilation works too, might not if we are cross-compiling
 820     if test "x$HAVE_LIBCACA" = "xyes"; then
 821       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 822                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 823     fi
 824   fi
 825 ])
 826
 827 dnl *** libdv ***
 828 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 829 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 830   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 831 ])
 832
 833 dnl *** libpng ***
 834 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 835 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 836   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 837 ])
 838
 839 dnl *** pulseaudio ***
 840 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 841 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 842
 843   dnl used in ext/pulse/pulseutil.c
 844   AC_CHECK_HEADERS([process.h])
 845
 846   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 847   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 848   if test x$HAVE_PULSE_0_9_11 = xyes; then
 849     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 850   fi
 851   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 852   if test x$HAVE_PULSE_0_9_12 = xyes; then
 853     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 854   fi
 855   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 856   if test x$HAVE_PULSE_0_9_13 = xyes; then
 857     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 858   fi
 859   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 860   if test x$HAVE_PULSE_0_9_15 = xyes; then
 861     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 862   fi
 863   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_16, libpulse >= 0.9.16)
 864   if test x$HAVE_PULSE_0_9_16 = xyes; then
 865     AC_DEFINE(HAVE_PULSE_0_9_16, 1, [defined if pulseaudio >= 0.9.16 is available])
 866   fi
 867   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 868   if test x$HAVE_PULSE_0_9_20 = xyes; then
 869     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 870   fi
 871 ])
 872
 873 dnl *** dv1394 ***
 874 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 875 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 876   dnl first test for libraw1394 >= 2.0.0
 877   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 878   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 879   dnl now see how far we got
 880   if test x$HAVE_RAW1394 = xyes && \
 881      test x$HAVE_LIBIEC61883 = xyes; then
 882        AG_GST_CHECK_LIBHEADER(AVC1394,
 883         avc1394, avc1394_send_command, $RAW1394_LIBS,
 884         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 885        AG_GST_CHECK_LIBHEADER(ROM1394,
 886         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 887         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 888        if test x$HAVE_AVC1394 = xyes && \
 889           test x$HAVE_AVC1394 = xyes && \
 890           test x$HAVE_ROM1394 = xyes; then
 891           HAVE_DV1394=yes
 892           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 893           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 894           AC_SUBST(DV1394_CFLAGS)
 895           AC_SUBST(DV1394_LIBS)
 896         fi
 897   else
 898        if test x$HAVE_RAW1394 = xno; then
 899           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 900           AG_GST_CHECK_LIBHEADER(AVC1394,
 901            avc1394, avc1394_send_command, $RAW1394_LIBS,
 902            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 903           AG_GST_CHECK_LIBHEADER(ROM1394,
 904            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 905            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 906           if test x$HAVE_RAW1394 = xyes && \
 907              test x$HAVE_AVC1394 = xyes && \
 908              test x$HAVE_ROM1394 = xyes; then
 909              HAVE_DV1394=yes
 910              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 911              DV1394_CFLAGS="$RAW1394_CFLAGS"
 912              if test x$HAVE_LIBIEC61883 = xyes; then
 913                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 914                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 915              fi
 916              AC_SUBST(DV1394_CFLAGS)
 917              AC_SUBST(DV1394_LIBS)
 918            fi
 919          fi
 920   fi
 921 ])
 922 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 923
 924 dnl *** shout2 ***
 925 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 926 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 927   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 928   if test $HAVE_SHOUT2 = no
 929   then
 930     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 931     AC_SUBST(SHOUT2_CFLAGS)
 932     AC_SUBST(SHOUT2_LIBS)
 933   fi
 934 ])
 935
 936 dnl *** soup ***
 937 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 938 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 939   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 940     HAVE_SOUP="yes"
 941     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 942   ],[
 943     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 944       HAVE_SOUP="no"
 945     ])
 946   ])
 947   AC_SUBST(SOUP_CFLAGS)
 948   AC_SUBST(SOUP_LIBS)
 949 ])
 950
 951 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 952 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 953 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 954 dnl   speex_jitter.h is 1.1.x only
 955 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 956 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 957   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 958   if test $HAVE_SPEEX = no
 959   then
 960     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 961       AC_CHECK_HEADER(speex/speex_jitter.h, [
 962         dnl speex 1.1.x :
 963         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 964           dnl speex 1.1.5 or + :
 965           HAVE_SPEEX="yes"
 966           SPEEX_LIBS="-lspeex"
 967           AC_SUBST(SPEEX_CFLAGS)
 968           AC_SUBST(SPEEX_LIBS)
 969         ],[
 970           HAVE_SPEEX="no"
 971         ])
 972       ],[
 973         dnl speex 1.0.x :
 974           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 975             dnl speex 1.0.4
 976             HAVE_SPEEX="yes"
 977             SPEEX_LIBS="-lspeex"
 978             AC_SUBST(SPEEX_CFLAGS)
 979             AC_SUBST(SPEEX_LIBS)
 980
 981             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 982               [defined if speex 1.0.x API detected])
 983         ],[
 984             HAVE_SPEEX="no"
 985             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 986         ], [
 987 #include <speex/speex.h>
 988         ])
 989       ])
 990     ])
 991   fi
 992 ])
 993
 994 dnl *** taglib ***
 995 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 996 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 997   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 998   if test "x$HAVE_CXX" != "xyes"; then
 999     USE_TAGLIB=false
1000     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
1001   else
1002     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
1003     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
1004         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
1005       ], [
1006         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
1007     ])
1008     AC_SUBST(TAGLIB_CXXFLAGS)
1009   fi
1010 ])
1011
1012 dnl *** wavpack ***
1013 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
1014 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
1015   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
1016     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
1017       HAVE_WAVPACK=yes
1018       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
1019     ],[
1020       HAVE_WAVPACK=no
1021     ])
1022   ])
1023   AC_SUBST(WAVPACK_CFLAGS)
1024   AC_SUBST(WAVPACK_LIBS)
1025 ])
1026
1027 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
1028 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
1029 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
1030   AG_GST_CHECK_LIBHEADER(ZLIB,
1031     z, uncompress,, zlib.h, [
1032     HAVE_ZLIB="yes"
1033     ZLIB_LIBS="-lz"
1034     AC_SUBST(ZLIB_LIBS)
1035   ])
1036 ])
1037
1038 dnl *** matroska prefers to have bz2 ***
1039 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
1040 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
1041   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
1042   AC_SUBST(BZ2_LIBS)
1043 ])
1044
1045 else
1046
1047 dnl not building plugins with external dependencies,
1048 dnl but we still need to set the conditionals
1049 AM_CONDITIONAL(USE_AALIB, false)
1050 AM_CONDITIONAL(USE_ANNODEX, false)
1051 AM_CONDITIONAL(USE_BZ2, false)
1052 AM_CONDITIONAL(USE_CAIRO, false)
1053 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
1054 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1055 AM_CONDITIONAL(USE_DV1394, false)
1056 AM_CONDITIONAL(USE_ESD, false)
1057 AM_CONDITIONAL(USE_FLAC, false)
1058 AM_CONDITIONAL(USE_GCONF, false)
1059 AM_CONDITIONAL(USE_GCONFTOOL, false)
1060 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1061 AM_CONDITIONAL(USE_GST_V4L2, false)
1062 AM_CONDITIONAL(USE_HAL, false)
1063 AM_CONDITIONAL(USE_JACK, false)
1064 AM_CONDITIONAL(USE_JPEG, false)
1065 AM_CONDITIONAL(USE_LIBCACA, false)
1066 AM_CONDITIONAL(USE_LIBDV, false)
1067 AM_CONDITIONAL(USE_LIBIEC61883, false)
1068 AM_CONDITIONAL(USE_LIBPNG, false)
1069 AM_CONDITIONAL(USE_OSS, false)
1070 AM_CONDITIONAL(USE_OSS4, false)
1071 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1072 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1073 AM_CONDITIONAL(USE_PULSE, false)
1074 AM_CONDITIONAL(USE_SHOUT2, false)
1075 AM_CONDITIONAL(USE_SOUP, false)
1076 AM_CONDITIONAL(USE_SPEEX, false)
1077 AM_CONDITIONAL(USE_SUNAUDIO, false)
1078 AM_CONDITIONAL(USE_TAGLIB, false)
1079 AM_CONDITIONAL(USE_WAVPACK, false)
1080 AM_CONDITIONAL(USE_X, false)
1081 AM_CONDITIONAL(USE_XSHM, false)
1082 AM_CONDITIONAL(USE_XVIDEO, false)
1083 AM_CONDITIONAL(USE_ZLIB, false)
1084
1085 fi dnl of EXT plugins
1086
1087 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1088
1089 dnl Overview:
1090 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1091 dnl GST_*:              flags shared by all built objects
1092 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1093 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1094 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1095 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1096
1097 dnl GST_OPTION_CFLAGS
1098 if test "x$USE_DEBUG" = xyes; then
1099    PROFILE_CFLAGS="-g"
1100 fi
1101 AC_SUBST(PROFILE_CFLAGS)
1102
1103 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1104   dnl Define _only_ for git (not pre-releases or releases)
1105   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1106 else
1107   DEPRECATED_CFLAGS=""
1108 fi
1109 AC_SUBST(DEPRECATED_CFLAGS)
1110
1111 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1112 dnl at make time with e.g. make ERROR_CFLAGS=""
1113 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1114 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1115 AC_SUBST(GST_OPTION_CFLAGS)
1116 AC_SUBST(GST_OPTION_CXXFLAGS)
1117
1118 dnl our libraries need to be versioned correctly
1119 AC_SUBST(GST_LT_LDFLAGS)
1120
1121 dnl FIXME: do we want to rename to GST_ALL_* ?
1122 dnl prefer internal headers to already installed ones
1123 dnl also add builddir include for enumtypes and marshal
1124 dnl add ERROR_CFLAGS, but overridable
1125 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1126 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1127 AC_SUBST(GST_CFLAGS)
1128 AC_SUBST(GST_CXXFLAGS)
1129 AC_SUBST(GST_LIBS)
1130
1131 dnl LDFLAGS really should only contain flags, not libs - they get added before
1132 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1133 GST_ALL_LDFLAGS="-no-undefined"
1134 AC_SUBST(GST_ALL_LDFLAGS)
1135
1136 dnl this really should only contain flags, not libs - they get added before
1137 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1138 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1139 AC_SUBST(GST_PLUGIN_LDFLAGS)
1140
1141 dnl *** output files ***
1142
1143 dnl keep this alphabetic per directory, please
1144 AC_CONFIG_FILES(
1145 Makefile
1146 gst/Makefile
1147 gst/alpha/Makefile
1148 gst/apetag/Makefile
1149 gst/audiofx/Makefile
1150 gst/audioparsers/Makefile
1151 gst/auparse/Makefile
1152 gst/autodetect/Makefile
1153 gst/avi/Makefile
1154 gst/cutter/Makefile
1155 gst/deinterlace/Makefile
1156 gst/debugutils/Makefile
1157 gst/effectv/Makefile
1158 gst/equalizer/Makefile
1159 gst/flv/Makefile
1160 gst/id3demux/Makefile
1161 gst/icydemux/Makefile
1162 gst/imagefreeze/Makefile
1163 gst/interleave/Makefile
1164 gst/goom/Makefile
1165 gst/goom2k1/Makefile
1166 gst/law/Makefile
1167 gst/level/Makefile
1168 gst/matroska/Makefile
1169 gst/monoscope/Makefile
1170 gst/multifile/Makefile
1171 gst/multipart/Makefile
1172 gst/quicktime/Makefile
1173 gst/replaygain/Makefile
1174 gst/rtp/Makefile
1175 gst/rtpmanager/Makefile
1176 gst/rtsp/Makefile
1177 gst/shapewipe/Makefile
1178 gst/smpte/Makefile
1179 gst/spectrum/Makefile
1180 gst/udp/Makefile
1181 gst/videobox/Makefile
1182 gst/videocrop/Makefile
1183 gst/videofilter/Makefile
1184 gst/videomixer/Makefile
1185 gst/wavenc/Makefile
1186 gst/wavparse/Makefile
1187 gst/flx/Makefile
1188 gst/y4m/Makefile
1189 ext/Makefile
1190 ext/aalib/Makefile
1191 ext/annodex/Makefile
1192 ext/cairo/Makefile
1193 ext/dv/Makefile
1194 ext/esd/Makefile
1195 ext/flac/Makefile
1196 ext/gconf/Makefile
1197 ext/gdk_pixbuf/Makefile
1198 ext/hal/Makefile
1199 ext/jack/Makefile
1200 ext/jpeg/Makefile
1201 ext/libcaca/Makefile
1202 ext/libpng/Makefile
1203 ext/pulse/Makefile
1204 ext/raw1394/Makefile
1205 ext/shout2/Makefile
1206 ext/soup/Makefile
1207 ext/speex/Makefile
1208 ext/taglib/Makefile
1209 ext/wavpack/Makefile
1210 sys/Makefile
1211 sys/directsound/Makefile
1212 sys/oss/Makefile
1213 sys/oss4/Makefile
1214 sys/osxaudio/Makefile
1215 sys/osxvideo/Makefile
1216 sys/sunaudio/Makefile
1217 sys/v4l2/Makefile
1218 sys/waveform/Makefile
1219 sys/ximage/Makefile
1220 po/Makefile.in
1221 tests/Makefile
1222 tests/check/Makefile
1223 tests/examples/Makefile
1224 tests/examples/audiofx/Makefile
1225 tests/examples/cairo/Makefile
1226 tests/examples/equalizer/Makefile
1227 tests/examples/jack/Makefile
1228 tests/examples/level/Makefile
1229 tests/examples/pulse/Makefile
1230 tests/examples/rtp/Makefile
1231 tests/examples/shapewipe/Makefile
1232 tests/examples/spectrum/Makefile
1233 tests/examples/v4l2/Makefile
1234 tests/files/Makefile
1235 tests/icles/Makefile
1236 gconf/Makefile
1237 gconf/gstreamer.schemas
1238 common/Makefile
1239 common/m4/Makefile
1240 m4/Makefile
1241 docs/Makefile
1242 docs/plugins/Makefile
1243 docs/version.entities
1244 pkgconfig/Makefile
1245 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1246 gst-plugins-good.spec
1247 )
1248
1249 dnl Create the config.h file for Visual Studio builds
1250 dnl Beware of spaces and /'s in some of the shell variable contents.
1251 sed \
1252     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1253     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1254     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1255     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1256     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1257     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1258     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1259     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1260     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1261     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1262     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1263     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1264     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1265     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1266     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1267     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1268     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1269     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1270     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1271     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1272     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1273     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1274     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1275     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1276     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1277     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1278     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1279     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1280     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1281     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1282     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1283     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1284     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1285     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1286     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1287     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1288     config.h.in >win32/common/config.h-new
1289
1290 AC_OUTPUT
1291
1292 AG_GST_OUTPUT_PLUGINS
1293 ORC_OUTPUT
1294