configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [3])
   5 m4_define([v_mic], [3])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-05])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_rev], m4_eval(v_maj + v_min))
  16 m4_define([lt_cur], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eet], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  30 AM_CONFIG_HEADER([config.h])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 AC_LIBTOOL_WIN32_DLL
  34 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  35 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  36 AC_PROG_LIBTOOL
  37
  38 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  41 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  42 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  43 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  44 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  45 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  46 version_info="lt_rev:lt_cur:lt_age"
  47 release_info="v_rel"
  48 AC_SUBST(version_info)
  49 AC_SUBST(release_info)
  50 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 VMAJ=v_maj
  53 AC_SUBST(VMAJ)
  54
  55 ### Default options with respect to host
  56
  57 want_gnutls="auto"
  58 want_openssl="auto"
  59 want_cipher="yes"
  60 want_signature="yes"
  61
  62 requirement_eet=""
  63
  64
  65 ### Additional options to configure
  66
  67 # Amalgamation
  68
  69 AC_ARG_ENABLE([amalgamation],
  70    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
  71    [if test "x${enableval}" = "xyes"; then
  72        do_amalgamation="yes"
  73     else
  74        do_amalgamation="no"
  75     fi
  76    ],
  77    [do_amalgamation="no"]
  78 )
  79 AM_CONDITIONAL(EET_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
  80
  81 EFL_ENABLE_BIN([eet])
  82
  83 # Old eet file format support
  84
  85 old_eet_file_format="yes"
  86 AC_ARG_ENABLE(old-eet-file-format,
  87    [AC_HELP_STRING(
  88       [--disable-old-eet-file-format],
  89       [disable old eet file format support. [[default=enabled]]]
  90     )],
  91    [old_eet_file_format=$enableval]
  92 )
  93 AC_MSG_CHECKING([whether to support old eet file format])
  94 AC_MSG_RESULT([${old_eet_file_format}])
  95
  96 if test "x${old_eet_file_format}" = "xyes" ; then
  97    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 1, [support old eet file format])
  98 else
  99    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 0, [support old eet file format])
 100 fi
 101
 102 # Gnutls support
 103
 104 AC_ARG_ENABLE([gnutls],
 105    [AC_HELP_STRING([--disable-gnutls], [disable gnutls eet support])],
 106    [want_gnutls=$enableval]
 107 )
 108 AC_MSG_CHECKING([whether to use Gnutls])
 109 AC_MSG_RESULT([${want_gnutls}])
 110
 111 # Specific GNUTLS improvement
 112
 113 new_gnutls_api="yes"
 114 AC_ARG_ENABLE(new-gnutls-api,
 115    [AC_HELP_STRING(
 116       [--disable-new-gnutls-api],
 117       [enable use of gnutls_x509_crt_verify_hash. [[default=enable]]]
 118     )],
 119    [new_gnutls_api=$enableval]
 120 )
 121 AC_MSG_CHECKING([whether to use gnutls_x509_crt_verify_hash])
 122 AC_MSG_RESULT([${new_gnutls_api}])
 123
 124 if test "x${new_gnutls_api}" = "xyes" ; then
 125    AC_CHECK_LIB(gnutls, gnutls_x509_crt_verify_hash,
 126                 [ new_gnutls_api="yes" ],
 127                 [ new_gnutls_api="no" ]
 128                 )
 129
 130    if test "x${new_gnutls_api}" = "xyes"; then
 131       AC_DEFINE(EET_USE_NEW_GNUTLS_API, 1, [use gnutls_x509_crt_verify_hash])
 132    fi
 133 fi
 134
 135 # Openssl support
 136
 137 AC_ARG_ENABLE([openssl],
 138    [AC_HELP_STRING([--disable-openssl], [disable openssl eet support])],
 139    [want_openssl=$enableval]
 140 )
 141 AC_MSG_CHECKING([whether to use OpenSSL])
 142 AC_MSG_RESULT([${want_openssl}])
 143
 144 # Cryptography support
 145
 146 AC_ARG_ENABLE([cipher],
 147    [AC_HELP_STRING([--disable-cipher], [disable cipher support for eet API])],
 148    [want_cipher=$enableval]
 149 )
 150 AC_MSG_CHECKING([whether to use cipher])
 151 AC_MSG_RESULT([${want_cipher}])
 152
 153 AC_ARG_ENABLE([signature],
 154    [AC_HELP_STRING([--disable-signature], [disable signature file support for eet])],
 155    [want_signature=$enableval]
 156 )
 157 AC_MSG_CHECKING([whether to use signature])
 158 AC_MSG_RESULT([${want_signature}])
 159
 160 # Assert or fail.
 161 prefer_assert="no"
 162 AC_ARG_ENABLE([assert],
 163    [AC_HELP_STRING([--enable-assert], [enable assert, [[default=disabled]]])],
 164    [prefer_assert=$enableval]
 165 )
 166
 167 # Examples
 168
 169 AC_ARG_ENABLE([install-examples],
 170    [AC_HELP_STRING([--disable-install-examples],
 171        [disable installing examples (compiled or just source). @<:@default==enabled@:>@])],
 172    [
 173     if test "x${enableval}" = "xyes" ; then
 174        install_examples="yes"
 175     else
 176        install_examples="no"
 177     fi
 178    ],
 179    [install_examples="yes"])
 180 AM_CONDITIONAL([INSTALL_EXAMPLES], [test "x${install_examples}" = "xyes"])
 181
 182 AC_ARG_ENABLE([build-examples],
 183    [AC_HELP_STRING([--enable-build-examples],
 184        [enable building examples. @<:@default==disabled@:>@])],
 185    [
 186     if test "x${enableval}" = "xyes" ; then
 187        build_examples="yes"
 188     else
 189        build_examples="no"
 190     fi
 191    ],
 192    [build_examples="no"])
 193 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x${build_examples}" = "xyes"])
 194
 195 # Unit tests, coverage and benchmarking
 196
 197 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 198 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 199
 200 if test "x${prefer_assert}" = "xno"; then
 201    DEBUG_CFLAGS="-DNDEBUG"
 202 else
 203 # use debug symbols and set DEBUG if coverage support is enabled
 204    DEBUG_CFLAGS="${EFL_DEBUG_CFLAGS}"
 205 fi
 206 AC_SUBST(DEBUG_CFLAGS)
 207
 208
 209 ### Checks for programs
 210 AC_PROG_CC
 211
 212 # pkg-config
 213 PKG_PROG_PKG_CONFIG
 214
 215 # Check whether pkg-config supports Requires.private
 216 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 217    pkgconfig_requires_private="Requires.private"
 218 else
 219    pkgconfig_requires_private="Requires"
 220 fi
 221 AC_SUBST(pkgconfig_requires_private)
 222
 223
 224 # doxygen program for documentation building
 225
 226 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 227
 228 ### Checks for libraries
 229
 230 # Evil library for compilation on Windows
 231
 232 EFL_EET_BUILD=""
 233 case "$host_os" in
 234    mingw*)
 235       PKG_CHECK_MODULES([EVIL], [evil])
 236       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 237       requirement_eet="evil ${requirement_eet}"
 238       EFL_EET_BUILD="-DEFL_EET_BUILD"
 239    ;;
 240 esac
 241 AC_SUBST(EFL_EET_BUILD)
 242
 243 EET_LIBS=""
 244 case "$host_os" in
 245    mingw32ce*)
 246       EET_LIBS="-lws2"
 247       ;;
 248    mingw*)
 249       EET_LIBS="-lws2_32"
 250       ;;
 251 esac
 252 AC_SUBST(EET_LIBS)
 253
 254 # Eina library
 255
 256 PKG_CHECK_MODULES(EINA, [eina-0])
 257 requirement_eet="eina-0 ${requirement_eet}"
 258
 259 # Gnutls library
 260 have_gnutls="no"
 261 if test "x${want_gnutls}" = "xyes" || test "x${want_gnutls}" = "xauto" ; then
 262    PKG_CHECK_MODULES(GNUTLS, [gnutls >= 1.7.6],
 263       [
 264        have_gnutls="yes"
 265        want_openssl="no"
 266        AC_DEFINE(HAVE_GNUTLS, 1, [Have Gnutls support])
 267        requirement_eet="gnutls ${requirement_eet}"
 268       ],
 269       [have_gnutls="no"])
 270    if test "x${have_gnutls}" = "xyes" ; then
 271       AC_PATH_GENERIC([libgcrypt], [], [have_gnutls="yes"], [have_gnutls="no"])
 272       if test "x${have_gnutls}" = "xyes" ; then
 273          GNUTLS_CFLAGS="${GNUTLS_CFLAGS} ${LIBGCRYPT_CFLAGS}"
 274          GNUTLS_LIBS="${GNUTLS_LIBS} ${LIBGCRYPT_LIBS}"
 275       fi
 276    fi
 277 fi
 278
 279 # Openssl library
 280 have_openssl="no"
 281 if test "x${want_openssl}" = "xyes" || test "x${want_openssl}" = "xauto" ; then
 282    PKG_CHECK_MODULES(OPENSSL, openssl,
 283       [
 284        have_openssl="yes"
 285        AC_DEFINE(HAVE_OPENSSL, 1, [Have Openssl support])
 286        requirement_eet="openssl ${requirement_eet}"
 287       ],
 288       [have_openssl="no"])
 289 fi
 290
 291 if test "x${have_gnutls}" = "xyes" ; then
 292    secure_layer="GnuTLS"
 293 elif test "x${have_openssl}" = "xyes" ; then
 294    secure_layer="OpenSSL"
 295 else
 296    secure_layer="no"
 297 fi
 298
 299 have_cipher="no"
 300 if test "x${have_gnutls}" = "xyes" && test "x${want_cipher}" = "xyes" ; then
 301    have_cipher="yes"
 302    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 303 elif test "x${have_openssl}" = "xyes" && test "x${want_cipher}" = "xyes" ; then
 304    have_cipher="yes"
 305    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 306 fi
 307
 308 AC_MSG_CHECKING(whether to activate cipher support in eet)
 309 AC_MSG_RESULT(${have_cipher})
 310
 311 have_signature="no"
 312 if test "x${have_gnutls}" = "xyes" && test "x${want_signature}" = "xyes" ; then
 313    have_signature="yes"
 314    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 315 elif test "x${have_openssl}" = "xyes" && test "x${want_signature}" = "xyes" ; then
 316    have_signature="yes"
 317    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 318 fi
 319
 320 AC_MSG_CHECKING(whether to activate signature support in eet)
 321 AC_MSG_RESULT(${have_signature})
 322
 323 # pthread library
 324
 325 EFL_CHECK_THREADS(["no"],
 326    [
 327     if test "x${_efl_have_posix_threads}" = "xyes" ; then
 328        have_threads="POSIX"
 329     else
 330        if test "x${_efl_have_win32_threads}" = "xyes" ; then
 331           have_threads="Win32"
 332        else
 333           have_threads="no"
 334        fi
 335     fi],
 336    [have_threads="no"])
 337
 338
 339 ### Checks for header files
 340
 341 AC_CHECK_HEADER([zlib.h],
 342    [dummy="yes"],
 343    [AC_MSG_ERROR("Cannot find zlib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 344
 345 AC_CHECK_HEADER([jpeglib.h],
 346    [dummy="yes"],
 347    [AC_MSG_ERROR("Cannot find jpeglib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 348
 349 AC_CHECK_HEADERS(netinet/in.h)
 350
 351
 352 ### Checks for types
 353
 354
 355 ### Checks for structures
 356
 357
 358 ### Checks for compiler characteristics
 359 AM_PROG_CC_C_O
 360 AC_C_CONST
 361 AC_C_INLINE
 362 AC_PROG_CC_STDC
 363 AC_C___ATTRIBUTE__
 364
 365 # Check whether the null pointer is zero on this arch
 366 AC_TRY_RUN(
 367    [
 368 #include <stdlib.h>
 369 int main (int argc, char **argv) {
 370   void *foo = NULL;
 371   int bar = (int)foo;
 372   return (int)foo;
 373 }
 374    ],
 375    [have_null="yes"],
 376    [have_null="no"],
 377    [
 378     AC_MSG_WARN([Cannot check when cross-compiling -- assuming null is okay])
 379     have_null="yes"
 380    ])
 381 AC_MSG_CHECKING([value of the null pointer])
 382 AC_MSG_RESULT([${have_null}])
 383
 384 if test ! "x${have_null}" = "xyes" ; then
 385    AC_MSG_WARN([Your system is a bit too funny, eet might not work properly])
 386 fi
 387
 388 # These are needed for fmemopen/open_memstream
 389 AC_DEFINE(_GNU_SOURCE, , [Enable GNU extensions])
 390
 391 EET_CPPFLAGS=""
 392 EET_CFLAGS=""
 393 case "$host_os" in
 394    mingw32ce*)
 395       EET_CPPFLAGS="-D_WIN32_WCE=0x0420"
 396       ;;
 397    mingw*)
 398       EET_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 399       ;;
 400 esac
 401 AC_SUBST(EET_CPPFLAGS)
 402 AC_SUBST(EET_CFLAGS)
 403
 404
 405 ### Checks for linker characteristics
 406
 407 # use --enable-auto-import on Windows
 408
 409 lt_enable_auto_import=""
 410 case "$host_os" in
 411    mingw*)
 412       lt_enable_auto_import="-Wl,--enable-auto-import"
 413       ;;
 414 esac
 415 AC_SUBST(lt_enable_auto_import)
 416
 417 # use --as-needed if supported
 418
 419 LDFLAGS_SAVE=${LDFLAGS}
 420 LDFLAGS="${LDFLAGS} -Wl,--as-needed"
 421
 422 AC_LINK_IFELSE(
 423    [AC_LANG_PROGRAM([[]], [])],
 424    [ld_as_needed="-Wl,--as-needed"],
 425    [ld_as_needed=""]
 426 )
 427
 428 LDFLAGS=${LDFLAGS_SAVE}
 429 AC_SUBST(ld_as_needed)
 430
 431
 432 ### Checks for library functions
 433 AC_FUNC_ALLOCA
 434
 435 AC_CHECK_FUNCS(fmemopen open_memstream realpath)
 436
 437 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 438
 439
 440 AC_SUBST(requirement_eet)
 441
 442 AC_OUTPUT([
 443 Makefile
 444 eet.pc
 445 doc/Makefile
 446 doc/eet.dox
 447 src/Makefile
 448 src/lib/Makefile
 449 src/bin/Makefile
 450 src/tests/Makefile
 451 src/examples/Makefile
 452 README
 453 eet.spec
 454 ])
 455
 456
 457 #####################################################################
 458 ## Info
 459
 460 echo
 461 echo
 462 echo
 463 echo "------------------------------------------------------------------------"
 464 echo "$PACKAGE_NAME $PACKAGE_VERSION"
 465 echo "------------------------------------------------------------------------"
 466 echo
 467 echo "Configuration Options Summary:"
 468 echo
 469 echo "  Amalgamation.........: ${do_amalgamation}"
 470 echo "  Secure layer.........: ${secure_layer}"
 471 if test "x${have_gnutls}" = "xyes" || test "x${have_openssl}" = "xyes" ; then
 472    echo "    Cipher support.....: ${have_cipher}"
 473    echo "    Signature..........: ${have_signature}"
 474 fi
 475 echo "  Thread Support.......: ${have_threads}"
 476 echo
 477 echo "  Old eet file format..: ${old_eet_file_format}"
 478 echo
 479 echo "  Tests................: ${enable_tests}"
 480 echo "  Coverage.............: ${enable_coverage}"
 481 echo
 482 echo "  Build eet............: $have_eet"
 483 echo
 484 echo "  Documentation........: ${build_doc}"
 485 if test "x${build_doc}" = "xyes" ; then
 486    echo "    Building...........: make doc"
 487 fi
 488 echo "  Examples.............: ${build_examples}"
 489 if test "x${build_examples}" = "xyes" ; then
 490    echo "    Install............: ${install_examples}"
 491 fi
 492 echo
 493 echo "Compilation............: make (or gmake)"
 494 echo "  CPPFLAGS.............: $CPPFLAGS"
 495 echo "  CFLAGS...............: $CFLAGS"
 496 echo "  LDFLAGS..............: $LDFLAGS"
 497 echo
 498 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 499 echo "  prefix...............: $prefix"
 500 echo