configure.ac

   1 AC_PREREQ(2.69)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer libav, 1.5.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-libav)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/libav/gstav.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output by default
  34 AM_SILENT_RULES([yes])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 AG_GST_LIBTOOL_PREPARE
  43 AS_LIBTOOL(GST, 501, 0, 501)
  44
  45 dnl *** required versions of GStreamer stuff ***
  46 GST_REQ=1.5.1
  47 GST_PBREQ=1.5.1
  48
  49 ORC_REQ=0.4.16
  50 ORC_CHECK([$ORC_REQ])
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl *** check for arguments to configure ***
  61
  62 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  63
  64 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  65 AG_GST_ARG_WITH_PACKAGE_NAME
  66 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  67 AG_GST_ARG_VALGRIND
  68 AG_GST_ARG_GCOV
  69
  70 dnl *** checks for platform ***
  71
  72 dnl * hardware/architecture *
  73
  74 dnl common/m4/gst-arch.m4
  75 dnl check CPU type
  76 AG_GST_ARCH
  77
  78 dnl *** checks for programs ***
  79
  80 dnl find a compiler
  81 AC_PROG_CC
  82 AC_PROG_CC_STDC
  83
  84 dnl check if the compiler supports '-c' and '-o' options
  85 AM_PROG_CC_C_O
  86
  87 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  88 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  89
  90 dnl check for documentation tools
  91 GTK_DOC_CHECK([1.12])
  92 AG_GST_PLUGIN_DOCS([1.12])
  93
  94 dnl *** checks for libraries ***
  95
  96 dnl check for libm, for sin()
  97 LT_LIB_M
  98 AC_SUBST(LIBM)
  99
 100 dnl *** checks for header files ***
 101
 102 dnl check if we have ANSI C header files
 103 AC_HEADER_STDC
 104
 105 dnl *** checks for types/defines ***
 106
 107 dnl *** checks for structures ***
 108
 109 dnl *** checks for compiler characteristics ***
 110
 111 dnl *** checks for library functions ***
 112
 113 dnl *** checks for dependancy libraries ***
 114
 115 dnl checks for gstreamer
 116 dnl uninstalled is selected preferentially -- see pkg-config(1)
 117 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ])
 118 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ])
 119 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_PBREQ])
 120 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 121 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 122
 123 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 124 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 125
 126 dnl *** set variables based on configure arguments ***
 127
 128 dnl set location of plugin directory
 129 AG_GST_SET_PLUGINDIR
 130
 131 dnl build static plugins or not
 132 AC_MSG_CHECKING([whether to build static plugins or not])
 133 AC_ARG_ENABLE(
 134   static-plugins,
 135   AC_HELP_STRING(
 136     [--enable-static-plugins],
 137     [build static plugins @<:@default=no@:>@]),
 138   [AS_CASE(
 139     [$enableval], [no], [], [yes], [],
 140     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 141   [enable_static_plugins=no])
 142 AC_MSG_RESULT([$enable_static_plugins])
 143 if test "x$enable_static_plugins" = xyes; then
 144   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 145     [Define if static plugins should be built])
 146   GST_PLUGIN_LIBTOOLFLAGS=""
 147 else
 148   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 149 fi
 150 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 151 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 152
 153 dnl define an ERROR_CFLAGS Makefile variable
 154 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 155     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 156     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 157     -Winit-self -Wmissing-include-dirs -Waddress
 158     -Waggregate-return -Wno-multichar -Wnested-externs ])
 159
 160 dnl define correct level for debugging messages
 161 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 162
 163 dnl *** finalize CFLAGS, LDFLAGS, LIBS ***
 164
 165 dnl Overview:
 166 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 167 dnl GST_*:              flags shared by built objects to link against GStreamer
 168 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 169 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 170 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 171 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 172
 173 dnl GST_OPTION_CFLAGS
 174 if test "x$USE_DEBUG" = xyes; then
 175    PROFILE_CFLAGS="-g"
 176 fi
 177 AC_SUBST(PROFILE_CFLAGS)
 178
 179 if test "x$GST_GIT" = "xyes"; then
 180   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 181 else
 182   DEPRECATED_CFLAGS=""
 183 fi
 184 AC_SUBST(DEPRECATED_CFLAGS)
 185
 186 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 187 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 188
 189 AC_SUBST(GST_OPTION_CFLAGS)
 190
 191 dnl FIXME: do we want to rename to GST_ALL_* ?
 192 dnl prefer internal headers to already installed ones
 193 dnl also add builddir include for enumtypes and marshal
 194 dnl add GST_OPTION_CFLAGS, but overridable
 195 GST_CFLAGS="$GST_CFLAGS"
 196 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 197 AC_SUBST(GST_CFLAGS)
 198 AC_SUBST(GST_LIBS)
 199
 200 GST_ALL_LDFLAGS="-no-undefined"
 201 AC_SUBST(GST_ALL_LDFLAGS)
 202
 203 dnl this really should only contain flags, not libs - they get added before
 204 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 205 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 206 AC_SUBST(GST_PLUGIN_LDFLAGS)
 207
 208 dnl Add MacOSX specific flags
 209 AC_CANONICAL_HOST
 210 case $host_os in
 211      darwin*)
 212         DARWIN_LDFLAGS="-Wl,-read_only_relocs,suppress"
 213         ;;
 214      *)
 215         DARWIN_LDFLAGS=""
 216         ;;
 217 esac
 218 AC_SUBST(DARWIN_LDFLAGS)
 219
 220 dnl *** Check for bz2
 221 save_LIBS=$LIBS
 222 LIBS="$LIBS -lbz2"
 223 AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 224 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 225 AC_MSG_RESULT($HAVE_BZ2)
 226 LIBS=$save_LIBS
 227 AM_CONDITIONAL(HAVE_BZ2, test "x$HAVE_BZ2" = "xyes")
 228 if test "x$HAVE_BZ2" = "xno"; then
 229   AC_WARN([libbz2 not found, matroska demuxer will not be able to read bz2 tracks])
 230 fi
 231
 232 AC_ARG_ENABLE(lgpl,
 233               [AC_HELP_STRING([--enable-lgpl], [build a LGPL licensed gst-libav])])
 234 AM_CONDITIONAL(GST_LIBAV_ENABLE_LGPL, test "x$enable_lgpl" = "xyes")
 235 if test "x$enable_lgpl" = "xyes"; then
 236   AC_DEFINE([GST_LIBAV_ENABLE_LGPL], [], [Defined if building a LGPL-only version of gst-libav])
 237 fi
 238
 239 dnl *** configure external libs ***
 240
 241 HAVE_LIBAV_UNINSTALLED=1
 242
 243 AC_ARG_WITH(system-libav,
 244             [AC_HELP_STRING([--with-system-libav], [use system Libav libraries])])
 245
 246 if test "x$with_system_libav" = "xyes"; then
 247   PKG_CHECK_MODULES(LIBAV, libavformat libavcodec libavresample libavutil)
 248   PKG_CHECK_MODULES(SWSCALE, libswscale libavutil)
 249   saved_CPPFLAGS="$CPPFLAGS"
 250   CPPFLAGS="$CPPFLAGS $LIBAV_CFLAGS"
 251   AC_CHECK_HEADERS([avi.h])
 252   CPPFLAGS="$saved_CPPFLAGS"
 253   AC_DEFINE([LIBAV_SOURCE], ["system install"], [Describes where the Libav libraries come from.])
 254   HAVE_LIBAV_UNINSTALLED=0
 255   AC_MSG_NOTICE([Using system-installed libav code])
 256 else
 257   AC_MSG_NOTICE([Using local Libav snapshot])
 258
 259   dnl libgstlibav.la: include dirs
 260   LIBAV_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 261                 -I \$(top_builddir)/gst-libs/ext/libav \
 262                  -Wno-deprecated-declarations"
 263
 264   LIBAV_DEPS="\$(top_builddir)/gst-libs/ext/libav/libavformat/libavformat.a \
 265               \$(top_builddir)/gst-libs/ext/libav/libavcodec/libavcodec.a \
 266               \$(top_builddir)/gst-libs/ext/libav/libavresample/libavresample.a \
 267               \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 268   if test "x$enable_static_plugins" = xyes; then
 269       dnl with static linking we can't use the .a archive directly as they would
 270       dnl be included in the final libgstlibav.a as a file and won't be usable.
 271       dnl libav*.a must be copied to the final destination too
 272       LIBAV_LIBS="-lavformat -lavcodec -lavresample -lavutil"
 273   else
 274       dnl libgstlibav.la: libs to statically link to
 275       LIBAV_LIBS="$LIBAV_DEPS"
 276   fi
 277
 278   dnl
 279   SWSCALE_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 280                   -I \$(top_builddir)/gst-libs/ext/libav \
 281                   -Wno-deprecated-declarations"
 282
 283   SWSCALE_DEPS="\$(top_builddir)/gst-libs/ext/libav/libswscale/libswscale.a \
 284                 \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 285   if test "x$enable_static_plugins" = xyes; then
 286       dnl with static linking we can't use the .a archive directly as they would
 287       dnl be included in the final libgstswscale.a as a file and won't be usable.
 288       dnl libav*.a must be copied to the final destination too
 289       SWSCALE_LIBS="-lswscale -lavutil"
 290   else
 291       dnl libgstswscale.la: libs to statically link to
 292       SWSCALE_LIBS="$SWSCALE_DEPS"
 293   fi
 294
 295   LIBAV_SUBDIRS=gst-libs
 296   AC_DEFINE(HAVE_AVI_H)
 297   AC_DEFINE([LIBAV_SOURCE], ["local snapshot"], [Describes where the Libav libraries come from.])
 298
 299   AC_ARG_WITH(libav-extra-configure,
 300       AC_HELP_STRING([--with-libav-extra-configure="xxx"],
 301       [extra configure options for internal libav ./configure script]),,
 302       with_libav=no)
 303
 304   # basic arguments
 305   emblibav_configure_args="--prefix=$prefix"
 306
 307   # Enable pic and static so that we get .a files, but with PIC code.
 308   emblibav_configure_args="$emblibav_configure_args --disable-avserver --disable-avplay\
 309         --disable-avconv --disable-avprobe --enable-static --enable-pic \
 310         --disable-encoder=flac --disable-protocols --disable-devices\
 311         --disable-network --disable-hwaccels --disable-dxva2 --disable-vdpau\
 312         --disable-filters --disable-doc --enable-optimizations"
 313
 314   if test "x$enable_lgpl" != "xyes"; then
 315     emblibav_configure_args="$emblibav_configure_args --enable-gpl"
 316   fi
 317
 318   # if we are cross-compiling, tell libav so
 319   case $host in
 320       *android*)
 321         target_os=linux
 322       ;;
 323       *darwin*)
 324         target_os=darwin
 325       ;;
 326       *)
 327         target_os=`echo $host_os | sed 's/-gnu//'`
 328       ;;
 329   esac
 330
 331   if test "x$cross_compiling" = xyes; then
 332     emblibav_configure_args="$emblibav_configure_args --enable-cross-compile \
 333         --target-os=$target_os --arch=$host_cpu --cross-prefix=$host_alias-"
 334   fi
 335
 336   case $host_os in
 337     mingw32*)
 338       emblibav_configure_args="$emblibav_configure_args --enable-memalign-hack"
 339       WIN32_LIBS="-lws2_32"
 340       ;;
 341     *)
 342       WIN32_LIBS=
 343       ;;
 344   esac
 345
 346   if test x"$AR" != x; then
 347     emblibav_configure_args="$emblibav_configure_args --ar=\\\"\\\$AR\\\""
 348   fi
 349
 350   if test x"$AS" != x; then
 351     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$CC\\\""
 352   fi
 353
 354   if test x"$CC" != x; then
 355     emblibav_configure_args="$emblibav_configure_args --cc=\\\"\\\$CC\\\""
 356   fi
 357
 358   if test x"$LD" != x; then
 359     emblibav_configure_args="$emblibav_configure_args --ld=\\\"\\\$CC\\\""
 360   fi
 361
 362   if test x"$NM" != x; then
 363     emblibav_configure_args="$emblibav_configure_args --nm=\\\"\\\$NM\\\""
 364   fi
 365
 366   dnl checks for extra enable/disable flags
 367   LIBAV_OPTS=`cd $srcdir/gst-libs/ext/libav && ./configure --help`
 368   # Let's check if we can disable the building of the libav binary
 369   can_disable=`echo "$LIBAV_OPTS" | grep 'disable-ffmpeg'`
 370   if test "$can_disable" != ""; then
 371     emblibav_configure_args="$emblibav_configure_args --disable-ffmpeg"
 372   fi
 373   dnl check if libswscale needs enabling explicitly
 374   can_enable=`echo "$LIBAV_OPTS" | grep 'enable-swscale'`
 375   if test "$can_enable" != ""; then
 376     emblibav_configure_args="$emblibav_configure_args --enable-swscale"
 377   fi
 378
 379   # append extra configure options to emblibav_configure_args if needed
 380   if test "x$with_libav_extra_configure" != "xno"; then
 381     emblibav_configure_args="$emblibav_configure_args $with_libav_extra_configure"
 382   fi
 383
 384   AC_SUBST(LIBAV_CO_DIR)
 385   AC_SUBST(LIBAV_SVN)
 386   AC_SUBST(LIBAV_REVISION)
 387   AC_SUBST(LIBAV_EXTERNALS_REVISION)
 388   AC_CONFIG_COMMANDS([configure-embedded-libav],
 389     [echo "Configuring included Libav instance with args $emblibav_configure_args"
 390      origdir=`pwd`
 391      dnl Don't put path on the configure call when not needed, as FFmpeg's configure relies on it
 392      dnl to detect out-of-tree builds
 393      if test -z "$srcdir" -o "$srcdir" = .; then
 394        confcmd=./configure
 395      else
 396        confcmd="$ac_abs_top_srcdir"/gst-libs/ext/libav/configure
 397      fi
 398
 399      AS_MKDIR_P(["$ac_top_build_prefix"gst-libs/ext/libav])
 400      cd "$ac_top_build_prefix"gst-libs/ext/libav &&
 401          eval "$confcmd $emblibav_configure_args" ||
 402          AC_MSG_ERROR([Failed to configure embedded Libav tree])
 403      cd "$origdir"
 404     ],
 405     [emblibav_configure_args="$emblibav_configure_args"])
 406   AC_MSG_NOTICE([Using included Libav code])
 407 fi
 408
 409 AC_SUBST(LIBAV_CFLAGS)
 410 AC_SUBST(LIBAV_DEPS)
 411 AC_SUBST(LIBAV_LIBS)
 412 AC_SUBST(LIBAV_SUBDIRS)
 413 AC_SUBST(SWSCALE_CFLAGS)
 414 AC_SUBST(SWSCALE_DEPS)
 415 AC_SUBST(SWSCALE_LIBS)
 416 AC_SUBST(WIN32_LIBS)
 417
 418 if test x$HAVE_LIBAV_UNINSTALLED = x1; then
 419   AC_DEFINE(HAVE_LIBAV_UNINSTALLED, [], [Defined if building against uninstalled Libav source])
 420 fi
 421 AM_CONDITIONAL(HAVE_LIBAV_UNINSTALLED, test x$HAVE_LIBAV_UNINSTALLED = x1)
 422
 423 AC_CONFIG_FILES(
 424 Makefile
 425 common/Makefile
 426 common/m4/Makefile
 427 gst-libav.spec
 428 ext/Makefile
 429 ext/libav/Makefile
 430 ext/libswscale/Makefile
 431 gst-libs/Makefile
 432 gst-libs/ext/Makefile
 433 docs/Makefile
 434 docs/plugins/Makefile
 435 docs/version.entities
 436 tests/Makefile
 437 tests/check/Makefile
 438 tests/files/Makefile
 439 pkgconfig/Makefile
 440 pkgconfig/gstreamer-plugins-libav-uninstalled.pc
 441 )
 442 AC_OUTPUT
 443
 444 ORC_OUTPUT