configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23
  24 m4_define(PA_MAJOR, [0])
  25 m4_define(PA_MINOR, [9])
  26 m4_define(PA_MICRO, [0])
  27
  28 AC_INIT([polypaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  29 AC_CONFIG_SRCDIR([src/daemon/main.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AM_INIT_AUTOMAKE([foreign -Wall])
  32
  33 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  34 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  35
  36 AC_SUBST(PA_API_VERSION, 9)
  37 AC_SUBST(PA_PROTOCOL_VERSION, 9)
  38
  39 AC_SUBST(LIBPOLYP_VERSION_INFO, [0:0:0])
  40 AC_SUBST(LIBPOLYPCORE_VERSION_INFO, [0:0:0])
  41 AC_SUBST(LIBPOLYP_SIMPLE_VERSION_INFO, [0:0:0])
  42 AC_SUBST(LIBPOLYP_BROWSE_VERSION_INFO, [0:0:0])
  43 AC_SUBST(LIBPOLYP_MAINLOOP_GLIB_VERSION_INFO, [0:0:0])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 #### Platform hacks ####
  51
  52 case $host in
  53    *-*-solaris* )
  54       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  55       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  56       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  57       ;;
  58 esac
  59
  60 #### Checks for programs. ####
  61
  62 # CC
  63
  64 AC_PROG_CC
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_GNU_SOURCE
  67
  68 # M4
  69
  70 AC_PATH_PROG([M4], [m4 gm4], [no])
  71 if test "x$M4" = xno ; then
  72    AC_MSG_ERROR([m4 missing])
  73 fi
  74
  75 # GCC flags
  76
  77 test_gcc_flag() {
  78     AC_LANG_CONFTEST([int main() {}])
  79     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  80     ret=$?
  81     rm -f conftest.o
  82     return $ret
  83 }
  84
  85 # If using GCC specify some additional parameters
  86 if test "x$GCC" = "xyes" ; then
  87
  88     # We use gnu99 instead of c99 because many have interpreted the standard
  89     # in a way that int64_t isn't defined on non-64 bit platforms.
  90     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     for flag in $DESIRED_FLAGS ; do
  93         AC_MSG_CHECKING([whether $CC accepts $flag])
  94         if test_gcc_flag $flag ; then
  95            CFLAGS="$CFLAGS $flag"
  96            AC_MSG_RESULT([yes])
  97         else
  98            AC_MSG_RESULT([no])
  99         fi
 100     done
 101 fi
 102
 103 # LYNX documentation generation
 104 AC_ARG_ENABLE(lynx,
 105         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
 106 [case "${enableval}" in
 107   yes) lynx=yes ;;
 108   no)  lynx=no ;;
 109   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
 110 esac],[lynx=auto])
 111
 112 if test x$lynx != xno ; then
 113    AC_CHECK_PROG(have_lynx, lynx, yes, no)
 114
 115    if test x$have_lynx = xno ; then
 116        if test x$lynx = xyes ; then
 117            AC_MSG_ERROR([*** lynx not found])
 118        else
 119            AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 120        fi
 121    fi
 122 fi
 123
 124 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 125
 126 #### libtool stuff ####
 127
 128 AC_LTDL_ENABLE_INSTALL
 129 AC_LIBLTDL_INSTALLABLE
 130 AC_SUBST(LTDLINCL)
 131 AC_SUBST(LIBLTDL)
 132 AC_LIBTOOL_DLOPEN
 133 AC_LIBTOOL_WIN32_DLL
 134 AC_PROG_LIBTOOL
 135 AC_CONFIG_SUBDIRS(libltdl)
 136
 137 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 138     AC_MSG_ERROR([[
 139
 140         *** Cannot find the libltdl development files.
 141         *** Maybe you need to install the libltdl-dev package.
 142         ]])
 143 fi
 144
 145 #### Determine build environment ####
 146
 147 os_is_win32=0
 148
 149 case "$host_os" in
 150         mingw*)
 151         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 152         os_is_win32=1
 153                 ;;
 154         esac
 155
 156 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 157
 158 ###################################
 159 #   Basic environment checks      #
 160 ###################################
 161
 162 #### Checks for header files. ####
 163
 164 # ISO
 165 AC_HEADER_STDC
 166
 167 # POSIX
 168 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h iconv.h netdb.h netinet/in.h \
 169     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 170     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 171     syslog.h])
 172 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 173 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 174
 175 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 176 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 177
 178 # XPG4-UNIX
 179 AC_CHECK_HEADERS([sys/poll.h])
 180
 181 # Linux
 182 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 183
 184 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 185
 186 # Solaris
 187 AC_CHECK_HEADERS([sys/filio.h])
 188
 189 # Windows
 190 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 191
 192 # Other
 193 AC_CHECK_HEADERS([sys/ioctl.h])
 194
 195 #### Typdefs, structures, etc. ####
 196
 197 AC_C_CONST
 198 AC_C_BIGENDIAN
 199 AC_TYPE_PID_T
 200 AC_TYPE_SIZE_T
 201 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 202     [Define ssize_t if it is not done by the standard libs.])])
 203 AC_TYPE_OFF_T
 204 AC_TYPE_SIGNAL
 205 AC_TYPE_UID_T
 206
 207 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 208 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 209
 210 # Solaris lacks this
 211 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 212     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 213
 214 #### Check for libs ####
 215
 216 # ISO
 217 AC_SEARCH_LIBS([pow], [m])
 218
 219 # POSIX
 220 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 221 AC_SEARCH_LIBS([dlopen], [dl])
 222
 223 # BSD
 224 AC_SEARCH_LIBS([connect], [socket])
 225
 226 # Non-standard
 227
 228 # This magic is needed so we do not needlessly add static libs to the win32
 229 # build, disabling its ability to make dlls.
 230 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 231
 232 #### Check for functions ####
 233
 234 # POSIX
 235 AC_FUNC_FORK
 236 AC_FUNC_GETGROUPS
 237 AC_FUNC_SELECT_ARGTYPES
 238 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 239     getuid inet_ntop inet_pton nanosleep pipe setpgid setsid sigaction sleep])
 240 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 241
 242 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 243
 244 # X/OPEN
 245 AC_CHECK_FUNCS([readlink])
 246
 247 # SUSv2
 248 AC_CHECK_FUNCS([ctime_r usleep])
 249
 250 # SUSv3
 251 AC_CHECK_FUNCS([strerror_r])
 252
 253 # BSD
 254 AC_CHECK_FUNCS([lstat])
 255
 256 # Non-standard
 257
 258 AC_CHECK_FUNCS(setresuid)
 259 AC_CHECK_FUNCS(setreuid)
 260
 261 #### POSIX threads ####
 262
 263 ACX_PTHREAD
 264
 265 #### Large File-Support (LFS) ####
 266
 267 AC_SYS_LARGEFILE
 268
 269 ###################################
 270 #      External libraries         #
 271 ###################################
 272
 273 #### X11 (optional) ####
 274
 275 HAVE_X11=0
 276
 277 # The macro tests the host, not the build target
 278 if test "x$os_is_win32" != "x1" ; then
 279     AC_PATH_XTRA
 280     test "x$no_x" != "xyes" && HAVE_X11=1
 281 fi
 282
 283 AC_SUBST(HAVE_X11)
 284 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 285 if test "x$HAVE_X11" = "x1" ; then
 286     AC_DEFINE([HAVE_X11], 1, [Have X11])
 287 fi
 288
 289 #### Capabilities (optional) ####
 290
 291 CAP_LIBS=''
 292
 293 AC_ARG_WITH(
 294         [caps],
 295         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 296
 297 if test "x${with_caps}" != "xno"; then
 298     AC_SEARCH_LIBS([cap_init], [cap], [], [
 299                     if test "x${with_caps}" = "xyes" ; then
 300                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 301                     fi])
 302     AC_CHECK_HEADERS([sys/capability.h], [], [
 303                     if test "x${with_caps}" = "xyes" ; then
 304                         AC_MSG_ERROR([*** POSIX caps headers not found])
 305                     fi])
 306 fi
 307
 308 #### pkg-config ####
 309
 310 # Check for pkg-config manually first, as if its not installed the
 311 # PKG_PROG_PKG_CONFIG macro won't be defined.
 312 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 313
 314 if test x"$have_pkg_config" = "xno"; then
 315     AC_MSG_ERROR(pkg-config is required to install this program)
 316 fi
 317
 318 PKG_PROG_PKG_CONFIG
 319
 320 #### Sample rate conversion ####
 321
 322 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 323 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 324 AC_SUBST(LIBSAMPLERATE_LIBS)
 325
 326 #### Sound file ####
 327
 328 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 329 AC_SUBST(LIBSNDFILE_CFLAGS)
 330 AC_SUBST(LIBSNDFILE_LIBS)
 331
 332 #### OSS support (optional) ####
 333
 334 AC_ARG_ENABLE([oss],
 335     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 336     [case "${enableval}" in yes) oss=yes ;; no) oss=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;; esac],[oss=auto])
 337 if test "x${oss}" != xno ; then
 338     AC_CHECK_HEADERS([sys/soundcard.h], [
 339     HAVE_OSS=1
 340     AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 341     ], [HAVE_OSS=0 ; if test "x$oss" = xyes ; then AC_MSG_ERROR([*** OSS support not found]) ; fi])
 342 else HAVE_OSS=0; fi
 343 AC_SUBST(HAVE_OSS)
 344 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 345
 346
 347 #### ALSA support (optional) ####
 348
 349 AC_ARG_ENABLE([alsa],
 350     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 351     [case "${enableval}" in yes) alsa=yes ;; no) alsa=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;; esac],[alsa=auto])
 352 if test "x${alsa}" != xno ; then
 353     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [
 354     HAVE_ALSA=1
 355     AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 356     ], [HAVE_ALSA=0 ; if test "x$alsa" = xyes ; then AC_MSG_ERROR([*** ALSA support not found]) ; fi])
 357 else HAVE_ALSA=0 ; fi
 358 AC_SUBST(ASOUNDLIB_CFLAGS)
 359 AC_SUBST(ASOUNDLIB_LIBS)
 360 AC_SUBST(HAVE_ALSA)
 361 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 362
 363 #### Solaris audio support (optional) ####
 364
 365 AC_ARG_ENABLE([solaris],
 366     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 367     [case "${enableval}" in yes) solaris=yes ;; no) solaris=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;; esac],[solaris=auto])
 368 if test "x${solaris}" != xno ; then
 369     AC_CHECK_HEADERS([sys/audio.h], [
 370     HAVE_SOLARIS=1
 371     AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 372     ], [HAVE_SOLARIS=0 ; if test "x$solaris" = xyes ; then AC_MSG_ERROR([*** Solaris audio support not found]) ; fi])
 373 else HAVE_SOLARIS=0 ; fi
 374 AC_SUBST(HAVE_SOLARIS)
 375 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 376
 377 #### GLib 2 support (optional) ####
 378
 379 AC_ARG_ENABLE([glib2],
 380     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 381     [case "${enableval}" in yes) glib2=yes ;; no) glib2=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;; esac],[glib2=auto])
 382 if test "x${glib2}" != xno ; then
 383     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, [HAVE_GLIB20=0 ; if test "x$glib2" = xyes ; then AC_MSG_ERROR([*** GLib 2 support not found]) ; fi])
 384 else HAVE_GLIB20=0 ; fi
 385 AC_SUBST(GLIB20_CFLAGS)
 386 AC_SUBST(GLIB20_LIBS)
 387 AC_SUBST(HAVE_GLIB20)
 388 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 389
 390 #### GLib 1 support (optional) ####
 391
 392 AC_ARG_ENABLE([glib1],
 393     AC_HELP_STRING([--disable-glib1], [Disable optional GLib 1 support]),
 394     [case "${enableval}" in yes) glib1=yes ;; no) glib1=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib1) ;; esac],[glib1=auto])
 395 if test "x${glib1}" != xno ; then
 396     PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, [HAVE_GLIB12=0 ; if test "x$glib1" = xyes ; then AC_MSG_ERROR([*** GLib 1 support not found]) ; fi])
 397 else HAVE_GLIB12=0 ; fi
 398 AC_SUBST(GLIB12_CFLAGS)
 399 AC_SUBST(GLIB12_LIBS)
 400 AC_SUBST(HAVE_GLIB12)
 401 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 402
 403 #### Howl support (optional) ####
 404
 405 AC_ARG_ENABLE([howl],
 406     AC_HELP_STRING([--disable-howl], [Disable optional Howl support]),
 407     [case "${enableval}" in yes) howl=yes ;; no) howl=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-howl) ;; esac],[howl=auto])
 408 if test "x${howl}" != xno ; then
 409     PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, PKG_CHECK_MODULES(HOWL, [ avahi-compat-howl >= 0.9.8 ], HAVE_HOWL=1, [HAVE_HOWL=0 ; if test "x$howl" = xyes ; then AC_MSG_ERROR([*** Howl support not found]) ; fi]))
 410 else HAVE_HOWL=0 ; fi
 411 AC_SUBST(HOWL_CFLAGS)
 412 AC_SUBST(HOWL_LIBS)
 413 AC_SUBST(HAVE_HOWL)
 414 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 415
 416 ### LIBOIL ####
 417
 418 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 419 AC_SUBST(LIBOIL_CFLAGS)
 420 AC_SUBST(LIBOIL_LIBS)
 421
 422 ### JACK (optional) ####
 423
 424 AC_ARG_ENABLE([jack],
 425     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 426     [case "${enableval}" in yes) jack=yes ;; no) jack=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;; esac],[jack=auto])
 427 if test "x${jack}" != xno ; then
 428     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ], HAVE_JACK=1, [HAVE_JACK=0 ; if test "x$jack" = xyes ; then AC_MSG_ERROR([*** JACK support not found]) ; fi])
 429 else HAVE_JACK=0 ; fi
 430 AC_SUBST(JACK_CFLAGS)
 431 AC_SUBST(JACK_LIBS)
 432 AC_SUBST(HAVE_JACK)
 433 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 434
 435 #### Async DNS support (optional) ####
 436
 437 AC_ARG_ENABLE([asyncns],
 438     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 439     [case "${enableval}" in yes) asyncns=yes ;; no) asyncns=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;; esac],[asyncns=auto])
 440 if test "x${asyncns}" != xno ; then
 441     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, [HAVE_LIBASYNCNS=0 ; if test "x$asyncns" = xyes ; then AC_MSG_ERROR([*** Async DNS support not found]) ; fi])
 442 else HAVE_LIBASYNCNS=0 ; fi
 443 AC_SUBST(LIBASYNCNS_CFLAGS)
 444 AC_SUBST(LIBASYNCNS_LIBS)
 445 AC_SUBST(HAVE_LIBASYNCNS)
 446 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 447
 448 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 449    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 450 fi
 451
 452 #### TCP wrappers (optional) ####
 453
 454 AC_ARG_ENABLE([tcpwrap],
 455     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 456     [case "${enableval}" in yes) tcpwrap=yes ;; no) tcpwrap=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;; esac],[tcpwrap=auto])
 457 if test "x${tcpwrap}" != xno ; then
 458     ACX_LIBWRAP
 459     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 460         AC_MSG_ERROR([*** TCP wrappers support not found])
 461     fi
 462 else LIBWRAP_LIBS= ; fi
 463 AC_SUBST(LIBWRAP_LIBS)
 464
 465 #### LIRC support (optional) ####
 466
 467 AC_ARG_ENABLE([lirc],
 468     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 469     [case "${enableval}" in yes) lirc=yes ;; no) lirc=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;; esac],[lirc=auto])
 470 if test "x${lirc}" != xno ; then
 471     ACX_LIRC
 472     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 473         AC_MSG_ERROR([*** LIRC support not found])
 474     fi
 475 else HAVE_LIRC=0 ; fi
 476 AC_SUBST(LIRC_CFLAGS)
 477 AC_SUBST(LIRC_LIBS)
 478 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 479
 480 ###################################
 481 #            Output               #
 482 ###################################
 483
 484 AC_ARG_ENABLE(
 485         [static-bins],
 486         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 487         [STATIC_BINS=1], [STATIC_BINS=0])
 488 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 489
 490 AC_ARG_WITH(
 491         [preopen-mods],
 492         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 493         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 494 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 495 if test "x$PREOPEN_MODS" != "xall" ; then
 496     tmpLIBS=""
 497     for mod in $PREOPEN_MODS; do
 498         tmpLIBS="$tmpLIBS module-$mod.la"
 499     done
 500     PREOPEN_MODS="$tmpLIBS"
 501     AC_SUBST(PREOPEN_MODS)
 502 fi
 503
 504 AC_ARG_WITH(
 505         [module-dir],
 506         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/polypaudio-${PA_MAJORMINOR}/modules/]),
 507         [modlibexecdir=$withval], [modlibexecdir="${libdir}/polypaudio-${PA_MAJORMINOR}/modules/"])
 508
 509 AC_SUBST(modlibexecdir)
 510
 511 AC_ARG_ENABLE(
 512         [force-preopen],
 513         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 514         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 515 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 516
 517 AC_CONFIG_FILES([
 518 Makefile
 519 src/Makefile
 520 polyplib.pc
 521 polyplib-simple.pc
 522 polyplib-browse.pc
 523 polyplib-glib-mainloop.pc
 524 polyplib-glib12-mainloop.pc
 525 doc/Makefile
 526 doc/README.html
 527 doc/cli.html
 528 doc/daemon.html
 529 doc/modules.html
 530 doxygen/Makefile
 531 doxygen/doxygen.conf
 532 src/polyp/version.h
 533 doc/FAQ.html
 534 ])
 535 AC_OUTPUT