configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23
  24 m4_define(PA_MAJOR, [0])
  25 m4_define(PA_MINOR, [9])
  26 m4_define(PA_MICRO, [1])
  27
  28 AC_INIT([polypaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  29 AC_CONFIG_SRCDIR([src/daemon/main.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AM_INIT_AUTOMAKE([foreign -Wall])
  32
  33 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  34 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  35
  36 AC_SUBST(PA_API_VERSION, 9)
  37 AC_SUBST(PA_PROTOCOL_VERSION, 9)
  38
  39 AC_SUBST(LIBPOLYP_VERSION_INFO, [0:0:0])
  40 AC_SUBST(LIBPOLYPCORE_VERSION_INFO, [0:1:0])
  41 AC_SUBST(LIBPOLYP_SIMPLE_VERSION_INFO, [0:0:0])
  42 AC_SUBST(LIBPOLYP_BROWSE_VERSION_INFO, [0:0:0])
  43 AC_SUBST(LIBPOLYP_MAINLOOP_GLIB_VERSION_INFO, [0:0:0])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 #### Platform hacks ####
  51
  52 case $host in
  53    *-*-solaris* )
  54       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  55       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  56       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  57       ;;
  58 esac
  59
  60 #### Checks for programs. ####
  61
  62 # CC
  63
  64 AC_PROG_CC
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_GNU_SOURCE
  67
  68 # M4
  69
  70 AC_PATH_PROG([M4], [m4 gm4], [no])
  71 if test "x$M4" = xno ; then
  72    AC_MSG_ERROR([m4 missing])
  73 fi
  74
  75 # GCC flags
  76
  77 test_gcc_flag() {
  78     AC_LANG_CONFTEST([int main() {}])
  79     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  80     ret=$?
  81     rm -f conftest.o
  82     return $ret
  83 }
  84
  85 # If using GCC specify some additional parameters
  86 if test "x$GCC" = "xyes" ; then
  87
  88     # We use gnu99 instead of c99 because many have interpreted the standard
  89     # in a way that int64_t isn't defined on non-64 bit platforms.
  90     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     for flag in $DESIRED_FLAGS ; do
  93         AC_MSG_CHECKING([whether $CC accepts $flag])
  94         if test_gcc_flag $flag ; then
  95            CFLAGS="$CFLAGS $flag"
  96            AC_MSG_RESULT([yes])
  97         else
  98            AC_MSG_RESULT([no])
  99         fi
 100     done
 101 fi
 102
 103 # LYNX documentation generation
 104 AC_ARG_ENABLE(lynx,
 105         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
 106 [case "${enableval}" in
 107   yes) lynx=yes ;;
 108   no)  lynx=no ;;
 109   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
 110 esac],[lynx=auto])
 111
 112 if test x$lynx != xno ; then
 113    AC_CHECK_PROG(have_lynx, lynx, yes, no)
 114
 115    if test x$have_lynx = xno ; then
 116        if test x$lynx = xyes ; then
 117            AC_MSG_ERROR([*** lynx not found])
 118        else
 119            AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 120        fi
 121    fi
 122 fi
 123
 124 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 125
 126 #### libtool stuff ####
 127
 128 AC_LTDL_ENABLE_INSTALL
 129 AC_LIBLTDL_INSTALLABLE
 130 AC_SUBST(LTDLINCL)
 131 AC_SUBST(LIBLTDL)
 132 AC_LIBTOOL_DLOPEN
 133 AC_LIBTOOL_WIN32_DLL
 134 AC_PROG_LIBTOOL
 135 AC_CONFIG_SUBDIRS(libltdl)
 136
 137 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 138     AC_MSG_ERROR([[
 139
 140         *** Cannot find the libltdl development files.
 141         *** Maybe you need to install the libltdl-dev package.
 142         ]])
 143 fi
 144
 145 #### Determine build environment ####
 146
 147 os_is_win32=0
 148
 149 case "$host_os" in
 150         mingw*)
 151         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 152         os_is_win32=1
 153                 ;;
 154         esac
 155
 156 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 157
 158 ###################################
 159 #   Basic environment checks      #
 160 ###################################
 161
 162 #### Checks for header files. ####
 163
 164 # ISO
 165 AC_HEADER_STDC
 166
 167 # POSIX
 168 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h iconv.h netdb.h netinet/in.h \
 169     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 170     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 171     syslog.h])
 172 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 173 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 174
 175 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 176 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 177
 178 # XPG4-UNIX
 179 AC_CHECK_HEADERS([sys/poll.h])
 180
 181 # Linux
 182 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 183
 184 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 185
 186 # Solaris
 187 AC_CHECK_HEADERS([sys/filio.h])
 188
 189 # Windows
 190 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 191
 192 # Other
 193 AC_CHECK_HEADERS([sys/ioctl.h])
 194
 195 #### Typdefs, structures, etc. ####
 196
 197 AC_C_CONST
 198 AC_C_BIGENDIAN
 199 AC_TYPE_PID_T
 200 AC_TYPE_SIZE_T
 201 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 202     [Define ssize_t if it is not done by the standard libs.])])
 203 AC_TYPE_OFF_T
 204 AC_TYPE_SIGNAL
 205 AC_TYPE_UID_T
 206
 207 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 208 HAVE_SIGXCPU=1
 209 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 210 ], [HAVE_SIGXCPU=0])
 211 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 212
 213 # Solaris lacks this
 214 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 215     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 216         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 217
 218 #### Check for libs ####
 219
 220 # ISO
 221 AC_SEARCH_LIBS([pow], [m])
 222
 223 # POSIX
 224 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 225 AC_SEARCH_LIBS([dlopen], [dl])
 226
 227 # BSD
 228 AC_SEARCH_LIBS([connect], [socket])
 229
 230 # Non-standard
 231
 232 # This magic is needed so we do not needlessly add static libs to the win32
 233 # build, disabling its ability to make dlls.
 234 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 235
 236 #### Check for functions ####
 237
 238 # POSIX
 239 AC_FUNC_FORK
 240 AC_FUNC_GETGROUPS
 241 AC_FUNC_SELECT_ARGTYPES
 242 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 243     getuid inet_ntop inet_pton nanosleep pipe setpgid setsid sigaction sleep])
 244 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 245
 246 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 247
 248 # X/OPEN
 249 AC_CHECK_FUNCS([readlink])
 250
 251 # SUSv2
 252 AC_CHECK_FUNCS([ctime_r usleep])
 253
 254 # SUSv3
 255 AC_CHECK_FUNCS([strerror_r])
 256
 257 # BSD
 258 AC_CHECK_FUNCS([lstat])
 259
 260 # Non-standard
 261
 262 AC_CHECK_FUNCS(setresuid)
 263 AC_CHECK_FUNCS(setreuid)
 264
 265 #### POSIX threads ####
 266
 267 ACX_PTHREAD
 268
 269 #### Large File-Support (LFS) ####
 270
 271 AC_SYS_LARGEFILE
 272
 273 ###################################
 274 #      External libraries         #
 275 ###################################
 276
 277 #### X11 (optional) ####
 278
 279 HAVE_X11=0
 280
 281 # The macro tests the host, not the build target
 282 if test "x$os_is_win32" != "x1" ; then
 283     AC_PATH_XTRA
 284     test "x$no_x" != "xyes" && HAVE_X11=1
 285 fi
 286
 287 AC_SUBST(HAVE_X11)
 288 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 289 if test "x$HAVE_X11" = "x1" ; then
 290     AC_DEFINE([HAVE_X11], 1, [Have X11])
 291 fi
 292
 293 #### Capabilities (optional) ####
 294
 295 CAP_LIBS=''
 296
 297 AC_ARG_WITH(
 298         [caps],
 299         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 300
 301 if test "x${with_caps}" != "xno"; then
 302     AC_SEARCH_LIBS([cap_init], [cap], [], [
 303                     if test "x${with_caps}" = "xyes" ; then
 304                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 305                     fi])
 306     AC_CHECK_HEADERS([sys/capability.h], [], [
 307                     if test "x${with_caps}" = "xyes" ; then
 308                         AC_MSG_ERROR([*** POSIX caps headers not found])
 309                     fi])
 310 fi
 311
 312 #### pkg-config ####
 313
 314 # Check for pkg-config manually first, as if its not installed the
 315 # PKG_PROG_PKG_CONFIG macro won't be defined.
 316 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 317
 318 if test x"$have_pkg_config" = "xno"; then
 319     AC_MSG_ERROR(pkg-config is required to install this program)
 320 fi
 321
 322 PKG_PROG_PKG_CONFIG
 323
 324 #### Sample rate conversion ####
 325
 326 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 327 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 328 AC_SUBST(LIBSAMPLERATE_LIBS)
 329
 330 #### Sound file ####
 331
 332 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 333 AC_SUBST(LIBSNDFILE_CFLAGS)
 334 AC_SUBST(LIBSNDFILE_LIBS)
 335
 336 #### OSS support (optional) ####
 337
 338 AC_ARG_ENABLE([oss],
 339     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 340         [
 341             case "${enableval}" in
 342                 yes) oss=yes ;;
 343                 no) oss=no ;;
 344                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 345             esac
 346         ],
 347         [oss=auto])
 348
 349 if test "x${oss}" != xno ; then
 350     AC_CHECK_HEADERS([sys/soundcard.h],
 351         [
 352             HAVE_OSS=1
 353             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 354         ],
 355         [
 356             HAVE_OSS=0
 357             if test "x$oss" = xyes ; then
 358                 AC_MSG_ERROR([*** OSS support not found])
 359             fi
 360         ])
 361 else
 362     HAVE_OSS=0
 363 fi
 364
 365 AC_SUBST(HAVE_OSS)
 366 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 367
 368
 369 #### ALSA support (optional) ####
 370
 371 AC_ARG_ENABLE([alsa],
 372     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 373         [
 374             case "${enableval}" in
 375                 yes) alsa=yes ;;
 376                 no) alsa=no ;;
 377                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 378             esac
 379         ],
 380         [alsa=auto])
 381
 382 if test "x${alsa}" != xno ; then
 383     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 384         [
 385             HAVE_ALSA=1
 386             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 387         ],
 388         [
 389             HAVE_ALSA=0
 390             if test "x$alsa" = xyes ; then
 391                 AC_MSG_ERROR([*** ALSA support not found])
 392             fi
 393         ])
 394 else
 395     HAVE_ALSA=0
 396 fi
 397
 398 AC_SUBST(ASOUNDLIB_CFLAGS)
 399 AC_SUBST(ASOUNDLIB_LIBS)
 400 AC_SUBST(HAVE_ALSA)
 401 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 402
 403 #### Solaris audio support (optional) ####
 404
 405 AC_ARG_ENABLE([solaris],
 406     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 407         [
 408             case "${enableval}" in
 409                 yes) solaris=yes ;;
 410                 no) solaris=no ;;
 411                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 412             esac
 413         ],
 414         [solaris=auto])
 415
 416 if test "x${solaris}" != xno ; then
 417     AC_CHECK_HEADERS([sys/audio.h],
 418         [
 419             HAVE_SOLARIS=1
 420             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 421         ],
 422         [
 423             HAVE_SOLARIS=0
 424             if test "x$solaris" = xyes ; then
 425                 AC_MSG_ERROR([*** Solaris audio support not found])
 426             fi
 427         ])
 428 else
 429     HAVE_SOLARIS=0
 430 fi
 431
 432 AC_SUBST(HAVE_SOLARIS)
 433 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 434
 435 #### GLib 2 support (optional) ####
 436
 437 AC_ARG_ENABLE([glib2],
 438     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 439         [
 440             case "${enableval}" in
 441                 yes) glib2=yes ;;
 442                 no) glib2=no ;;
 443                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 444             esac
 445         ],
 446         [glib2=auto])
 447
 448 if test "x${glib2}" != xno ; then
 449     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 450         HAVE_GLIB20=1,
 451         [
 452             HAVE_GLIB20=0
 453             if test "x$glib2" = xyes ; then
 454                 AC_MSG_ERROR([*** GLib 2 support not found])
 455             fi
 456         ])
 457 else
 458     HAVE_GLIB20=0
 459 fi
 460
 461 AC_SUBST(GLIB20_CFLAGS)
 462 AC_SUBST(GLIB20_LIBS)
 463 AC_SUBST(HAVE_GLIB20)
 464 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 465
 466 #### GLib 1 support (optional) ####
 467
 468 AC_ARG_ENABLE([glib1],
 469     AC_HELP_STRING([--disable-glib1], [Disable optional GLib 1 support]),
 470         [
 471             case "${enableval}" in
 472                 yes) glib1=yes ;;
 473                 no) glib1=no ;;
 474                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib1) ;;
 475             esac
 476         ],
 477         [glib1=auto])
 478
 479 if test "x${glib1}" != xno ; then
 480     PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ],
 481         HAVE_GLIB12=1,
 482         [
 483             HAVE_GLIB12=0
 484             if test "x$glib1" = xyes ; then
 485                 AC_MSG_ERROR([*** GLib 1 support not found])
 486             fi
 487         ])
 488 else
 489     HAVE_GLIB12=0
 490 fi
 491
 492 AC_SUBST(GLIB12_CFLAGS)
 493 AC_SUBST(GLIB12_LIBS)
 494 AC_SUBST(HAVE_GLIB12)
 495 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 496
 497 #### Howl support (optional) ####
 498
 499 AC_ARG_ENABLE([howl],
 500     AC_HELP_STRING([--disable-howl], [Disable optional Howl support]),
 501         [
 502             case "${enableval}" in
 503                 yes) howl=yes ;;
 504                 no) howl=no ;;
 505                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-howl) ;;
 506             esac
 507         ],
 508         [howl=auto])
 509
 510 if test "x${howl}" != xno ; then
 511     PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ],
 512         HAVE_HOWL=1,
 513         [
 514             PKG_CHECK_MODULES(HOWL, [ avahi-compat-howl >= 0.9.8 ],
 515                 HAVE_HOWL=1,
 516                 [
 517                     HAVE_HOWL=0
 518                     if test "x$howl" = xyes ; then
 519                         AC_MSG_ERROR([*** Howl support not found])
 520                     fi
 521                 ])
 522         ])
 523 else
 524     HAVE_HOWL=0
 525 fi
 526
 527 AC_SUBST(HOWL_CFLAGS)
 528 AC_SUBST(HOWL_LIBS)
 529 AC_SUBST(HAVE_HOWL)
 530 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 531
 532 ### LIBOIL ####
 533
 534 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 535 AC_SUBST(LIBOIL_CFLAGS)
 536 AC_SUBST(LIBOIL_LIBS)
 537
 538 ### JACK (optional) ####
 539
 540 AC_ARG_ENABLE([jack],
 541     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 542         [
 543             case "${enableval}" in
 544                 yes) jack=yes ;;
 545                 no) jack=no ;;
 546                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 547             esac
 548         ],
 549         [jack=auto])
 550
 551 if test "x${jack}" != xno ; then
 552     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 553         HAVE_JACK=1,
 554         [
 555             HAVE_JACK=0
 556             if test "x$jack" = xyes ; then
 557                 AC_MSG_ERROR([*** JACK support not found])
 558             fi
 559         ])
 560 else
 561     HAVE_JACK=0
 562 fi
 563
 564 AC_SUBST(JACK_CFLAGS)
 565 AC_SUBST(JACK_LIBS)
 566 AC_SUBST(HAVE_JACK)
 567 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 568
 569 #### Async DNS support (optional) ####
 570
 571 AC_ARG_ENABLE([asyncns],
 572     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 573         [
 574             case "${enableval}" in
 575                 yes) asyncns=yes ;;
 576                 no) asyncns=no ;;
 577                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 578             esac
 579         ],
 580         [asyncns=auto])
 581
 582 if test "x${asyncns}" != xno ; then
 583     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 584         HAVE_LIBASYNCNS=1,
 585         [
 586             HAVE_LIBASYNCNS=0
 587             if test "x$asyncns" = xyes ; then
 588                 AC_MSG_ERROR([*** Async DNS support not found])
 589             fi
 590         ])
 591 else
 592     HAVE_LIBASYNCNS=0
 593 fi
 594
 595 AC_SUBST(LIBASYNCNS_CFLAGS)
 596 AC_SUBST(LIBASYNCNS_LIBS)
 597 AC_SUBST(HAVE_LIBASYNCNS)
 598 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 599
 600 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 601    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 602 fi
 603
 604 #### TCP wrappers (optional) ####
 605
 606 AC_ARG_ENABLE([tcpwrap],
 607     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 608         [
 609             case "${enableval}" in
 610                 yes) tcpwrap=yes ;;
 611                 no) tcpwrap=no ;;
 612                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 613             esac
 614         ],
 615         [tcpwrap=auto])
 616
 617 if test "x${tcpwrap}" != xno ; then
 618     ACX_LIBWRAP
 619     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 620         AC_MSG_ERROR([*** TCP wrappers support not found])
 621     fi
 622 else
 623     LIBWRAP_LIBS=
 624 fi
 625
 626 AC_SUBST(LIBWRAP_LIBS)
 627
 628 #### LIRC support (optional) ####
 629
 630 AC_ARG_ENABLE([lirc],
 631     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 632         [
 633             case "${enableval}" in
 634                 yes) lirc=yes ;;
 635                 no) lirc=no ;;
 636                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 637             esac
 638         ],
 639         [lirc=auto])
 640
 641 if test "x${lirc}" != xno ; then
 642     ACX_LIRC
 643     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 644         AC_MSG_ERROR([*** LIRC support not found])
 645     fi
 646 else
 647     HAVE_LIRC=0
 648 fi
 649
 650 AC_SUBST(LIRC_CFLAGS)
 651 AC_SUBST(LIRC_LIBS)
 652 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 653
 654 ###################################
 655 #            Output               #
 656 ###################################
 657
 658 AC_ARG_ENABLE(
 659         [static-bins],
 660         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 661         [STATIC_BINS=1], [STATIC_BINS=0])
 662 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 663
 664 AC_ARG_WITH(
 665         [preopen-mods],
 666         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 667         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 668 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 669 if test "x$PREOPEN_MODS" != "xall" ; then
 670     tmpLIBS=""
 671     for mod in $PREOPEN_MODS; do
 672         tmpLIBS="$tmpLIBS module-$mod.la"
 673     done
 674     PREOPEN_MODS="$tmpLIBS"
 675     AC_SUBST(PREOPEN_MODS)
 676 fi
 677
 678 AC_ARG_WITH(
 679         [module-dir],
 680         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/polypaudio-${PA_MAJORMINOR}/modules/]),
 681         [modlibexecdir=$withval], [modlibexecdir="${libdir}/polypaudio-${PA_MAJORMINOR}/modules/"])
 682
 683 AC_SUBST(modlibexecdir)
 684
 685 AC_ARG_ENABLE(
 686         [force-preopen],
 687         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 688         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 689 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 690
 691 AC_CONFIG_FILES([
 692 Makefile
 693 src/Makefile
 694 polyplib.pc
 695 polyplib-simple.pc
 696 polyplib-browse.pc
 697 polyplib-glib-mainloop.pc
 698 polyplib-glib12-mainloop.pc
 699 doc/Makefile
 700 doc/README.html
 701 doc/cli.html
 702 doc/daemon.html
 703 doc/modules.html
 704 doxygen/Makefile
 705 doxygen/doxygen.conf
 706 src/polyp/version.h
 707 doc/FAQ.html
 708 ])
 709 AC_OUTPUT