configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer libav, 1.3.0.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-libav)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/libav/gstav.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use major.minor as a version
  39 GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  40 dnl we override it here if we need to for the release candidate of new series
  41 GST_API_VERSION=1.0
  42 AC_SUBST(GST_API_VERSION)
  43
  44 AG_GST_LIBTOOL_PREPARE
  45 AS_LIBTOOL(GST, 300, 0, 300)
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=1.3.0.1
  49 GST_PBREQ=1.3.0.1
  50
  51 ORC_REQ=0.4.16
  52 ORC_CHECK([$ORC_REQ])
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  61
  62 dnl *** check for arguments to configure ***
  63
  64 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  65
  66 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  67 AG_GST_ARG_WITH_PACKAGE_NAME
  68 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  69 AG_GST_ARG_VALGRIND
  70 AG_GST_ARG_GCOV
  71
  72 dnl *** checks for platform ***
  73
  74 dnl * hardware/architecture *
  75
  76 dnl common/m4/gst-arch.m4
  77 dnl check CPU type
  78 AG_GST_ARCH
  79
  80 dnl *** checks for programs ***
  81
  82 dnl find a compiler
  83 AC_PROG_CC
  84 AC_PROG_CC_STDC
  85
  86 dnl check if the compiler supports '-c' and '-o' options
  87 AM_PROG_CC_C_O
  88
  89 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  90 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  91
  92 dnl check for documentation tools
  93 AG_GST_DOCBOOK_CHECK
  94 GTK_DOC_CHECK([1.12])
  95 AS_PATH_PYTHON([2.1])
  96 AG_GST_PLUGIN_DOCS([1.3],[2.1])
  97
  98 dnl *** checks for libraries ***
  99
 100 dnl check for libm, for sin()
 101 LT_LIB_M
 102 AC_SUBST(LIBM)
 103
 104 dnl *** checks for header files ***
 105
 106 dnl check if we have ANSI C header files
 107 AC_HEADER_STDC
 108
 109 dnl *** checks for types/defines ***
 110
 111 dnl *** checks for structures ***
 112
 113 dnl *** checks for compiler characteristics ***
 114
 115 dnl *** checks for library functions ***
 116
 117 dnl *** checks for dependancy libraries ***
 118
 119 dnl checks for gstreamer
 120 dnl uninstalled is selected preferentially -- see pkg-config(1)
 121 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ])
 122 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ])
 123 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_PBREQ])
 124 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 125 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 126
 127 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 128 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 129
 130 dnl *** set variables based on configure arguments ***
 131
 132 dnl set location of plugin directory
 133 AG_GST_SET_PLUGINDIR
 134
 135 dnl build static plugins or not
 136 AC_MSG_CHECKING([whether to build static plugins or not])
 137 AC_ARG_ENABLE(
 138   static-plugins,
 139   AC_HELP_STRING(
 140     [--enable-static-plugins],
 141     [build static plugins @<:@default=no@:>@]),
 142   [AS_CASE(
 143     [$enableval], [no], [], [yes], [],
 144     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 145   [enable_static_plugins=no])
 146 AC_MSG_RESULT([$enable_static_plugins])
 147 if test "x$enable_static_plugins" = xyes; then
 148   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 149     [Define if static plugins should be built])
 150   GST_PLUGIN_LIBTOOLFLAGS=""
 151 else
 152   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 153 fi
 154 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 155 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 156
 157 dnl define an ERROR_CFLAGS Makefile variable
 158 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 159     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 160     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 161     -Winit-self -Wmissing-include-dirs -Waddress
 162     -Waggregate-return -Wno-multichar -Wnested-externs ])
 163
 164 dnl define correct level for debugging messages
 165 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 166
 167 dnl *** finalize CFLAGS, LDFLAGS, LIBS ***
 168
 169 dnl Overview:
 170 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 171 dnl GST_*:              flags shared by built objects to link against GStreamer
 172 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 173 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 174 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 175 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 176
 177 dnl GST_OPTION_CFLAGS
 178 if test "x$USE_DEBUG" = xyes; then
 179    PROFILE_CFLAGS="-g"
 180 fi
 181 AC_SUBST(PROFILE_CFLAGS)
 182
 183 if test "x$GST_GIT" = "xyes"; then
 184   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 185 else
 186   DEPRECATED_CFLAGS=""
 187 fi
 188 AC_SUBST(DEPRECATED_CFLAGS)
 189
 190 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 191 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 192
 193 AC_SUBST(GST_OPTION_CFLAGS)
 194
 195 dnl FIXME: do we want to rename to GST_ALL_* ?
 196 dnl prefer internal headers to already installed ones
 197 dnl also add builddir include for enumtypes and marshal
 198 dnl add GST_OPTION_CFLAGS, but overridable
 199 GST_CFLAGS="$GST_CFLAGS"
 200 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 201 AC_SUBST(GST_CFLAGS)
 202 AC_SUBST(GST_LIBS)
 203
 204 GST_ALL_LDFLAGS="-no-undefined"
 205 AC_SUBST(GST_ALL_LDFLAGS)
 206
 207 dnl this really should only contain flags, not libs - they get added before
 208 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 209 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 210 AC_SUBST(GST_PLUGIN_LDFLAGS)
 211
 212 dnl Add MacOSX specific flags
 213 AC_CANONICAL_HOST
 214 case $host_os in
 215      darwin*)
 216         DARWIN_LDFLAGS="-Wl,-read_only_relocs,suppress"
 217         ;;
 218      *)
 219         DARWIN_LDFLAGS=""
 220         ;;
 221 esac
 222 AC_SUBST(DARWIN_LDFLAGS)
 223
 224 dnl *** Check for bz2
 225 save_LIBS=$LIBS
 226 LIBS="$LIBS -lbz2"
 227 AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 228 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 229 AC_MSG_RESULT($HAVE_BZ2)
 230 LIBS=$save_LIBS
 231 AM_CONDITIONAL(HAVE_BZ2, test "x$HAVE_BZ2" = "xyes")
 232 if test "x$HAVE_BZ2" = "xno"; then
 233   AC_WARN([libbz2 not found, matroska demuxer will not be able to read bz2 tracks])
 234 fi
 235
 236 AC_ARG_ENABLE(lgpl,
 237               [AC_HELP_STRING([--enable-lgpl], [build a LGPL licensed gst-libav])])
 238 AM_CONDITIONAL(GST_LIBAV_ENABLE_LGPL, test "x$enable_lgpl" = "xyes")
 239 if test "x$enable_lgpl" = "xyes"; then
 240   AC_DEFINE([GST_LIBAV_ENABLE_LGPL], [], [Defined if building a LGPL-only version of gst-libav])
 241 fi
 242
 243 dnl *** configure external libs ***
 244
 245 HAVE_LIBAV_UNINSTALLED=1
 246
 247 AC_ARG_WITH(system-libav,
 248             [AC_HELP_STRING([--with-system-libav], [use system Libav libraries])])
 249
 250 if test "x$with_system_libav" = "xyes"; then
 251   PKG_CHECK_MODULES(LIBAV, libavformat libavcodec libavutil)
 252   PKG_CHECK_MODULES(SWSCALE, libswscale libavutil)
 253   saved_CPPFLAGS="$CPPFLAGS"
 254   CPPFLAGS="$CPPFLAGS $LIBAV_CFLAGS"
 255   AC_CHECK_HEADERS([avi.h])
 256   CPPFLAGS="$saved_CPPFLAGS"
 257   AC_DEFINE([LIBAV_SOURCE], ["system install"], [Describes where the Libav libraries come from.])
 258   HAVE_LIBAV_UNINSTALLED=0
 259   AC_MSG_NOTICE([Using system-installed libav code])
 260 else
 261   AC_MSG_NOTICE([Using local Libav snapshot])
 262
 263   dnl libgstlibav.la: include dirs
 264   LIBAV_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 265                 -I \$(top_builddir)/gst-libs/ext/libav \
 266                  -Wno-deprecated-declarations"
 267
 268   LIBAV_DEPS="\$(top_builddir)/gst-libs/ext/libav/libavformat/libavformat.a \
 269               \$(top_builddir)/gst-libs/ext/libav/libavcodec/libavcodec.a \
 270               \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 271   if test "x$enable_static_plugins" = xyes; then
 272       dnl with static linking we can't use the .a archive directly as they would
 273       dnl be included in the final libgstlibav.a as a file and won't be usable.
 274       dnl libav*.a must be copied to the final destination too
 275       LIBAV_LIBS="-lavformat -lavcodec -lavutil"
 276   else
 277       dnl libgstlibav.la: libs to statically link to
 278       LIBAV_LIBS="$LIBAV_DEPS"
 279   fi
 280
 281   dnl
 282   SWSCALE_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 283                   -I \$(top_builddir)/gst-libs/ext/libav \
 284                   -Wno-deprecated-declarations"
 285
 286   SWSCALE_DEPS="\$(top_builddir)/gst-libs/ext/libav/libswscale/libswscale.a \
 287                 \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 288   if test "x$enable_static_plugins" = xyes; then
 289       dnl with static linking we can't use the .a archive directly as they would
 290       dnl be included in the final libgstswscale.a as a file and won't be usable.
 291       dnl libav*.a must be copied to the final destination too
 292       SWSCALE_LIBS="-lswscale -lavutil"
 293   else
 294       dnl libgstswscale.la: libs to statically link to
 295       SWSCALE_LIBS="$SWSCALE_DEPS"
 296   fi
 297
 298   LIBAV_SUBDIRS=gst-libs
 299   AC_DEFINE(HAVE_AVI_H)
 300   AC_DEFINE([LIBAV_SOURCE], ["local snapshot"], [Describes where the Libav libraries come from.])
 301
 302   AC_ARG_WITH(libav-extra-configure,
 303       AC_HELP_STRING([--with-libav-extra-configure="xxx"],
 304       [extra configure options for internal libav ./configure script]),,
 305       with_libav=no)
 306
 307   # basic arguments
 308   emblibav_configure_args="--prefix=$prefix"
 309
 310   # Enable pic and static so that we get .a files, but with PIC code.
 311   emblibav_configure_args="$emblibav_configure_args --disable-avserver --disable-avplay\
 312         --disable-avconv --disable-avprobe --enable-static --enable-pic \
 313         --disable-encoder=flac --disable-decoder=cavs --disable-protocols --disable-devices\
 314         --disable-network --disable-hwaccels --disable-dxva2 --disable-vdpau\
 315         --disable-filters --disable-doc --enable-optimizations"
 316
 317   if test "x$enable_lgpl" != "xyes"; then
 318     emblibav_configure_args="$emblibav_configure_args --enable-gpl"
 319   fi
 320
 321   # if we are cross-compiling, tell libav so
 322   case $host in
 323       *android*)
 324         target_os=linux
 325       ;;
 326       *darwin*)
 327         target_os=darwin
 328       ;;
 329       *)
 330         target_os=`echo $host_os | sed 's/-gnu//'`
 331       ;;
 332   esac
 333
 334   if test "x$cross_compiling" = xyes; then
 335     emblibav_configure_args="$emblibav_configure_args --enable-cross-compile \
 336         --target-os=$target_os --arch=$host_cpu --cross-prefix=$host_alias-"
 337   fi
 338
 339   case $host_os in
 340     mingw32*)
 341       emblibav_configure_args="$emblibav_configure_args --enable-memalign-hack"
 342       WIN32_LIBS="-lws2_32"
 343       ;;
 344     *)
 345       WIN32_LIBS=
 346       ;;
 347   esac
 348
 349   if test x"$AR" != x; then
 350     emblibav_configure_args="$emblibav_configure_args --ar=\\\"\\\$AR\\\""
 351   fi
 352
 353   if test x"$AS" != x; then
 354     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$CC\\\""
 355   fi
 356
 357   if test x"$CC" != x; then
 358     emblibav_configure_args="$emblibav_configure_args --cc=\\\"\\\$CC\\\""
 359   fi
 360
 361   if test x"$LD" != x; then
 362     emblibav_configure_args="$emblibav_configure_args --ld=\\\"\\\$CC\\\""
 363   fi
 364
 365   if test x"$NM" != x; then
 366     emblibav_configure_args="$emblibav_configure_args --nm=\\\"\\\$NM\\\""
 367   fi
 368
 369   dnl checks for extra enable/disable flags
 370   LIBAV_OPTS=`cd $srcdir/gst-libs/ext/libav && ./configure --help`
 371   # Let's check if we can disable the building of the libav binary
 372   can_disable=`echo "$LIBAV_OPTS" | grep 'disable-ffmpeg'`
 373   if test "$can_disable" != ""; then
 374     emblibav_configure_args="$emblibav_configure_args --disable-ffmpeg"
 375   fi
 376   dnl check if libswscale needs enabling explicitly
 377   can_enable=`echo "$LIBAV_OPTS" | grep 'enable-swscale'`
 378   if test "$can_enable" != ""; then
 379     emblibav_configure_args="$emblibav_configure_args --enable-swscale"
 380   fi
 381
 382   # append extra configure options to emblibav_configure_args if needed
 383   if test "x$with_libav_extra_configure" != "xno"; then
 384     emblibav_configure_args="$emblibav_configure_args $with_libav_extra_configure"
 385   fi
 386
 387   AC_SUBST(LIBAV_CO_DIR)
 388   AC_SUBST(LIBAV_SVN)
 389   AC_SUBST(LIBAV_REVISION)
 390   AC_SUBST(LIBAV_EXTERNALS_REVISION)
 391   AC_CONFIG_COMMANDS([configure-embedded-libav],
 392     [echo "Configuring included Libav instance with args $emblibav_configure_args"
 393      origdir=`pwd`
 394      dnl Don't put path on the configure call when not needed, as FFmpeg's configure relies on it
 395      dnl to detect out-of-tree builds
 396      if test -z "$srcdir" -o "$srcdir" = .; then
 397        confcmd=./configure
 398      else
 399        confcmd="$ac_abs_top_srcdir"/gst-libs/ext/libav/configure
 400      fi
 401
 402      AS_MKDIR_P(["$ac_top_build_prefix"gst-libs/ext/libav])
 403      cd "$ac_top_build_prefix"gst-libs/ext/libav &&
 404          eval "$confcmd $emblibav_configure_args" ||
 405          AC_MSG_ERROR([Failed to configure embedded Libav tree])
 406      cd "$origdir"
 407     ],
 408     [emblibav_configure_args="$emblibav_configure_args"])
 409   AC_MSG_NOTICE([Using included Libav code])
 410 fi
 411
 412 AC_SUBST(LIBAV_CFLAGS)
 413 AC_SUBST(LIBAV_DEPS)
 414 AC_SUBST(LIBAV_LIBS)
 415 AC_SUBST(LIBAV_SUBDIRS)
 416 AC_SUBST(SWSCALE_CFLAGS)
 417 AC_SUBST(SWSCALE_DEPS)
 418 AC_SUBST(SWSCALE_LIBS)
 419 AC_SUBST(WIN32_LIBS)
 420
 421 if test x$HAVE_LIBAV_UNINSTALLED = x1; then
 422   AC_DEFINE(HAVE_LIBAV_UNINSTALLED, [], [Defined if building against uninstalled Libav source])
 423 fi
 424 AM_CONDITIONAL(HAVE_LIBAV_UNINSTALLED, test x$HAVE_LIBAV_UNINSTALLED = x1)
 425
 426 AC_CONFIG_FILES(
 427 Makefile
 428 common/Makefile
 429 common/m4/Makefile
 430 gst-libav.spec
 431 ext/Makefile
 432 ext/libav/Makefile
 433 ext/libswscale/Makefile
 434 gst-libs/Makefile
 435 gst-libs/ext/Makefile
 436 docs/Makefile
 437 docs/version.entities
 438 tests/Makefile
 439 tests/check/Makefile
 440 tests/files/Makefile
 441 pkgconfig/Makefile
 442 pkgconfig/gstreamer-plugins-libav-uninstalled.pc
 443 )
 444 AC_OUTPUT
 445
 446 ORC_OUTPUT