configure.ac

   1 dnl  Copyright 2005 Red Hat, Inc.
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Red Hat not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Red Hat makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  RED HAT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL RED HAT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 AC_PREREQ([2.57])
  24
  25 #   Pixman versioning scheme
  26 #
  27 #   - The version in git has an odd MICRO version number
  28 #
  29 #   - Released versions both development and stable have an even MICRO
  30 #     version number
  31 #
  32 #   - Released development versions have an odd MINOR number
  33 #
  34 #   - Released stable versions have an even MINOR number
  35 #
  36 #   - Versions that break ABI must have a new MAJOR number
  37 #
  38 #   - If you break the ABI, then at least this must be done:
  39 #
  40 #        - increment MAJOR
  41 #
  42 #        - In the first development release where you break ABI, find
  43 #          all instances of "pixman-n" and change them to pixman-(n+1)
  44 #
  45 #          This needs to be done at least in
  46 #                    configure.ac
  47 #                    all Makefile.am's
  48 #                    pixman-n.pc.in
  49 #
  50 #      This ensures that binary incompatible versions can be installed
  51 #      in parallel.  See http://www106.pair.com/rhp/parallel.html for
  52 #      more information
  53 #
  54
  55 m4_define([pixman_major], 0)
  56 m4_define([pixman_minor], 23)
  57 m4_define([pixman_micro], 5)
  58
  59 m4_define([pixman_version],[pixman_major.pixman_minor.pixman_micro])
  60
  61 AC_INIT(pixman, pixman_version, [pixman@lists.freedesktop.org], pixman)
  62 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  63
  64 # Suppress verbose compile lines
  65 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  66
  67 AM_CONFIG_HEADER(config.h)
  68
  69 AC_CANONICAL_HOST
  70
  71 test_CFLAGS=${CFLAGS+set} # We may override autoconf default CFLAGS.
  72
  73 AC_PROG_CC
  74 AM_PROG_AS
  75 AC_PROG_LIBTOOL
  76 AC_CHECK_FUNCS([getisax])
  77 AC_C_BIGENDIAN
  78 AC_C_INLINE
  79
  80 dnl PIXMAN_LINK_WITH_ENV(env-setup, program, true-action, false-action)
  81 dnl
  82 dnl Compiles and links the given program in the environment setup by env-setup
  83 dnl and executes true-action on success and false-action on failure.
  84 AC_DEFUN([PIXMAN_LINK_WITH_ENV],[dnl
  85         save_CFLAGS="$CFLAGS"
  86         save_LDFLAGS="$LDFLAGS"
  87         save_LIBS="$LIBS"
  88         CFLAGS=""
  89         LDFLAGS=""
  90         LIBS=""
  91         $1
  92         AC_LINK_IFELSE(
  93                 [AC_LANG_SOURCE([$2])],
  94                 [pixman_cc_stderr=`test -f conftest.err && cat conftest.err`
  95                  pixman_cc_flag=yes],
  96                 [pixman_cc_stderr=`test -f conftest.err && cat conftest.err`
  97                  pixman_cc_flag=no])
  98
  99         if test "x$pixman_cc_stderr" != "x"; then
 100                 pixman_cc_flag=no
 101         fi
 102
 103         if test "x$pixman_cc_flag" = "xyes"; then
 104                 ifelse([$3], , :, [$3])
 105         else
 106                 ifelse([$4], , :, [$4])
 107         fi
 108         CFLAGS="$save_CFLAGS"
 109         LDFLAGS="$save_LDFLAGS"
 110         LIBS="$save_LIBS"
 111 ])
 112
 113 dnl Find a -Werror for catching warnings.
 114 WERROR=
 115 for w in -Werror -errwarn; do
 116     if test "z$WERROR" = "z"; then
 117         AC_MSG_CHECKING([whether the compiler supports $w])
 118         PIXMAN_LINK_WITH_ENV(
 119                 [CFLAGS=$w],
 120                 [int main(int c, char **v) { (void)c; (void)v; return 0; }],
 121                 [WERROR=$w; yesno=yes], [yesno=no])
 122         AC_MSG_RESULT($yesno)
 123     fi
 124 done
 125
 126 dnl PIXMAN_CHECK_CFLAG(flag, [program])
 127 dnl  Adds flag to CFLAGS if the given program links without warnings or errors.
 128 AC_DEFUN([PIXMAN_CHECK_CFLAG], [dnl
 129         AC_MSG_CHECKING([whether the compiler supports $1])
 130         PIXMAN_LINK_WITH_ENV(
 131                 [CFLAGS="$WERROR $1"],
 132                 [$2
 133                  int main(int c, char **v) { (void)c; (void)v; return 0; }
 134                 ],
 135                 [_yesno=yes],
 136                 [_yesno=no])
 137         if test "x$_yesno" = xyes; then
 138            CFLAGS="$CFLAGS $1"
 139         fi
 140         AC_MSG_RESULT($_yesno)
 141 ])
 142
 143 AC_CHECK_SIZEOF(long)
 144
 145 # Checks for Sun Studio compilers
 146 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
 147 AC_CHECK_DECL([__amd64], [AMD64_ABI="yes"], [AMD64_ABI="no"])
 148
 149 # Default CFLAGS to -O -g rather than just the -g from AC_PROG_CC
 150 # if we're using Sun Studio and neither the user nor a config.site
 151 # has set CFLAGS.
 152 if test $SUNCC = yes &&                 \
 153    test "$test_CFLAGS" == "" &&         \
 154    test "$CFLAGS" = "-g"
 155 then
 156   CFLAGS="-O -g"
 157 fi
 158
 159 #
 160 # We ignore pixman_major in the version here because the major version should
 161 # always be encoded in the actual library name. Ie., the soname is:
 162 #
 163 #      pixman-$(pixman_major).0.minor.micro
 164 #
 165 m4_define([lt_current], [pixman_minor])
 166 m4_define([lt_revision], [pixman_micro])
 167 m4_define([lt_age], [pixman_minor])
 168
 169 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 170
 171 PIXMAN_VERSION_MAJOR=pixman_major()
 172 AC_SUBST(PIXMAN_VERSION_MAJOR)
 173 PIXMAN_VERSION_MINOR=pixman_minor()
 174 AC_SUBST(PIXMAN_VERSION_MINOR)
 175 PIXMAN_VERSION_MICRO=pixman_micro()
 176 AC_SUBST(PIXMAN_VERSION_MICRO)
 177
 178 AC_SUBST(LT_VERSION_INFO)
 179
 180 # Check for dependencies
 181
 182 PIXMAN_CHECK_CFLAG([-Wall])
 183 PIXMAN_CHECK_CFLAG([-fno-strict-aliasing])
 184
 185 AC_PATH_PROG(PERL, perl, no)
 186 if test "x$PERL" = xno; then
 187     AC_MSG_ERROR([Perl is required to build pixman.])
 188 fi
 189 AC_SUBST(PERL)
 190
 191 dnl =========================================================================
 192 dnl OpenMP for the test suite?
 193 dnl
 194
 195 # Check for OpenMP support only when autoconf support that (require autoconf >=2.62)
 196 OPENMP_CFLAGS=
 197 m4_ifdef([AC_OPENMP], [AC_OPENMP])
 198
 199 if test "x$enable_openmp" = "xyes" && test "x$ac_cv_prog_c_openmp" = "xunsupported" ; then
 200   AC_MSG_WARN([OpenMP support requested but found unsupported])
 201 fi
 202
 203 dnl May not fail to link without -Wall -Werror added
 204 dnl So try to link only when openmp is supported
 205 dnl ac_cv_prog_c_openmp is not defined when --disable-openmp is used
 206 if test "x$ac_cv_prog_c_openmp" != "xunsupported" && test "x$ac_cv_prog_c_openmp" != "x"; then
 207   m4_define([openmp_test_program],[dnl
 208   #include <stdio.h>
 209
 210   extern unsigned int lcg_seed;
 211   #pragma omp threadprivate(lcg_seed)
 212   unsigned int lcg_seed;
 213
 214   unsigned function(unsigned a, unsigned b)
 215   {
 216         lcg_seed ^= b;
 217         return ((a + b) ^ a ) + lcg_seed;
 218   }
 219
 220   int main(int argc, char **argv)
 221   {
 222         int i;
 223         int n1 = 0, n2 = argc;
 224         unsigned checksum = 0;
 225         int verbose = argv != NULL;
 226         unsigned (*test_function)(unsigned, unsigned);
 227         test_function = function;
 228         #pragma omp parallel for reduction(+:checksum) default(none) \
 229                                         shared(n1, n2, test_function, verbose)
 230         for (i = n1; i < n2; i++)
 231         {
 232                 unsigned crc = test_function (i, 0);
 233                 if (verbose)
 234                         printf ("%d: %08X\n", i, crc);
 235                 checksum += crc;
 236         }
 237         printf("%u\n", checksum);
 238         return 0;
 239   }
 240   ])
 241
 242   PIXMAN_LINK_WITH_ENV(
 243         [CFLAGS="$OPENMP_CFLAGS" LDFLAGS="$OPENMP_CFLAGS"],
 244         [openmp_test_program],
 245         [have_openmp=yes],
 246         [have_openmp=no])
 247   if test "x$have_openmp" = "xyes" ; then
 248     AC_DEFINE(USE_OPENMP, 1, [use OpenMP in the test suite])
 249   fi
 250 fi
 251 AC_SUBST(OPENMP_CFLAGS)
 252
 253 dnl =========================================================================
 254 dnl -fvisibility stuff
 255
 256 PIXMAN_CHECK_CFLAG([-fvisibility=hidden], [dnl
 257 #if defined(__GNUC__) && (__GNUC__ >= 4)
 258 #ifdef _WIN32
 259 #error Have -fvisibility but it is ignored and generates a warning
 260 #endif
 261 #else
 262 error Need GCC 4.0 for visibility
 263 #endif
 264 ])
 265
 266 PIXMAN_CHECK_CFLAG([-xldscope=hidden], [dnl
 267 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
 268 #else
 269 error Need Sun Studio 8 for visibility
 270 #endif
 271 ])
 272
 273 dnl ===========================================================================
 274 dnl Check for MMX
 275
 276 if test "x$MMX_CFLAGS" = "x" ; then
 277    if test "x$SUNCC" = "xyes"; then
 278       # Sun Studio doesn't have an -xarch=mmx flag, so we have to use sse
 279       # but if we're building 64-bit, mmx & sse support is on by default and
 280       # -xarch=sse throws an error instead
 281       if test "$AMD64_ABI" = "no" ; then
 282          MMX_CFLAGS="-xarch=sse"
 283       fi
 284    else
 285       MMX_CFLAGS="-mmmx -Winline"
 286    fi
 287 fi
 288
 289 have_mmx_intrinsics=no
 290 AC_MSG_CHECKING(whether to use MMX intrinsics)
 291 xserver_save_CFLAGS=$CFLAGS
 292 CFLAGS="$MMX_CFLAGS $CFLAGS"
 293 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 294 #if defined(__GNUC__) && (__GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 4))
 295 error "Need GCC >= 3.4 for MMX intrinsics"
 296 #endif
 297 #include <mmintrin.h>
 298 int main () {
 299     __m64 v = _mm_cvtsi32_si64 (1);
 300     return _mm_cvtsi64_si32 (v);
 301 }]])], have_mmx_intrinsics=yes)
 302 CFLAGS=$xserver_save_CFLAGS
 303
 304 AC_ARG_ENABLE(mmx,
 305    [AC_HELP_STRING([--disable-mmx],
 306                    [disable x86 MMX fast paths])],
 307    [enable_mmx=$enableval], [enable_mmx=auto])
 308
 309 if test $enable_mmx = no ; then
 310    have_mmx_intrinsics=disabled
 311 fi
 312
 313 if test $have_mmx_intrinsics = yes ; then
 314    AC_DEFINE(USE_X86_MMX, 1, [use x86 MMX compiler intrinsics])
 315 else
 316    MMX_CFLAGS=
 317 fi
 318
 319 AC_MSG_RESULT($have_mmx_intrinsics)
 320 if test $enable_mmx = yes && test $have_mmx_intrinsics = no ; then
 321    AC_MSG_ERROR([x86 MMX intrinsics not detected])
 322 fi
 323
 324 AM_CONDITIONAL(USE_X86_MMX, test $have_mmx_intrinsics = yes)
 325
 326 dnl ===========================================================================
 327 dnl Check for SSE2
 328
 329 if test "x$SSE2_CFLAGS" = "x" ; then
 330    if test "x$SUNCC" = "xyes"; then
 331       # SSE2 is enabled by default in the Sun Studio 64-bit environment
 332       if test "$AMD64_ABI" = "no" ; then
 333          SSE2_CFLAGS="-xarch=sse2"
 334       fi
 335    else
 336       SSE2_CFLAGS="-msse2 -Winline"
 337    fi
 338 fi
 339
 340 have_sse2_intrinsics=no
 341 AC_MSG_CHECKING(whether to use SSE2 intrinsics)
 342 xserver_save_CFLAGS=$CFLAGS
 343 CFLAGS="$SSE2_CFLAGS $CFLAGS"
 344
 345 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 346 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 2))
 347 #   if !defined(__amd64__) && !defined(__x86_64__)
 348 #      error "Need GCC >= 4.2 for SSE2 intrinsics on x86"
 349 #   endif
 350 #endif
 351 #include <mmintrin.h>
 352 #include <xmmintrin.h>
 353 #include <emmintrin.h>
 354 int main () {
 355     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 356         c = _mm_xor_si128 (a, b);
 357     return 0;
 358 }]])], have_sse2_intrinsics=yes)
 359 CFLAGS=$xserver_save_CFLAGS
 360
 361 AC_ARG_ENABLE(sse2,
 362    [AC_HELP_STRING([--disable-sse2],
 363                    [disable SSE2 fast paths])],
 364    [enable_sse2=$enableval], [enable_sse2=auto])
 365
 366 if test $enable_sse2 = no ; then
 367    have_sse2_intrinsics=disabled
 368 fi
 369
 370 if test $have_sse2_intrinsics = yes ; then
 371    AC_DEFINE(USE_SSE2, 1, [use SSE2 compiler intrinsics])
 372 fi
 373
 374 AC_MSG_RESULT($have_sse2_intrinsics)
 375 if test $enable_sse2 = yes && test $have_sse2_intrinsics = no ; then
 376    AC_MSG_ERROR([SSE2 intrinsics not detected])
 377 fi
 378
 379 AM_CONDITIONAL(USE_SSE2, test $have_sse2_intrinsics = yes)
 380
 381 dnl ===========================================================================
 382 dnl Other special flags needed when building code using MMX or SSE instructions
 383 case $host_os in
 384    solaris*)
 385       # When building 32-bit binaries, apply a mapfile to ensure that the
 386       # binaries aren't flagged as only able to run on MMX+SSE capable CPUs
 387       # since they check at runtime before using those instructions.
 388       # Not all linkers grok the mapfile format so we check for that first.
 389       if test "$AMD64_ABI" = "no" ; then
 390          use_hwcap_mapfile=no
 391          AC_MSG_CHECKING(whether to use a hardware capability map file)
 392          hwcap_save_LDFLAGS="$LDFLAGS"
 393          HWCAP_LDFLAGS='-Wl,-M,$(srcdir)/solaris-hwcap.mapfile'
 394          LDFLAGS="$LDFLAGS -Wl,-M,pixman/solaris-hwcap.mapfile"
 395          AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])],
 396                         use_hwcap_mapfile=yes,
 397                         HWCAP_LDFLAGS="")
 398          LDFLAGS="$hwcap_save_LDFLAGS"
 399          AC_MSG_RESULT($use_hwcap_mapfile)
 400       fi
 401       if test "x$MMX_LDFLAGS" = "x" ; then
 402          MMX_LDFLAGS="$HWCAP_LDFLAGS"
 403       fi
 404       if test "x$SSE2_LDFLAGS" = "x" ; then
 405          SSE2_LDFLAGS="$HWCAP_LDFLAGS"
 406       fi
 407       ;;
 408 esac
 409
 410 AC_SUBST(MMX_CFLAGS)
 411 AC_SUBST(MMX_LDFLAGS)
 412 AC_SUBST(SSE2_CFLAGS)
 413 AC_SUBST(SSE2_LDFLAGS)
 414
 415 dnl ===========================================================================
 416 dnl Check for VMX/Altivec
 417 if test -n "`$CC -v 2>&1 | grep version | grep Apple`"; then
 418     VMX_CFLAGS="-faltivec"
 419 else
 420     VMX_CFLAGS="-maltivec -mabi=altivec"
 421 fi
 422
 423 have_vmx_intrinsics=no
 424 AC_MSG_CHECKING(whether to use VMX/Altivec intrinsics)
 425 xserver_save_CFLAGS=$CFLAGS
 426 CFLAGS="$VMX_CFLAGS $CFLAGS"
 427 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 428 #if defined(__GNUC__) && (__GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 4))
 429 error "Need GCC >= 3.4 for sane altivec support"
 430 #endif
 431 #include <altivec.h>
 432 int main () {
 433     vector unsigned int v = vec_splat_u32 (1);
 434     v = vec_sub (v, v);
 435     return 0;
 436 }]])], have_vmx_intrinsics=yes)
 437 CFLAGS=$xserver_save_CFLAGS
 438
 439 AC_ARG_ENABLE(vmx,
 440    [AC_HELP_STRING([--disable-vmx],
 441                    [disable VMX fast paths])],
 442    [enable_vmx=$enableval], [enable_vmx=auto])
 443
 444 if test $enable_vmx = no ; then
 445    have_vmx_intrinsics=disabled
 446 fi
 447
 448 if test $have_vmx_intrinsics = yes ; then
 449    AC_DEFINE(USE_VMX, 1, [use VMX compiler intrinsics])
 450 else
 451    VMX_CFLAGS=
 452 fi
 453
 454 AC_MSG_RESULT($have_vmx_intrinsics)
 455 if test $enable_vmx = yes && test $have_vmx_intrinsics = no ; then
 456    AC_MSG_ERROR([VMX intrinsics not detected])
 457 fi
 458
 459 AC_SUBST(VMX_CFLAGS)
 460
 461 AM_CONDITIONAL(USE_VMX, test $have_vmx_intrinsics = yes)
 462
 463 dnl ==========================================================================
 464 dnl Check if assembler is gas compatible and supports ARM SIMD instructions
 465 have_arm_simd=no
 466 AC_MSG_CHECKING(whether to use ARM SIMD assembler)
 467 xserver_save_CFLAGS=$CFLAGS
 468 CFLAGS="-x assembler-with-cpp $CFLAGS"
 469 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 470 .text
 471 .arch armv6
 472 .object_arch armv4
 473 .arm
 474 .altmacro
 475 #ifndef __ARM_EABI__
 476 #error EABI is required (to be sure that calling conventions are compatible)
 477 #endif
 478 pld [r0]
 479 uqadd8 r0, r0, r0]])], have_arm_simd=yes)
 480 CFLAGS=$xserver_save_CFLAGS
 481
 482 AC_ARG_ENABLE(arm-simd,
 483    [AC_HELP_STRING([--disable-arm-simd],
 484                    [disable ARM SIMD fast paths])],
 485    [enable_arm_simd=$enableval], [enable_arm_simd=auto])
 486
 487 if test $enable_arm_simd = no ; then
 488    have_arm_simd=disabled
 489 fi
 490
 491 if test $have_arm_simd = yes ; then
 492    AC_DEFINE(USE_ARM_SIMD, 1, [use ARM SIMD assembly optimizations])
 493 fi
 494
 495 AM_CONDITIONAL(USE_ARM_SIMD, test $have_arm_simd = yes)
 496
 497 AC_MSG_RESULT($have_arm_simd)
 498 if test $enable_arm_simd = yes && test $have_arm_simd = no ; then
 499    AC_MSG_ERROR([ARM SIMD intrinsics not detected])
 500 fi
 501
 502 dnl ==========================================================================
 503 dnl Check if assembler is gas compatible and supports NEON instructions
 504 have_arm_neon=no
 505 AC_MSG_CHECKING(whether to use ARM NEON assembler)
 506 xserver_save_CFLAGS=$CFLAGS
 507 CFLAGS="-x assembler-with-cpp $CFLAGS"
 508 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 509 .text
 510 .fpu neon
 511 .arch armv7a
 512 .object_arch armv4
 513 .eabi_attribute 10, 0
 514 .arm
 515 .altmacro
 516 #ifndef __ARM_EABI__
 517 #error EABI is required (to be sure that calling conventions are compatible)
 518 #endif
 519 pld [r0]
 520 vmovn.u16 d0, q0]])], have_arm_neon=yes)
 521 CFLAGS=$xserver_save_CFLAGS
 522
 523 AC_ARG_ENABLE(arm-neon,
 524    [AC_HELP_STRING([--disable-arm-neon],
 525                    [disable ARM NEON fast paths])],
 526    [enable_arm_neon=$enableval], [enable_arm_neon=auto])
 527
 528 if test $enable_arm_neon = no ; then
 529    have_arm_neon=disabled
 530 fi
 531
 532 if test $have_arm_neon = yes ; then
 533    AC_DEFINE(USE_ARM_NEON, 1, [use ARM NEON assembly optimizations])
 534 fi
 535
 536 AM_CONDITIONAL(USE_ARM_NEON, test $have_arm_neon = yes)
 537
 538 AC_MSG_RESULT($have_arm_neon)
 539 if test $enable_arm_neon = yes && test $have_arm_neon = no ; then
 540    AC_MSG_ERROR([ARM NEON intrinsics not detected])
 541 fi
 542
 543 dnl ===========================================================================
 544 dnl Check for IWMMXT
 545
 546 if test "x$IWMMXT_CFLAGS" = "x" ; then
 547    IWMMXT_CFLAGS="-march=iwmmxt -flax-vector-conversions -Winline"
 548 fi
 549
 550 have_iwmmxt_intrinsics=no
 551 AC_MSG_CHECKING(whether to use ARM IWMMXT intrinsics)
 552 xserver_save_CFLAGS=$CFLAGS
 553 CFLAGS="$IWMMXT_CFLAGS $CFLAGS"
 554 AC_COMPILE_IFELSE([
 555 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 3 && __GNUC_MINOR__ < 6))
 556 #error "Need GCC >= 4.6 for IWMMXT intrinsics"
 557 #endif
 558 #include <mmintrin.h>
 559 int main () {
 560         union {
 561                 __m64 v;
 562                 [char c[8];]
 563         } a = { .c = {1, 2, 3, 4, 5, 6, 7, 8} };
 564         int b = 4;
 565         __m64 c = _mm_srli_si64 (a.v, b);
 566 }], have_iwmmxt_intrinsics=yes)
 567 CFLAGS=$xserver_save_CFLAGS
 568
 569 AC_ARG_ENABLE(arm-iwmmxt,
 570    [AC_HELP_STRING([--disable-arm-iwmmxt],
 571                    [disable ARM IWMMXT fast paths])],
 572    [enable_iwmmxt=$enableval], [enable_iwmmxt=auto])
 573
 574 if test $enable_iwmmxt = no ; then
 575    have_iwmmxt_intrinsics=disabled
 576 fi
 577
 578 if test $have_iwmmxt_intrinsics = yes ; then
 579    AC_DEFINE(USE_ARM_IWMMXT, 1, [use ARM IWMMXT compiler intrinsics])
 580 else
 581    IWMMXT_CFLAGS=
 582 fi
 583
 584 AC_MSG_RESULT($have_iwmmxt_intrinsics)
 585 if test $enable_iwmmxt = yes && test $have_iwmmxt_intrinsics = no ; then
 586    AC_MSG_ERROR([IWMMXT intrinsics not detected])
 587 fi
 588
 589 AM_CONDITIONAL(USE_ARM_IWMMXT, test $have_iwmmxt_intrinsics = yes)
 590
 591 dnl =========================================================================================
 592 dnl Check for GNU-style inline assembly support
 593
 594 have_gcc_inline_asm=no
 595 AC_MSG_CHECKING(whether to use GNU-style inline assembler)
 596 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 597 int main () {
 598     /* Most modern architectures have a NOP instruction, so this is a fairly generic test. */
 599         asm volatile ( "\tnop\n" : : : "cc", "memory" );
 600     return 0;
 601 }]])], have_gcc_inline_asm=yes)
 602
 603 AC_ARG_ENABLE(gcc-inline-asm,
 604    [AC_HELP_STRING([--disable-gcc-inline-asm],
 605                    [disable GNU-style inline assembler])],
 606    [enable_gcc_inline_asm=$enableval], [enable_gcc_inline_asm=auto])
 607
 608 if test $enable_gcc_inline_asm = no ; then
 609    have_gcc_inline_asm=disabled
 610 fi
 611
 612 if test $have_gcc_inline_asm = yes ; then
 613    AC_DEFINE(USE_GCC_INLINE_ASM, 1, [use GNU-style inline assembler])
 614 fi
 615
 616 AC_MSG_RESULT($have_gcc_inline_asm)
 617 if test $enable_gcc_inline_asm = yes && test $have_gcc_inline_asm = no ; then
 618    AC_MSG_ERROR([GNU-style inline assembler not detected])
 619 fi
 620
 621 AM_CONDITIONAL(USE_GCC_INLINE_ASM, test $have_gcc_inline_asm = yes)
 622
 623 dnl ==============================================
 624 dnl Static test programs
 625
 626 AC_ARG_ENABLE(static-testprogs,
 627    [AC_HELP_STRING([--enable-static-testprogs],
 628                    [build test programs as static binaries [default=no]])],
 629    [enable_static_testprogs=$enableval], [enable_static_testprogs=no])
 630
 631 TESTPROGS_EXTRA_LDFLAGS=
 632 if test "x$enable_static_testprogs" = "xyes" ; then
 633    TESTPROGS_EXTRA_LDFLAGS="-all-static"
 634 fi
 635 AC_SUBST(TESTPROGS_EXTRA_LDFLAGS)
 636
 637 dnl ==============================================
 638 dnl Timers
 639
 640 AC_ARG_ENABLE(timers,
 641    [AC_HELP_STRING([--enable-timers],
 642                    [enable TIMER_BEGIN and TIMER_END macros [default=no]])],
 643    [enable_timers=$enableval], [enable_timers=no])
 644
 645 if test $enable_timers = yes ; then
 646    AC_DEFINE(PIXMAN_TIMERS, 1, [enable TIMER_BEGIN/TIMER_END macros])
 647 fi
 648 AC_SUBST(PIXMAN_TIMERS)
 649
 650 dnl ===================================
 651 dnl GTK+
 652
 653 AC_ARG_ENABLE(gtk,
 654    [AC_HELP_STRING([--enable-gtk],
 655                    [enable tests using GTK+ [default=auto]])],
 656    [enable_gtk=$enableval], [enable_gtk=auto])
 657
 658 PKG_PROG_PKG_CONFIG
 659
 660 if test $enable_gtk = yes ; then
 661    AC_CHECK_LIB([pixman-1], [pixman_version_string])
 662    PKG_CHECK_MODULES(GTK, [gtk+-2.0 pixman-1])
 663 fi
 664
 665 if test $enable_gtk = auto ; then
 666    AC_CHECK_LIB([pixman-1], [pixman_version_string], [enable_gtk=auto], [enable_gtk=no])
 667 fi
 668
 669 if test $enable_gtk = auto ; then
 670    PKG_CHECK_MODULES(GTK, [gtk+-2.0 pixman-1], [enable_gtk=yes], [enable_gtk=no])
 671 fi
 672
 673 AM_CONDITIONAL(HAVE_GTK, [test "x$enable_gtk" = xyes])
 674
 675 AC_SUBST(GTK_CFLAGS)
 676 AC_SUBST(GTK_LIBS)
 677 AC_SUBST(DEP_CFLAGS)
 678 AC_SUBST(DEP_LIBS)
 679
 680 dnl =====================================
 681 dnl posix_memalign, sigaction, alarm, gettimeofday
 682
 683 AC_CHECK_FUNC(posix_memalign, have_posix_memalign=yes, have_posix_memalign=no)
 684 if test x$have_posix_memalign = xyes; then
 685    AC_DEFINE(HAVE_POSIX_MEMALIGN, 1, [Whether we have posix_memalign()])
 686 fi
 687
 688 AC_CHECK_FUNC(sigaction, have_sigaction=yes, have_sigaction=no)
 689 if test x$have_sigaction = xyes; then
 690    AC_DEFINE(HAVE_SIGACTION, 1, [Whether we have sigaction()])
 691 fi
 692
 693 AC_CHECK_FUNC(alarm, have_alarm=yes, have_alarm=no)
 694 if test x$have_alarm = xyes; then
 695    AC_DEFINE(HAVE_ALARM, 1, [Whether we have alarm()])
 696 fi
 697
 698 AC_CHECK_HEADER([sys/mman.h],
 699    [AC_DEFINE(HAVE_SYS_MMAN_H, [1], [Define to 1 if we have <sys/mman.h>])])
 700
 701 AC_CHECK_FUNC(mmap, have_mmap=yes, have_mmap=no)
 702 if test x$have_mmap = xyes; then
 703    AC_DEFINE(HAVE_MMAP, 1, [Whether we have mmap()])
 704 fi
 705
 706 AC_CHECK_FUNC(mprotect, have_mprotect=yes, have_mprotect=no)
 707 if test x$have_mprotect = xyes; then
 708    AC_DEFINE(HAVE_MPROTECT, 1, [Whether we have mprotect()])
 709 fi
 710
 711 AC_CHECK_FUNC(getpagesize, have_getpagesize=yes, have_getpagesize=no)
 712 if test x$have_getpagesize = xyes; then
 713    AC_DEFINE(HAVE_GETPAGESIZE, 1, [Whether we have getpagesize()])
 714 fi
 715
 716 AC_CHECK_HEADER([fenv.h],
 717    [AC_DEFINE(HAVE_FENV_H, [1], [Define to 1 if we have <fenv.h>])])
 718
 719 AC_CHECK_LIB(m, feenableexcept, have_feenableexcept=yes, have_feenableexcept=no)
 720 if test x$have_feenableexcept = xyes; then
 721    AC_DEFINE(HAVE_FEENABLEEXCEPT, 1, [Whether we have feenableexcept()])
 722 fi
 723
 724 AC_CHECK_FUNC(gettimeofday, have_gettimeofday=yes, have_gettimeofday=no)
 725 AC_CHECK_HEADER(sys/time.h, have_sys_time_h=yes, have_sys_time_h=no)
 726 if test x$have_gettimeofday = xyes && test x$have_sys_time_h = xyes; then
 727    AC_DEFINE(HAVE_GETTIMEOFDAY, 1, [Whether we have gettimeofday()])
 728 fi
 729
 730 dnl =====================================
 731 dnl Thread local storage
 732
 733 support_for__thread=no
 734
 735 AC_MSG_CHECKING(for __thread)
 736 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 737 #if defined(__MINGW32__) && !(__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 5))
 738 #error This MinGW version has broken __thread support
 739 #endif
 740 #ifdef __OpenBSD__
 741 #error OpenBSD has broken __thread support
 742 #endif
 743 static __thread int x ;
 744 int main () { x = 123; return x; }
 745 ]])], support_for__thread=yes)
 746
 747 if test $support_for__thread = yes; then
 748    AC_DEFINE([TOOLCHAIN_SUPPORTS__THREAD],[],[Whether the tool chain supports __thread])
 749 fi
 750
 751 AC_MSG_RESULT($support_for__thread)
 752
 753 dnl
 754 dnl posix tls
 755 dnl
 756
 757 m4_define([pthread_test_program],AC_LANG_SOURCE([[dnl
 758 #include <stdlib.h>
 759 #include <pthread.h>
 760
 761 static pthread_once_t once_control = PTHREAD_ONCE_INIT;
 762 static pthread_key_t key;
 763
 764 static void
 765 make_key (void)
 766 {
 767     pthread_key_create (&key, NULL);
 768 }
 769
 770 int
 771 main ()
 772 {
 773     void *value = NULL;
 774
 775     if (pthread_once (&once_control, make_key) != 0)
 776     {
 777         value = NULL;
 778     }
 779     else
 780     {
 781         value = pthread_getspecific (key);
 782         if (!value)
 783         {
 784             value = malloc (100);
 785             pthread_setspecific (key, value);
 786         }
 787     }
 788     return 0;
 789 }
 790 ]]))
 791
 792 AC_DEFUN([PIXMAN_CHECK_PTHREAD],[dnl
 793     if test "z$support_for_pthread_setspecific" != "zyes"; then
 794         PIXMAN_LINK_WITH_ENV(
 795                 [$1], [pthread_test_program],
 796                 [PTHREAD_CFLAGS="$CFLAGS"
 797                  PTHREAD_LIBS="$LIBS"
 798                  PTHREAD_LDFLAGS="$LDFLAGS"
 799                  support_for_pthread_setspecific=yes])
 800     fi
 801 ])
 802
 803 if test $support_for__thread = no; then
 804     support_for_pthread_setspecific=no
 805
 806     AC_MSG_CHECKING(for pthread_setspecific)
 807
 808     PIXMAN_CHECK_PTHREAD([CFLAGS="-D_REENTRANT"; LIBS="-lpthread"])
 809     PIXMAN_CHECK_PTHREAD([CFLAGS="-pthread"; LDFLAGS="-pthread"])
 810     PIXMAN_CHECK_PTHREAD([CFLAGS="-D_REENTRANT"; LDFLAGS="-lroot"])
 811
 812     if test $support_for_pthread_setspecific = yes; then
 813         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 814         AC_DEFINE([HAVE_PTHREAD_SETSPECIFIC], [], [Whether pthread_setspecific() is supported])
 815     fi
 816
 817     AC_MSG_RESULT($support_for_pthread_setspecific);
 818 fi
 819
 820 AC_SUBST(TOOLCHAIN_SUPPORTS__THREAD)
 821 AC_SUBST(HAVE_PTHREAD_SETSPECIFIC)
 822 AC_SUBST(PTHREAD_LDFLAGS)
 823 AC_SUBST(PTHREAD_LIBS)
 824
 825 dnl =====================================
 826 dnl __attribute__((constructor))
 827
 828 support_for_attribute_constructor=no
 829
 830 AC_MSG_CHECKING(for __attribute__((constructor)))
 831 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 832 #if defined(__GNUC__) && (__GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7))
 833 /* attribute 'constructor' is supported since gcc 2.7, but some compilers
 834  * may only pretend to be gcc, so let's try to actually use it
 835  */
 836 static int x = 1;
 837 static void __attribute__((constructor)) constructor_function () { x = 0; }
 838 int main (void) { return x; }
 839 #else
 840 #error not gcc or gcc version is older than 2.7
 841 #endif
 842 ]])], support_for_attribute_constructor=yes)
 843
 844 if test x$support_for_attribute_constructor = xyes; then
 845    AC_DEFINE([TOOLCHAIN_SUPPORTS_ATTRIBUTE_CONSTRUCTOR],
 846              [],[Whether the tool chain supports __attribute__((constructor))])
 847 fi
 848
 849 AC_MSG_RESULT($support_for_attribute_constructor)
 850 AC_SUBST(TOOLCHAIN_SUPPORTS_ATTRIBUTE_CONSTRUCTOR)
 851
 852 dnl ==================
 853 dnl libpng
 854
 855 PKG_CHECK_MODULES(PNG, [libpng], have_libpng=yes, have_libpng=no)
 856
 857 if test x$have_libpng = xyes; then
 858     AC_DEFINE([HAVE_LIBPNG], [1], [Whether we have libpng])
 859 fi
 860
 861 AC_SUBST(HAVE_LIBPNG)
 862
 863 AC_OUTPUT([pixman-1.pc
 864            pixman-1-uninstalled.pc
 865            Makefile
 866            pixman/Makefile
 867            pixman/pixman-version.h
 868            demos/Makefile
 869            test/Makefile])
 870
 871 m4_if(m4_eval(pixman_minor % 2), [1], [
 872    echo
 873    echo "@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@"
 874    echo
 875    echo "      Thanks for testing this development snapshot of pixman. Please"
 876    echo "      report any problems you find, either by sending email to "
 877    echo
 878    echo "          pixman@lists.freedesktop.org"
 879    echo
 880    echo "      or by filing a bug at "
 881    echo
 882    echo "          https://bugs.freedesktop.org/enter_bug.cgi?product=pixman "
 883    echo
 884    echo "      If you are looking for a stable release of pixman, please note "
 885    echo "      that stable releases have _even_ minor version numbers. Ie., "
 886    echo "      pixman-0.]m4_eval(pixman_minor & ~1)[.x are stable releases, whereas pixman-$PIXMAN_VERSION_MAJOR.$PIXMAN_VERSION_MINOR.$PIXMAN_VERSION_MICRO is a "
 887    echo "      development snapshot that may contain bugs and experimental "
 888    echo "      features. "
 889    echo
 890    echo "@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@"
 891    echo
 892 ])