configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [9])
   6 m4_define([dbus_micro_version], [7])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability subdir-objects])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=13
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=2
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=10
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     # Yes, on Windows it really does work like this.
 103     # http://support.microsoft.com/kb/111855
 104     AC_DEFINE(FD_SETSIZE,8192,[The maximum number of connections that can be handled at once])
 105     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 106     AC_SUBST(BUILD_TIMESTAMP)
 107     # Assume DBUS_VERSION is always three numbers
 108     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 109     AC_SUBST(BUILD_FILEVERSION)
 110     AC_CHECK_TOOL(WINDRES, windres, no)
 111     if test "$WINDRES" = no; then
 112       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 113     fi
 114     if test "$dbus_wince" = yes; then
 115       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 116       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 117     fi
 118 else
 119     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 120 fi
 121 if test "$dbus_cygwin" = yes; then
 122     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 123 fi
 124
 125 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 126 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 127 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 128 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 129
 130 # this must come first: other options use this to set their defaults
 131 AC_ARG_ENABLE([developer],
 132   [AS_HELP_STRING([--enable-developer],
 133     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 134   [],
 135   [enable_developer=no])
 136
 137 DBUS_STATIC_BUILD_CPPFLAGS=
 138 if test "x$enable_shared" = xno; then
 139     # On Windows, linking against the static library requires special effort
 140     # to turn off DLL import/export processing. We normally link some things
 141     # against the dynamic library, but if we're not building that, we'll
 142     # have to link everything statically.
 143     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 144 fi
 145 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 146
 147 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 148 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 149 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 150 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 151 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 152 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 153 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 154 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 155 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 156 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 157 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 158 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 159 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 160 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 161
 162 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 163 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 164 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 165 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 166 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 167 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 168 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 169 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 170 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 171 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 172
 173 AC_ARG_ENABLE([embedded-tests],
 174   AS_HELP_STRING([--enable-embedded-tests],
 175     [enable unit test code in the library and binaries]),
 176   [], [enable_embedded_tests=$enable_developer])
 177 AC_ARG_ENABLE([modular-tests],
 178   AS_HELP_STRING([--enable-modular-tests],
 179     [enable modular regression tests (requires GLib)]),
 180   [], [enable_modular_tests=auto])
 181 # --enable-tests overrides both --enable-embedded-tests and
 182 # --enable-modular-tests
 183 AC_ARG_ENABLE([tests],
 184   AS_HELP_STRING([--enable-tests],
 185     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 186   [
 187   if test "x$enableval" = xyes; then
 188     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 189     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 190   fi
 191   enable_embedded_tests=$enableval
 192   enable_modular_tests=$enableval
 193   ],
 194   [])
 195
 196 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 197 # and also some stuff in the test/ subdir.
 198 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 199   [test "x$enable_embedded_tests" = xyes])
 200 if test "x$enable_embedded_tests" = xyes; then
 201     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 202       [Define to build test code into the library and binaries])
 203 fi
 204
 205 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 206 # These use GTest, from GLib, because life's too short. They're enabled by
 207 # default (unless you don't have GLib), because they don't bloat the library
 208 # or binaries.
 209
 210 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_26], [Ignore post-2.26 deprecations])
 211 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_38], [Prevent post-2.38 APIs])
 212
 213 with_glib=yes
 214
 215 AS_IF([test "x$enable_modular_tests" != xno],
 216   [
 217   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 218     [],
 219     [if test "x$enable_modular_tests" = xyes; then
 220       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 221       AC_MSG_ERROR([$GLIB_ERRORS])
 222     else # assumed to be "auto"
 223       with_glib=no
 224     fi])
 225   ],
 226   [with_glib=no])
 227
 228 # Not required, because we can use internal APIs (but that makes the
 229 # "installable tests" less useful as integration tests)
 230 AC_ARG_WITH([dbus_glib],
 231   [AS_HELP_STRING([--with-dbus-glib], [Use dbus-glib for regression tests])],
 232   [],
 233   [with_dbus_glib=auto])
 234 AS_IF([test "x$with_dbus_glib" != xno],
 235   [PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 236     [],
 237     [AS_IF([test "x$with_dbus_glib" = xyes],
 238       dnl specifically requested, but not found
 239       [AC_MSG_ERROR([$DBUS_GLIB_ERRORS])],
 240       dnl else: assumed to be "auto"
 241       [with_dbus_glib=no])])])
 242 AM_CONDITIONAL([DBUS_WITH_DBUS_GLIB], [test "x$with_dbus_glib" != xno])
 243
 244 if test "x$enable_modular_tests" != xno; then
 245   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 246     [Define to build independent test binaries])
 247 fi
 248 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 249   [test "x$enable_modular_tests" != xno])
 250
 251 if test "x$with_glib" != xno; then
 252   AC_DEFINE([DBUS_WITH_GLIB], [1],
 253     [Define if GLib, GObject, GIO are available])
 254 fi
 255 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 256
 257 AC_ARG_ENABLE([installed-tests],
 258   AS_HELP_STRING([--enable-installed-tests],
 259     [enable unit test code in the library and binaries]),
 260   [], [enable_installed_tests=no])
 261 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 262   [test "x$enable_installed_tests" = xyes])
 263
 264 if test "x$enable_tests" = xyes; then
 265   # full test coverage is required, Python is a hard dependency
 266   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygi])
 267   AM_PATH_PYTHON([2.6])
 268   AC_MSG_CHECKING([for Python modules for full test coverage])
 269   if "$PYTHON" -c "import dbus, gi.repository.GObject, dbus.mainloop.glib"; then
 270     AC_MSG_RESULT([yes])
 271   else
 272     AC_MSG_RESULT([no])
 273     AC_MSG_ERROR([cannot import dbus, gi.repository.GObject, dbus.mainloop.glib Python modules])
 274   fi
 275 else
 276   # --enable-tests not given: do not abort if Python is missing
 277   AM_PATH_PYTHON([2.6], [], [:])
 278 fi
 279
 280 if test x$enable_verbose_mode = xyes; then
 281     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 282 fi
 283
 284 if test x$enable_asserts = xno; then
 285     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 286     DISABLE_UNUSED_WARNINGS="unused-label"
 287     R_DYNAMIC_LDFLAG=""
 288     if test x$enable_embedded_tests = xyes; then
 289         DISABLE_UNUSED_WARNINGS="$DISABLE_UNUSED_WARNINGS \
 290                 unused-but-set-variable unused-variable \
 291                 unused-function"
 292     fi
 293 else
 294     # -rdynamic is needed for glibc's backtrace_symbols to work.
 295     # No clue how much overhead this adds, but it's useful
 296     # to do this on any assertion failure,
 297     # so for now it's enabled anytime asserts are (currently not
 298     # in production builds).
 299
 300     # To get -rdynamic you pass -export-dynamic to libtool.
 301     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 302     R_DYNAMIC_LDFLAG=-export-dynamic
 303 fi
 304 AC_SUBST(R_DYNAMIC_LDFLAG)
 305
 306 if test x$enable_checks = xno; then
 307     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 308     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 309     DISABLE_UNUSED_WARNINGS="unused-label"
 310 fi
 311
 312 AH_BOTTOM([
 313 /* explicitly define these macros to get less confusing conditions */
 314 #ifndef DBUS_DISABLE_ASSERT
 315 #  define DBUS_ENABLE_ASSERT 1
 316 #endif
 317 #ifndef DBUS_DISABLE_CHECKS
 318 #  define DBUS_ENABLE_CHECKS 1
 319 #endif])
 320
 321 if test x$enable_compiler_coverage = xyes; then
 322      ## so that config.h changes when you toggle gcov support
 323      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 324 fi
 325
 326 # glibc21.m4 serial 3
 327 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 328 dnl This file is free software; the Free Software Foundation
 329 dnl gives unlimited permission to copy and/or distribute it,
 330 dnl with or without modifications, as long as this notice is preserved.
 331
 332 # Test for the GNU C Library, version 2.1 or newer.
 333 # From Bruno Haible.
 334
 335 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 336   ac_cv_gnu_library_2_1,
 337   [AC_EGREP_CPP([Lucky GNU user],
 338     [
 339 #include <features.h>
 340 #ifdef __GNU_LIBRARY__
 341  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 342   Lucky GNU user
 343  #endif
 344 #endif
 345     ],
 346     ac_cv_gnu_library_2_1=yes,
 347     ac_cv_gnu_library_2_1=no)
 348   ]
 349 )
 350
 351 #### Integer sizes
 352
 353 AC_CHECK_SIZEOF(char)
 354 AC_CHECK_SIZEOF(short)
 355 AC_CHECK_SIZEOF(long)
 356 AC_CHECK_SIZEOF(int)
 357 AC_CHECK_SIZEOF(void *)
 358 AC_CHECK_SIZEOF(long long)
 359 AC_CHECK_SIZEOF(__int64)
 360
 361 ### See what our 64 bit type is called
 362 AC_MSG_CHECKING([64-bit integer type])
 363
 364 case 8 in
 365 $ac_cv_sizeof_int)
 366   dbusint64=int
 367   dbusint64_constant='(val)'
 368   dbusuint64_constant='(val)'
 369   dbusint64_printf_modifier='""'
 370   ;;
 371 $ac_cv_sizeof_long)
 372   dbusint64=long
 373   dbusint64_constant='(val##L)'
 374   dbusuint64_constant='(val##UL)'
 375   dbusint64_printf_modifier='"l"'
 376   ;;
 377 $ac_cv_sizeof_long_long)
 378   dbusint64='long long'
 379   dbusint64_constant='(val##LL)'
 380   dbusuint64_constant='(val##ULL)'
 381   # Ideally we discover what the format is, but this is
 382   # only used in verbose mode, so eh...
 383   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 384     dbusint64_printf_modifier='"ll"'
 385   fi
 386   ;;
 387 $ac_cv_sizeof___int64)
 388   dbusint64=__int64
 389   dbusint64_constant='(val##i64)'
 390   dbusuint64_constant='(val##ui64)'
 391   # See above case
 392   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 393     dbusint64_printf_modifier='"ll"'
 394   fi
 395   ;;
 396 esac
 397
 398 AS_IF(
 399   [test -z "$dbusint64"],
 400   [AC_MSG_RESULT([not found])
 401   AC_MSG_ERROR([Could not find a 64-bit integer type.
 402
 403 Please report a bug here with details of your platform and compiler:
 404
 405     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core])
 406   ],
 407   dnl else
 408   [
 409         DBUS_INT64_TYPE="$dbusint64"
 410         DBUS_INT64_CONSTANT="$dbusint64_constant"
 411         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 412         if test x"$dbusint64_printf_modifier" != x; then
 413                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 414         fi
 415         AC_MSG_RESULT($DBUS_INT64_TYPE)
 416   ])
 417
 418 AC_SUBST(DBUS_INT64_TYPE)
 419 AC_SUBST(DBUS_INT64_CONSTANT)
 420 AC_SUBST(DBUS_UINT64_CONSTANT)
 421
 422 ### see what 32-bit int is called
 423 AC_MSG_CHECKING([32-bit integer type])
 424
 425 case 4 in
 426 $ac_cv_sizeof_short)
 427   dbusint32=short
 428   ;;
 429 $ac_cv_sizeof_int)
 430   dbusint32=int
 431   ;;
 432 $ac_cv_sizeof_long)
 433   dbusint32=long
 434   ;;
 435 esac
 436
 437 if test -z "$dbusint32" ; then
 438         DBUS_INT32_TYPE="no_int32_type_detected"
 439         AC_MSG_ERROR([No 32-bit integer type found])
 440 else
 441         DBUS_INT32_TYPE="$dbusint32"
 442         AC_MSG_RESULT($DBUS_INT32_TYPE)
 443 fi
 444
 445 AC_SUBST(DBUS_INT32_TYPE)
 446
 447 ### see what 16-bit int is called
 448 AC_MSG_CHECKING([16-bit integer type])
 449
 450 case 2 in
 451 $ac_cv_sizeof_short)
 452   dbusint16=short
 453   ;;
 454 $ac_cv_sizeof_int)
 455   dbusint16=int
 456   ;;
 457 esac
 458
 459 if test -z "$dbusint16" ; then
 460         DBUS_INT16_TYPE="no_int16_type_detected"
 461         AC_MSG_ERROR([No 16-bit integer type found])
 462 else
 463         DBUS_INT16_TYPE="$dbusint16"
 464         AC_MSG_RESULT($DBUS_INT16_TYPE)
 465 fi
 466
 467 AC_SUBST(DBUS_INT16_TYPE)
 468
 469 ## byte order
 470 case $host_os in
 471         darwin*)
 472                 # check at compile-time, so that it is possible to build universal
 473                 # (with multiple architectures at once on the compile line)
 474                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 475                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 476                         #if defined(__BIG_ENDIAN__)
 477                         #define WORDS_BIGENDIAN 1
 478                         #endif
 479                 ])
 480                 ;;
 481         *)
 482                 AC_C_BIGENDIAN
 483                 ;;
 484 esac
 485
 486 dnl **********************************
 487 dnl *** va_copy checks (from GLib) ***
 488 dnl **********************************
 489 dnl we currently check for all three va_copy possibilities, so we get
 490 dnl all results in config.log for bug reports.
 491 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 492         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 493 #include <stdlib.h>
 494         static void f (int i, ...) {
 495         va_list args1, args2;
 496         va_start (args1, i);
 497         va_copy (args2, args1);
 498         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 499           exit (1);
 500         va_end (args1); va_end (args2);
 501         }
 502         int main() {
 503           f (0, 42);
 504           return 0;
 505         }])],
 506         [dbus_cv_va_copy=yes],
 507         [dbus_cv_va_copy=no])
 508 ])
 509 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 510         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 511 #include <stdlib.h>
 512         static void f (int i, ...) {
 513         va_list args1, args2;
 514         va_start (args1, i);
 515         __va_copy (args2, args1);
 516         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 517           exit (1);
 518         va_end (args1); va_end (args2);
 519         }
 520         int main() {
 521           f (0, 42);
 522           return 0;
 523         }])],
 524         [dbus_cv___va_copy=yes],
 525         [dbus_cv___va_copy=no])
 526 ])
 527
 528 if test "x$dbus_cv_va_copy" = "xyes"; then
 529   dbus_va_copy_func=va_copy
 530 else if test "x$dbus_cv___va_copy" = "xyes"; then
 531   dbus_va_copy_func=__va_copy
 532 fi
 533 fi
 534
 535 if test -n "$dbus_va_copy_func"; then
 536   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 537 fi
 538
 539 AC_LANG_PUSH(C)
 540 AC_CACHE_CHECK([whether va_lists can be copied by value],
 541         dbus_cv_va_val_copy,
 542         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 543 [[
 544         #include <stdarg.h>
 545         #include <stdlib.h>
 546 ]],
 547 [[
 548         static void f (int i, ...) {
 549         va_list args1, args2;
 550         va_start (args1, i);
 551         args2 = args1;
 552         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 553           exit (1);
 554         va_end (args1); va_end (args2);
 555         }
 556         int main() {
 557           f (0, 42);
 558           return 0;
 559         }
 560 ]])],
 561         [dbus_cv_va_val_copy=yes],
 562         [dbus_cv_va_val_copy=no],
 563         [dbus_cv_va_val_copy=yes])
 564 ])
 565 AC_LANG_POP(C)
 566
 567 if test "x$dbus_cv_va_val_copy" = "xno"; then
 568   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 569 fi
 570
 571
 572 #### Atomic integers
 573
 574 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 575   dbus_cv_sync_sub_and_fetch,
 576   [AC_LINK_IFELSE([
 577      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 578      [dbus_cv_sync_sub_and_fetch=yes],
 579      [dbus_cv_sync_sub_and_fetch=no])
 580   ])
 581
 582 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 583    have_sync=1
 584 else
 585    have_sync=0
 586 fi
 587
 588 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 589
 590 #### Various functions
 591 AC_SEARCH_LIBS(socket,[socket network])
 592 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 593
 594 AC_CHECK_FUNCS([vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid getrlimit])
 595
 596 AC_CHECK_HEADERS([syslog.h])
 597 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 598   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 599 fi
 600
 601 # For test-segfault.c
 602 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 603 AC_CHECK_FUNCS_ONCE([prctl raise])
 604
 605 #### Check for broken poll; taken from Glib's configure
 606
 607 AC_MSG_CHECKING([for broken poll])
 608 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 609     #include <stdlib.h>
 610     #include <fcntl.h>
 611     #include <poll.h>
 612     #ifdef HAVE_SYS_POLL_H
 613     #include <sys/poll.h>
 614     #endif
 615     int main(void) {
 616       struct pollfd fds[1];
 617       int fd;
 618       fd = open("/dev/null", 1);
 619       fds[0].fd = fd;
 620       fds[0].events = POLLIN;
 621       fds[0].revents = 0;
 622       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 623             exit(1);  /* Does not work for devices -- fail */
 624       }
 625       exit(0);
 626     }]])],
 627   [broken_poll=no],
 628   [broken_poll=yes
 629    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 630   [broken_poll="no (cross compiling)"])
 631 AC_MSG_RESULT($broken_poll)
 632
 633 AC_MSG_CHECKING(for dirfd)
 634 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 635 #include <sys/types.h>
 636 #include <dirent.h>
 637 ]], [[
 638 DIR *dirp;
 639 dirp = opendir(".");
 640 dirfd(dirp);
 641 closedir(dirp);
 642 ]])],
 643 [dbus_have_dirfd=yes],
 644 [dbus_have_dirfd=no])
 645 AC_MSG_RESULT($dbus_have_dirfd)
 646 if test "$dbus_have_dirfd" = yes; then
 647         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 648 else
 649         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 650         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 651 #include <sys/types.h>
 652 #include <dirent.h>
 653         ]], [[
 654 DIR *dirp;
 655 int fd;
 656 dirp = opendir(".");
 657 fd = dirp->dd_fd;
 658 closedir(dirp);
 659         ]])],
 660         [dbus_have_ddfd=yes],
 661         [dbus_have_ddfd=no])
 662         AC_MSG_RESULT($dbus_have_ddfd)
 663         if test "$dbus_have_ddfd" = yes; then
 664                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 665         fi
 666 fi
 667
 668 AC_CHECK_HEADERS(sys/resource.h)
 669
 670 AC_CHECK_HEADERS(dirent.h)
 671
 672 AC_CHECK_HEADERS([execinfo.h],
 673         [AC_SEARCH_LIBS([backtrace], [execinfo],
 674                 [AC_DEFINE([HAVE_BACKTRACE], [1],
 675                         [Define to 1 if you have backtrace().])])])
 676
 677 AC_CHECK_HEADERS(errno.h)
 678
 679 AC_CHECK_HEADERS(signal.h)
 680
 681 AC_CHECK_HEADERS(locale.h)
 682
 683 AC_CHECK_HEADERS(byteswap.h)
 684
 685 AC_CHECK_HEADERS(unistd.h)
 686
 687 AC_CHECK_HEADERS(ws2tcpip.h)
 688
 689 AC_CHECK_HEADERS(alloca.h)
 690
 691 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 692 #
 693 case $host_os in
 694     solaris*)
 695        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 696 esac
 697
 698 # checking for a posix version of getpwnam_r
 699 # if we are cross compiling and can not run the test
 700 # assume getpwnam_r is the posix version
 701 # it is up to the person cross compiling to change
 702 # this behavior if desired
 703 AC_LANG_PUSH(C)
 704 AC_CACHE_CHECK([for posix getpwnam_r],
 705                 ac_cv_func_posix_getpwnam_r,
 706                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 707 [[
 708 #include <errno.h>
 709 #include <pwd.h>
 710 ]],
 711 [[
 712     char buffer[10000];
 713     struct passwd pwd, *pwptr = &pwd;
 714     int error;
 715     errno = 0;
 716     error = getpwnam_r ("", &pwd, buffer,
 717                         sizeof (buffer), &pwptr);
 718    return (error < 0 && errno == ENOSYS)
 719            || error == ENOSYS;
 720 ]])],
 721         [ac_cv_func_posix_getpwnam_r=yes],
 722         [ac_cv_func_posix_getpwnam_r=no],
 723         [ac_cv_func_posix_getpwnam_r=yes]
 724 )])
 725 AC_LANG_POP(C)
 726
 727 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 728         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 729                 [Have POSIX function getpwnam_r])
 730 else
 731         AC_CACHE_CHECK([for nonposix getpwnam_r],
 732                 ac_cv_func_nonposix_getpwnam_r,
 733                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 734                         struct passwd pwd;
 735                         getpwnam_r ("", &pwd, buffer,
 736                                         sizeof (buffer));]])],
 737                         [ac_cv_func_nonposix_getpwnam_r=yes],
 738                         [ac_cv_func_nonposix_getpwnam_r=no])])
 739                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 740                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 741                         [Have non-POSIX function getpwnam_r])
 742         fi
 743 fi
 744
 745 dnl check for socklen_t
 746 AC_MSG_CHECKING(whether socklen_t is defined)
 747 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 748 #include <sys/types.h>
 749 #include <sys/socket.h>
 750 #include <netdb.h>
 751 ]], [[
 752 socklen_t foo;
 753 foo = 1;
 754 ]])],
 755 [dbus_have_socklen_t=yes],
 756 [dbus_have_socklen_t=no])
 757 AC_MSG_RESULT($dbus_have_socklen_t)
 758
 759 if test "x$dbus_have_socklen_t" = "xyes"; then
 760     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 761 fi
 762
 763 dnl check for writev header and writev function so we're
 764 dnl good to go if HAVE_WRITEV gets defined.
 765 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 766
 767 dnl needed on darwin for NAME_MAX
 768 AC_CHECK_HEADERS(sys/syslimits.h)
 769
 770 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 771 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 772 #include <sys/socket.h> ]])
 773
 774 dnl check for flavours of varargs macros (test from GLib)
 775 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 776 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 777 int a(int p1, int p2, int p3);
 778 #define call_a(...) a(1,__VA_ARGS__)
 779 call_a(2,3);
 780 ]])],
 781 [dbus_have_iso_c_varargs=yes],
 782 [dbus_have_iso_c_varargs=no])
 783 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 784
 785 AC_MSG_CHECKING(for GNUC varargs macros)
 786 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 787 int a(int p1, int p2, int p3);
 788 #define call_a(params...) a(1,params)
 789 call_a(2,3);
 790 ]])],
 791 [dbus_have_gnuc_varargs=yes],
 792 [dbus_have_gnuc_varargs=no])
 793 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 794
 795 dnl Output varargs tests
 796 if test x$dbus_have_iso_c_varargs = xyes; then
 797     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 798 fi
 799 if test x$dbus_have_gnuc_varargs = xyes; then
 800     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 801 fi
 802
 803 dnl Check for various credentials.
 804 AC_MSG_CHECKING(for struct cmsgcred)
 805 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 806 #include <sys/types.h>
 807 #include <sys/socket.h>
 808 ]], [[
 809 struct cmsgcred cred;
 810
 811 cred.cmcred_pid = 0;
 812 ]])],
 813 [dbus_have_struct_cmsgcred=yes],
 814 [dbus_have_struct_cmsgcred=no])
 815 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 816
 817 if test x$dbus_have_struct_cmsgcred = xyes; then
 818     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 819 fi
 820
 821 AC_CHECK_MEMBER([struct unpcbid.unp_pid],
 822                 [AC_DEFINE([HAVE_UNPCBID], 1, [Have unpcbid structure])],
 823                 [],
 824                 [[#include <sys/un.h>]])
 825
 826 AC_CHECK_FUNCS(getpeerucred getpeereid)
 827
 828 AC_CHECK_FUNCS(pipe2 accept4)
 829
 830 #### Abstract sockets
 831
 832 if test x$enable_abstract_sockets = xauto; then
 833 AC_LANG_PUSH(C)
 834 warn_on_xcompile=no
 835 AC_CACHE_CHECK([abstract socket namespace],
 836                 ac_cv_have_abstract_sockets,
 837                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 838 [[
 839 #include <sys/types.h>
 840 #include <stdlib.h>
 841 #include <string.h>
 842 #include <stdio.h>
 843 #include <sys/socket.h>
 844 #include <sys/un.h>
 845 #include <errno.h>
 846 ]],
 847 [[
 848   size_t slen;
 849   int listen_fd;
 850   struct sockaddr_un addr;
 851
 852   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 853
 854   if (listen_fd < 0)
 855     {
 856       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 857       exit (1);
 858     }
 859
 860   memset (&addr, '\0', sizeof (addr));
 861   addr.sun_family = AF_UNIX;
 862   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 863   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 864    * beginning.
 865    */
 866   slen = SUN_LEN(&addr);
 867   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 868
 869   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 870     {
 871        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 872                 strerror (errno));
 873        exit (1);
 874     }
 875   else
 876     exit (0);
 877 ]])],
 878               [ac_cv_have_abstract_sockets=yes],
 879               [ac_cv_have_abstract_sockets=no],
 880               [
 881                 ac_cv_have_abstract_sockets=no
 882                 warn_on_xcompile=yes
 883               ]
 884 )])
 885 if test x$warn_on_xcompile = xyes ; then
 886   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 887 fi
 888 AC_LANG_POP(C)
 889 fi
 890
 891 if test x$enable_abstract_sockets = xyes; then
 892     if test x$ac_cv_have_abstract_sockets = xno; then
 893         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 894     fi
 895 fi
 896
 897 if test x$enable_abstract_sockets = xno; then
 898    ac_cv_have_abstract_sockets=no;
 899 fi
 900
 901 if test x$ac_cv_have_abstract_sockets = xyes ; then
 902    DBUS_PATH_OR_ABSTRACT=abstract
 903    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 904 else
 905    DBUS_PATH_OR_ABSTRACT=path
 906 fi
 907
 908 # this is used in addresses to prefer abstract, e.g.
 909 # unix:path=/foo or unix:abstract=/foo
 910 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 911
 912 #### Sort out XML library
 913
 914 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 915              [ AC_CHECK_HEADERS(expat.h, [],
 916                                 [AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])]) ],
 917              [ AC_MSG_ERROR([Explicitly requested expat but expat not found]) ])
 918
 919 XML_LIBS=-lexpat
 920 XML_CFLAGS=
 921 AC_SUBST([XML_CFLAGS])
 922 AC_SUBST([XML_LIBS])
 923
 924 # Thread lib detection
 925 AC_ARG_VAR([THREAD_LIBS])
 926 save_libs="$LIBS"
 927 LIBS="$LIBS $THREAD_LIBS"
 928
 929 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 930
 931 # Don't do these automatic checks if the user set THREAD_LIBS on the
 932 # configure command-line. If they did, we assume they're right.
 933 #
 934 # We also don't do these checks on Windows, because you don't need magical
 935 # linker flags to have threading support there.
 936 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 937   [
 938     # Mandatory pthread functions. In principle, some of these could be made
 939     # optional if there are platforms that don't have them.
 940     #
 941     # Currently, we only look in -lpthread.
 942     # In principle we might need to look in -lpthreads, -lthreads, ...
 943     # as well - please file a bug if your platform needs this.
 944     AC_SEARCH_LIBS([pthread_cond_timedwait],
 945         [pthread],
 946         [THREAD_LIBS="$LIBS"],
 947         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 948         [])
 949     AC_SEARCH_LIBS([pthread_mutexattr_init],
 950         [pthread],
 951         [THREAD_LIBS="$LIBS"],
 952         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 953         [])
 954     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 955         [pthread],
 956         [THREAD_LIBS="$LIBS"],
 957         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 958         [])
 959
 960     # Optional, for monotonic clocks. Because it's optional, this check
 961     # is non-fatal if we don't find it.
 962     AC_SEARCH_LIBS([pthread_condattr_setclock],
 963         [pthread],
 964         [THREAD_LIBS="$LIBS"])
 965
 966     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 967       [
 968         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 969         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 970         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 971 [[#include <time.h>
 972 #include <pthread.h>
 973 ]], [[
 974 struct timespec monotonic_timer;
 975 pthread_condattr_t attr;
 976 pthread_condattr_init (&attr);
 977 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 978 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 979 ]])],
 980             [have_clock_monotonic=true],
 981             [have_clock_monotonic=false])
 982         AS_IF([test x$have_clock_monotonic = xtrue],
 983           [
 984             AC_MSG_RESULT([found])
 985             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 986           ],
 987           [AC_MSG_RESULT([not found])])
 988       ]) dnl have pthread_condattr_setclock
 989   ]) dnl on Unix
 990
 991 LIBS="$save_libs"
 992
 993 AC_SUBST([THREAD_LIBS])
 994
 995 # SELinux detection
 996 if test x$enable_selinux = xno ; then
 997     have_selinux=no;
 998 else
 999     # See if we have SELinux library
1000     AC_CHECK_LIB(selinux, is_selinux_enabled,
1001                  have_selinux=yes, have_selinux=no)
1002
1003     # see if we have the SELinux header with the new D-Bus stuff in it
1004     if test x$have_selinux = xyes ; then
1005         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
1006         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
1007                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
1008                             #else
1009                             #error DBUS__ACQUIRE_SVC not defined
1010                             #endif]])],
1011                           [have_selinux=yes],
1012                           [have_selinux=no])
1013         AC_MSG_RESULT($have_selinux)
1014     fi
1015
1016     if test x$enable_selinux = xauto ; then
1017         if test x$have_selinux = xno ; then
1018                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1019         fi
1020     else
1021         if test x$have_selinux = xno ; then
1022                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1023         fi
1024     fi
1025 fi
1026
1027 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1028
1029 if test x$have_selinux = xyes ; then
1030     # the selinux code creates threads
1031     # which requires libpthread even on linux
1032     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1033                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1034
1035     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1036     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1037 else
1038     SELINUX_LIBS=
1039 fi
1040
1041 # inotify checks
1042 if test x$enable_inotify = xno ; then
1043     have_inotify=no;
1044 else
1045     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1046 fi
1047
1048 dnl check if inotify backend is enabled
1049 if test x$have_inotify = xyes; then
1050    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1051    AC_CHECK_FUNCS(inotify_init1)
1052 fi
1053
1054 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1055
1056 # For simplicity, we require the userland API for epoll_create1 at
1057 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1058 # not to have it at runtime.
1059 AC_ARG_ENABLE([epoll],
1060               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1061               [enable_epoll=$enableval], [enable_epoll=auto])
1062 if test x$enable_epoll = xno; then
1063     have_linux_epoll=no
1064 else
1065     AC_MSG_CHECKING([for Linux epoll(4)])
1066     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1067         [
1068         #ifndef __linux__
1069         #error This is not Linux
1070         #endif
1071         #include <sys/epoll.h>
1072         ],
1073         [epoll_create1 (EPOLL_CLOEXEC);])],
1074         [have_linux_epoll=yes],
1075         [have_linux_epoll=no])
1076     AC_MSG_RESULT([$have_linux_epoll])
1077 fi
1078 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1079     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1080 fi
1081 if test x$have_linux_epoll = xyes; then
1082   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1083 fi
1084 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1085
1086 # kqueue checks
1087 if test x$enable_kqueue = xno ; then
1088     have_kqueue=no
1089 else
1090     have_kqueue=yes
1091     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1092     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1093
1094     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1095         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1096     fi
1097 fi
1098
1099 dnl check if kqueue backend is enabled
1100 if test x$have_kqueue = xyes; then
1101    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1102 fi
1103
1104 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1105
1106 # launchd checks
1107 if test x$enable_launchd = xno ; then
1108     have_launchd=no
1109 else
1110     have_launchd=yes
1111     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1112     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1113     if test "x$LAUNCHCTL" = "x"; then
1114         have_launchd=no
1115     fi
1116
1117     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1118         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1119     fi
1120 fi
1121
1122 dnl check if launchd is enabled
1123 if test x$have_launchd = xyes; then
1124     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1125 fi
1126
1127 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1128
1129 #### Directory to place launchd agent file
1130 if test "x$with_launchd_agent_dir" = "x"; then
1131    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1132 else
1133    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1134 fi
1135
1136 AC_SUBST(LAUNCHD_AGENT_DIR)
1137
1138 dnl console owner file
1139 if test x$enable_console_owner_file = xno ; then
1140     have_console_owner_file=no;
1141 else
1142     case $host_os in
1143     solaris*)
1144         have_console_owner_file=yes;
1145         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1146         ;;
1147     *)
1148         have_console_owner_file=no;;
1149     esac
1150 fi
1151
1152 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1153
1154 dnl systemd detection
1155 if test x$enable_systemd = xno ; then
1156     have_systemd=no;
1157 else
1158     PKG_CHECK_MODULES([SYSTEMD],
1159         [libsystemd >= 209],
1160         [have_systemd=yes],
1161         [PKG_CHECK_MODULES([SYSTEMD],
1162             [libsystemd-login >= 32, libsystemd-daemon >= 32, libsystemd-journal >= 32],
1163             [have_systemd=yes],
1164             [have_systemd=no])])
1165 fi
1166
1167 if test x$have_systemd = xyes; then
1168     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1169 fi
1170
1171 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1172     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1173 fi
1174
1175 # libaudit detection
1176 if test x$enable_libaudit = xno ; then
1177     have_libaudit=no;
1178 else
1179     # See if we have audit daemon & capabilities library
1180     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1181                  have_libaudit=yes, have_libaudit=no)
1182     if test x$have_libaudit = xyes ; then
1183         AC_CHECK_LIB(cap-ng, capng_clear,
1184                  have_libaudit=yes, have_libaudit=no)
1185     fi
1186 fi
1187
1188 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1189
1190 if test x$have_libaudit = xyes ; then
1191     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1192     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1193 fi
1194
1195 AC_SUBST([SELINUX_LIBS])
1196
1197 # Check for ADT API (Solaris Basic Security Mode auditing)
1198 AC_MSG_CHECKING(for ADT API)
1199 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1200 #include <bsm/adt.h>
1201 adt_user_context = ADT_USER;
1202 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1203
1204 if test ${check_adt_audit} = yes
1205 then
1206    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1207    ADT_LIBS="-lbsm"
1208    LIBS="-lbsm $LIBS"
1209    AC_MSG_RESULT(yes)
1210 else
1211    AC_MSG_RESULT(no)
1212 fi
1213 AC_SUBST([ADT_LIBS])
1214
1215 # Check for SCM_RIGHTS
1216 AC_MSG_CHECKING([for SCM_RIGHTS])
1217 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1218 #include <sys/types.h>
1219 #include <sys/socket.h>
1220 #include <sys/un.h>
1221 static int x = SCM_RIGHTS;
1222 ]], [[]])],
1223 [ AC_MSG_RESULT([supported])
1224   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1225 [ AC_MSG_RESULT([not supported]) ])
1226
1227 NETWORK_libs=
1228 if test x$dbus_win = xyes ; then
1229   if test x$dbus_wince = xyes ; then
1230     NETWORK_libs="-lws2"
1231   else
1232     NETWORK_libs="-lws2_32 -liphlpapi"
1233   fi
1234 fi
1235
1236 AC_SUBST([NETWORK_libs])
1237
1238 AC_ARG_WITH([valgrind],
1239   [AS_HELP_STRING([--with-valgrind],
1240      [Add instrumentation to help valgrind to understand our allocator])],
1241   [],
1242   [with_valgrind=no])
1243
1244 AS_IF([test "x$with_valgrind" = xauto],
1245   [PKG_CHECK_EXISTS([valgrind >= 3.6],
1246     [with_valgrind=yes], [with_valgrind=no])])
1247
1248 if test x$with_valgrind != xno; then
1249   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1250   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1251 fi
1252
1253 #### Set up final flags
1254 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs $SYSTEMD_LIBS"
1255 AC_SUBST([LIBDBUS_LIBS])
1256
1257 ### X11 detection
1258 DBUS_X_LIBS=
1259 DBUS_X_CFLAGS=
1260
1261 AC_ARG_ENABLE([x11-autolaunch],
1262   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1263   [], [enable_x11_autolaunch=auto])
1264
1265 if test "x$dbus_win" = xyes; then
1266     if test "x$enable_x11_autolaunch" = xyes; then
1267         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1268     fi
1269
1270     enable_x11_autolaunch=no
1271     have_x11=no
1272 else
1273     AC_PATH_XTRA
1274
1275     if test "x$no_x" = xyes; then
1276         have_x11=no
1277     else
1278         have_x11=yes
1279         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1280         DBUS_X_CFLAGS="$X_CFLAGS"
1281     fi
1282 fi
1283
1284 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1285     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1286 else
1287     # move from "auto" to "yes" or "no" if necessary
1288     if test "x$enable_x11_autolaunch" != xno; then
1289         enable_x11_autolaunch="$have_x11"
1290     fi
1291 fi
1292
1293 if test "x$have_x11" = xyes ; then
1294    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1295 fi
1296
1297 if test "x$enable_x11_autolaunch" = xyes ; then
1298    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1299 fi
1300
1301 AC_SUBST([DBUS_X_CFLAGS])
1302 AC_SUBST([DBUS_X_LIBS])
1303
1304 #### gcc warning flags
1305
1306 cc_supports_flag() {
1307   AC_MSG_CHECKING(whether $CC supports "$*")
1308   save_CFLAGS="$CFLAGS"
1309   CFLAGS="$*"
1310   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1311   CFLAGS="$save_CFLAGS"
1312   AC_MSG_RESULT([$rc])
1313   test "x$rc" = xyes
1314 }
1315
1316 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1317   dnl Use -Werror by default if:
1318   dnl - we're not on Windows (too many warnings), and
1319   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1320   dnl Override with --enable-Werror or --disable-Werror
1321   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1322
1323   dnl Enable these warnings if possible:
1324   [all \
1325    extra \
1326    char-subscripts \
1327    missing-declarations \
1328    missing-prototypes \
1329    nested-externs \
1330    pointer-arith \
1331    cast-align \
1332    no-address \
1333    float-equal \
1334    declaration-after-statement \
1335   ],
1336
1337   dnl Disable these warnings if possible, make them non-fatal if possible,
1338   dnl and don't enable -Werror unless we succeeded.
1339   dnl
1340   dnl Intentional:
1341   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1342   dnl   checking or not asserting
1343   dnl - missing field initializers being 0 is a C feature, not a bug
1344   dnl - unused-parameter is to make writing callbacks less annoying
1345   dnl
1346   dnl To be fixed one day:
1347   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1348   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1349   dnl   is better than nothing
1350   [$DISABLE_UNUSED_WARNINGS \
1351    missing-field-initializers \
1352    unused-parameter \
1353    sign-compare \
1354    pointer-sign \
1355    type-limits \
1356   ])
1357
1358 if test "x$GCC" = "xyes"; then
1359   # We're treating -fno-common like a warning: it makes the linker more
1360   # strict, because on some systems the linker is *always* this strict
1361   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1362
1363   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1364   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1365
1366   if test "x$enable_ansi" = "xyes"; then
1367     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1368       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1369   fi
1370 fi
1371
1372 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1373 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1374 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1375 dnl is the next best thing
1376 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1377
1378 case $host_os in
1379     solaris*)
1380         # Solaris' C library apparently needs these runes to be threadsafe...
1381         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1382         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1383         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1384         # ... and this opt-in to get file descriptor passing support
1385         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1386         ;;
1387 esac
1388
1389 ### Doxygen Documentation
1390
1391 AC_PATH_PROG(DOXYGEN, doxygen, no)
1392
1393 AC_MSG_CHECKING([whether to build Doxygen documentation])
1394
1395 if test x$DOXYGEN = xno ; then
1396     have_doxygen=no
1397 else
1398     have_doxygen=yes
1399 fi
1400
1401 if test x$enable_doxygen_docs = xauto ; then
1402     if test x$have_doxygen = xno ; then
1403         enable_doxygen_docs=no
1404     else
1405         enable_doxygen_docs=yes
1406     fi
1407 fi
1408
1409 if test x$enable_doxygen_docs = xyes; then
1410     if test x$have_doxygen = xno; then
1411         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1412     fi
1413 fi
1414
1415 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1416 AC_MSG_RESULT($enable_doxygen_docs)
1417
1418 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1419 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1420
1421 ### XML Documentation
1422
1423 AC_PATH_PROG(XMLTO, xmlto, no)
1424
1425 AC_MSG_CHECKING([whether to build XML documentation])
1426
1427 if test x$XMLTO = xno ; then
1428     have_xmlto=no
1429 else
1430     have_xmlto=yes
1431 fi
1432
1433 if test x$enable_xml_docs = xauto ; then
1434     if test x$have_xmlto = xno ; then
1435         enable_xml_docs=no
1436     else
1437         enable_xml_docs=yes
1438     fi
1439 fi
1440
1441 if test x$enable_xml_docs = xyes; then
1442     if test x$have_xmlto = xno; then
1443         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1444     fi
1445 fi
1446
1447 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1448 AC_MSG_RESULT($enable_xml_docs)
1449
1450 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1451     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes])
1452
1453 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1454
1455 #### find the actual value for $prefix that we'll end up with
1456 ##   (I know this is broken and should be done in the Makefile, but
1457 ##    that's a major pain and almost nobody actually seems to care)
1458 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1459 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1460 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1461 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1462 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1463 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1464 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1465
1466 #### Check our operating system
1467 operating_system=unknown
1468 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1469    operating_system=redhat
1470 fi
1471
1472 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1473    operating_system=slackware
1474 fi
1475
1476 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1477    operating_system=cygwin
1478 fi
1479
1480 #### Sort out init scripts
1481
1482 if test x$with_init_scripts = x; then
1483     case x$operating_system in
1484         xredhat)        with_init_scripts=redhat ;;
1485         xslackware)     with_init_scripts=slackware ;;
1486         xcygwin)        with_init_scripts=cygwin ;;
1487         *)                      with_init_scripts=none ;;
1488     esac
1489 fi
1490
1491 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1492 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1493 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1494
1495 ##### systemd unit files
1496 AC_ARG_WITH([systemdsystemunitdir],
1497 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1498     [],
1499     [
1500     PKG_CHECK_EXISTS([systemd],
1501       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1502       [with_systemdsystemunitdir=no])
1503     ])
1504 if test "x$with_systemdsystemunitdir" != xno; then
1505    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1506 fi
1507 AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" != "xno" -a -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1508
1509 ##### Set up location for system bus socket
1510 if ! test -z "$with_system_socket"; then
1511    DBUS_SYSTEM_SOCKET=$with_system_socket
1512 else
1513    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1514 fi
1515
1516 AC_SUBST(DBUS_SYSTEM_SOCKET)
1517 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1518
1519 ## System bus only listens on local domain sockets, and never
1520 ## on an abstract socket (so only root can create the socket).
1521 ##
1522 ## This won't work on Windows. It's not meant to - the system bus is
1523 ## meaningless on Windows anyway.
1524 ##
1525 ## This has to be suitable for hard-coding in client libraries as well as
1526 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1527 ## and also to connect to. If this ever changes, it'll need to be split into
1528 ## two variables, one for the listening address and one for the connecting
1529 ## address.
1530 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1531 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1532 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1533
1534 #### Set up the pid file
1535 if ! test -z "$with_system_pid_file"; then
1536    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1537 elif test x$with_init_scripts = xredhat ; then
1538    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1539 else
1540    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1541 fi
1542
1543 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1544
1545 #### Directory to check for console ownership
1546 if ! test -z "$with_console_auth_dir"; then
1547    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1548 else
1549    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1550 fi
1551
1552 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1553 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1554
1555 #### File to check for console ownership
1556 if test x$have_console_owner_file = xyes; then
1557    if ! test -z "$with_console_owner_file"; then
1558       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1559    else
1560       DBUS_CONSOLE_OWNER_FILE=/dev/console
1561    fi
1562 else
1563   DBUS_CONSOLE_OWNER_FILE=
1564 fi
1565
1566 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1567 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1568
1569 #### User to start the system bus as
1570 if test -z "$with_dbus_user" ; then
1571     DBUS_USER=messagebus
1572 else
1573     DBUS_USER=$with_dbus_user
1574 fi
1575 AC_SUBST(DBUS_USER)
1576 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1577
1578 #### Prefix to install into
1579 DBUS_PREFIX=$EXPANDED_PREFIX
1580 AC_SUBST(DBUS_PREFIX)
1581 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1582
1583 #### Direcotry to install data files into
1584 DBUS_DATADIR=$EXPANDED_DATADIR
1585 AC_SUBST(DBUS_DATADIR)
1586 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1587
1588 #### Directory to install dbus-daemon
1589 if test -z "$with_dbus_daemondir" ; then
1590     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1591     dbus_daemondir='$bindir'
1592 else
1593     DBUS_DAEMONDIR=$with_dbus_daemondir
1594     dbus_daemondir=$with_dbus_daemondir
1595 fi
1596 AC_SUBST(DBUS_DAEMONDIR)
1597 AC_SUBST(dbus_daemondir)
1598 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1599
1600 #### Directory to install the other binaries
1601 DBUS_BINDIR="$EXPANDED_BINDIR"
1602 AC_SUBST(DBUS_BINDIR)
1603 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1604
1605 #### Directory to install the libexec binaries
1606 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1607 AC_SUBST(DBUS_LIBEXECDIR)
1608 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1609
1610 #### Tell tests where to find certain stuff in builddir
1611
1612 DBUS_PWD=`pwd`
1613 # Useful in a cross-compilation environment, where the tests are run on the host system.
1614 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1615                            DBUS_PWD=$withval)
1616
1617 DBUS_TEST_EXEC="$DBUS_PWD/test"
1618 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1619
1620 AC_SUBST([DBUS_TEST_DATA])
1621 AC_SUBST([DBUS_TEST_EXEC])
1622
1623 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1624                    [Full path to the daemon in the builddir])
1625 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1626                    [Extension for executables, typically empty or .exe])
1627
1628 AC_DEFINE_UNQUOTED(TEST_BUS_LAUNCH_BINARY, ["$DBUS_PWD/tools/dbus-launch$EXEEXT"],
1629                    [Full path to the dbus-launch in the builddir])
1630
1631 ## Export the non-setuid external helper
1632 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1633 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1634 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1635                    [Full path to the launch helper test program in the builddir])
1636
1637 #### Find socket directories
1638 if ! test -z "$TMPDIR" ; then
1639    DEFAULT_SOCKET_DIR=$TMPDIR
1640 elif ! test -z "$TEMP" ; then
1641    DEFAULT_SOCKET_DIR=$TEMP
1642 elif ! test -z "$TMP" ; then
1643    DEFAULT_SOCKET_DIR=$TMP
1644 else
1645    DEFAULT_SOCKET_DIR=/tmp
1646 fi
1647
1648 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1649
1650 if ! test -z "$with_test_socket_dir" ; then
1651    TEST_SOCKET_DIR="$with_test_socket_dir"
1652 else
1653    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1654 fi
1655 AC_SUBST(TEST_SOCKET_DIR)
1656 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1657
1658 if test "x$dbus_unix" = xyes; then
1659   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1660 else
1661   TEST_LISTEN="tcp:host=localhost"
1662 fi
1663 AC_SUBST([TEST_LISTEN])
1664 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1665   [Listening address for regression tests])
1666
1667 if ! test -z "$with_session_socket_dir" ; then
1668    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1669 else
1670    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1671 fi
1672 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1673 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1674
1675 # This must be a listening address. It doesn't necessarily need to be an
1676 # address you can connect to - it can be something vague like
1677 # "nonce-tcp:".
1678 #
1679 # The default varies by platform.
1680 AC_ARG_WITH([dbus_session_bus_listen_address],
1681             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1682                            [default address for a session bus to listen on (see configure.ac)]),
1683             [with_dbus_session_bus_listen_address=$withval],
1684             [with_dbus_session_bus_listen_address=])
1685
1686 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1687         # the user specified something, trust them
1688         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1689 elif test x$dbus_win = xyes; then
1690         # On Windows, you can (and should) listen on autolaunch addresses,
1691         # because autolaunching is different.
1692         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1693         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1694 elif test x$have_launchd = xyes; then
1695         # Mac OS X default is to use launchd
1696         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1697 else
1698         # The default on all other Unix platforms (notably Linux)
1699         # is to create a randomly named socket in /tmp or similar
1700         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1701 fi
1702 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1703
1704 # This must be an address you can connect to. It doesn't necessarily
1705 # need to be an address you can listen on - it can be "autolaunch:",
1706 # even on Unix.
1707 #
1708 # The default varies by platform.
1709 AC_ARG_WITH([dbus_session_bus_connect_address],
1710             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1711                            [fallback address for a session bus client to connect to (see configure.ac)]),
1712             [with_dbus_session_bus_connect_address=$withval],
1713             [with_dbus_session_bus_connect_address=])
1714
1715 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1716         # the user specified something, trust them
1717         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1718 elif test x$dbus_win = xyes; then
1719         # Windows autolaunching is a bit different; leaving it in its own
1720         # branch of the conditional because the default might conceivably
1721         # change (see #38201)
1722         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1723 else
1724         # The default on all other Unix platforms (notably Linux)
1725         # is to use auto-launching - this works a bit differently on Mac OS X
1726         # but comes out basically the same in the end
1727         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1728 fi
1729 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1730 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1731   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1732   [Fallback address for session bus clients])
1733
1734 # darwin needs this to initialize the environment
1735 AC_CHECK_HEADERS(crt_externs.h)
1736 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1737 AH_VERBATIM(_DARWIN_ENVIRON,
1738 [
1739 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1740 # include <sys/time.h>
1741 # include <crt_externs.h>
1742 # define environ (*_NSGetEnviron())
1743 #endif
1744 ])
1745
1746 AC_ARG_ENABLE([stats],
1747   [AS_HELP_STRING([--disable-stats],
1748     [disable bus daemon usage statistics])],
1749   [], [enable_stats=yes])
1750 if test "x$enable_stats" = xyes; then
1751   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1752     [Define to enable bus daemon usage statistics])
1753 fi
1754
1755 AC_CONFIG_FILES([
1756 Doxyfile
1757 dbus/versioninfo.rc
1758 dbus/dbus-arch-deps.h
1759 bus/system.conf
1760 bus/session.conf
1761 bus/example-system-enable-stats.conf
1762 bus/example-session-disable-stats.conf
1763 bus/messagebus
1764 bus/messagebus-config
1765 bus/org.freedesktop.dbus-session.plist
1766 bus/rc.messagebus
1767 bus/dbus.service
1768 bus/dbus.socket
1769 Makefile
1770 dbus/Makefile
1771 bus/Makefile
1772 tools/Makefile
1773 test/Makefile
1774 test/name-test/Makefile
1775 doc/Makefile
1776 doc/dbus-cleanup-sockets.1.xml
1777 doc/dbus-daemon.1.xml
1778 doc/dbus-launch.1.xml
1779 doc/dbus-monitor.1.xml
1780 doc/dbus-run-session.1.xml
1781 doc/dbus-send.1.xml
1782 doc/dbus-uuidgen.1.xml
1783 dbus-1.pc
1784 dbus-1-uninstalled.pc
1785 test/data/valid-config-files/debug-allow-all.conf
1786 test/data/valid-config-files/debug-allow-all-sha1.conf
1787 test/data/valid-config-files/finite-timeout.conf
1788 test/data/valid-config-files/incoming-limit.conf
1789 test/data/valid-config-files-system/debug-allow-all-pass.conf
1790 test/data/valid-config-files-system/debug-allow-all-fail.conf
1791 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1792 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1793 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1794 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1795 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1796 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1797 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1798 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1799 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1800 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1801 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1802 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1803 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1804 ])
1805 AC_OUTPUT
1806
1807 dnl ==========================================================================
1808 echo "
1809                     D-Bus $VERSION
1810                   ==============
1811
1812         prefix:                   ${EXPANDED_PREFIX}
1813         exec_prefix:              ${exec_prefix}
1814         libdir:                   ${EXPANDED_LIBDIR}
1815         libexecdir:               ${EXPANDED_LIBEXECDIR}
1816         bindir:                   ${EXPANDED_BINDIR}
1817         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1818         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1819         datadir:                  ${EXPANDED_DATADIR}
1820         source code location:     ${srcdir}
1821         compiler:                 ${CC}
1822         cflags:                   ${CFLAGS}
1823         cppflags:                 ${CPPFLAGS}
1824         cxxflags:                 ${CXXFLAGS}
1825         64-bit int:               ${DBUS_INT64_TYPE}
1826         32-bit int:               ${DBUS_INT32_TYPE}
1827         16-bit int:               ${DBUS_INT16_TYPE}
1828         Doxygen:                  ${DOXYGEN:-not found}
1829         xmlto:                    ${XMLTO:-not found}"
1830
1831 echo "
1832         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1833         gcc coverage profiling:   ${enable_compiler_coverage}
1834         Building embedded tests:  ${enable_embedded_tests}
1835         Building modular tests:   ${enable_modular_tests}
1836             - with GLib:          ${with_glib}
1837             - with dbus-glib:     ${with_dbus_glib}
1838         Building verbose mode:    ${enable_verbose_mode}
1839         Building assertions:      ${enable_asserts}
1840         Building checks:          ${enable_checks}
1841         Building bus stats API:   ${enable_stats}
1842         Building SELinux support: ${have_selinux}
1843         Building inotify support: ${have_inotify}
1844         Building kqueue support:  ${have_kqueue}
1845         Building systemd support: ${have_systemd}
1846         Building X11 code:        ${have_x11}
1847         Building Doxygen docs:    ${enable_doxygen_docs}
1848         Building XML docs:        ${enable_xml_docs}
1849         Building launchd support: ${have_launchd}
1850         Init scripts style:       ${with_init_scripts}
1851         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1852         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1853         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1854         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1855         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1856         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1857         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1858         Console owner file:       ${have_console_owner_file}
1859         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1860         System bus user:          ${DBUS_USER}
1861         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1862         'make check' socket dir:  ${TEST_SOCKET_DIR}
1863 "
1864 if test x$have_launchd = xyes; then
1865         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1866 fi
1867 echo
1868
1869 if test x$enable_embedded_tests = xyes; then
1870         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1871 fi
1872 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1873         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1874 fi
1875 if test x$enable_compiler_coverage = xyes; then
1876         echo "NOTE: building with coverage profiling is definitely for developers only."
1877 fi
1878 if test x$enable_verbose_mode = xyes; then
1879         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1880 fi
1881 if test x$enable_asserts = xyes; then
1882         echo "NOTE: building with assertions increases library size and decreases performance."
1883 fi
1884 if test x$enable_checks = xno; then
1885         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1886 fi