configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ(2.57)
  22 AC_INIT([libdrm], 2.4.0, [dri-devel@lists.sourceforge.net], libdrm)
  23 AC_CONFIG_SRCDIR([Makefile.am])
  24 AM_INIT_AUTOMAKE([dist-bzip2])
  25
  26 AM_CONFIG_HEADER([libdrm/config.h])
  27
  28 AC_DISABLE_STATIC
  29 AC_PROG_LIBTOOL
  30 AC_PROG_CC
  31
  32 AC_HEADER_STDC
  33 AC_SYS_LARGEFILE
  34
  35 pkgconfigdir=${libdir}/pkgconfig
  36 AC_SUBST(pkgconfigdir)
  37
  38
  39 dnl ===========================================================================
  40 dnl check compiler flags
  41 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
  42   AC_MSG_CHECKING([whether $CC supports $1])
  43
  44   libdrm_save_CFLAGS="$CFLAGS"
  45   CFLAGS="$CFLAGS $1"
  46
  47   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
  48   CFLAGS="$libdrm_save_CFLAGS"
  49
  50   if test "x$libdrm_cc_flag" = "xyes"; then
  51     ifelse([$2], , :, [$2])
  52   else
  53     ifelse([$3], , :, [$3])
  54   fi
  55   AC_MSG_RESULT([$libdrm_cc_flag])
  56 ])
  57
  58 dnl Use lots of warning flags with with gcc and compatible compilers
  59
  60 dnl Note: if you change the following variable, the cache is automatically
  61 dnl skipped and all flags rechecked.  So there's no need to do anything
  62 dnl else.  If for any reason you need to force a recheck, just change
  63 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
  64
  65 MAYBE_WARN="-Wall -Wextra \
  66 -Wsign-compare -Werror-implicit-function-declaration \
  67 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
  68 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
  69 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
  70 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
  71 -Wdeclaration-after-statement -Wold-style-definition \
  72 -Wno-missing-field-initializers -Wno-unused-parameter \
  73 -Wno-attributes -Wno-long-long -Winline"
  74
  75 # invalidate cached value if MAYBE_WARN has changed
  76 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
  77         unset libdrm_cv_warn_cflags
  78 fi
  79 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
  80         echo
  81         WARN_CFLAGS=""
  82
  83         # Some warning options are not supported by all versions of
  84         # gcc, so test all desired options against the current
  85         # compiler.
  86         #
  87         # Note that there are some order dependencies
  88         # here. Specifically, an option that disables a warning will
  89         # have no net effect if a later option then enables that
  90         # warnings, (perhaps implicitly). So we put some grouped
  91         # options (-Wall and -Wextra) up front and the -Wno options
  92         # last.
  93
  94         for W in $MAYBE_WARN; do
  95                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
  96         done
  97
  98         libdrm_cv_warn_cflags=$WARN_CFLAGS
  99         libdrm_cv_warn_maybe=$MAYBE_WARN
 100
 101         AC_MSG_CHECKING([which warning flags were supported])])
 102 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 103
 104 AC_SUBST(WARN_CFLAGS)
 105 AC_OUTPUT([
 106         Makefile
 107         libdrm/Makefile
 108         libdrm/intel/Makefile
 109         shared-core/Makefile
 110         tests/Makefile
 111         libdrm.pc])