configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [0])
   4 m4_define([v_min], [5])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v exported || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 m4_define([relname], [ver-pre-svn-07])
  12 m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])],
  15 [m4_define([v_ver], [v_maj.v_min.v_mic])])
  16 m4_define([lt_rev], m4_eval(v_maj + v_min))
  17 m4_define([lt_cur], v_mic)
  18 m4_define([lt_age], v_min)
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  21
  22 AC_INIT([e_dbus], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  23 AC_PREREQ([2.52])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_MACRO_DIR([m4])
  26 AC_CANONICAL_BUILD
  27 AC_CANONICAL_HOST
  28
  29 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  30 AM_CONFIG_HEADER([config.h])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 AC_LIBTOOL_WIN32_DLL
  34 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  35 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  36 AC_PROG_LIBTOOL
  37
  38 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  41 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  42 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  43 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  44 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  45 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  46 version_info="lt_rev:lt_cur:lt_age"
  47 release_info="v_rel"
  48 AC_SUBST(version_info)
  49 AC_SUBST(release_info)
  50 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 VMAJ=v_maj
  53 AC_SUBST(VMAJ)
  54
  55 ### Needed information
  56
  57 want_ebluez="yes"
  58 want_econnman="yes"
  59 want_ehal="yes"
  60 want_enotify="yes"
  61 want_eofono="yes"
  62 want_eukit="yes"
  63
  64 case "$host_os" in
  65    mingw*)
  66       want_ebluez="no"
  67       want_econnman="no"
  68       want_ehal="no"
  69       want_enotify="no"
  70       want_eofono="no"
  71       want_eukit="no"
  72       ;;
  73 esac
  74
  75 requirement_ebluez="edbus"
  76 requirement_econnman="edbus"
  77 requirement_edbus="ecore eina-0 dbus-1"
  78 requirement_ehal="edbus"
  79 requirement_enotify="edbus"
  80 requirement_eofono="edbus"
  81 requirement_eukit="edbus"
  82
  83 ### Additional options to configure
  84
  85 dnl Check enabled modules to build
  86
  87 AC_ARG_ENABLE([ebluez],
  88    [AC_HELP_STRING([--enable-ebluez], [Enable ebluez build])],
  89    [enable_ebluez=$enableval],
  90    [enable_ebluez="${want_ebluez}"])
  91
  92 AC_ARG_ENABLE([econnman],
  93    [AC_HELP_STRING([--enable-econnman], [Enable econnman build])],
  94    [enable_econnman=$enableval],
  95    [enable_econnman="${want_econnman}"])
  96
  97 AC_ARG_ENABLE([ehal],
  98    [AC_HELP_STRING([--disable-ehal], [Disable ehal build])],
  99    [enable_ehal=$enableval],
 100    [enable_ehal="${want_ehal}"])
 101
 102 AC_ARG_ENABLE([enotify],
 103    [AC_HELP_STRING([--disable-enotify], [Disable enotify build])],
 104    [enable_enotify=$enableval],
 105    [enable_enotify="${want_enotify}"])
 106
 107 AC_ARG_ENABLE([eofono],
 108    [AC_HELP_STRING([--enable-eofono], [Enable eofono build])],
 109    [enable_eofono=$enableval],
 110    [enable_eofono="${want_eofono}"])
 111
 112 AC_ARG_ENABLE([eukit],
 113    [AC_HELP_STRING([--disable-eukit], [Disable eukit build])],
 114    [enable_eukit=$enableval],
 115    [enable_eukit="${want_eukit}"])
 116
 117
 118 ### Checks for programs
 119
 120 AC_PROG_CC
 121 AM_PROG_CC_C_O
 122
 123 # pkg-config
 124 PKG_PROG_PKG_CONFIG
 125
 126 # Check whether pkg-config supports Requires.private
 127 if $PKG_CONFIG --atleast-pkgconfig-version 0.22 ; then
 128    pkgconfig_requires_private="Requires.private"
 129 else
 130    pkgconfig_requires_private="Requires"
 131 fi
 132 AC_SUBST(pkgconfig_requires_private)
 133
 134 # doxygen program for documentation building
 135 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 136
 137
 138 ### Checks for libraries
 139
 140 PKG_CHECK_MODULES([DBUS], [dbus-1 >= 0.62])
 141 AC_SUBST(DBUS_LIBS)
 142
 143 PKG_CHECK_MODULES([EDBUS], [ecore >= 0.9.9 eina-0 dbus-1 >= 0.62])
 144
 145 # Find out the version of DBUS we're using
 146 dbus_version=`pkg-config --modversion dbus-1`
 147 DBUS_VERSION_MAJOR=`echo $dbus_version | awk -F. '{print $1}'`
 148 DBUS_VERSION_MINOR=`echo $dbus_version | awk -F. '{print $2}'`
 149 DBUS_VERSION_MICRO=`echo $dbus_version | awk -F. '{print $3}'`
 150
 151 if test "z$DBUS_VERSION_MAJOR" = "z" ; then
 152    DBUS_VERSION_MAJOR="0"
 153 fi
 154
 155 if test "z$DBUS_VERSION_MINOR" = "z" ; then
 156    DBUS_VERSION_MINOR="0"
 157 fi
 158
 159 if test "z$DBUS_VERSION_MICRO" = "z" ; then
 160    DBUS_VERSION_MICRO="0"
 161 fi
 162
 163 DBUS_VERSION_CFLAGS="$DBUS_VERSION_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 164 DBUS_VERSION_CFLAGS="$DBUS_VERSION_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 165 DBUS_VERSION_CFLAGS="$DBUS_VERSION_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 166 AC_SUBST(DBUS_VERSION_CFLAGS)
 167
 168 # evas
 169 if test "x${enable_enotify}" = "xyes" ; then
 170    PKG_CHECK_MODULES(EVAS,
 171       [evas >= 0.9.9],
 172       [requirement_enotify="evas ${requirement_enotify}"],
 173       [enable_enotify="no"])
 174 fi
 175
 176 AM_CONDITIONAL([BUILD_EBLUEZ],   [test "x${enable_ebluez}"   = "xyes"])
 177 AM_CONDITIONAL([BUILD_ECONNMAN], [test "x${enable_econnman}" = "xyes"])
 178 AM_CONDITIONAL([BUILD_EHAL],     [test "x${enable_ehal}"     = "xyes"])
 179 AM_CONDITIONAL([BUILD_ENOTIFY],  [test "x${enable_enotify}"  = "xyes"])
 180 AM_CONDITIONAL([BUILD_EOFONO],   [test "x${enable_eofono}"   = "xyes"])
 181 AM_CONDITIONAL([BUILD_EUKIT],    [test "x${enable_eukit}"    = "xyes"])
 182
 183
 184 ### Checks for header files
 185
 186
 187 ### Checks for types
 188
 189
 190 ### Checks for structures
 191
 192
 193 ### Checks for compiler characteristics
 194
 195 EFL_EDBUS_BUILD=""
 196 case "$host_os" in
 197    mingw*)
 198       EFL_EDBUS_BUILD="-DEFL_EDBUS_BUILD"
 199    ;;
 200 esac
 201 AC_SUBST(EFL_EDBUS_BUILD)
 202
 203 AC_HEADER_STDC
 204 AC_C___ATTRIBUTE__
 205
 206 if ! test "x${VMIC}" = "x" ; then
 207    EFL_COMPILER_FLAG([-Wall])
 208    EFL_COMPILER_FLAG([-W])
 209 fi
 210
 211 EFL_COMPILER_FLAG([-Wshadow])
 212
 213
 214 ### Checks for linker characteristics
 215
 216 lt_enable_auto_import=""
 217 case "$host_os" in
 218    mingw*)
 219       lt_enable_auto_import="-Wl,--enable-auto-import"
 220    ;;
 221 esac
 222 AC_SUBST(lt_enable_auto_import)
 223
 224
 225 ### Checks for library functions
 226
 227 AC_FUNC_ALLOCA
 228
 229
 230 AC_SUBST(requirement_ebluez)
 231 AC_SUBST(requirement_econnman)
 232 AC_SUBST(requirement_edbus)
 233 AC_SUBST(requirement_ehal)
 234 AC_SUBST(requirement_enotify)
 235 AC_SUBST(requirement_eofono)
 236 AC_SUBST(requirement_eukit)
 237
 238 AC_OUTPUT([
 239 e_dbus.spec
 240 Makefile
 241 doc/Makefile
 242 src/Makefile
 243 src/lib/Makefile
 244 src/lib/bluez/Makefile
 245 src/lib/connman/Makefile
 246 src/lib/dbus/Makefile
 247 src/lib/hal/Makefile
 248 src/lib/notification/Makefile
 249 src/lib/ofono/Makefile
 250 src/lib/ukit/Makefile
 251 src/bin/Makefile
 252 ebluez.pc
 253 econnman.pc
 254 edbus.pc
 255 ehal.pc
 256 enotify.pc
 257 eofono.pc
 258 eukit.pc
 259 ])
 260
 261
 262 #####################################################################
 263 ## Info
 264
 265 echo
 266 echo
 267 echo
 268 echo "------------------------------------------------------------------------"
 269 echo "$PACKAGE $VERSION"
 270 echo "------------------------------------------------------------------------"
 271 echo
 272 echo "Configuration Options Summary:"
 273 echo
 274 echo "  Modules:"
 275 echo
 276 echo "    EBluez.............: $enable_ebluez"
 277 echo "    EConnman...........: $enable_econnman"
 278 echo "    EHal...............: $enable_ehal"
 279 echo "    ENotify............: $enable_enotify"
 280 echo "    EOfono.............: $enable_eofono"
 281 echo "    EUkit..............: $enable_eukit"
 282 echo
 283 echo "Documentation..........: ${build_doc}"
 284 echo
 285 echo "Compilation............: make (or gmake)"
 286 echo "  CPPFLAGS.............: $CPPFLAGS"
 287 echo "  CFLAGS...............: $CFLAGS"
 288 echo "  LDFLAGS..............: $LDFLAGS"
 289 echo
 290 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 291 echo "  prefix...............: $prefix"
 292 echo