configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [1])
   5 m4_define([v_mic], [99])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39 AC_SYS_LARGEFILE
  40
  41 AC_LIBTOOL_WIN32_DLL
  42 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  43 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  44 AC_PROG_LIBTOOL
  45
  46 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  47 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  48 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  49 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  50 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  51 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  52 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  53 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  54 version_info="lt_cur:lt_rev:lt_age"
  55 release_info="v_rel"
  56 AC_SUBST(version_info)
  57 AC_SUBST(release_info)
  58 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  59 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  60 VMAJ=v_maj
  61 AC_SUBST(VMAJ)
  62
  63
  64 ### Needed information
  65
  66 AC_CANONICAL_BUILD
  67 AC_CANONICAL_HOST
  68
  69 requirement_eina=""
  70
  71 case "$host_os" in
  72    mingw32ce*)
  73       MODULE_ARCH="$host_os-$host_cpu"
  74       ;;
  75    *)
  76       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  77       ;;
  78 esac
  79 AC_SUBST(MODULE_ARCH)
  80 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  81
  82 case "$host_os" in
  83    mingw*)
  84       MODULE_EXT=".dll"
  85       ;;
  86    *)
  87       MODULE_EXT=".so"
  88       ;;
  89 esac
  90
  91 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  92
  93 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  94 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  95 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  96 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  97
  98 EFL_CHECK_THREADS(
  99    [
 100     if test "x${_efl_have_posix_threads}" = "xyes" ; then
 101        have_threads="POSIX"
 102     else
 103        if test "x${_efl_have_win32_threads}" = "xyes" ; then
 104           have_threads="Win32"
 105        else
 106           have_threads="no"
 107        fi
 108     fi
 109    ],
 110    [have_threads="no"])
 111 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 112
 113 if ! test "x${have_threads}" = "xno" ; then
 114    EINA_CONFIGURE_HAVE_THREADS="#define EINA_HAVE_THREADS"
 115 fi
 116 AC_SUBST(EINA_CONFIGURE_HAVE_THREADS)
 117 AM_CONDITIONAL([EINA_HAVE_THREADS], [! test "x${have_threads}" = "xno"])
 118
 119 if ! test "x${have_debug_threads}" = "xno"; then
 120    EINA_CONFIGURE_HAVE_DEBUG_THREADS="#define EINA_HAVE_DEBUG_THREADS"
 121 fi
 122 AC_SUBST(EINA_CONFIGURE_HAVE_DEBUG_THREADS)
 123 AM_CONDITIONAL([EINA_DEBUG_THREADS], [! test "x${have_debug_threads}" = "xno"])
 124
 125 if ! test "x${have_on_off_threads}" = "xno"; then
 126    EINA_CONFIGURE_HAVE_ON_OFF_THREADS="#define EINA_HAVE_ON_OFF_THREADS"
 127 fi
 128 AC_SUBST(EINA_CONFIGURE_HAVE_ON_OFF_THREADS)
 129 AM_CONDITIONAL([EINA_ON_OFF_THREADS], [! test "x${have_on_off_threads}" = "xno"])
 130
 131 ### Additional options to configure
 132
 133 # Magic debug
 134 AC_ARG_ENABLE([magic-debug],
 135    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 136    [
 137     if test "x${enableval}" = "xyes" ; then
 138        have_magic_debug="yes"
 139     else
 140        have_magic_debug="no"
 141     fi
 142    ],
 143    [have_magic_debug="yes"])
 144
 145 AC_MSG_CHECKING([whether magic debug is enable])
 146 AC_MSG_RESULT([${have_magic_debug}])
 147
 148 if test "x${have_magic_debug}" = "xyes" ; then
 149    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 150 fi
 151 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 152
 153 # Safety checks (avoid crashes on wrong api usage)
 154 AC_ARG_ENABLE(safety-checks,
 155    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 156    [
 157     if test "x${enableval}" = "xyes" ; then
 158        have_safety_checks="yes"
 159     else
 160        have_safety_checks="no"
 161     fi
 162    ],
 163    [have_safety_checks="yes"])
 164
 165 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 166 AC_MSG_RESULT($have_safety_checks)
 167
 168 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 169 if test "x$have_safety_checks" = "xyes"; then
 170   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 171   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 172 fi
 173 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 174
 175 with_max_log_level="<unset>"
 176 AC_ARG_WITH(internal-maximum-log-level,
 177    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 178                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 179    [
 180     if test "x${withval}" != "xno"; then
 181        if echo "${withval}" | grep -E '^[[0-9]]+$' >/dev/null 2>/dev/null; then
 182           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 183           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 184           with_max_log_level="${withval}"
 185        else
 186           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 187        fi
 188     fi
 189     ], [:])
 190
 191 AC_ARG_ENABLE([amalgamation],
 192    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 193    [if test "x${enableval}" = "xyes"; then
 194        do_amalgamation="yes"
 195     else
 196        do_amalgamation="no"
 197     fi
 198    ],
 199    [do_amalgamation="no"]
 200 )
 201 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 202
 203 # Choose best memory pool
 204 AC_ARG_ENABLE([default-mempool],
 205    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 206    [
 207     if test "x${enableval}" = "xyes"; then
 208        have_default_mempool="yes"
 209     else
 210        have_default_mempool="no"
 211     fi
 212    ],
 213    [have_default_mempool="no"]
 214 )
 215 AC_MSG_CHECKING([whether to use default mempool allocator])
 216 AC_MSG_RESULT([${have_default_mempool}])
 217
 218 if test "x${have_default_mempool}" = "xyes" ; then
 219    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 220 fi
 221 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 222
 223 # Report stringshare usage
 224 AC_ARG_ENABLE([stringshare-usage],
 225    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 226    [
 227     if test "x${enableval}" = "xyes"; then
 228        have_stringshare_usage="yes"
 229     else
 230        have_stringshare_usage="no"
 231     fi
 232    ],
 233    [have_stringshare_usage="no"]
 234 )
 235 AC_MSG_CHECKING([whether to report stringshare usage])
 236 AC_MSG_RESULT([${have_stringshare_usage}])
 237
 238 if test "x${have_stringshare_usage}" = "xyes"; then
 239    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 240 fi
 241
 242 # Check if we want to benchmark on real data
 243 enable_benchmark_e17="no"
 244 AC_ARG_ENABLE([e17],
 245    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 246    [
 247     if test "x${enableval}" = "xyes" ; then
 248        enable_benchmark_e17="yes"
 249     else
 250        enable_benchmark_e17="no"
 251     fi
 252    ],
 253    [enable_benchmark_e17="no"])
 254
 255 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 256 AC_MSG_RESULT([${enable_benchmark_e17}])
 257
 258 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 259
 260
 261 ### Checks for programs
 262 AC_PROG_CC
 263 AC_PROG_CXX
 264
 265 # pkg-config
 266 PKG_PROG_PKG_CONFIG
 267
 268 # Check whether pkg-config supports Requires.private
 269 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 270    pkgconfig_requires_private="Requires.private"
 271 else
 272    pkgconfig_requires_private="Requires"
 273 fi
 274 AC_SUBST(pkgconfig_requires_private)
 275
 276 # doxygen program for documentation building
 277
 278 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 279
 280
 281 ### Checks for libraries
 282
 283 # Valgrind
 284 want_valgrind="auto"
 285 have_valgrind="no"
 286
 287 AC_ARG_ENABLE([valgrind],
 288   [AC_HELP_STRING([--enable-valgrind], [improve valgrind support by hinting it of our memory usages, having it to report proper mempool leaks.])],
 289   [want_valgrind=$enableval])
 290
 291 AC_MSG_CHECKING([whether to enable build with valgrind])
 292 AC_MSG_RESULT([${want_valgrind}])
 293
 294 if test "x${want_valgrind}" = "xyes" || test "x${want_valgrind}" = "xauto"; then
 295    PKG_CHECK_MODULES([VALGRIND],
 296       [valgrind >= 2.4.0],
 297       [
 298        requirement_eina="valgrind ${requirement_eina}"
 299        have_valgrind="yes"
 300       ],
 301       [
 302        AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 303        if test "x${want_valgrind}" = "xyes"; then
 304           AC_MSG_ERROR([Valgrind >= 2.4.0 is required])
 305        fi
 306       ])
 307 else
 308     AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 309 fi
 310
 311
 312 # Evil library for compilation on Windows CE
 313
 314 EFL_EINA_BUILD=""
 315 case "$host_os" in
 316    mingw*)
 317       PKG_CHECK_MODULES([EVIL], [evil >= 1.0.0])
 318       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if evil package is installed])
 319       requirement_eina="${requirement_eina} evil"
 320       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 321    ;;
 322 esac
 323 AC_SUBST([EFL_EINA_BUILD])
 324
 325 # Check ememoa memory pool library
 326
 327 AC_ARG_ENABLE([ememoa],
 328    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 329    [
 330     if test "x${enableval}" = "xyes" ; then
 331        enable_ememoa="yes"
 332     else
 333        enable_ememoa="no"
 334     fi
 335    ],
 336    [enable_ememoa="yes"])
 337
 338 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 339 AC_MSG_RESULT([$enable_ememoa])
 340
 341 if test "x${enable_ememoa}" = "xyes" ; then
 342    PKG_CHECK_MODULES([EMEMOA],
 343       [ememoa >= 0.0.26 ],
 344       [enable_ememoa="yes"],
 345       [enable_ememoa="no"])
 346 fi
 347
 348 PKG_CHECK_MODULES([ECORE_EVAS],
 349    [ecore-evas ecore evas],
 350    [build_tiler_example="yes"],
 351    [build_tiler_example="no"])
 352
 353 AM_CONDITIONAL([BUILD_TILER_EXAMPLE], [test "x${build_tiler_example}" = "xyes"])
 354
 355 ### Checks for compiler characteristics
 356 AC_C_CONST
 357 AC_C_BIGENDIAN
 358 AC_C_INLINE
 359 AC_PROG_CC_STDC
 360 EFL_ATTRIBUTE_UNUSED
 361
 362 have_wince="no"
 363 have_win32="no"
 364 EINA_CFLAGS=""
 365 case "$host_os" in
 366    mingw32ce*)
 367       EINA_CFLAGS="${EVIL_CFLAGS}"
 368       have_win32="yes"
 369       have_wince="yes"
 370       ;;
 371    mingw*)
 372       EINA_CFLAGS="${EVIL_CFLAGS}"
 373       have_win32="yes"
 374       ;;
 375 esac
 376 AM_CONDITIONAL([EINA_HAVE_WINCE], [test "x$have_wince" = "xyes"])
 377 AM_CONDITIONAL([EINA_HAVE_WIN32], [test "x$have_win32" = "xyes"])
 378
 379 m4_ifdef([v_mic],
 380    [
 381     EFL_COMPILER_FLAG([-Wall])
 382     EFL_COMPILER_FLAG([-W])
 383    ])
 384
 385 EFL_COMPILER_FLAG([-Wshadow])
 386
 387 case "$host_vendor" in
 388   ps3*)
 389       PKG_CHECK_MODULES([ESCAPE], [escape])
 390       AC_DEFINE(HAVE_ESCAPE, 1, [Set to 1 if Escape package is installed])
 391       requirement_eina="${requirement_eina} escape"
 392       EINA_CFLAGS="${ESCAPE_CFLAGS} ${EINA_CFLAGS}"
 393     ;;
 394 esac
 395
 396 AC_SUBST([EINA_CFLAGS])
 397
 398
 399 ### Checks for linker characteristics
 400 EINA_LIBS=
 401 lt_enable_auto_import=""
 402 case "${host_os}" in
 403    mingw*)
 404       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 405       lt_enable_auto_import="-Wl,--enable-auto-import"
 406    ;;
 407    dragonfly*|openbsd*)
 408       EINA_LIBS="-lm"
 409    ;;
 410    freebsd*|netbsd*)
 411       EINA_LIBS="-lrt -lm"
 412    ;;
 413    darwin*)
 414       EINA_LIBS="-lm"
 415    ;;
 416    cygwin*)
 417       EINA_LIBS="-ldl -lm"
 418    ;;
 419    *)
 420       EINA_LIBS="-ldl -lrt -lm"
 421    ;;
 422 esac
 423 case "$host_vendor" in
 424   ps3*)
 425       # Escape had already been checked to exist
 426       EINA_LIBS="${ESCAPE_LIBS}"
 427     ;;
 428 esac
 429 AC_SUBST([EINA_LIBS])
 430 AC_SUBST([lt_enable_auto_import])
 431
 432 EFL_LINKER_FLAG([-fno-strict-aliasing])
 433
 434 CFLAGS="${CFLAGS} ${EINA_CFLAGS}"
 435 LDFLAGS="${LDFLAGS} ${EINA_LDFLAGS}"
 436 LIBS="${LIBS} ${EINA_LIBS}"
 437
 438 ### Checks for header files
 439 AC_HEADER_ASSERT
 440 AC_HEADER_TIME
 441 EFL_CHECK_PATH_MAX
 442 AC_CHECK_HEADERS([unistd.h libgen.h inttypes.h stdint.h sys/types.h siginfo.h strings.h sys/mman.h])
 443
 444 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 445    EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"
 446    AC_DEFINE([HAVE_INTTYPES_H], [1], [Define to 1 if you have the <inttypes.h> header file.])
 447 fi
 448 AC_SUBST([EINA_CONFIGURE_HAVE_INTTYPES_H])
 449
 450 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 451     EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"
 452     AC_DEFINE([HAVE_STDINT_H], [1], [Define to 1 if you have the <stdint.h> header file.])
 453 fi
 454 AC_SUBST([EINA_CONFIGURE_HAVE_STDINT_H])
 455
 456 ### Checks for types
 457
 458 AC_CHECK_SIZEOF([wchar_t])
 459 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 460 AC_SUBST([EINA_SIZEOF_WCHAR_T])
 461 AC_CHECK_TYPES([siginfo_t], [], [],
 462    [[#include <signal.h>
 463      #if HAVE_SIGINFO_H
 464      # include <siginfo.h>
 465      #endif
 466    ]])
 467
 468 ### Check if dirent.h is usable
 469
 470 AC_CHECK_TYPES([struct dirent], [have_dirent="yes"], [have_dirent="no"],
 471    [[#include <dirent.h>
 472    ]])
 473
 474 if test "x${have_dirent}" = "xyes" ; then
 475     EINA_CONFIGURE_HAVE_DIRENT_H="#define EINA_HAVE_DIRENT_H"
 476     AC_DEFINE([HAVE_DIRENT_H], [1], [Define to 1 if you have a valid <dirent.h> header file.])
 477 fi
 478 AC_SUBST([EINA_CONFIGURE_HAVE_DIRENT_H])
 479
 480 ### Checks for library functions
 481 AC_ISC_POSIX
 482 AC_FUNC_ALLOCA
 483 AC_CHECK_FUNCS([strlcpy openat fstatat fpathconf execvp backtrace backtrace_symbols])
 484
 485 AC_CHECK_HEADERS([execinfo.h], [AC_DEFINE([HAVE_EXECINFO_H], [1], [Have execinfo.h])])
 486
 487 AC_MSG_CHECKING([for dirfd])
 488 AC_LINK_IFELSE(
 489    [
 490     AC_LANG_PROGRAM(
 491        [[
 492 #include <dirent.h>
 493        ]],
 494        [[
 495 int main(void)
 496 {
 497   DIR *dirp;
 498   return dirfd(dirp);
 499 }
 500        ]])
 501    ],
 502    [have_dirfd="yes"],
 503    [have_dirfd="no"])
 504
 505 AC_MSG_RESULT([${have_dirfd}])
 506
 507 if test "x${have_dirfd}" = "xyes" ; then
 508    AC_DEFINE([HAVE_DIRFD], [1], [ Define to 1 if you have the `dirfd' function or macro.])
 509 fi
 510
 511 # check debug information for malloc
 512 AC_CHECK_FUNCS([malloc_usable_size], [malloc_true_size="yes"], [malloc_true_size="no"])
 513 if test "x${malloc_true_size}" = "xyes" ; then
 514    AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [We will be able to know the exact amount of wasted memory])
 515 fi
 516
 517 want_debug_malloc="no"
 518 AC_ARG_ENABLE([debug-malloc],
 519    [AC_HELP_STRING([--enable-debug-malloc], [enable debugging of malloc usage overhead in our allocator @<:@default=enabled@:>@])],
 520    [
 521      if test "x${enableval}" = "xyes" ; then
 522         want_debug_malloc="yes"
 523      else
 524         want_debug_malloc="no"
 525      fi
 526    ], [want_debug_malloc="no"])
 527
 528 if test "x${malloc_true_size}" = "xyes" -a "x${want_debug_malloc}" = "xyes"; then
 529    AC_DEFINE([EINA_DEBUG_MALLOC], [1], [Turn on debugging overhead in mempool])
 530 fi
 531
 532 # dlopen and dladdr
 533 dlopen_libs=""
 534 case "$host_os" in
 535    mingw*)
 536 # managed by evil
 537       AC_DEFINE([HAVE_DLADDR])
 538       AC_DEFINE([HAVE_DLOPEN])
 539       ;;
 540    *)
 541       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 542       if test "x${res}" = "xyes" ; then
 543          AC_CHECK_FUNCS([dladdr], [AC_DEFINE([HAVE_DLADDR])])
 544          AC_DEFINE([HAVE_DLOPEN])
 545       else
 546          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 547          if test "x${res}" = "xyes" ; then
 548             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE([HAVE_DLADDR])])
 549             AC_DEFINE(HAVE_DLOPEN)
 550             dlopen_libs="-ldl"
 551          fi
 552       fi
 553       ;;
 554 esac
 555 AC_SUBST([dlopen_libs])
 556
 557 have_log="yes"
 558 EFL_CHECK_FNMATCH([have_log="yes"], [have_log="no"])
 559
 560 want_log="yes"
 561 AC_ARG_ENABLE([log],
 562    [AC_HELP_STRING([--disable-log], [disable Eina_Log infrastructure completly @<:@default=enabled@:>@])],
 563    [
 564     if test "x${enableval}" = "xyes" ; then
 565        want_log="yes"
 566     else
 567        want_log="no"
 568     fi
 569    ],
 570    [want_log="yes"])
 571
 572 enable_log="no"
 573 if test "x${have_log}" = xyes -a "x${want_log}" = xyes; then
 574    enable_log="yes"
 575 fi
 576
 577 AC_MSG_CHECKING([wether to build Eina_Log infrastructure])
 578 AC_MSG_RESULT([${enable_log}])
 579
 580 if test "x${enable_log}" = "xyes"; then
 581     EINA_CONFIGURE_ENABLE_LOG="#define EINA_ENABLE_LOG"
 582     AC_DEFINE([HAVE_LOG], [1], [Define to 1 if we log support is on])
 583 fi
 584 AC_SUBST([EINA_CONFIGURE_ENABLE_LOG])
 585
 586 AC_CHECK_HEADERS([mcheck.h], [AC_DEFINE([HAVE_MCHECK], [1], [Have mcheck.h])])
 587 AC_CHECK_FUNCS([mtrace], [AC_DEFINE([HAVE_MTRACE], [1], [Have mtrace])])
 588
 589 # iconv library
 590 have_iconv="no"
 591 AC_ARG_WITH([iconv-link],
 592    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 593    [
 594     LIBS="$withval $LIBS"
 595     have_iconv="yes"
 596     iconv_libs=$withval
 597    ])
 598
 599 AC_MSG_CHECKING(for explicit iconv link options)
 600 if test "x${iconv_libs}" = "x" ; then
 601    AC_MSG_RESULT([no explicit iconv link option])
 602 else
 603    AC_MSG_RESULT([$iconv_libs])
 604 fi
 605
 606 if test "x${have_iconv}" = "xno" ; then
 607    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 608
 609    if test "x${have_iconv}" = "xyes" ; then
 610       AC_MSG_CHECKING([whether iconv() is in libc])
 611
 612       AC_LINK_IFELSE(
 613          [AC_LANG_PROGRAM(
 614              [[
 615 #include <stdlib.h>
 616 #include <iconv.h>
 617              ]],
 618              [[
 619 iconv_t ic;
 620 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 621              ]])],
 622          [have_iconv="yes"],
 623          [have_iconv="no"])
 624
 625       AC_MSG_RESULT([${have_iconv}])
 626    fi
 627
 628    if test "x${have_iconv}" = "xno" ; then
 629       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 630
 631       LIBS_save="${LIBS}"
 632       LIBS="-liconv $LIBS"
 633       AC_LINK_IFELSE(
 634          [AC_LANG_PROGRAM(
 635              [[
 636 #include <stdlib.h>
 637 #include <iconv.h>
 638              ]],
 639              [[
 640 iconv_t ic;
 641 size_t count;
 642 count = iconv(ic, NULL, NULL, NULL, NULL);
 643              ]])],
 644          [
 645           have_iconv="yes"
 646           iconv_libs="-liconv"
 647          ],
 648          [
 649           have_iconv="no"
 650           LIBS=${LIBS_save}
 651          ])
 652
 653       AC_MSG_RESULT([${have_iconv}])
 654    fi
 655
 656    if test "x${have_iconv}" = "xno" ; then
 657       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 658
 659       LIBS_save="${LIBS}"
 660       LIBS="-liconv_plug $LIBS"
 661       AC_LINK_IFELSE(
 662          [AC_LANG_PROGRAM(
 663              [[
 664 #include <stdlib.h>
 665 #include <iconv.h>
 666              ]],
 667              [[
 668 iconv_t ic;
 669 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 670              ]])],
 671          [
 672           have_iconv="yes"
 673           iconv_libs="-liconv_plug"
 674          ],
 675          [
 676           have_iconv="no"
 677           LIBS=${LIBS_save}
 678          ])
 679
 680       AC_MSG_RESULT([${have_iconv}])
 681    fi
 682 fi
 683
 684 AC_SUBST([iconv_libs])
 685
 686 if test "x${have_iconv}" = "xyes" ; then
 687    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 688 fi
 689
 690 # shmopen
 691 have_shmopen=no
 692 AC_MSG_CHECKING([for shm_open availability])
 693
 694 LIBS_save="${LIBS}"
 695 LIBS="${LIBS} -lrt"
 696 AC_LINK_IFELSE(
 697    [AC_LANG_PROGRAM(
 698        [[
 699 #include <sys/mman.h>
 700 #include <sys/stat.h>        /* For mode constants */
 701 #include <fcntl.h>           /* For O_* constants */
 702        ]],
 703        [[
 704 int fd;
 705
 706 fd = shm_open("/dev/null", O_RDONLY, S_IRWXU | S_IRWXG | S_IRWXO);
 707        ]])],
 708    [have_shmopen="yes"],
 709    [have_shmopen="no"])
 710
 711 LIBS="${LIBS_save}"
 712
 713 AC_MSG_RESULT([${have_shmopen}])
 714
 715 if test "x${have_shmopen}" = "xyes"; then
 716    AC_DEFINE([HAVE_SHMOPEN], [1], [Define to 1 if you have the `shm_open' function.])
 717    rt_libs="-lrt"
 718 fi
 719
 720 AC_SUBST([rt_libs])
 721
 722 # extended attribute
 723
 724 AC_MSG_CHECKING([for extended attributes])
 725
 726 AC_COMPILE_IFELSE(
 727    [AC_LANG_PROGRAM(
 728        [[
 729 #include <stdlib.h>
 730 #include <sys/types.h>
 731 #include <sys/xattr.h>
 732        ]],
 733        [[
 734 size_t tmp = listxattr("/", NULL, 0);
 735 tmp = getxattr("/", "user.ethumb.md5", NULL, 0);
 736 setxattr("/", "user.ethumb.md5", NULL, 0, 0);
 737        ]])],
 738    [
 739     AC_DEFINE([HAVE_XATTR], [1], [Define to 1 if you have the `listxattr', `setxattr' and `getxattr' functions.])
 740     have_xattr="yes"
 741    ],
 742    [have_xattr="no"])
 743
 744 AC_MSG_RESULT([${have_xattr}])
 745
 746 ### Modules
 747
 748 if test "x${have_default_mempool}" = "xyes" ; then
 749    enable_chained_pool="no"
 750    enable_pass_through="static"
 751 else
 752    enable_chained_pool="static"
 753    enable_pass_through="no"
 754 fi
 755
 756 enable_one_big="static"
 757
 758 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 759 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 760 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 761 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 762 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 763 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 764 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 765
 766 ### Make the debug preprocessor configurable
 767
 768 ### Unit tests, coverage and benchmarking
 769
 770 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 771
 772 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 773 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 774 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 775 if test "x$enable_coverage" = "xyes" ; then
 776    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 777 fi
 778
 779 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 780 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 781 if test -n "$CXX" && test "x$enable_benchmark" = "xyes" ; then
 782    AC_DEFINE_UNQUOTED([CITYHASH_BENCH], [1], [enable bench tests for google hash method])
 783 fi
 784 AM_CONDITIONAL([CITYHASH_BENCH], [test -n "$CXX" && test "x$enable_benchmark" = "xyes"])
 785
 786 AC_SUBST([requirement_eina])
 787
 788 ### Build and install examples
 789 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
 790 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
 791
 792 AC_CONFIG_FILES([
 793 Makefile
 794 eina.pc
 795 eina.spec
 796 doc/Makefile
 797 doc/Doxyfile
 798 src/Makefile
 799 src/include/Makefile
 800 src/include/eina_config.h
 801 src/lib/Makefile
 802 src/modules/Makefile
 803 src/modules/mp/Makefile
 804 src/modules/mp/chained_pool/Makefile
 805 src/modules/mp/ememoa_fixed/Makefile
 806 src/modules/mp/ememoa_unknown/Makefile
 807 src/modules/mp/pass_through/Makefile
 808 src/modules/mp/fixed_bitmap/Makefile
 809 src/modules/mp/buddy/Makefile
 810 src/modules/mp/one_big/Makefile
 811 src/tests/Makefile
 812 src/examples/Makefile
 813 ])
 814
 815 AC_OUTPUT
 816
 817 #####################################################################
 818 ## Info
 819
 820 echo
 821 echo
 822 echo
 823 echo "------------------------------------------------------------------------"
 824 echo "$PACKAGE $VERSION"
 825 echo "------------------------------------------------------------------------"
 826 echo
 827 echo
 828 echo "Configuration Options Summary:"
 829 echo
 830 echo "  Magic debug..........: ${have_magic_debug}"
 831 echo "  Safety checks........: ${have_safety_checks}"
 832 echo "  Maximum log level....: ${with_max_log_level}"
 833 echo "  Report string usage..: ${have_stringshare_usage}"
 834 echo "  Valgrind support.....: ${have_valgrind}"
 835 echo "  Default mempool......: ${have_default_mempool}"
 836 echo "  Log support..........: ${enable_log}"
 837 echo "  Thread Support.......: ${have_threads}"
 838 if test "${have_threads}" = "POSIX" ; then
 839 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 840 echo "    debug usage........: ${have_debug_threads}"
 841 echo "    on/off support.....: ${have_on_off_threads}"
 842 fi
 843 echo "  Amalgamation.........: ${do_amalgamation}"
 844 echo "  Iconv support........: ${have_iconv}"
 845 echo "  File dirfd...........: ${have_dirfd}"
 846 echo "  File xattr...........: ${have_xattr}"
 847 echo
 848 echo "  Documentation........: ${build_doc}"
 849 echo "  Tests................: ${enable_tests}"
 850 echo "  Coverage.............: ${enable_coverage}"
 851 echo "  Examples.............: ${enable_build_examples}"
 852 echo "  Tiler Example........: ${build_tiler_example}"
 853 echo "  Examples installed...: ${enable_install_examples}"
 854 echo "  Benchmark............: ${enable_benchmark}"
 855 if test "x${enable_benchmark}" = "xyes" ; then
 856 echo "    Glib...............: ${enable_benchmark_glib}"
 857 echo "    E17 real data......: ${enable_benchmark_e17}"
 858 fi
 859 echo
 860 echo "  CPU Specific Extensions:"
 861 echo "    MMX................: ${have_mmx}"
 862 echo "    SSE................: ${have_sse}"
 863 echo "    SSE2...............: ${have_sse2}"
 864 echo "    ALTIVEC............: ${have_altivec}"
 865 echo
 866 echo "  Memory pools:"
 867 echo "    Buddy..............: ${enable_buddy}"
 868 echo "    Chained pool.......: ${enable_chained_pool}"
 869 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 870 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 871 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 872 echo "    One big............: ${enable_one_big}"
 873 echo "    Pass through.......: ${enable_pass_through}"
 874 echo
 875 echo "Compilation............: make (or gmake)"
 876 echo "  CPPFLAGS.............: $CPPFLAGS"
 877 echo "  CFLAGS...............: $CFLAGS"
 878 echo "  LDFLAGS..............: $LDFLAGS"
 879 echo
 880 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 881 echo "  prefix...............: $prefix"
 882 echo
 883 EFL_FORM_VOLTRON