configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [0])
   4 m4_define([v_min], [9])
   5 m4_define([v_mic], [9])
   6 m4_define([v_rev], m4_esyscmd([(svnversion . | grep -v exported || echo 0) | awk -F : '{printf("%s", $1);}' | tr 'A-z' ' ' | sed 's/ //g']))
   7 ##--   When released, remove the dnl on the below line
   8 dnl m4_undefine([v_rev])
   9 ##--   When doing snapshots - change soname. remove dnl on below line
  10 m4_define([v_rel], [-release ver-pre-svn-05])
  11 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  12 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])],
  13 [m4_define([v_ver], [v_maj.v_min.v_mic])])
  14 m4_define([lt_rev], m4_eval(v_maj + v_min))
  15 m4_define([lt_cur], v_mic)
  16 m4_define([lt_age], v_min)
  17 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19
  20 AC_INIT([embryo], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  21 AC_PREREQ([2.52])
  22 AC_CONFIG_SRCDIR([configure.ac])
  23 AC_CONFIG_MACRO_DIR([m4])
  24 AC_CANONICAL_BUILD
  25 AC_CANONICAL_HOST
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  29 AM_CONFIG_HEADER([config.h])
  30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  31
  32 AC_LIBTOOL_WIN32_DLL
  33 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  34 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  35 AC_PROG_LIBTOOL
  36
  37 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  38 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  39 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  40 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  41 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  42 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  43 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  44 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  45 version_info="lt_rev:lt_cur:lt_age"
  46 release_info="v_rel"
  47 AC_SUBST(version_info)
  48 AC_SUBST(release_info)
  49 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  50 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  51
  52 EFL_CHECK_PATH_MAX
  53
  54 ### Default options with respect to host
  55
  56 requirement_embryo=""
  57 embryoincludedir="${datadir}/include"
  58
  59
  60 ### Additional options to configure
  61
  62 EFL_ENABLE_BIN([embryo-cc])
  63
  64
  65 ### Checks for programs
  66 AC_PROG_CC
  67
  68 # doxygen program for documentation building
  69
  70 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
  71
  72 # pkg-config
  73
  74 PKG_PROG_PKG_CONFIG
  75
  76 # Check whether pkg-config supports Requires.private
  77 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
  78    pkgconfig_requires_private="Requires.private"
  79 else
  80    pkgconfig_requires_private="Requires"
  81 fi
  82 AC_SUBST(pkgconfig_requires_private)
  83
  84
  85 ### Checks for libraries
  86
  87 # Evil library for compilation on Windows
  88
  89 EFL_EMBRYO_BUILD=""
  90 case "$host_os" in
  91    mingw* | cegcc*)
  92    PKG_CHECK_MODULES([EVIL], [evil])
  93    AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
  94    requirement_embryo="evil ${requirement_embryo}"
  95    EFL_EMBRYO_BUILD="-DEFL_EMBRYO_BUILD"
  96    ;;
  97 esac
  98 AC_SUBST(EFL_EMBRYO_BUILD)
  99
 100
 101 ### Checks for header files
 102
 103
 104 ### Checks for types
 105
 106
 107 ### Checks for structures
 108
 109
 110 ### Checks for compiler characteristics
 111 AC_C_BIGENDIAN
 112 AM_PROG_CC_C_O
 113 AC_C_CONST
 114 AC_C_INLINE
 115 AC_PROG_CC_STDC
 116 AC_HEADER_STDC
 117 AC_C___ATTRIBUTE__
 118
 119 EMBRYO_CPPFLAGS=""
 120 EMBRYO_CFLAGS=""
 121 case "$host_os" in
 122    mingw32ce*)
 123       EMBRYO_CPPFLAGS="-D_WIN32_WCE=0x0420"
 124       ;;
 125    cegcc*)
 126       EMBRYO_CPPFLAGS="-D_WIN32_WCE=0x0420"
 127       EMBRYO_CFLAGS="-mwin32"
 128       ;;
 129 esac
 130 AC_SUBST(EMBRYO_CPPFLAGS)
 131 AC_SUBST(EMBRYO_CFLAGS)
 132
 133
 134 ### Checks for linker characteristics
 135
 136 lt_enable_auto_import=""
 137 case "$host_os" in
 138    mingw* | cegcc*)
 139       lt_enable_auto_import="-Wl,--enable-auto-import"
 140       ;;
 141 esac
 142 AC_SUBST(lt_enable_auto_import)
 143
 144
 145 ### Checks for library functions
 146
 147 # alloca
 148 AC_FUNC_ALLOCA
 149
 150 # fnmatch
 151 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 152
 153 case "$host_os" in
 154    mingw* | cegcc*)
 155       AC_DEFINE(HAVE_GETTIMEOFDAY, 1, [Defined to 1 (MinGW / CeGCC platform)])
 156       ;;
 157    *)
 158       AC_CHECK_FUNCS(gettimeofday)
 159       ;;
 160 esac
 161
 162
 163 AC_SUBST(requirement_embryo)
 164 AC_SUBST(embryoincludedir)
 165
 166 AC_OUTPUT([
 167 Makefile
 168 doc/Makefile
 169 doc/embryo.dox
 170 embryo.pc
 171 include/Makefile
 172 src/Makefile
 173 src/lib/Makefile
 174 src/bin/Makefile
 175 README
 176 embryo.spec
 177 ])
 178
 179
 180 #####################################################################
 181 ## Info
 182
 183 echo
 184 echo
 185 echo
 186 echo "------------------------------------------------------------------------"
 187 echo "$PACKAGE $VERSION"
 188 echo "------------------------------------------------------------------------"
 189 echo
 190 echo "Configuration Options Summary:"
 191 echo
 192 echo "  Build embryo_cc......: $have_embryo_cc"
 193 echo
 194 echo "  Documentation........: ${build_doc}"
 195 echo
 196 echo "Compilation............: make (or gmake)"
 197 echo "  CPPFLAGS.............: $CPPFLAGS"
 198 echo "  CFLAGS...............: $CFLAGS"
 199 echo "  LDFLAGS..............: $LDFLAGS"
 200 echo
 201 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 202 echo "  prefix...............: $prefix"
 203 echo