configure.ac

   1 AC_PREREQ([2.64])
   2
   3 m4_define([libinput_major_version], [0])
   4 m4_define([libinput_minor_version], [3])
   5 m4_define([libinput_micro_version], [0])
   6 m4_define([libinput_version],
   7           [libinput_major_version.libinput_minor_version.libinput_micro_version])
   8
   9 AC_INIT([libinput],
  10         [libinput_version],
  11         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=libinput&version=libinput_version],
  12         [libinput],
  13         [http://www.freedesktop.org/wiki/Software/libinput/])
  14
  15 AC_SUBST([LIBINPUT_VERSION_MAJOR], [libinput_major_version])
  16 AC_SUBST([LIBINPUT_VERSION_MINOR], [libinput_minor_version])
  17 AC_SUBST([LIBINPUT_VERSION_MICRO], [libinput_micro_version])
  18 AC_SUBST([LIBINPUT_VERSION], [libinput_version])
  19
  20 AC_CONFIG_HEADERS([config.h])
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz])
  24
  25 # Before making a release, the LIBINPUT_LT_VERSION string should be
  26 # modified.
  27 # The string is of the form C:R:A.
  28 # - If interfaces have been changed or added, but binary compatibility has
  29 #   been preserved, change to C+1:0:A+1
  30 # - If binary compatibility has been broken (eg removed or changed interfaces)
  31 #   change to C+1:0:0
  32 # - If the interface is the same as the previous version, change to C:R+1:A
  33 LIBINPUT_LT_VERSION=2:0:0
  34 AC_SUBST(LIBINPUT_LT_VERSION)
  35
  36 AM_SILENT_RULES([yes])
  37
  38 # Check for programs
  39 AC_PROG_CC_C99
  40 AC_PROG_CXX # Only used by build C++ test
  41
  42 # Initialize libtool
  43 LT_PREREQ([2.2])
  44 LT_INIT
  45
  46 AC_CHECK_DECL(EPOLL_CLOEXEC, [],
  47               [AC_MSG_ERROR("EPOLL_CLOEXEC is needed to compile libinput")],
  48               [[#include <sys/epoll.h>]])
  49 AC_CHECK_DECL(TFD_CLOEXEC,[],
  50               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile libinput")],
  51               [[#include <sys/timerfd.h>]])
  52 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
  53               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile libinput")],
  54               [[#include <time.h>]])
  55
  56 PKG_PROG_PKG_CONFIG()
  57 PKG_CHECK_MODULES(MTDEV, [mtdev >= 1.1.0])
  58 PKG_CHECK_MODULES(LIBUDEV, [libudev])
  59 PKG_CHECK_MODULES(LIBEVDEV, [libevdev >= 0.4])
  60
  61 if test "x$GCC" = "xyes"; then
  62         GCC_CXXFLAGS="-Wall -Wextra -Wno-unused-parameter -g -fvisibility=hidden"
  63         GCC_CFLAGS="$GCC_CXXFLAGS -Wmissing-prototypes -Wstrict-prototypes"
  64 fi
  65 AC_SUBST(GCC_CFLAGS)
  66 AC_SUBST(GCC_CXXFLAGS)
  67
  68 AC_PATH_PROG(DOXYGEN, [doxygen])
  69 if test "x$DOXYGEN" = "x"; then
  70         AC_MSG_WARN([doxygen not found - required for documentation])
  71         have_doxygen="no"
  72 else
  73         have_doxygen="yes"
  74 fi
  75 AM_CONDITIONAL([HAVE_DOXYGEN], [test "x$have_doxygen" = "xyes"])
  76
  77 AC_ARG_ENABLE(event-gui,
  78               AS_HELP_STRING([--enable-event-gui], [Build the GUI event viewer (default=auto)]),
  79               [build_eventgui="$enableval"],
  80               [build_eventgui="auto"])
  81 PKG_CHECK_EXISTS([cairo glib-2.0 gtk+-3.0], [HAVE_GUILIBS="yes"], [HAVE_GUILIBS="no"])
  82
  83 if test "x$build_eventgui" = "xauto"; then
  84         build_eventgui="$HAVE_GUILIBS"
  85 fi
  86 if test "x$build_eventgui" = "xyes"; then
  87         PKG_CHECK_MODULES(CAIRO, [cairo])
  88         PKG_CHECK_MODULES(GTK, [glib-2.0 gtk+-3.0])
  89 fi
  90 AM_CONDITIONAL(BUILD_EVENTGUI, [test "x$build_eventgui" = "xyes"])
  91
  92 AC_ARG_ENABLE(tests,
  93               AS_HELP_STRING([--enable-tests], [Build the tests (default=auto)]),
  94               [build_tests="$enableval"],
  95               [build_tests="auto"])
  96
  97 PKG_CHECK_MODULES(CHECK, [check >= 0.9.9], [HAVE_CHECK="yes"], [HAVE_CHECK="no"])
  98
  99 if test "x$build_tests" = "xauto"; then
 100         build_tests="$HAVE_CHECK"
 101 fi
 102 if test "x$build_tests" = "xyes"; then
 103         if test "x$HAVE_CHECK" = "xno"; then
 104                 AC_MSG_ERROR([Cannot build tests, check is missing])
 105         fi
 106
 107         AC_PATH_PROG(VALGRIND, [valgrind])
 108 fi
 109
 110 AM_CONDITIONAL(HAVE_VALGRIND, [test "x$VALGRIND" != "x"])
 111 AM_CONDITIONAL(BUILD_TESTS, [test "x$build_tests" = "xyes"])
 112
 113 AC_CONFIG_FILES([Makefile
 114                  doc/Makefile
 115                  doc/libinput.doxygen
 116                  src/Makefile
 117                  src/libinput.pc
 118                  src/libinput-version.h
 119                  test/Makefile
 120                  tools/Makefile])
 121 AC_OUTPUT