configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.11.1])
  10 AC_CONFIG_SRCDIR([src/rygel/rygel-root-device.vala])
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 AC_SEARCH_LIBS([strerror],[cposix])
  16 AC_PROG_CC
  17 AC_HEADER_STDC
  18 AC_FUNC_MMAP
  19
  20 # Disable generation of static libraries
  21 LT_PREREQ([2.2.6])
  22 LT_INIT([dlopen disable-static])
  23
  24 VALA_REQUIRED=0.11.6
  25 GSSDP_REQUIRED=0.9.2
  26 GUPNP_REQUIRED=0.13.4
  27 GUPNP_AV_REQUIRED=0.7.0
  28 GUPNP_DLNA_REQUIRED=0.5.0
  29 GUPNP_VALA_REQUIRED=0.7.5
  30 GSTREAMER_REQUIRED=0.10.23
  31 GSTREAMER_TAG_REQUIRED=0.10.28
  32 GSTREAMER_APP_REQUIRED=0.10.28
  33 GIO_REQUIRED=2.26
  34 GEE_REQUIRED=0.5.2
  35 UUID_REQUIRED=1.41.3
  36 LIBSOUP_REQUIRED=2.26.0
  37 LIBSQLITE3_REQUIRED=3.5
  38 GTK_REQUIRED=2.90.3
  39
  40 PKG_CHECK_MODULES(LIBGSSDP, gssdp-1.0 >= $GSSDP_REQUIRED)
  41 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  42 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  43 PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.0 >= $GUPNP_DLNA_REQUIRED)
  44 PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  45 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  46 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  47 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  48 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  49
  50 # glib-genmarshal
  51 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
  52 AC_SUBST(GLIB_GENMARSHAL)
  53
  54 AC_ARG_ENABLE(vala,
  55     AS_HELP_STRING([--enable-vala],[enable checks for vala]),,
  56         enable_vala=no)
  57 AC_ARG_ENABLE(sql-debugging,
  58     AS_HELP_STRING([--enable-sql-debugging],[enable SQL statement debugging]),,
  59         enable_sql_debugging=no)
  60
  61 if test x$enable_sql_debugging = xyes ; then
  62     VALAFLAGS="$VALAFLAGS -D RYGEL_DEBUG_SQL"
  63 fi
  64
  65 # Enable check for Vala even if not asked to do so if stamp files are absent.
  66 if test ! -e src/rygel/rygel_vala.stamp -o \
  67         ! -e src/ui/rygel_preferences_vala.stamp -o \
  68         ! -e src/plugins/playbin/librygel_playbin_la_vala.stamp -o \
  69         ! -e src/plugins/tracker/librygel_media_tracker_la_vala.stamp -o \
  70         ! -e src/plugins/test/librygel_test_la_vala.stamp -o \
  71         ! -e src/plugins/media-export/librygel_media_export_la_vala.stamp -o \
  72         ! -e src/plugins/mediathek/librygel_mediathek_la_vala.stamp -o \
  73         ! -e src/plugins/gst-launch/librygel_gst_launch_la_vala.stamp -o \
  74         ! -e src/plugins/mpris/librygel_mpris_la_vala.stamp -o \
  75         ! -e src/plugins/external/librygel_external_la_vala.stamp ; then
  76     enable_vala=yes
  77 fi
  78
  79 # Vala
  80 if test x$enable_vala = xyes ; then
  81     # check for vala
  82     AM_PROG_VALAC([$VALA_REQUIRED])
  83
  84     if test "x$VALAC" = "x"; then
  85         AC_MSG_ERROR([Cannot find the "valac" compiler in your PATH])
  86     fi
  87
  88     PKG_CHECK_MODULES(GUPNP_VALA, gupnp-vala-1.0 >= $GUPNP_VALA_REQUIRED)
  89
  90     VALA_CHECK_PACKAGES([gupnp-1.0
  91                          gupnp-av-1.0
  92                          gupnp-dlna-1.0
  93                          gstreamer-0.10
  94                          gstreamer-pbutils-0.10
  95                          gio-2.0
  96                          gee-1.0
  97                          posix])
  98 fi
  99
 100 VAPIDIR="${datadir}/vala/vapi"
 101 AC_SUBST(VAPIDIR)
 102
 103 # Debugging
 104 AC_ARG_ENABLE(debug,
 105         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 106         enable_debug=no)
 107 if test "x$enable_debug" = "xyes"; then
 108         CFLAGS="$CFLAGS -O0 -g"
 109 fi
 110
 111 AC_ARG_ENABLE([strict-valac],
 112     AS_HELP_STRING([--enable-strict-valac],[enable strict Vala compiler]),,
 113               [enable_strict_valac=no])
 114 if test "x$enable_strict_valac" = "xyes"; then
 115         VALAFLAGS="$VALAFLAGS --fatal-warnings"
 116 fi
 117
 118 # Strict compiler
 119 AC_ARG_ENABLE(strict-cc,
 120         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 121         enable_strict_cc=no)
 122 if test "x$enable_strict_cc" = "xyes"; then
 123         CFLAGS="$CFLAGS -Wall -Werror"
 124 else
 125         CFLAGS="$CFLAGS -w"
 126 fi
 127
 128 # Run uninstalled
 129 AC_ARG_ENABLE(uninstalled,
 130     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 131         enable_uninstalled=no)
 132 if test "x$enable_uninstalled" = "xyes"; then
 133         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 134 fi
 135
 136 # Check wether user wants to build UIs
 137 AC_ARG_WITH( ui,
 138   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 139   try_ui=$withval, try_ui=yes )
 140
 141 HAVE_GTK=no
 142 if test x$try_ui = xyes ; then
 143     dnl check for gtk
 144     PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQUIRED,
 145       [
 146         AC_SUBST(GTK_CFLAGS)
 147         AC_SUBST(GTK_LIBS)
 148         if test x$enable_vala = xyes ; then
 149                 VALA_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 150         else
 151                 HAVE_GTK=yes
 152         fi
 153       ],
 154       [
 155         HAVE_GTK=no
 156         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 157         AC_MSG_WARN([UI applications will not be built.])
 158       ])
 159 else
 160     AC_MSG_NOTICE([UI applications disabled.])
 161 fi
 162
 163 if test x$HAVE_GTK = xno; then
 164   BUILD_UI=no
 165 else
 166   BUILD_UI=yes
 167   AC_DEFINE(HAVE_GTK, , [Build UI applications])
 168 fi
 169
 170 AC_SUBST(HAVE_GTK)
 171 AM_CONDITIONAL(BUILD_UI, test x$BUILD_UI = xyes)
 172
 173 # Build test plugin
 174 RYGEL_ADD_PLUGIN([test],[Test],[no])
 175 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
 176 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
 177 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
 178 RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
 179 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
 180 RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
 181 RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
 182
 183 AC_SUBST(abs_top_builddir)
 184
 185 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 186
 187 if test "x$enable_media_export_plugin" = "xyes";
 188 then
 189     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 190     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-0.10 >= $GSTREAMER_TAG_REQUIRED);
 191     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-0.10 >= $GSTREAMER_APP_REQUIRED);
 192     if test x$enable_vala = xyes ; then
 193         VALA_CHECK_PACKAGES([sqlite3
 194                              gstreamer-tag-0.10
 195                              gstreamer-app-0.10])
 196     fi
 197 fi
 198
 199 # Gettext
 200 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 201 AC_SUBST(GETTEXT_PACKAGE)
 202 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 203   [Define the gettext package to be used])
 204
 205 AM_GLIB_GNU_GETTEXT
 206 IT_PROG_INTLTOOL([0.40.0])
 207
 208 AC_SUBST(VALAFLAGS)
 209
 210 dnl Shave the output
 211 AM_SILENT_RULES([yes])
 212
 213 dnl documenation
 214 AC_PATH_PROG([XSLTPROC], [xsltproc])
 215 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 216
 217 AC_SUBST(VERSION)
 218
 219 AC_CONFIG_FILES([
 220 Makefile
 221 src/Makefile
 222 src/rygel/Makefile
 223 src/ui/Makefile
 224 src/plugins/Makefile
 225 data/Makefile
 226 data/xml/Makefile
 227 data/icons/Makefile
 228 data/icons/32x32/Makefile
 229 data/icons/48x48/Makefile
 230 data/icons/120x120/Makefile
 231 data/icons/scalable/Makefile
 232 data/rygel.desktop.in
 233 data/rygel-preferences.desktop.in
 234 doc/Makefile
 235 po/Makefile.in
 236 rygel-1.0.pc
 237 tests/Makefile
 238 ])
 239 AC_OUTPUT
 240
 241 echo "
 242
 243                     ${PACKAGE} ${VERSION}
 244                     ============
 245
 246
 247         Prefix:                 ${prefix}
 248         Source code location:   ${srcdir}
 249         Compiler:               ${CC}
 250         CFLAGS:                 ${CFLAGS}
 251         uninstalled:            ${enable_uninstalled}
 252         preferences ui:         ${BUILD_UI}
 253         SQL debugging:          ${enable_sql_debugging}
 254     Plugins:
 255         test:                   ${enable_test_plugin}
 256         tracker:                ${enable_tracker_plugin}
 257         mediathek:              ${enable_mediathek_plugin}
 258         media-export            ${enable_media_export_plugin}
 259         external:               ${enable_external_plugin}
 260         MPRIS2:                 ${enable_mpris_plugin}
 261         gst-launch:             ${enable_gst_launch_plugin}
 262         playbin:                ${enable_playbin_plugin}
 263 "