configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.7.1.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 701, 0, 701)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.7.1.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for gobject-introspection
 158 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 159
 160 dnl check for documentation tools
 161 GTK_DOC_CHECK([1.12])
 162 AG_GST_PLUGIN_DOCS([1.12])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 LT_LIB_M
 168 AC_SUBST(LIBM)
 169
 170 dnl *** checks for header files ***
 171
 172 dnl check if we have ANSI C header files
 173 AC_HEADER_STDC
 174
 175 dnl check for GCC specific SSE headers
 176 dnl these are used by the speex resampler code
 177 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 178
 179 dnl used in gst/tcp
 180 AC_CHECK_HEADERS([sys/socket.h],
 181   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 182 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 183
 184 dnl used in gst-libs/gst/rtsp
 185 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 186 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 187 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 188   WIN32_LIBS="-lws2_32"
 189   AC_SUBST(WIN32_LIBS)
 190 fi
 191
 192 dnl used in gst-libs/gst/pbutils and associated unit test
 193 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 194
 195 dnl checks for ARM NEON support
 196 dnl this instruction set is used by the speex resampler code
 197 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 198 AC_LINK_IFELSE([
 199 AC_LANG_PROGRAM([[
 200   #include <arm_neon.h>
 201   int32x4_t testfunc(int16_t *a, int16_t *b) {
 202       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 203       return vmull_s16(vld1_s16(a), vld1_s16(b));
 204   }
 205 ]])],
 206 [
 207   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 208   AC_MSG_RESULT(yes)
 209 ],
 210 [
 211   AC_MSG_RESULT(no)
 212 ])
 213
 214 dnl also, Windows does not have long long
 215 AX_CREATE_STDINT_H
 216
 217 dnl *** checks for functions ***
 218 AC_CHECK_FUNCS([localtime_r gmtime_r])
 219
 220 dnl *** checks for math functions ***
 221 LIBS_SAVE=$LIBS
 222 LIBS="$LIBS $LIBM"
 223 AC_CHECK_FUNCS(log2)
 224 LIBS=$LIBS_SAVE
 225
 226 dnl *** checks for types/defines ***
 227
 228 dnl *** checks for structures ***
 229
 230 dnl *** checks for compiler characteristics ***
 231
 232 dnl *** checks for library functions ***
 233
 234 dnl check for fseeko()
 235 AC_FUNC_FSEEKO
 236
 237 dnl Check for fast float to int casting as defined in C99
 238 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 239 save_libs=$LIBS
 240 LIBS="$LIBS $LIBM"
 241 AC_C99_FUNC_LRINT
 242 AC_C99_FUNC_LRINTF
 243 LIBS=$save_libs
 244
 245 dnl Check for a way to display the function name in debug output
 246 AG_GST_CHECK_FUNCTION
 247
 248 dnl *** checks for dependency libraries ***
 249
 250 dnl GLib
 251 GLIB_REQ=2.40.0
 252 AG_GST_GLIB_CHECK([$GLIB_REQ])
 253
 254 ORC_CHECK([0.4.23])
 255
 256 dnl checks for gstreamer
 257 dnl uninstalled is selected preferentially -- see pkg-config(1)
 258 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 259 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 260 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 261 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 262 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 263 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 264
 265 dnl Check for documentation xrefs
 266 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 267 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 268 AC_SUBST(GLIB_PREFIX)
 269 AC_SUBST(GST_PREFIX)
 270
 271 dnl GTK is optional and only used in examples
 272 HAVE_GTK=no
 273 HAVE_GTK_X11=no
 274 GTK_REQ=3.10
 275 if test "x$BUILD_EXAMPLES" = "xyes"; then
 276   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 277   dnl some examples need gtk+-x11
 278   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 279   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 280   AC_SUBST(GTK_LIBS)
 281   AC_SUBST(GTK_CFLAGS)
 282 fi
 283 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 284 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 285 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 286
 287 HAVE_QT=no
 288 HAVE_QT_MOC=no
 289 dnl QT is optional and only used in examples
 290 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 291   HAVE_QT=yes
 292 ], [
 293   HAVE_QT=no
 294 ])
 295 if test "x$HAVE_QT" = "xyes"; then
 296   AC_CHECK_TOOL(QT_MOC, moc)
 297   AC_MSG_CHECKING([for Qt5 moc])
 298   mocversion=`$QT_MOC -v 2>&1`
 299   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 300   if test x"$mocversiongrep" != x"$mocversion"; then
 301     AC_MSG_RESULT([no])
 302     # moc was not the qt5 one, try with moc-qt5
 303     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 304     AC_MSG_CHECKING([for Qt5 moc-qt5])
 305     mocversion=`$QT_MOC -v 2>&1`
 306     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 307     if test x"$mocversiongrep" != x"$mocversion"; then
 308       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 309       AC_MSG_CHECKING([for qtchooser])
 310       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 311       mocversion=`$qt5tooldir/moc -v 2>&1`
 312       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 313       if test x"$mocversiongrep" != x"$mocversion"; then
 314         # no valid moc found
 315         QT_MOC="no"
 316       else
 317         QT_MOC=$qt5tooldir/moc
 318       fi
 319     else
 320       QT_MOC=$QT_MOC
 321     fi
 322   fi
 323   AC_SUBST(QT_MOC)
 324   AC_MSG_RESULT([$QT_MOC])
 325 fi
 326 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 327 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 328
 329 dnl chck for linux headers needed by the joystick seek example
 330 AC_COMPILE_IFELSE(
 331 [
 332   AC_LANG_PROGRAM([
 333     #include <linux/input.h>
 334     #include <linux/joystick.h>
 335   ],[
 336     struct js_event js;
 337     js.type = JS_EVENT_AXIS;
 338   ])
 339 ], [
 340   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 341 ], [
 342   HAVE_LINUX_JOYSTICK_HEADERS="no"
 343 ])
 344 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 345
 346 dnl Check for -Bsymbolic-functions linker flag used to avoid
 347 dnl intra-library PLT jumps, if available.
 348 AC_ARG_ENABLE(Bsymbolic,
 349               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 350               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 351                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 352                LDFLAGS=-Wl,-Bsymbolic-functions
 353                LIBS=
 354                AC_TRY_LINK([], [return 0],
 355                            AC_MSG_RESULT(yes)
 356                            enable_Bsymbolic=yes,
 357                            AC_MSG_RESULT(no)
 358                            enable_Bsymbolic=no)
 359                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 360
 361
 362 dnl *** set variables based on configure arguments ***
 363
 364 dnl set license and copyright notice
 365 GST_LICENSE="LGPL"
 366 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 367 AC_SUBST(GST_LICENSE)
 368
 369 dnl set location of plugin directory
 370 AG_GST_SET_PLUGINDIR
 371
 372 dnl set release date/time
 373 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 374   ["${srcdir}/gst-plugins-base.doap"],
 375   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 376
 377 dnl build static plugins or not
 378 AC_MSG_CHECKING([whether to build static plugins or not])
 379 AC_ARG_ENABLE(
 380   static-plugins,
 381   AC_HELP_STRING(
 382     [--enable-static-plugins],
 383     [build static plugins @<:@default=no@:>@]),
 384   [AS_CASE(
 385     [$enableval], [no], [], [yes], [],
 386     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 387   [enable_static_plugins=no])
 388 AC_MSG_RESULT([$enable_static_plugins])
 389 if test "x$enable_static_plugins" = xyes; then
 390   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 391     [Define if static plugins should be built])
 392   GST_PLUGIN_LIBTOOLFLAGS=""
 393 else
 394   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 395 fi
 396 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 397 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 398
 399 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 400 dnl make sure it doesn't complain about unused variables if debugging is disabled
 401 NO_WARNINGS=""
 402 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 403
 404 dnl define an ERROR_CFLAGS Makefile variable
 405 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 406 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 407     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 408     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 409     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 410     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 411
 412 dnl define an ERROR_CXXFLAGS Makefile variable
 413 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 414     -Wmissing-declarations -Wredundant-decls -Wundef
 415     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 416     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 417     -Wno-multichar $NO_WARNINGS])
 418
 419 dnl define correct level for debugging messages
 420 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 421
 422 dnl used in examples
 423 AG_GST_DEFAULT_ELEMENTS
 424
 425 dnl needed for encoding-target
 426 GST_DATADIR="$GST_PREFIX/share"
 427 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 428 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 429
 430 dnl behaviour of speex based audio resampler
 431 AC_MSG_CHECKING(which audio resample format to use for integer)
 432 AC_ARG_WITH([audioresample_format],
 433         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 434         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 435 AC_MSG_RESULT($ac_cv_audioresample_format)
 436 case $ac_cv_audioresample_format in
 437   int)
 438     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 439     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 440   ;;
 441   float)
 442     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 443     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 444   ;;
 445   auto)
 446     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 447     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 448 esac
 449
 450 dnl Check for mmap (needed by allocators library)
 451 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 452
 453 dnl *** plug-ins to include ***
 454
 455 dnl these are all the gst plug-ins, compilable without additional libs
 456 AG_GST_CHECK_PLUGIN(adder)
 457 AG_GST_CHECK_PLUGIN(app)
 458 AG_GST_CHECK_PLUGIN(audioconvert)
 459 AG_GST_CHECK_PLUGIN(audiorate)
 460 AG_GST_CHECK_PLUGIN(audiotestsrc)
 461 AG_GST_CHECK_PLUGIN(encoding)
 462 AG_GST_CHECK_PLUGIN(videoconvert)
 463 AG_GST_CHECK_PLUGIN(gio)
 464 AG_GST_CHECK_PLUGIN(playback)
 465 AG_GST_CHECK_PLUGIN(audioresample)
 466 AG_GST_CHECK_PLUGIN(subparse)
 467 AG_GST_CHECK_PLUGIN(tcp)
 468 AG_GST_CHECK_PLUGIN(typefind)
 469 AG_GST_CHECK_PLUGIN(videotestsrc)
 470 AG_GST_CHECK_PLUGIN(videorate)
 471 AG_GST_CHECK_PLUGIN(videoscale)
 472 AG_GST_CHECK_PLUGIN(volume)
 473
 474 dnl iso-codes is optional, used by libgsttag
 475 AC_ARG_ENABLE(iso-codes,
 476 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 477 [case "${enableval}" in
 478   yes) enable_iso_codes=yes ;;
 479   no)  enable_iso_codes=no ;;
 480   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 481 esac
 482 ],
 483 [enable_iso_codes=yes]) dnl Default value
 484
 485 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 486 if test "x$enable_iso_codes" = "xyes"; then
 487   AC_MSG_RESULT([yes])
 488   have_iso_codes=no
 489   AC_MSG_CHECKING([whether iso-codes are available on this system])
 490   if $PKG_CONFIG iso-codes; then
 491     AC_MSG_RESULT([yes])
 492     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 493     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 494       AC_MSG_RESULT([yes])
 495       AC_MSG_CHECKING([for iso-codes prefix])
 496       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 497       if test -d "$ISO_CODES_PREFIX"; then
 498         AC_MSG_RESULT([yes])
 499         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 500         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 501         ISO_639_DOMAIN="iso_639"
 502         AC_MSG_CHECKING([ISO_639_DOMAIN])
 503         AC_MSG_RESULT([$ISO_639_DOMAIN])
 504         have_iso_codes=yes
 505         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 506         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 507         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 508         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 509       else
 510         AC_MSG_RESULT([no])
 511       fi
 512     else
 513       AC_MSG_RESULT([no])
 514     fi
 515   else
 516     AC_MSG_RESULT([no])
 517   fi
 518   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 519 else
 520   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 521   AM_CONDITIONAL(USE_ISO_CODES, false)
 522 fi
 523
 524 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 525 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 526 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 527   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 528       HAVE_ZLIB="yes"
 529     ], [
 530       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 531         HAVE_ZLIB="yes"
 532         ZLIB_LIBS="-lz"
 533         AC_SUBST(ZLIB_LIBS)
 534       ])
 535     ])
 536 ])
 537
 538 dnl *** sys plug-ins ***
 539
 540 echo
 541 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 542 echo
 543
 544 dnl *** X11 ***
 545 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 546 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 547                   [ximagesink], [
 548   AG_GST_PKG_CHECK_MODULES(X, x11)
 549 ])
 550
 551 dnl Check for Xv extension
 552 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 553 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 554                   [xvimagesink], [
 555   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 556 ])
 557
 558 dnl check for X Shm
 559 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 560 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 561   if test x$HAVE_X = xyes; then
 562     PKG_CHECK_MODULES(XSHM, xext, [
 563       AC_CHECK_LIB(Xext, XShmAttach, [
 564         HAVE_XSHM="yes"
 565       ], [
 566         HAVE_XSHM="no"
 567         XSHM_LIBS=""
 568       ], [ $X_LIBS ])
 569     ], [
 570       HAVE_XSHM="no"
 571     ])
 572   fi
 573 ], , [
 574   AC_SUBST(HAVE_XSHM)
 575   AC_SUBST(XSHM_LIBS)
 576 ])
 577
 578 dnl *** ext plug-ins ***
 579 dnl keep this list sorted alphabetically !
 580
 581 if test "x$BUILD_EXTERNAL" = "xyes"; then
 582
 583 echo
 584 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 585 echo
 586
 587 dnl *** alsa ***
 588 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 589 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 590   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 591     HAVE_ALSA="yes"
 592     AC_SUBST(ALSA_CFLAGS)
 593     AC_SUBST(ALSA_LIBS)
 594   ], [
 595     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 596   ])
 597 ])
 598
 599 dnl *** CDParanoia ***
 600 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 601 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 602 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 603   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 604     HAVE_CDPARANOIA="yes"
 605   ], [
 606     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 607                         cdda_open, -lm,
 608                         cdda_interface.h,
 609                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 610                         HEADER_DIR="no"
 611                         FOUND_CDPARANOIA="yes")
 612     if test "x$FOUND_CDPARANOIA" != "xyes";
 613     then
 614       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 615                           cdda_open, -lm,
 616                           cdda/cdda_interface.h,
 617                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 618                           HEADER_DIR="yes"
 619                           FOUND_CDPARANOIA="yes")
 620     fi
 621     if test "x$HEADER_DIR" = "xyes";
 622     then
 623       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 624                          defined if cdda headers are in a cdda/ directory)
 625     fi
 626     if test "x$FOUND_CDPARANOIA" = "xyes";
 627     then
 628       AC_CHECK_LIB(cdda_paranoia,
 629                    paranoia_cachemodel_size,
 630                    : ,
 631                    HAVE_CDPARANOIA=no,
 632                  [-lcdda_interface])
 633     fi
 634
 635     AC_SUBST(CDPARANOIA_LIBS)
 636   ])
 637 ])
 638 dnl FIXME : add second check somehow if that is necessary
 639 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 640 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 641
 642 dnl *** ivorbis ***
 643 dnl AM_PATH_IVORBIS only takes two options
 644 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 645 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 646   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 647   if test $HAVE_IVORBIS = no
 648   then
 649     IVORBIS_LIBS=
 650     IVORBIS_CFLAGS=
 651     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 652       [IVORBIS_LIBS=-lvorbisidec
 653       HAVE_IVORBIS=yes
 654       case $host in
 655       arm-*-*)
 656         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 657       esac
 658       ],
 659       HAVE_IVORBIS=no)
 660     AC_SUBST(IVORBIS_LIBS)
 661     AC_SUBST(IVORBIS_CFLAGS)
 662   else
 663     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 664       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 665       USE_TREMOLO=no)
 666   fi
 667 ])
 668
 669 dnl *** libvisual ***
 670 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 671 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 672   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 673   if test x$HAVE_LIBVISUAL = xyes; then
 674     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 675   fi
 676   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 677   if test x$LIBVIS_PLUGINSDIR != x; then
 678     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 679         "$LIBVIS_PLUGINSDIR",
 680         [directory in which the detected libvisual's plugins are located])
 681   fi
 682 ])
 683
 684 dnl *** ogg ***
 685 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 686 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 687   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 688 ])
 689
 690 dnl *** pango ***
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 692 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 693   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 694 ])
 695
 696 dnl *** theora ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 698 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 699   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 700 ])
 701
 702 dnl *** vorbis ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 704 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 705   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 706 ])
 707
 708 if test "x$HAVE_VORBIS" = "xyes"; then
 709   ac_cflags_save="$CFLAGS"
 710   AC_COMPILE_IFELSE([
 711     AC_LANG_PROGRAM([[
 712 #include <vorbis/codec.h>
 713                      ]],[[
 714 vorbis_dsp_state *v;
 715
 716 vorbis_synthesis_restart (v);
 717                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 718   if test "x$HAVE_VSR" = "xyes"; then
 719     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 720                        [defined if vorbis_synthesis_restart is present])
 721   fi
 722   CFLAGS="$ac_cflags_save"
 723 fi
 724
 725 else
 726
 727 dnl not building plugins with external dependencies,
 728 dnl but we still need to set the conditionals
 729 AM_CONDITIONAL(USE_ALSA, false)
 730 AM_CONDITIONAL(USE_CDPARANOIA, false)
 731 AM_CONDITIONAL(USE_IVORBIS, false)
 732 AM_CONDITIONAL(USE_LIBVISUAL, false)
 733 AM_CONDITIONAL(USE_OGG, false)
 734 AM_CONDITIONAL(USE_PANGO, false)
 735 AM_CONDITIONAL(USE_THEORA, false)
 736 AM_CONDITIONAL(USE_VORBIS, false)
 737
 738 fi dnl of EXT plugins
 739
 740 dnl seeking needs freetype, so check for it here
 741 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 742   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 743 ])
 744 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 745 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 746 AC_SUBST(FT2_CFLAGS)
 747 AC_SUBST(FT2_LIBS)
 748
 749 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 750 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 751     HAVE_GIO_UNIX_2_0="yes",
 752     HAVE_GIO_UNIX_2_0="no")
 753 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 754
 755 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 756
 757 dnl Overview:
 758 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 759 dnl GST_*:              flags shared by built objects to link against GStreamer
 760 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 761 dnl                          (compare to other modules) or for i18n
 762 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 763 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 764 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 765 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 766
 767 dnl GST_OPTION_CFLAGS
 768 if test "x$USE_DEBUG" = xyes; then
 769    PROFILE_CFLAGS="-g"
 770 fi
 771 AC_SUBST(PROFILE_CFLAGS)
 772
 773 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 774   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 775   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 776 else
 777   DEPRECATED_CFLAGS=""
 778 fi
 779 AC_SUBST(DEPRECATED_CFLAGS)
 780
 781 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 782 dnl at make time with e.g. make ERROR_CFLAGS=""
 783 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 784 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 785 AC_SUBST(GST_OPTION_CFLAGS)
 786 AC_SUBST(GST_OPTION_CXXFLAGS)
 787
 788 dnl our libraries need to be versioned correctly
 789 AC_SUBST(GST_LT_LDFLAGS)
 790
 791 dnl GST_PLUGINS_BASE_CFLAGS
 792 dnl prefer internal headers to already installed ones
 793 dnl also add builddir include for enumtypes and marshal
 794 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 795 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 796
 797 dnl FIXME: do we want to rename to GST_ALL_* ?
 798 dnl add GST_OPTION_CFLAGS, but overridable
 799 GST_CFLAGS="$GST_CFLAGS"
 800 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 801 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 802 AC_SUBST(GST_CFLAGS)
 803 AC_SUBST(GST_CXXFLAGS)
 804 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 805 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 806 AC_SUBST(GST_LIBS)
 807
 808 dnl LDFLAGS really should only contain flags, not libs - they get added before
 809 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 810 GST_ALL_LDFLAGS="-no-undefined"
 811 if test "x${enable_Bsymbolic}" = "xyes"; then
 812   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 813 fi
 814 AC_SUBST(GST_ALL_LDFLAGS)
 815
 816 dnl GST_LIB_LDFLAGS
 817 dnl linker flags shared by all libraries
 818 dnl LDFLAGS modifier defining exported symbols from built libraries
 819 dnl (export _gst_foo but not __gst_foo)
 820 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 821 AC_SUBST(GST_LIB_LDFLAGS)
 822
 823 dnl this really should only contain flags, not libs - they get added before
 824 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 825 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 826 AC_SUBST(GST_PLUGIN_LDFLAGS)
 827
 828 dnl *** output files ***
 829
 830 $MKDIR_P tests/check/orc
 831
 832 AC_CONFIG_FILES(
 833 Makefile
 834 gst-plugins-base.spec
 835 gst/Makefile
 836 gst/adder/Makefile
 837 gst/app/Makefile
 838 gst/audioconvert/Makefile
 839 gst/audiorate/Makefile
 840 gst/audiotestsrc/Makefile
 841 gst/encoding/Makefile
 842 gst/videoconvert/Makefile
 843 gst/gio/Makefile
 844 gst/playback/Makefile
 845 gst/audioresample/Makefile
 846 gst/subparse/Makefile
 847 gst/tcp/Makefile
 848 gst/typefind/Makefile
 849 gst/videotestsrc/Makefile
 850 gst/videorate/Makefile
 851 gst/videoscale/Makefile
 852 gst/volume/Makefile
 853 sys/Makefile
 854 sys/ximage/Makefile
 855 sys/xvimage/Makefile
 856 ext/Makefile
 857 ext/alsa/Makefile
 858 ext/cdparanoia/Makefile
 859 ext/libvisual/Makefile
 860 ext/ogg/Makefile
 861 ext/pango/Makefile
 862 ext/theora/Makefile
 863 ext/vorbis/Makefile
 864 gst-libs/Makefile
 865 gst-libs/gst/Makefile
 866 gst-libs/gst/allocators/Makefile
 867 gst-libs/gst/audio/Makefile
 868 gst-libs/gst/app/Makefile
 869 gst-libs/gst/fft/Makefile
 870 gst-libs/gst/riff/Makefile
 871 gst-libs/gst/rtp/Makefile
 872 gst-libs/gst/rtsp/Makefile
 873 gst-libs/gst/sdp/Makefile
 874 gst-libs/gst/tag/Makefile
 875 gst-libs/gst/pbutils/Makefile
 876 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 877 gst-libs/gst/video/Makefile
 878 tools/Makefile
 879 pkgconfig/Makefile
 880 pkgconfig/gstreamer-allocators.pc
 881 pkgconfig/gstreamer-allocators-uninstalled.pc
 882 pkgconfig/gstreamer-audio.pc
 883 pkgconfig/gstreamer-audio-uninstalled.pc
 884 pkgconfig/gstreamer-app.pc
 885 pkgconfig/gstreamer-app-uninstalled.pc
 886 pkgconfig/gstreamer-fft.pc
 887 pkgconfig/gstreamer-fft-uninstalled.pc
 888 pkgconfig/gstreamer-pbutils.pc
 889 pkgconfig/gstreamer-pbutils-uninstalled.pc
 890 pkgconfig/gstreamer-riff.pc
 891 pkgconfig/gstreamer-riff-uninstalled.pc
 892 pkgconfig/gstreamer-rtp.pc
 893 pkgconfig/gstreamer-rtp-uninstalled.pc
 894 pkgconfig/gstreamer-rtsp.pc
 895 pkgconfig/gstreamer-rtsp-uninstalled.pc
 896 pkgconfig/gstreamer-sdp.pc
 897 pkgconfig/gstreamer-sdp-uninstalled.pc
 898 pkgconfig/gstreamer-tag.pc
 899 pkgconfig/gstreamer-tag-uninstalled.pc
 900 pkgconfig/gstreamer-video.pc
 901 pkgconfig/gstreamer-video-uninstalled.pc
 902 pkgconfig/gstreamer-plugins-base.pc
 903 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 904 tests/Makefile
 905 tests/check/Makefile
 906 tests/examples/Makefile
 907 tests/examples/app/Makefile
 908 tests/examples/audio/Makefile
 909 tests/examples/dynamic/Makefile
 910 tests/examples/encoding/Makefile
 911 tests/examples/fft/Makefile
 912 tests/examples/gio/Makefile
 913 tests/examples/overlay/Makefile
 914 tests/examples/seek/Makefile
 915 tests/examples/snapshot/Makefile
 916 tests/examples/playback/Makefile
 917 tests/examples/playrec/Makefile
 918 tests/files/Makefile
 919 tests/icles/Makefile
 920 tests/icles/playback/Makefile
 921 docs/Makefile
 922 docs/design/Makefile
 923 docs/libs/Makefile
 924 docs/plugins/Makefile
 925 docs/version.entities
 926 po/Makefile.in
 927 common/Makefile
 928 common/m4/Makefile
 929 m4/Makefile
 930 )
 931
 932 dnl Create the config.h file for Visual Studio builds
 933 dnl Beware of spaces and /'s in some of the shell variable contents.
 934 sed \
 935     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 936     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 937     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 938     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 939     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 940     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 941     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 942     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 943     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 944     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 945     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 946     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 947     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 948     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 949     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 950     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 951     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 952     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 953     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 954     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 955     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 956     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 957     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 958     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 959     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 960     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 961     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 962     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 963     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 964     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 965     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 966     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 967     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 968     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 969     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 970     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 971     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 972     config.h.in >win32/common/config.h-new
 973
 974
 975
 976 AC_OUTPUT
 977
 978 AG_GST_OUTPUT_PLUGINS
 979 ORC_OUTPUT
 980