configure.ac

   1 dnl These m4 macros are whitespace sensitive and break if moved around much.
   2 m4_define([LU_VERSION_H], m4_include([libusb/version.h]))
   3 m4_define([LU_DEFINE_VERSION_ATOM],
   4         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   5         [^#define\s*$1\s*\([0-9]*\).*], [\1]))])
   6 m4_define([LU_DEFINE_VERSION_RC_ATOM],
   7         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   8         [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))])
   9 dnl The m4_bregexp() returns (only) the numbers following the #define named
  10 dnl in the first macro parameter. m4_define() then defines the name for use
  11 dnl in AC_INIT.
  12
  13 LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR])
  14 LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR])
  15 LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO])
  16 LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC])
  17
  18 AC_INIT([libusbx],[LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC],[libusbx-devel@lists.sourceforge.net],[libusbx],[http://libusbx.org])
  19
  20 # Library versioning
  21 # These numbers should be tweaked on every release. Read carefully:
  22 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  23 # http://sourceware.org/autobook/autobook/autobook_91.html
  24 lt_current="1"
  25 lt_revision="0"
  26 lt_age="1"
  27 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_CONFIG_SRCDIR([libusb/core.c])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AC_CONFIG_HEADERS([config.h])
  35 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  36
  37 AC_PREREQ([2.50])
  38 AC_PROG_CC
  39 LT_INIT
  40 LT_LANG([Windows Resource])
  41 AC_C_INLINE
  42 AM_PROG_CC_C_O
  43 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  44
  45 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  46
  47 AC_MSG_CHECKING([operating system])
  48
  49 case $host in
  50 *-linux*)
  51         AC_MSG_RESULT([Linux])
  52         backend="linux"
  53         threads="posix"
  54         ;;
  55 *-darwin*)
  56         AC_MSG_RESULT([Darwin/Mac OS X])
  57         backend="darwin"
  58         threads="posix"
  59         ;;
  60 *-openbsd*)
  61         AC_MSG_RESULT([OpenBSD])
  62         backend="bsd"
  63         threads="posix"
  64         ;;
  65 *-netbsd*)
  66         AC_MSG_RESULT([NetBSD (using OpenBSD backend)])
  67         backend="bsd"
  68         threads="posix"
  69         ;;
  70 *-mingw*)
  71         AC_MSG_RESULT([Windows])
  72         backend="windows"
  73         threads="windows"
  74         create_import_lib="yes"
  75         AM_CFLAGS="${AM_CFLAGS} -fno-omit-frame-pointer"
  76         ;;
  77 *-cygwin*)
  78         AC_MSG_RESULT([Cygwin (using Windows backend)])
  79         backend="windows"
  80         threads="posix"
  81         ;;
  82 *)
  83         AC_MSG_ERROR([unsupported operating system])
  84 esac
  85
  86 case $backend in
  87 linux)
  88         AC_DEFINE(OS_LINUX, 1, [Linux backend])
  89         AC_SUBST(OS_LINUX)
  90         AC_SEARCH_LIBS(clock_gettime, rt, [], [], -pthread)
  91         AC_ARG_ENABLE([udev],
  92                 [AC_HELP_STRING([--enable-udev], [use udev for device enumeration and hotplug support (recommended, default: yes)])],
  93                 [], [enable_udev="yes"])
  94                 if test "x$enable_udev" = "xyes" ; then
  95                         # system has udev. use it or fail!
  96                         AC_CHECK_HEADERS([libudev.h],[],[AC_ERROR(["udev support requested but libudev not installed"])])
  97                         AC_CHECK_LIB([udev], [udev_new], [], [AC_ERROR(["udev support requested but libudev not installed"])])
  98                         AC_DEFINE(USE_UDEV, 1, [Use udev for device enumeration/hotplug])
  99                 else
 100                         AC_CHECK_HEADERS([asm/types.h sys/socket.h], [], [])
 101                         AC_CHECK_HEADERS([linux/netlink.h linux/filter.h], [], [AC_ERROR(["Linux netlink headers not found"])], [
 102 #ifdef HAVE_ASM_TYPES_H
 103 #include <asm/types.h>
 104 #endif
 105 #ifdef HAVE_SYS_SOCKET_H
 106 #include <sys/socket.h>
 107 #endif
 108 ])
 109                 fi
 110                 AC_SUBST(USE_UDEV)
 111         THREAD_CFLAGS="-pthread"
 112         LIBS="${LIBS} -pthread"
 113         AC_CHECK_HEADERS([poll.h])
 114         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 115         ;;
 116 darwin)
 117         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
 118         AC_SUBST(OS_DARWIN)
 119         LIBS="-lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
 120         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
 121         AC_CHECK_HEADERS([poll.h])
 122         AC_CHECK_TYPE([nfds_t],
 123                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
 124                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
 125                 [#include <poll.h>])
 126         ;;
 127 bsd)
 128         AC_DEFINE(OS_OPENBSD, 1, [OpenBSD/NetBSD backend])
 129         AC_SUBST(OS_OPENBSD)
 130         THREAD_CFLAGS="-pthread"
 131         LIBS="-pthread"
 132         AC_CHECK_HEADERS([poll.h])
 133         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 134         ;;
 135 windows)
 136         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
 137         AC_SUBST(OS_WINDOWS)
 138         LIBS=""
 139         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
 140         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
 141         ;;
 142 esac
 143
 144 AC_SUBST(LIBS)
 145
 146 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
 147 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
 148 AM_CONDITIONAL(OS_OPENBSD, test "x$backend" = xbsd)
 149 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
 150 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
 151 AM_CONDITIONAL(CREATE_IMPORT_LIB, test "x$create_import_lib" = "xyes")
 152 AM_CONDITIONAL(USE_UDEV, test "x$enable_udev" = xyes)
 153 if test "$threads" = posix; then
 154         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
 155 fi
 156
 157 # timerfd
 158 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 159 AC_ARG_ENABLE([timerfd],
 160         [AS_HELP_STRING([--enable-timerfd],
 161                 [use timerfd for timing (default auto)])],
 162         [use_timerfd=$enableval], [use_timerfd='auto'])
 163
 164 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 165         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 166 fi
 167
 168 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 169 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 170         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 171 fi
 172
 173 AC_MSG_CHECKING([whether to use timerfd for timing])
 174 if test "x$use_timerfd" = "xno"; then
 175         AC_MSG_RESULT([no (disabled by user)])
 176 else
 177         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 178                 AC_MSG_RESULT([yes])
 179                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 180         else
 181                 AC_MSG_RESULT([no (header not available)])
 182         fi
 183 fi
 184
 185 AC_CHECK_TYPES(struct timespec)
 186
 187 # Message logging
 188 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 189         [log_enabled=$enableval],
 190         [log_enabled='yes'])
 191 if test "x$log_enabled" != "xno"; then
 192         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 193 fi
 194
 195 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 196         [start with debug message logging enabled (default n)])],
 197         [debug_log_enabled=$enableval],
 198         [debug_log_enabled='no'])
 199 if test "x$debug_log_enabled" != "xno"; then
 200         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Start with debug message logging enabled])
 201 fi
 202
 203 # Examples build
 204 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 205         [build example applications (default n)])],
 206         [build_examples=$enableval],
 207         [build_examples='no'])
 208 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 209
 210 # Tests build
 211 AC_ARG_ENABLE([tests-build], [AS_HELP_STRING([--enable-tests-build],
 212         [build test applications (default n)])],
 213         [build_tests=$enableval],
 214         [build_tests='no'])
 215 AM_CONDITIONAL([BUILD_TESTS], [test "x$build_tests" != "xno"])
 216
 217 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 218 saved_cflags="$CFLAGS"
 219 # -Werror required for cygwin
 220 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 221 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 222         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 223          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 224         [ VISIBILITY_CFLAGS=""
 225          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 226         ])
 227 CFLAGS="$saved_cflags"
 228
 229 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 230 saved_cflags="$CFLAGS"
 231 CFLAGS="$CFLAGS -Wno-pointer-sign"
 232 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 233         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 234 CFLAGS="$saved_cflags"
 235
 236 # sigaction not available on MinGW
 237 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 238 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 239
 240 # headers not available on all platforms but required on others
 241 AC_CHECK_HEADERS([sys/time.h])
 242 AC_CHECK_FUNCS(gettimeofday)
 243 AC_CHECK_HEADERS([signal.h])
 244
 245 AM_CFLAGS="${AM_CFLAGS} -std=gnu99 -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow ${THREAD_CFLAGS} ${VISIBILITY_CFLAGS}"
 246
 247 AC_SUBST(AM_CFLAGS)
 248 AC_SUBST(LTLDFLAGS)
 249
 250 AC_CONFIG_FILES([libusb-1.0.pc])
 251 AC_CONFIG_FILES([Makefile])
 252 AC_CONFIG_FILES([libusb/Makefile])
 253 AC_CONFIG_FILES([examples/Makefile])
 254 AC_CONFIG_FILES([tests/Makefile])
 255 AC_CONFIG_FILES([doc/Makefile])
 256 AC_CONFIG_FILES([doc/doxygen.cfg])
 257 AC_OUTPUT