configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [1])
   5 m4_define([v_mic], [99])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n' | sed 's/Unversioneddirectory/0/' | tr -d '\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([ecore], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39
  40 AC_LIBTOOL_WIN32_DLL
  41 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  42 AC_PROG_LIBTOOL
  43
  44 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  45 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  46 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  47 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  48 AC_DEFINE_UNQUOTED(VERS_MAJ, [v_maj], [Major version])
  49 AC_DEFINE_UNQUOTED(VERS_MIN, [v_min], [Minor version])
  50 AC_DEFINE_UNQUOTED(VERS_MIC, [v_mic], [Micro version])
  51 AC_DEFINE_UNQUOTED(VERS_REV, [v_rev], [Revison])
  52 version_info="lt_cur:lt_rev:lt_age"
  53 release_info="v_rel"
  54 AC_SUBST(version_info)
  55 AC_SUBST(release_info)
  56 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  57 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  58 VMAJ=v_maj
  59 AC_SUBST(VMAJ)
  60
  61 m4_ifdef([AM_GNU_GETTEXT_VERSION], [
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 ])
  64
  65 m4_ifdef([AM_GNU_GETTEXT], [
  66 AM_GNU_GETTEXT([external])
  67 po_makefile_in=po/Makefile.in
  68 have_po="yes"
  69 ],[
  70 have_po="no"
  71 ])
  72 AC_SUBST(LTLIBINTL)
  73
  74 if test "x${POSUB}" = "x" ; then
  75    have_po="no"
  76 fi
  77
  78 AM_CONDITIONAL([HAVE_PO], [test "x${have_po}" = "xyes"])
  79
  80 with_max_log_level="<unset>"
  81 AC_ARG_WITH(internal-maximum-log-level,
  82    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
  83                    [limit ecore internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
  84    [
  85     if test "x${withval}" != "xno"; then
  86        if echo "${withval}" | grep -E '^[[0-9]]+$' >/dev/null 2>/dev/null; then
  87           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
  88           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
  89           with_max_log_level="${withval}"
  90        else
  91           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
  92        fi
  93     fi
  94     ], [:])
  95
  96
  97 ### Default options with respect to host
  98
  99 AC_CANONICAL_BUILD
 100 AC_CANONICAL_HOST
 101
 102 # dependencies and options
 103 want_curl="no"
 104 want_local_sockets="yes"
 105 want_abstract_sockets="no"
 106 want_gnutls="no"
 107 want_openssl="no"
 108 want_cares="no"
 109 want_cipher="no"
 110 want_signature="no"
 111 want_poll="yes"
 112 want_inotify="no"
 113 want_notify_win32="no"
 114 want_tslib="no"
 115 want_glib="no"
 116
 117 # core modules
 118 want_ecore_con="yes"
 119 want_ecore_ipc="yes"
 120 want_ecore_file="yes"
 121 #want_ecore_config="no"
 122 want_ecore_imf="no"
 123 want_ecore_input="yes"
 124
 125 # graphic system modules
 126 want_evas_simple_x11="no"
 127 want_ecore_x_xcb="no"
 128 want_ecore_x="no"
 129 want_ecore_win32="no"
 130 want_ecore_cocoa="no"
 131 want_ecore_sdl="no"
 132 want_ecore_psl1ght="no"
 133 want_ecore_fb="no"
 134 want_ecore_directfb="no"
 135 want_ecore_wince="no"
 136 want_ecore_wayland="no"
 137
 138 # ecore_x options (both xlib and xcb)
 139 want_ecore_x_composite="yes"
 140 want_ecore_x_damage="yes"
 141 want_ecore_x_dpms="yes"
 142 want_ecore_x_randr="yes"
 143 want_ecore_x_render="yes"
 144 want_ecore_x_screensaver="yes"
 145 want_ecore_x_shape="yes"
 146 want_ecore_x_gesture="no"
 147 want_ecore_x_sync="yes"
 148 want_ecore_x_xfixes="yes"
 149 want_ecore_x_xinerama="yes"
 150 want_ecore_x_xprint="yes"
 151 want_ecore_x_xtest="yes"
 152 want_ecore_x_cursor="yes"
 153 want_ecore_x_input="yes"
 154 want_ecore_x_dri="yes"
 155
 156 # ecore_evas modules
 157 want_ecore_evas="yes"
 158 want_ecore_evas_software_buffer="yes"
 159 want_ecore_evas_software_x11="no"
 160 want_ecore_evas_opengl_x11="no"
 161 want_ecore_evas_software_16_x11="no"
 162 want_ecore_evas_software_8_x11="no"
 163 want_ecore_evas_software_xcb="no"
 164 want_ecore_evas_software_gdi="no"
 165 want_ecore_evas_software_ddraw="no"
 166 want_ecore_evas_direct3d="no"
 167 want_ecore_evas_opengl_glew="no"
 168 want_ecore_evas_software_16_ddraw="no"
 169 want_ecore_evas_software_sdl="no"
 170 want_ecore_evas_gl_sdl="no"
 171 want_ecore_evas_gl_cocoa="no"
 172 want_ecore_evas_psl1ght="no"
 173 want_ecore_evas_directfb="no"
 174 want_ecore_evas_fb="no"
 175 want_ecore_evas_software_16_wince="no"
 176 want_ecore_evas_ews="yes"
 177 want_ecore_evas_extn="yes"
 178 want_ecore_evas_wayland_shm="no"
 179 want_ecore_evas_wayland_egl="no"
 180
 181 # ecore_imf modules
 182 want_ecore_imf_xim="no"
 183 want_ecore_imf_scim="no"
 184
 185 case "$host_os" in
 186    mingw32ce*)
 187       want_ecore_con="no"
 188       want_ecore_ipc="no"
 189       want_ecore_wince="yes"
 190       want_ecore_evas_software_16_wince="yes"
 191       want_ecore_evas_extn="no"
 192       ;;
 193    mingw*)
 194       want_notify_win32="yes"
 195       want_curl="yes"
 196       want_glib="auto"
 197       want_gnutls="auto"
 198       want_openssl="auto"
 199       want_ecore_imf="yes"
 200       want_ecore_win32="yes"
 201       want_ecore_evas_software_gdi="yes"
 202       want_ecore_evas_software_ddraw="yes"
 203       want_ecore_evas_direct3d="yes"
 204       want_ecore_evas_opengl_glew="yes"
 205       want_ecore_evas_software_16_ddraw="auto"
 206       want_ecore_evas_software_sdl="yes"
 207       want_ecore_evas_gl_sdl="yes"
 208       ;;
 209    darwin*)
 210       want_curl="yes"
 211       want_glib="auto"
 212       want_gnutls="auto"
 213       want_openssl="auto"
 214       want_ecore_imf="yes"
 215       want_ecore_cocoa="yes"
 216       want_ecore_evas_software_sdl="yes"
 217       want_ecore_evas_gl_sdl="yes"
 218       want_ecore_evas_gl_cocoa="yes"
 219       ;;
 220    *)
 221       want_curl="yes"
 222       want_glib="auto"
 223       want_abstract_sockets="yes"
 224       want_gnutls="auto"
 225       want_openssl="auto"
 226       want_cipher="yes"
 227       want_signature="yes"
 228       want_inotify="yes"
 229       want_tslib="yes"
 230       want_ecore_fb="yes"
 231       want_ecore_imf="yes"
 232       want_ecore_x="yes"
 233       want_ecore_wayland="yes"
 234       want_ecore_evas_software_x11="yes"
 235       want_ecore_evas_opengl_x11="yes"
 236       want_ecore_evas_software_16_x11="yes"
 237       want_ecore_evas_software_8_x11="yes"
 238       want_ecore_evas_software_xcb="no"
 239       want_ecore_evas_software_sdl="yes"
 240       want_ecore_evas_gl_sdl="yes"
 241       want_ecore_evas_gl_cocoa="no"
 242       want_ecore_evas_directfb="yes"
 243       want_ecore_evas_fb="yes"
 244       want_ecore_evas_wayland_shm="yes"
 245       want_ecore_evas_wayland_egl="yes"
 246       want_ecore_imf_xim="yes"
 247       want_ecore_imf_scim="yes"
 248       ;;
 249 esac
 250
 251 case "$host_vendor" in
 252   ps3*)
 253       want_local_sockets="no"
 254       ;;
 255 esac
 256 requirements_ecore=""
 257 requirements_ecore_con=""
 258 #requirements_ecore_config=""
 259 requirements_ecore_directfb=""
 260 requirements_ecore_evas=""
 261 requirements_ecore_fb=""
 262 requirements_ecore_file=""
 263 requirements_ecore_imf=""
 264 requirements_ecore_imf_evas=""
 265 requirements_ecore_input=""
 266 requirements_ecore_input_evas=""
 267 requirements_ecore_ipc=""
 268 requirements_ecore_cocoa=""
 269 requirements_ecore_sdl=""
 270 requirements_ecore_psl1ght=""
 271 requirements_ecore_x=""
 272 requirements_ecore_win32=""
 273 requirements_ecore_wince=""
 274 requirements_ecore_imf_xim=""
 275 requirements_ecore_imf_scim=""
 276 requirements_ecore_wayland=""
 277
 278 AC_CHECK_DECL([MAXHOSTNAMELEN],[FOUND_MAXHOSTNAMELEN=yes])
 279
 280 if test x$FOUND_MAXHOSTNAMELEN != xyes ; then
 281   AC_MSG_CHECKING([for header that defines MAXHOSTNAMELEN])
 282
 283   FOUND_MAXHOSTNAMELEN='not found'
 284
 285   AC_COMPILE_IFELSE(
 286         AC_LANG_PROGRAM([#include <sys/param.h>],
 287                 [int h = MAXHOSTNAMELEN;]),
 288         [FOUND_MAXHOSTNAMELEN='sys/param.h'
 289            AC_DEFINE(NEED_SYS_PARAM_H,1,
 290              [Define to 1 if you need <sys/param.h> to define MAXHOSTNAMELEN])])
 291
 292         AC_COMPILE_IFELSE(
 293             AC_LANG_PROGRAM([#include <netdb.h>],
 294                             [int h = MAXHOSTNAMELEN;]),
 295             [FOUND_MAXHOSTNAMELEN='netdb.h'
 296              AC_DEFINE(NEED_NETDB_H,1,
 297                [Define to 1 if you need <netdb.h> to define MAXHOSTNAMELEN])])
 298
 299   AC_MSG_RESULT([$FOUND_MAXHOSTNAMELEN])
 300 fi
 301
 302 ### Additional options to configure
 303
 304 want_glib_integration_always=no
 305 AC_ARG_ENABLE(glib-integration-always,
 306   AC_HELP_STRING([--enable-glib-integration-always], [enable glib integration when ecore_init() is called always]),
 307   [want_glib_integration_always=$enableval])
 308
 309 if test "x${want_glib_integration_always}" = "xyes" ; then
 310   AC_DEFINE([GLIB_INTEGRATION_ALWAYS], [1], [Always integrate glib if support compiled])
 311   want_glib=yes
 312 fi
 313
 314 want_g_main_loop=no
 315 AC_ARG_ENABLE(g-main-loop,
 316   AC_HELP_STRING([--enable-g-main-loop], [ecore_main_loop based on g_main_loop]),
 317   [want_g_main_loop=$enableval])
 318
 319 if test "x${want_g_main_loop}" = "xyes" ; then
 320   AC_DEFINE([USE_G_MAIN_LOOP], [1], [Use g_main_loop in ecore])
 321   want_glib=yes
 322 fi
 323
 324 if test "x${want_glib_integration_always}" = "xyes" -a "x${want_g_main_loop}" = "xyes"; then
 325   AC_MSG_ERROR([--enable-glib-integration-always and --enable-glib-main-loop are mutually exclusive])
 326 fi
 327
 328 # local sockets (ecore_con.c)
 329 AC_ARG_ENABLE([local-sockets],
 330    [AC_HELP_STRING([--disable-local-sockets], [disable local sockets.])],
 331    [
 332     if test "x${enableval}" = "xyes" ; then
 333        want_ecore_con_local_sockets="yes"
 334     else
 335        want_ecore_con_local_sockets="no"
 336     fi
 337    ],
 338    [want_ecore_con_local_sockets=${want_local_sockets}])
 339
 340 if test "x${want_ecore_con_local_sockets}" = "xyes" ; then
 341    AC_DEFINE([HAVE_LOCAL_SOCKETS], [1], [Have local sockets support])
 342 fi
 343
 344 # abstract sockets (ecore_con.c)
 345 AC_ARG_ENABLE([abstract-sockets],
 346    [AC_HELP_STRING([--disable-abstract-sockets], [disable abstract sockets.])],
 347    [
 348     if test "x${enableval}" = "xyes" ; then
 349        want_ecore_con_abstract_sockets="yes"
 350     else
 351        want_ecore_con_abstract_sockets="no"
 352     fi
 353    ],
 354    [want_ecore_con_abstract_sockets=${want_abstract_sockets}])
 355
 356 if test "x${want_ecore_con_abstract_sockets}" = "xyes" ; then
 357    AC_DEFINE([HAVE_ABSTRACT_SOCKETS], [1], [Have abstract sockets namespace])
 358 fi
 359
 360 # Simple X11 build/link
 361
 362 AC_ARG_ENABLE(simple-x11,
 363   AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking]),
 364   [want_evas_simple_x11=$enableval])
 365
 366 # XIM
 367 AC_ARG_ENABLE([xim],
 368    [AC_HELP_STRING([--disable-xim], [disable X Input Method.])],
 369    [
 370     if test "x${enableval}" = "xyes" ; then
 371        want_xim="yes"
 372     else
 373        want_xim="no"
 374     fi
 375    ],
 376    [want_xim="yes"])
 377
 378 if test "x${want_xim}" = "xyes" ; then
 379    AC_DEFINE([ENABLE_XIM], [1], [Enable X Input Method])
 380 fi
 381
 382 # Unit tests
 383
 384 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 385
 386 ### Checks for programs
 387
 388 m4_ifdef([AC_PROG_OBJC],
 389    [
 390     AC_PROG_OBJC
 391     _AM_DEPENDENCIES(OBJC)
 392    ],
 393    [
 394     AC_CHECK_TOOL([OBJC], [gcc])
 395     AC_SUBST([OBJC])
 396     AC_SUBST([OBJCFLAGS])
 397    ])
 398 m4_ifndef([am__fastdepOBJC], [
 399     AM_CONDITIONAL([am__fastdepOBJC], [false])
 400 ])
 401
 402 AC_PROG_CXX
 403 AC_PROG_CC
 404
 405 have_gnu_objc=${ac_cv_objc_compiler_gnu}
 406
 407 # doxygen program for documentation building
 408
 409 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 410
 411 m4_ifdef([v_mic],
 412    [
 413     EFL_COMPILER_FLAG([-Wall])
 414     EFL_COMPILER_FLAG([-W])
 415    ])
 416
 417 # The first call to PKG_CHECK_MODULES is done conditionally,
 418 # so we should include this here:
 419 PKG_PROG_PKG_CONFIG
 420
 421 # Check whether pkg-config supports Requires.private
 422 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 423    pkgconfig_requires_private="Requires.private"
 424 else
 425    pkgconfig_requires_private="Requires"
 426 fi
 427 AC_SUBST(pkgconfig_requires_private)
 428
 429 ### Checks for some build time option
 430 have_backtrace="no"
 431 AC_CHECK_FUNCS([backtrace], [have_backtrace="yes"], [])
 432
 433 want_ecore_timer_dump="no"
 434
 435 AC_ARG_ENABLE([ecore-timer-dump],
 436    [AC_HELP_STRING([--disable-ecore-timer-dump], [disable tracking of timer allocation. @<:@default=enable@:>@])],
 437    [want_ecore_timer_dump=$enableval], [])
 438
 439 if test "x$want_ecore_timer_dump" = "xyes" -a "x$have_backtrace" = "xyes"; then
 440    AC_DEFINE(WANT_ECORE_TIMER_DUMP, [1], [Want Ecore_Timer dump infrastructure])
 441 fi
 442
 443 ### Checks for libraries
 444
 445 # Evil library for compilation on Windows
 446
 447 case "$host_os" in
 448    mingw*)
 449       PKG_CHECK_MODULES([EVIL], [evil >= 1.0.0])
 450       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 451       requirements_ecore="evil ${requirements_ecore}"
 452       requirements_ecore_evas="evil ${requirements_ecore_evas}"
 453       requirements_ecore_file="evil ${requirements_ecore_file}"
 454       requirements_ecore_imf="evil ${requirements_ecore_imf}"
 455       requirements_ecore_imf_evas="evil ${requirements_ecore_imf_evas}"
 456       EFL_ECORE_BUILD="-DEFL_ECORE_BUILD"
 457       EFL_ECORE_CON_BUILD="-DEFL_ECORE_CON_BUILD"
 458       EFL_ECORE_EVAS_BUILD="-DEFL_ECORE_EVAS_BUILD"
 459       EFL_ECORE_FILE_BUILD="-DEFL_ECORE_FILE_BUILD"
 460       EFL_ECORE_IMF_BUILD="-DEFL_ECORE_IMF_BUILD"
 461       EFL_ECORE_IMF_EVAS_BUILD="-DEFL_ECORE_IMF_EVAS_BUILD"
 462       EFL_ECORE_INPUT_BUILD="-DEFL_ECORE_INPUT_BUILD"
 463       EFL_ECORE_INPUT_EVAS_BUILD="-DEFL_ECORE_INPUT_EVAS_BUILD"
 464       EFL_ECORE_IPC_BUILD="-DEFL_ECORE_IPC_BUILD"
 465       ;;
 466 esac
 467
 468 have_win32=""
 469 have_wince=""
 470 case "$host_os" in
 471    mingw32ce* | cegcc*)
 472       EFL_ECORE_WINCE_BUILD="-DEFL_ECORE_WINCE_BUILD"
 473       requirements_ecore_wince="evil ${requirements_ecore_wince}"
 474       have_wince="yes"
 475       ;;
 476    mingw*)
 477       EFL_ECORE_WIN32_BUILD="-DEFL_ECORE_WIN32_BUILD"
 478       EFL_ECORE_SDL_BUILD="-DEFL_ECORE_SDL_BUILD"
 479       requirements_ecore_win32="evil ${requirements_ecore_win32}"
 480       requirements_ecore_sdl="evil ${requirements_ecore_sdl}"
 481       have_win32="yes"
 482       ;;
 483 esac
 484
 485 have_ps3=""
 486 case "$host_vendor" in
 487   ps3*)
 488       have_ps3="yes"
 489       PKG_CHECK_MODULES([ESCAPE], [escape])
 490       CFLAGS="$CFLAGS $ESCAPE_CFLAGS"
 491       AC_DEFINE(HAVE_ESCAPE, 1, [Set to 1 if Escape library is installed])
 492       EFL_ECORE_PSL1GHT_BUILD="-DEFL_ECORE_PSL1GHT_BUILD"
 493       requirements_ecore="escape ${requirements_ecore}"
 494       requirements_ecore_evas="escape ${requirements_ecore_evas}"
 495       requirements_ecore_file="escape ${requirements_ecore_file}"
 496       requirements_ecore_imf="escape ${requirements_ecore_imf}"
 497       requirements_ecore_imf_evas="escape ${requirements_ecore_imf_evas}"
 498       requirements_ecore_sdl="escape ${requirements_ecore_sdl}"
 499       want_ecore_psl1ght="yes"
 500       want_ecore_evas_psl1ght="yes"
 501       ;;
 502 esac
 503
 504 AC_SUBST(EFL_ECORE_BUILD)
 505 AC_SUBST(EFL_ECORE_CON_BUILD)
 506 AC_SUBST(EFL_ECORE_EVAS_BUILD)
 507 AC_SUBST(EFL_ECORE_FILE_BUILD)
 508 AC_SUBST(EFL_ECORE_IMF_BUILD)
 509 AC_SUBST(EFL_ECORE_IMF_EVAS_BUILD)
 510 AC_SUBST(EFL_ECORE_INPUT_BUILD)
 511 AC_SUBST(EFL_ECORE_INPUT_EVAS_BUILD)
 512 AC_SUBST(EFL_ECORE_IPC_BUILD)
 513 AC_SUBST(EFL_ECORE_WINCE_BUILD)
 514 AC_SUBST(EFL_ECORE_WIN32_BUILD)
 515 AC_SUBST(EFL_ECORE_SDL_BUILD)
 516 AC_SUBST(EFL_ECORE_PSL1GHT_BUILD)
 517
 518 AM_CONDITIONAL(ECORE_HAVE_WINCE, test "x${have_wince}" = "xyes")
 519 AM_CONDITIONAL(ECORE_HAVE_WIN32, test "x${have_win32}" = "xyes")
 520 AM_CONDITIONAL(ECORE_HAVE_PS3, test "x${have_ps3}" = "xyes")
 521
 522 WIN32_LIBS=""
 523 case "$host_os" in
 524    mingw32ce* | cegcc*)
 525       WIN32_LIBS="-lws2"
 526       dlopen_libs="-ldl"
 527       ;;
 528    mingw*)
 529       WIN32_LIBS="-lws2_32"
 530       dlopen_libs="-ldl"
 531       ;;
 532    *)
 533       AC_CHECK_LIB([c], [dlopen],
 534          [],
 535          [AC_CHECK_LIB([dl], [dlopen],
 536              [dlopen_libs=-ldl])
 537          ])
 538       AC_CHECK_LIB([c], [clock_gettime],
 539          [AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])],
 540          [AC_CHECK_LIB([rt], [clock_gettime],
 541              [
 542               rt_libs=-lrt
 543               AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])
 544              ])
 545          ])
 546       ;;
 547 esac
 548 AC_SUBST(WIN32_LIBS)
 549 AC_SUBST(dlopen_libs)
 550 AC_SUBST(rt_libs)
 551
 552 # Eina library
 553
 554 PKG_CHECK_MODULES(EINA, [eina >= 1.1.0])
 555 #FIXME check all the requirements when the eina move will be finished
 556 requirements_ecore="eina >= 1.1.0 ${requirements_ecore}"
 557 requirements_ecore_con="ecore >= 1.1.0 eina >= 1.1.0 ${requirements_ecore_con}"
 558 #requirements_ecore_config="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_config}"
 559 requirements_ecore_directfb="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_directfb}"
 560 requirements_ecore_evas="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_evas}"
 561 requirements_ecore_fb="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_fb}"
 562 requirements_ecore_file="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_file}"
 563 requirements_ecore_imf="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_imf}"
 564 requirements_ecore_imf_evas="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_imf_evas}"
 565 requirements_ecore_input="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_input}"
 566 requirements_ecore_input_evas="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_input_evas}"
 567 requirements_ecore_ipc="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_ipc}"
 568 requirements_ecore_cocoa="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_cocoa}"
 569 requirements_ecore_sdl="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_sdl}"
 570 requirements_ecore_psl1ght="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_sdl}"
 571 requirements_ecore_win32="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_win32}"
 572 requirements_ecore_wince="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_wince}"
 573 requirements_ecore_x="ecore >= 1.1.99 eina >= 1.1.0 ${requirements_ecore_x}"
 574
 575
 576 # glib support (main loop integration)
 577 AC_ARG_ENABLE([glib],
 578    [AC_HELP_STRING([--disable-glib], [disable glib support. @<:@default=detect@:>@])],
 579    [want_glib=$enableval], [])
 580
 581 if test "x$want_glib" != "xno"; then
 582    PKG_CHECK_MODULES([GLIB], [glib-2.0], [have_glib="yes"], [have_glib="no"])
 583 else
 584    have_glib="no"
 585 fi
 586 if test "x$want_glib" = "xyes" -a "x$have_glib" = "xno"; then
 587    AC_MSG_ERROR([GLib support requested, but no GLib found by pkg-config.])
 588 elif test "x$have_glib" = "xyes"; then
 589    AC_DEFINE(HAVE_GLIB, [1], [Have GLib])
 590    requirements_ecore="glib-2.0 ${requirements_ecore}"
 591 fi
 592
 593
 594 # SDL library (ecore_sdl)
 595
 596 have_sdl="no"
 597 PKG_CHECK_MODULES([SDL], [sdl >= 1.2.0], [have_sdl="yes"], [have_sdl="no"])
 598 if test "x${have_sdl}" != "xyes" ; then
 599    SDL_CONFIG="sdl-config"
 600    AC_ARG_WITH([sdl-config],
 601       [AC_HELP_STRING([--with-sdl-config=PATH], [use sdl-config specified])],
 602       [
 603        SDL_CONFIG=$withval
 604        AC_MSG_NOTICE([using ${SDL_CONFIG} for sdl-config])
 605       ])
 606
 607    AC_PATH_PROG([SDL_CONFIG], ["sdl-config"], [""], [$PATH])
 608
 609    if test -n "$SDL_CONFIG" ; then
 610       SDL_CFLAGS=`$SDL_CONFIG --cflags`
 611       SDL_LIBS=`$SDL_CONFIG --libs`
 612       AC_SUBST(SDL_CFLAGS)
 613       AC_SUBST(SDL_LIBS)
 614       have_sdl="yes"
 615    fi
 616 fi
 617
 618 if test "x${have_sdl}" = "xyes" ; then
 619    PKG_CHECK_EXISTS([sdl >= 1.3.0],
 620       [AC_DEFINE(BUILD_ECORE_EVAS_SDL_130, 1, [Support for SVN SDL])])
 621 fi
 622
 623
 624 # DirectFB library (ecore_directfb)
 625
 626 PKG_CHECK_MODULES([DIRECTFB],
 627    [directfb >= 0.9.16],
 628    [have_directfb="yes"],
 629    [have_directfb="no"])
 630
 631
 632 # Eet library (ecore_config)
 633
 634 #PKG_CHECK_MODULES([EET],
 635 #   [eet >= 1.4.0],
 636 #   [have_eet="yes"],
 637 #   [have_eet="no"])
 638
 639
 640 # Xlib and XCB (ecore_x)
 641
 642 have_x="no"
 643 have_ecore_x="no"
 644 have_ecore_x_xlib="no"
 645 have_ecore_x_xcb="no"
 646
 647 x_dir="";
 648 x_includes="";
 649 x_cflags="";
 650 x_libs="";
 651
 652 ecore_x_libs_private=""
 653
 654 AC_ARG_ENABLE(ecore-x-composite,
 655    [AC_HELP_STRING([--disable-ecore-x-composite],
 656        [disable the ecore_x support for Xcomposite extension.
 657         @<:@default=detect@:>@])],
 658    [want_ecore_x_composite=$enableval])
 659
 660 AC_ARG_ENABLE(ecore-x-damage,
 661    [AC_HELP_STRING([--disable-ecore-x-damage],
 662        [disable the ecore_x support for Xdamage extension.
 663         @<:@default=detect@:>@])],
 664    [want_ecore_x_damage=$enableval])
 665
 666 AC_ARG_ENABLE(ecore-x-dpms,
 667    [AC_HELP_STRING([--disable-ecore-x-dpms],
 668        [disable the ecore_x support for Xdpms extension.
 669         @<:@default=detect@:>@])],
 670    [want_ecore_x_dpms=$enableval])
 671
 672 AC_ARG_ENABLE(ecore-x-randr,
 673    [AC_HELP_STRING([--disable-ecore-x-randr],
 674        [disable the ecore_x support for Xrandr extension.
 675         @<:@default=detect@:>@])],
 676    [want_ecore_x_randr=$enableval])
 677
 678 AC_ARG_ENABLE(ecore-x-render,
 679    [AC_HELP_STRING([--disable-ecore-x-render],
 680        [disable the ecore_x support for Xrender extension.
 681         @<:@default=detect@:>@])],
 682    [want_ecore_x_render=$enableval])
 683
 684 AC_ARG_ENABLE(ecore-x-screensaver,
 685    [AC_HELP_STRING([--disable-ecore-x-screensaver],
 686        [disable the ecore_x support for Xscreensaver extension.
 687         @<:@default=detect@:>@])],
 688    [want_ecore_x_screensaver=$enableval])
 689
 690 AC_ARG_ENABLE(ecore-x-shape,
 691    [AC_HELP_STRING([--disable-ecore-x-shape],
 692        [disable the ecore_x support for Xshape extension.
 693         @<:@default=detect@:>@])],
 694    [want_ecore_x_shape=$enableval])
 695
 696 AC_ARG_ENABLE(ecore-x-gesture,
 697    [AC_HELP_STRING([--enable-ecore-x-gesture],
 698        [enable the ecore_x support for Xgesture extension.
 699         @<:@default=detect@:>@])],
 700    [want_ecore_x_gesture=$enableval])
 701
 702 AC_ARG_ENABLE(ecore-x-sync,
 703    [AC_HELP_STRING([--disable-ecore-x-sync],
 704        [disable the ecore_x support for Xsync extension.
 705         @<:@default=detect@:>@])],
 706    [want_ecore_x_sync=$enableval])
 707
 708 AC_ARG_ENABLE(ecore-x-xfixes,
 709    [AC_HELP_STRING([--disable-ecore-x-xfixes],
 710        [disable the ecore_x support for Xfixes extension.
 711         @<:@default=detect@:>@])],
 712    [want_ecore_x_xfixes=$enableval])
 713
 714 AC_ARG_ENABLE(ecore-x-xinerama,
 715    [AC_HELP_STRING([--disable-ecore-x-xinerama],
 716        [disable the ecore_x support for Xinerama extension.
 717         @<:@default=detect@:>@])],
 718    [want_ecore_x_xinerama=$enableval])
 719
 720 AC_ARG_ENABLE(ecore-x-xprint,
 721    [AC_HELP_STRING([--disable-ecore-x-xprint],
 722        [disable the ecore_x support for Xprint extension.
 723         @<:@default=detect@:>@])],
 724    [want_ecore_x_xprint=$enableval])
 725
 726 AC_ARG_ENABLE(ecore-x-xtest,
 727    [AC_HELP_STRING([--disable-ecore-x-xtest],
 728        [disable the ecore_x support for Xtest extension.
 729         @<:@default=detect@:>@])],
 730    [want_ecore_x_xtest=$enableval])
 731
 732 AC_ARG_ENABLE(ecore-x-cursor,
 733    [AC_HELP_STRING([--disable-ecore-x-cursor],
 734        [disable the ecore_x support for Xcursor extension.
 735         @<:@default=detect@:>@])],
 736    [want_ecore_x_cursor=$enableval])
 737
 738 AC_ARG_ENABLE(ecore-x-input,
 739    [AC_HELP_STRING([--disable-ecore-x-input],
 740        [disable the ecore_x support for Xinput/Xinput2 extension.
 741         @<:@default=detect@:>@])],
 742    [want_ecore_x_input=$enableval])
 743
 744 AC_ARG_ENABLE(ecore-x-dri,
 745    [AC_HELP_STRING([--disable-ecore-x-dri],
 746        [disable the ecore_x support for DRI extension.
 747         @<:@default=detect@:>@])],
 748    [want_ecore_x_dri=$enableval])
 749
 750 AC_ARG_ENABLE(ecore-x-xcb,
 751    [AC_HELP_STRING([--enable-ecore-x-xcb],
 752        [enable the ecore_x module with XCB backend. @<:@default=disabled@:>@])],
 753    [want_ecore_x_xcb=$enableval])
 754
 755 AC_MSG_CHECKING(whether ecore_x with XCB backend is to be built)
 756 AC_MSG_RESULT($want_ecore_x_xcb)
 757
 758 if test "x$want_ecore_x_xcb" = "xyes" ; then
 759
 760   AC_MSG_CHECKING([keysym definitions])
 761   KEYSYMDEFDIR=`$PKG_CONFIG --variable=includedir xproto`/X11
 762   FILES="keysymdef.h XF86keysym.h Sunkeysym.h DECkeysym.h HPkeysym.h"
 763   for i in $FILES; do
 764       if test -f "$KEYSYMDEFDIR/$i"; then
 765         KEYSYMDEFS="$KEYSYMDEFS $KEYSYMDEFDIR/$i"
 766       elif test "x$i" = "xkeysymdef.h"; then
 767         AC_MSG_ERROR([Cannot find keysymdef.h])
 768       fi
 769   done
 770   AC_MSG_RESULT([$KEYSYMDEFS])
 771   AC_SUBST(KEYSYMDEFS)
 772
 773   have_iconv="no"
 774   AC_ARG_WITH([iconv-link],
 775     AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 776       [
 777         LIBS="$withval $LIBS"
 778         have_iconv="yes"
 779       ])
 780
 781   AC_MSG_CHECKING(for explicit iconv link options)
 782   if test "x${iconv_libs}" = "x" ; then
 783     AC_MSG_RESULT([no explicit iconv link option])
 784   else
 785     AC_MSG_RESULT([$iconv_libs])
 786   fi
 787
 788   if test "x${have_iconv}" = "xno" ; then
 789     AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 790
 791     if test "x${have_iconv}" = "xyes" ; then
 792       AC_MSG_CHECKING([whether iconv() is in libc])
 793
 794       AC_LINK_IFELSE(
 795         [AC_LANG_PROGRAM(
 796         [[
 797           #include <stdlib.h>
 798           #include <iconv.h>
 799         ]],
 800         [[
 801           iconv_t ic;
 802           size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 803         ]])],
 804         [have_iconv="yes"],
 805         [have_iconv="no"])
 806
 807       AC_MSG_RESULT([${have_iconv}])
 808     fi
 809
 810     if test "x${have_iconv}" = "xno" ; then
 811       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 812
 813       LIBS_save="${LIBS}"
 814       LIBS="-liconv $LIBS"
 815       AC_LINK_IFELSE(
 816       [AC_LANG_PROGRAM(
 817         [[
 818           #include <stdlib.h>
 819           #include <iconv.h>
 820         ]],
 821         [[
 822           iconv_t ic;
 823           size_t count;
 824           count = iconv(ic, NULL, NULL, NULL, NULL);
 825         ]])],
 826         [have_iconv="yes"],
 827         [
 828           have_iconv="no"
 829           LIBS=${LIBS_save}
 830         ])
 831
 832       AC_MSG_RESULT([${have_iconv}])
 833     fi
 834
 835     if test "x${have_iconv}" = "xno" ; then
 836       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 837
 838       LIBS_save="${LIBS}"
 839       LIBS="-liconv_plug $LIBS"
 840       AC_LINK_IFELSE(
 841       [AC_LANG_PROGRAM(
 842       [[
 843         #include <stdlib.h>
 844         #include <iconv.h>
 845       ]],
 846       [[
 847         iconv_t ic;
 848         size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 849       ]])],
 850       [have_iconv="yes"],
 851       [
 852         have_iconv="no"
 853         LIBS=${LIBS_save}
 854       ])
 855
 856       AC_MSG_RESULT([${have_iconv}])
 857     fi
 858
 859     if test "x${have_iconv}" = "xyes" ; then
 860       AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 861     fi
 862   fi
 863
 864   PKG_CHECK_MODULES(ECORE_XCB, x11-xcb xcb xcb-shm xcb-event xcb-icccm >= 0.3.8 xcb-util >= 0.3.8 xcb-image xcb-keysyms >= 0.3.8,
 865     [ have_ecore_x_xcb="yes"
 866       requirements_ecore_x="x11-xcb xcb xcb-shm xcb-event xcb-icccm xcb-util xcb-image xcb-keysyms ${requirements_ecore_x}"
 867     ],
 868     [
 869         PKG_CHECK_MODULES(ECORE_XCB, x11-xcb xcb xcb-event xcb-shm xcb-icccm xcb-image xcb-keysyms,
 870           [ have_ecore_x_xcb="yes"
 871             AC_DEFINE(OLD_XCB_VERSION, 1, [xcb version])
 872             requirements_ecore_x="x11-xcb xcb xcb-event xcb-shm xcb-icccm xcb-image xcb-keysyms ${requirements_ecore_x}" ],
 873           [ have_ecore_x_xcb="no" ])
 874     ],
 875     [have_ecore_x_xcb="no" ])
 876
 877   if test "x$have_ecore_x_xcb" = "xyes" ; then
 878
 879    PKG_CHECK_MODULES([PIXMAN],
 880       [pixman-1],
 881       [
 882        have_pixman="yes"
 883        AC_DEFINE(HAVE_PIXMAN, 1, [have pixman for rendering])
 884        requirements_ecore_x="pixman-1 ${requirements_ecore_x}"
 885       ],
 886       [
 887        if test "x${want_pixman}" = "xyes" -a "x${use_strict}" = "xyes" ; then
 888           AC_MSG_ERROR([Pixman not found (strict dependencies checking)])
 889        fi
 890       ])
 891
 892     if test "x$want_ecore_x_composite" != "xno"; then
 893       PKG_CHECK_MODULES(XCB_COMPOSITE, xcb-composite,
 894         [ have_ecore_x_xcb_composite="yes"
 895           requirements_ecore_x="xcb-composite ${requirements_ecore_x}"
 896           AC_DEFINE(ECORE_XCB_COMPOSITE, 1, [Build support for XCB composite]) ],
 897         [ have_ecore_x_xcb_composite="no" ])
 898     else
 899       have_ecore_x_xcb_composite="no"
 900       AC_MSG_NOTICE("composite extension explicitly disabled")
 901     fi
 902
 903     if test "x$want_ecore_x_damage" != "xno"; then
 904       PKG_CHECK_MODULES(XCB_DAMAGE, xcb-damage,
 905         [ have_ecore_x_xcb_damage="yes"
 906           requirements_ecore_x="xcb-damage ${requirements_ecore_x}"
 907           AC_DEFINE(ECORE_XCB_DAMAGE, 1, [Build support for XCB damage]) ],
 908         [ have_ecore_x_xcb_damage="no" ])
 909     else
 910       have_ecore_x_xcb_damage="no"
 911       AC_MSG_NOTICE("damage extension explicitly disabled")
 912     fi
 913
 914     if test "x$want_ecore_x_dpms" != "xno"; then
 915       PKG_CHECK_MODULES(XCB_DPMS, xcb-dpms,
 916         [ have_ecore_x_xcb_dpms="yes"
 917           requirements_ecore_x="xcb-dpms ${requirements_ecore_x}"
 918           AC_DEFINE(ECORE_XCB_DPMS, 1, [Build support for XCB dpms]) ],
 919         [ have_ecore_x_xcb_dpms="no" ])
 920     else
 921       have_ecore_x_xcb_dpms="no"
 922       AC_MSG_NOTICE("dpms extension explicitly disabled")
 923     fi
 924
 925     if test "x$want_ecore_x_randr" != "xno"; then
 926       PKG_CHECK_MODULES(XCB_RANDR, xcb-randr,
 927         [ have_ecore_x_xcb_randr="yes"
 928           requirements_ecore_x="xcb-randr ${requirements_ecore_x}"
 929           AC_DEFINE(ECORE_XCB_RANDR, 1, [Build support for XCB randr]) ],
 930         [ have_ecore_x_xcb_randr="no" ])
 931     else
 932       have_ecore_x_xcb_randr="no"
 933       AC_MSG_NOTICE("randr extension explicitly disabled")
 934     fi
 935
 936     if test "x$want_ecore_x_render" != "xno"; then
 937       PKG_CHECK_MODULES(XCB_RENDER, xcb-render xcb-renderutil,
 938         [ have_ecore_x_xcb_render="yes"
 939           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
 940           AC_DEFINE(ECORE_XCB_RENDER, 1, [Build support for XCB render]) ],
 941         [ have_ecore_x_xcb_render="no" ])
 942     else
 943       have_ecore_x_xcb_render="no"
 944       AC_MSG_NOTICE("render extension explicitly disabled")
 945     fi
 946
 947     if test "x$want_ecore_x_screensaver" != "xno"; then
 948       PKG_CHECK_MODULES(XCB_SCREENSAVER, xcb-screensaver,
 949         [ have_ecore_x_xcb_screensaver="yes"
 950           requirements_ecore_x="xcb-screensaver ${requirements_ecore_x}"
 951           AC_DEFINE(ECORE_XCB_SCREENSAVER, 1, [Build support for XCB screensaver]) ],
 952         [ have_ecore_x_xcb_screensaver="no" ])
 953     else
 954       have_ecore_x_xcb_screensaver="no"
 955       AC_MSG_NOTICE("screensaver extension explicitly disabled")
 956     fi
 957
 958     if test "x$want_ecore_x_shape" != "xno"; then
 959       PKG_CHECK_MODULES(XCB_SHAPE, xcb-shape,
 960         [ have_ecore_x_xcb_shape="yes"
 961           requirements_ecore_x="xcb-shape ${requirements_ecore_x}"
 962           AC_DEFINE(ECORE_XCB_SHAPE, 1, [Build support for XCB shape]) ],
 963         [ have_ecore_x_xcb_shape="no" ])
 964     else
 965       have_ecore_x_xcb_shape="no"
 966       AC_MSG_NOTICE("shape extension explicitly disabled")
 967     fi
 968
 969     if test "x$want_ecore_x_gesture" != "xno"; then
 970       PKG_CHECK_MODULES(XCB_XGESTURE, xcb-gesture,
 971         [ have_ecore_x_xcb_gesture="yes"
 972           requirements_ecore_x="xcb-gesture ${requirements_ecore_x}"
 973           AC_DEFINE(ECORE_XCB_XGESTURE, 1, [Build support for XCB gesture]) ],
 974         [ have_ecore_x_xcb_gesture="no" ])
 975     else
 976       have_ecore_x_xcb_gesture="no"
 977       AC_MSG_NOTICE("gesture extension explicitly disabled")
 978     fi
 979
 980     if test "x$want_ecore_x_sync" != "xno"; then
 981       PKG_CHECK_MODULES(XCB_SYNC, xcb-sync,
 982         [ have_ecore_x_xcb_sync="yes"
 983           requirements_ecore_x="xcb-sync ${requirements_ecore_x}"
 984           AC_DEFINE(ECORE_XCB_SYNC, 1, [Build support for XCB sync]) ],
 985         [ have_ecore_x_xcb_sync="no" ])
 986     else
 987       have_ecore_x_xcb_sync="no"
 988       AC_MSG_NOTICE("sync extension explicitly disabled")
 989     fi
 990
 991     if test "x$want_ecore_x_xfixes" != "xno"; then
 992       PKG_CHECK_MODULES(XCB_XFIXES, xcb-xfixes,
 993         [ have_ecore_x_xcb_xfixes="yes"
 994           requirements_ecore_x="xcb-xfixes ${requirements_ecore_x}"
 995           AC_DEFINE(ECORE_XCB_XFIXES, 1, [Build support for XCB xfixes]) ],
 996         [ have_ecore_x_xcb_xfixes="no" ])
 997     else
 998       have_ecore_x_xcb_xfixes="no"
 999       AC_MSG_NOTICE("xfixes extension explicitly disabled")
1000     fi
1001
1002     if test "x$want_ecore_x_xinerama" != "xno"; then
1003       PKG_CHECK_MODULES(XCB_XINERAMA, xcb-xinerama,
1004         [ have_ecore_x_xcb_xinerama="yes"
1005           requirements_ecore_x="xcb-xinerama ${requirements_ecore_x}"
1006           AC_DEFINE(ECORE_XCB_XINERAMA, 1, [Build support for XCB xinerama]) ],
1007         [ have_ecore_x_xcb_xinerama="no" ])
1008     else
1009       have_ecore_x_xcb_xinerama="no"
1010       AC_MSG_NOTICE("xinerama extension explicitly disabled")
1011     fi
1012
1013     if test "x$want_ecore_x_xprint" != "xno"; then
1014       PKG_CHECK_MODULES(XCB_XPRINT, xcb-xprint,
1015         [ have_ecore_x_xcb_xprint="yes"
1016           requirements_ecore_x="xcb-xprint ${requirements_ecore_x}"
1017           AC_DEFINE(ECORE_XCB_XPRINT, 1, [Build support for XCB xprint]) ],
1018         [ have_ecore_x_xcb_xprint="no" ])
1019     else
1020       have_ecore_x_xcb_xprint="no"
1021       AC_MSG_NOTICE("xprint extension explicitly disabled")
1022     fi
1023
1024     if test "x$want_ecore_x_xtest" != "xno"; then
1025       PKG_CHECK_MODULES(XCB_XTEST, xcb-xtest,
1026         [ have_ecore_x_xcb_xtest="yes"
1027           requirements_ecore_x="xcb-xtest ${requirements_ecore_x}"
1028           AC_DEFINE(ECORE_XCB_XTEST, 1, [Build support for XCB xtest]) ],
1029         [ have_ecore_x_xcb_xtest="no" ])
1030     else
1031       have_ecore_x_xcb_xtest="no"
1032       AC_MSG_NOTICE("xtest extension explicitly disabled")
1033     fi
1034
1035 # input extension disabled currently in xcb as xcb-input has some issues
1036     want_ecore_x_input="no"
1037     if test "x$want_ecore_x_input" != "xno"; then
1038       PKG_CHECK_MODULES(XCB_XINPUT, xcb-xinput,
1039         [ have_ecore_x_xcb_xinput="yes"
1040           requirements_ecore_x="xcb-xinput ${requirements_ecore_x}"
1041           AC_DEFINE(ECORE_XCB_XINPUT, 1, [Build support for XCB xinput]) ],
1042         [ have_ecore_x_xcb_xinput="no" ])
1043     else
1044       have_ecore_x_xcb_xinput="no"
1045       AC_MSG_NOTICE("xinput extension explicitly disabled")
1046     fi
1047
1048     if test "x$want_ecore_x_cursor" != "xno"; then
1049       PKG_CHECK_MODULES(XCB_CURSOR, xcb-render xcb-renderutil,
1050         [ have_ecore_x_xcb_cursor="yes"
1051           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
1052           AC_DEFINE(ECORE_XCB_CURSOR, 1, [Build support for XCB cursor]) ],
1053         [ have_ecore_x_xcb_cursor="no" ])
1054     else
1055       have_ecore_x_xcb_cursor="no"
1056       AC_MSG_NOTICE("cursor extension explicitly disabled")
1057     fi
1058
1059 #    if test "x$want_ecore_x_dri" != "xno"; then
1060 #      PKG_CHECK_MODULES(XCB_DRI, xcb-dri2,
1061 #        [ have_ecore_x_xcb_dri="yes"
1062 #          requirements_ecore_x="xcb-dri2 ${requirements_ecore_x}"
1063 #          AC_DEFINE(ECORE_XCB_DRI, 1, [Build support for XCB dri/dri2]) ],
1064 #        [ have_ecore_x_xcb_dri="no" ])
1065 #    else
1066 #      have_ecore_x_xcb_dri="no"
1067 #      AC_MSG_NOTICE("dri extension explicitly disabled")
1068 #    fi
1069
1070     AC_DEFINE(HAVE_ECORE_X_XCB, 1, [Defined to 1 if XCB is enabled.])
1071
1072     x_cflags=$ECORE_XCB_CFLAGS
1073     x_libs=$ECORE_XCB_LIBS
1074     have_x="yes"
1075
1076     have_ecore_x_xcb_define="-DHAVE_ECORE_X_XCB"
1077     AC_SUBST(have_ecore_x_xcb_define)
1078   fi
1079 fi
1080
1081 if ! test "x$have_ecore_x_xcb" = "xyes" ; then
1082   AC_PATH_XTRA
1083   AC_CHECK_HEADER(X11/X.h,
1084     [
1085      if test "x$want_evas_simple_x11" = "xyes"; then
1086        x_libs="${x_libs} -lX11 -lXext"
1087      else
1088        x_dir=${x_dir:-/usr/X11R6}
1089        x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
1090        x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
1091      fi
1092      have_ecore_x_xlib="yes"
1093     ]
1094   )
1095
1096   if test "x$have_ecore_x_xlib" = "xyes"; then
1097     Xcursor_libs=""
1098     Xcursor_cflags=""
1099     use_Xcursor="no"
1100     PCFLAGS=$CFLAGS
1101     CFLAGS="$x_cflags $x_includes"
1102
1103     if test "x$want_ecore_x_cursor" = "xyes"; then
1104       AC_CHECK_HEADER(X11/Xcursor/Xcursor.h,
1105         [
1106           AC_CHECK_LIB(Xcursor, XcursorImageLoadCursor,
1107             [
1108               AC_DEFINE(ECORE_XCURSOR, 1, [Build support for Xcursor])
1109               Xcursor_cflags=""
1110               Xcursor_libs="-lXcursor"
1111               use_Xcursor="yes"
1112             ], [
1113               Xcursor_cflags=""
1114               Xcursor_libs=""
1115               use_Xcursor="no"
1116             ], [
1117               $x_libs -lXrender
1118             ]
1119           )
1120         ], [
1121           Xcursor_cflags=""
1122           Xcursor_libs=""
1123           use_Xcursor="no"
1124         ], [
1125           #include <X11/Xlib.h>
1126         ]
1127       )
1128       CFLAGS=$PCFLAGS
1129     else
1130       Xcursor_cflags=""
1131       Xcursor_libs=""
1132       use_Xcursor="no"
1133       AC_MSG_NOTICE("Xcursor explicitly disabled")
1134     fi
1135
1136     AC_SUBST(Xcursor_cflags)
1137     AC_SUBST(Xcursor_libs)
1138
1139     ECORE_CHECK_X_EXTENSION([Xkb], [XKB.h], [X11], [XkbSetDetectableAutoRepeat], [$want_ecore_x_xkb])
1140     ECORE_CHECK_X_EXTENSION([Xcomposite], [Xcomposite.h], [Xcomposite], [XCompositeQueryExtension], [$want_ecore_x_composite])
1141     ECORE_CHECK_X_EXTENSION([Xdamage], [Xdamage.h], [Xdamage], [XDamageSubtract], [$want_ecore_x_damage])
1142     ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xdpms], [DPMSQueryExtension], [$want_ecore_x_dpms])
1143     if test "x$use_xdpms" = "xno" ; then
1144       ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xext], [DPMSQueryExtension], [$want_ecore_x_dpms])
1145     fi
1146     ECORE_CHECK_X_EXTENSION([Xfixes], [Xfixes.h], [Xfixes], [XFixesExpandRegion], [$want_ecore_x_xfixes])
1147     ECORE_CHECK_X_EXTENSION([Xinerama], [Xinerama.h], [Xinerama], [XineramaQueryScreens], [$want_ecore_x_xinerama])
1148     ECORE_CHECK_X_EXTENSION([Xprint], [Print.h], [Xp], [XpQueryScreens], [$want_ecore_x_xprint])
1149     ECORE_CHECK_X_EXTENSION([Xrandr], [Xrandr.h], [Xrandr], [XRRGetScreenResourcesCurrent], [$want_ecore_x_randr])
1150     ECORE_CHECK_X_EXTENSION([Xgesture], [gesture.h], [Xgesture], [XGestureQueryExtension], [$want_ecore_x_gesture])
1151     ECORE_CHECK_X_EXTENSION([Xrender], [Xrender.h], [Xrender], [XRenderFindVisualFormat], [$want_ecore_x_render])
1152     ECORE_CHECK_X_EXTENSION([Xtest], [XTest.h], [Xtst], [XTestFakeKeyEvent], [$want_ecore_x_xtest])
1153     ECORE_CHECK_X_EXTENSION([Xss], [scrnsaver.h], [Xss], [XScreenSaverSelectInput], [$want_ecore_x_screensaver])
1154     ECORE_CHECK_X_EXTENSION([Xi2], [XInput2.h], [Xi], [XIQueryDevice], [$want_ecore_x_input])
1155
1156     ecore_x_libs_private="${Xcursor_libs} ${XKB_LIBS} ${XCOMPOSITE_LIBS} ${XGESTURE_LIBS} ${XDAMAGE_LIBS} ${XDPMS_LIBS} ${XFIXES_LIBS} ${XINERAMA_LIBS} ${XPRINT_LIBS} ${XRANDR_LIBS} ${XRENDER_LIBS} ${XTEST_LIBS} ${XSS_LIBS} ${XI2_LIBS}"
1157
1158     AC_DEFINE(HAVE_ECORE_X_XLIB, 1, [Defined to 1 if Xlib is enabled.])
1159     have_x="yes"
1160
1161     have_ecore_x_xlib="yes"
1162   fi
1163 fi
1164
1165 AC_SUBST(x_cflags)
1166 AC_SUBST(x_includes)
1167 AC_SUBST(x_libs)
1168 AC_SUBST(ecore_x_libs_private)
1169
1170 AM_CONDITIONAL(BUILD_ECORE_X_XLIB, test $have_ecore_x_xlib = yes)
1171 AM_CONDITIONAL(BUILD_ECORE_X_XCB, test $have_ecore_x_xcb = yes)
1172
1173
1174 # Evas library (ecore_config, ecore_input_evas, ecore_imf_evas and ecore_evas)
1175
1176 PKG_CHECK_MODULES([EVAS], [evas >= 1.1.99],
1177    [have_evas="yes"],
1178    [have_evas="no"])
1179
1180
1181 ### Checks for header files
1182
1183 AC_CHECK_HEADERS([sys/select.h sys/prctl.h])
1184
1185 EFL_CHECK_PATH_MAX
1186
1187 AC_HEADER_SYS_WAIT
1188 AC_SYS_LARGEFILE
1189
1190 have_addrinfo="no"
1191 case "$host_os" in
1192    mingw* | cegcc*)
1193       AC_DEFINE(HAVE_DLFCN_H, 1, [Define to 1 if you have the <dlfcn.h> header file.])
1194       AC_DEFINE(HAVE_SYS_MMAN_H, 1, [Define to 1 if you have the <sys/mman.h> header file.])
1195       AC_DEFINE(HAVE_SYS_TIME_H, 1, [Define to 1 if you have the <sys/time.h> header file.])
1196       have_addrinfo="yes"
1197       ;;
1198    *)
1199       AC_CHECK_HEADERS([dlfcn.h features.h langinfo.h locale.h sys/time.h sys/mman.h signal.h sys/resource.h])
1200       ;;
1201 esac
1202
1203 # ecore_con
1204
1205 AC_CHECK_HEADERS([arpa/inet.h arpa/nameser.h netinet/tcp.h net/if.h netinet/in.h sys/socket.h sys/un.h ws2tcpip.h netdb.h])
1206
1207 if test "x${ac_cv_header_netdb_h}" = "xyes" ; then
1208    have_addrinfo="yes"
1209 fi
1210
1211 # Framebuffer (ecore_fb)
1212 have_fb="no"
1213 AC_CHECK_HEADER([linux/fb.h],
1214    [AC_CHECK_HEADER([linux/input.h], [have_fb="yes"])])
1215
1216 # Cocoa header files (ecore_cocoa)
1217
1218 if test "x${want_ecore_cocoa}" = "xyes" ; then
1219    cocoa_ldflags=""
1220    have_cocoa="no"
1221    m4_ifdef([AC_PROG_OBJC],
1222       [
1223        if test "x${have_gnu_objc}" = "xyes" ; then
1224           AC_LANG_PUSH([Objective C])
1225           LIBS_save="$LIBS"
1226           LIBS="$LIBS -framework Cocoa"
1227           AC_LINK_IFELSE(
1228              [AC_LANG_PROGRAM(
1229                  [[
1230 #include <Cocoa/Cocoa.h>
1231                  ]],
1232                  [[
1233 NSWindow *window;
1234 window = [[NSWindow alloc]
1235            initWithContentRect:NSMakeRect(0, 0, 1, 1)
1236            styleMask:(NSTitledWindowMask)
1237            backing:NSBackingStoreBuffered
1238            defer:NO
1239            screen:nil
1240          ];
1241                  ]])],
1242              [
1243               have_cocoa="yes"
1244               cocoa_ldflags="-framework Cocoa"
1245              ],
1246              [have_cocoa="no"])
1247           LIBS="$LIBS_save"
1248           AC_MSG_CHECKING([whether Cocoa framework is supported])
1249           AC_MSG_RESULT([${have_cocoa}])
1250           AC_LANG_POP([Objective C])
1251        fi
1252    ])
1253 fi
1254 AC_SUBST(cocoa_ldflags)
1255
1256 want_epoll=yes
1257 AC_ARG_ENABLE(epoll,
1258   AC_HELP_STRING([--enable-epoll], [enable or disable epoll support]),
1259   [want_epoll=$enableval])
1260
1261 if test "x${want_epoll}" = "xyes" ; then
1262   # check for epoll support
1263   AC_CHECK_HEADERS([sys/epoll.h])
1264 fi
1265
1266 # timerfd_create
1267 AC_CHECK_HEADERS([sys/timerfd.h])
1268 AC_CHECK_FUNCS(timerfd_create)
1269
1270 # thread support
1271
1272 EFL_CHECK_THREADS(
1273    [
1274     if test "x${_efl_have_posix_threads}" = "xyes" ; then
1275        have_threads="POSIX"
1276     else
1277        if test "x${_efl_have_win32_threads}" = "xyes" ; then
1278           have_threads="Win32"
1279        else
1280           have_threads="no"
1281        fi
1282     fi
1283    ],
1284    [have_threads="no"])
1285
1286 ### enable thread safety if we have threads, unless specifically asked not to
1287 if test "x${have_threads}" = "xno"
1288 then
1289   want_thread_safety="no"
1290 else
1291   want_thread_safety="no"  # to be changed to yes when ready
1292   AC_ARG_ENABLE(thread-safety,
1293     AC_HELP_STRING([--enable-thread-safety], [enable or disable thread safety]),
1294     [want_thread_safety=$enableval])
1295 fi
1296
1297 if test "x${want_thread_safety}" = "xyes"
1298 then
1299    AC_DEFINE([HAVE_THREAD_SAFETY], [1], [Define to enable thread safety])
1300 fi
1301
1302 ### Checks for types
1303 AC_CHECK_SIZEOF(int, 4)
1304 AC_CHECK_SIZEOF(long, 4)
1305
1306
1307 ### Checks for structures
1308
1309
1310 ### Checks for compiler characteristics
1311 AC_PROG_CC_STDC
1312 AC_C_CONST
1313 AC_C_BIGENDIAN
1314 AC_HEADER_STDC
1315 AC_C___ATTRIBUTE__
1316
1317 WIN32_CPPFLAGS=""
1318 WIN32_CFLAGS=""
1319 case "$host_os" in
1320    mingw32ce*)
1321       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1322       ;;
1323    cegcc*)
1324       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1325       WIN32_CFLAGS="-mwin32"
1326       ;;
1327    mingw*)
1328       WIN32_CPPFLAGS="-D_WIN32_WINNT=0x0501"
1329       ;;
1330 esac
1331 AC_SUBST(WIN32_CPPFLAGS)
1332 AC_SUBST(WIN32_CFLAGS)
1333
1334
1335 ### Checks for linker characteristics
1336
1337 # use --enable-auto-import on Windows
1338
1339 lt_enable_auto_import=""
1340 case "$host_os" in
1341    mingw* | cegcc*)
1342       lt_enable_auto_import="-Wl,--enable-auto-import"
1343       ;;
1344 esac
1345 AC_SUBST(lt_enable_auto_import)
1346
1347 ### Checks for library functions
1348 AC_ISC_POSIX
1349 AC_FUNC_ALLOCA
1350 AC_CHECK_FUNCS([gettimeofday strlcpy execvp])
1351
1352 AC_COMPILE_IFELSE(
1353    [AC_LANG_PROGRAM(
1354        [[
1355 #include <math.h>
1356        ]],
1357        [[
1358 int i = isfinite(0);
1359        ]])],
1360    [
1361     AC_DEFINE(HAVE_ISFINITE, 1, [Define to 1 if you have `isfinite', as a function or macro.])
1362     have_isfinite="yes"
1363    ],
1364    [have_isfinite="no"])
1365
1366 AC_MSG_CHECKING([for isfinite])
1367 AC_MSG_RESULT([${have_isfinite}])
1368
1369 have_atfile_source=auto
1370 AC_ARG_ENABLE([atfile-source],
1371    [AC_HELP_STRING([--disable-atfile-source],
1372        [disable use of atfile source functions as openat and mkdirat @<:@default=detect@:>@])],
1373    [
1374     if test "x${enableval}" = "xyes" ; then
1375        have_atfile_source="yes"
1376     else
1377        have_atfile_source="no"
1378     fi],
1379    [have_atfile_source=auto])
1380
1381 if ! test "x${have_atfile_source}" = "xno" ; then
1382    AC_CHECK_FUNCS(mkdirat,
1383       [
1384        have_atfile_source="yes"
1385        AC_DEFINE(HAVE_ATFILE_SOURCE, 1, [mkdirat exists])
1386       ],
1387       [
1388        if test "x${have_atfile_source}" = "xyes" ; then
1389           AC_MSG_ERROR([required atfile-source but no mkdirat()])
1390        fi
1391        have_atfile_source="no"
1392       ])
1393 fi
1394
1395 SHM_OPEN_LIBS=""
1396 AC_COMPILE_IFELSE(
1397    [AC_LANG_PROGRAM(
1398        [[
1399 #include <sys/mman.h>
1400 #include <sys/stat.h>
1401 #include <fcntl.h>
1402        ]],
1403        [[
1404 int fd;
1405 fd = shm_open("/", O_RDWR | O_CREAT, S_IRUSR | S_IWUSR);
1406 shm_unlink("/");
1407        ]])],
1408    [
1409     have_shm_open="yes"
1410     AC_DEFINE(HAVE_SHM_OPEN, 1, [Have shm_open() call])
1411     SHM_OPEN_LIBS="-lrt"
1412    ],
1413    [have_shm_open="no"])
1414 AC_SUBST(SHM_OPEN_LIBS)
1415
1416 AC_MSG_CHECKING([shm_open])
1417 AC_MSG_RESULT([${have_shm_open}])
1418
1419 ### Checks for optionnal feature
1420 AC_CHECK_FUNC([mallinfo],
1421    [
1422     have_mallinfo="yes"
1423     AC_DEFINE(HAVE_MALLINFO, 1, [Gather memory statistic])
1424    ],
1425    [have_mallinfo="no"])
1426
1427 ### Ecore modules
1428
1429 ## Core modules
1430
1431 # ecore_con
1432 ECORE_CHECK_MODULE([con], [${want_ecore_con}], [Con], [${have_addrinfo}])
1433
1434 have_curl="no"
1435 have_gnutls="no"
1436 have_openssl="no"
1437 have_cares="no"
1438 want_ipv6="yes"
1439 have_ipv6="no"
1440
1441 AC_ARG_ENABLE([ipv6],
1442    [AC_HELP_STRING([--disable-ipv6],
1443        [disable ipv6 functionality @<:@default=detect@:>@])],
1444    [
1445     if test "x${enableval}" = "xyes" ; then
1446        want_ipv6="yes"
1447     else
1448        want_ipv6="no"
1449     fi],
1450    [want_ipv6="auto"])
1451
1452 if test "x${have_ecore_con}" = "xyes" ; then
1453
1454    # Verify IPV6 availability in headers
1455    if test "x${want_ipv6}" != "xno" ; then
1456       AC_CHECK_TYPES([struct ipv6_mreq],
1457          [have_ipv6="yes"],
1458          [have_ipv6="no"],
1459          [[
1460 #ifdef HAVE_NETINET_IN_H
1461 # include <netinet/in.h>
1462 #endif
1463 #ifdef HAVE_WS2TCPIP_H
1464 # include <ws2tcpip.h>
1465 #endif
1466          ]])
1467    fi
1468
1469    if test "x${have_ipv6}" = "xyes" ; then
1470       AC_DEFINE(HAVE_IPV6, 1, [Define if IPV6 is supported])
1471    fi
1472
1473    ECORE_CHECK_CURL([${want_curl}],
1474       [
1475        have_curl="yes"
1476        requirements_ecore_con="libcurl ${requirements_ecore_con}"
1477       ],
1478       [have_curl="no"])
1479
1480    ECORE_CHECK_GNUTLS([${want_gnutls}],
1481       [have_gnutls="yes"],
1482       [have_gnutls="no"])
1483
1484    ECORE_CHECK_OPENSSL([${want_openssl}],
1485       [have_openssl="yes"],
1486       [have_openssl="no"])
1487
1488    if test "x${have_gnutls}" = "xyes" ; then
1489       requirements_ecore_con="gnutls ${requirements_ecore_con}"
1490       # no need to add it to req_ecore_ipc, since they
1491       # depends on ecore_con anyway.
1492    else
1493       if test "x${have_openssl}" = "xyes" ; then
1494          requirements_ecore_con="openssl ${requirements_ecore_con}"
1495          # no need to add it to req_ecore_ipc, since they
1496          # depends on ecore_con anyway.
1497       fi
1498    fi
1499
1500    ECORE_CHECK_CARES([${want_cares}],
1501       [
1502        have_cares="yes"
1503        requirements_ecore_con="libcares ${requirements_ecore_con}"
1504       ],
1505       [have_cares="no"])
1506
1507 fi
1508
1509 AM_CONDITIONAL([HAVE_CARES], [test "x${have_cares}" = "xyes"])
1510
1511 # ecore_ipc
1512 ECORE_CHECK_MODULE([ipc], [${want_ecore_ipc}], [Ipc], [${have_ecore_con}],
1513    [
1514      requirements_ecore_ipc="ecore-con >= 1.1.99 ${requirements_ecore_ipc}"
1515      requirements_ecore_evas="ecore-ipc >= 1.1.99 ${requirements_ecore_evas}"
1516    ])
1517
1518 # ecore_file
1519 ECORE_CHECK_MODULE([file], [${want_ecore_file}], [File])
1520
1521 have_poll="no"
1522 have_inotify="no"
1523 have_notify_win32="no"
1524 if test "x${have_ecore_file}" = "xyes" ; then
1525    ECORE_CHECK_POLL([${want_poll}], [have_poll="yes"], [have_poll="no"])
1526    ECORE_CHECK_INOTIFY([${want_inotify}], [have_inotify="yes"], [have_inotify="no"])
1527    ECORE_CHECK_NOTIFY_WIN32([${want_notify_win32}], [have_notify_win32="yes"], [have_notify_win32="no"])
1528
1529    if test "x${have_ecore_con}" = "xyes" ; then
1530       requirements_ecore_file="ecore-con >= 1.1.99 ${requirements_ecore_file}"
1531    else
1532       ECORE_CHECK_CURL([${want_curl}],
1533          [
1534           have_curl="yes"
1535           requirements_ecore_file="libcurl ${requirements_ecore_file}"
1536          ],
1537          [have_curl="no"])
1538    fi
1539
1540 fi
1541
1542 # ecore_config
1543 #ecore_config_deps="no"
1544 #if test "x${have_eet}" = "xyes" -a "x${have_evas}"  -a "x${have_ecore_ipc}" ; then
1545 #   ecore_config_deps="yes"
1546 #fi
1547
1548 #ECORE_CHECK_MODULE([config], [${want_ecore_config}], [Config], [${ecore_config_deps}],
1549 #   [requirements_ecore_config="ecore-ipc >= 1.1.99 evas >= 1.1.99 eet >= 1.5.0 ${requirements_ecore_config}"])
1550
1551 AM_CONDITIONAL(BUILD_ECORE_CONFIG, false)
1552
1553 # ecore_imf
1554
1555 ECORE_CHECK_MODULE([imf], [${want_ecore_imf}], [Imf])
1556
1557 # ecore_imf_evas
1558
1559 ecore_imf_evas_deps="no"
1560 if test "x${have_ecore_imf}" = "xyes" -a "x${have_evas}" = "xyes" ; then
1561    ecore_imf_evas_deps="yes"
1562 fi
1563
1564 ECORE_CHECK_MODULE([imf-evas], [${want_ecore_imf}], [Imf_Evas], [${ecore_imf_evas_deps}],
1565    [requirements_ecore_imf_evas="ecore-imf >= 1.1.99 evas >= 1.1.99 ${requirements_ecore_imf_evas}"])
1566
1567 # ecore_input{_evas}
1568 ECORE_CHECK_MODULE([input], [${want_ecore_input}], [Input])
1569 ECORE_CHECK_MODULE([input-evas], [${want_ecore_input}], [Input_Evas], [${have_evas}],
1570    [requirements_ecore_input_evas="ecore-input >= 1.1.99 evas >= 1.1.99 ${requirements_ecore_input}"])
1571
1572 # ecore_imf_xim
1573 AM_CONDITIONAL(BUILD_ECORE_IMF_XIM, false)
1574 ecore_imf_xim_deps="no"
1575 echo "have_ecore_x_xlib: ${have_ecore_x_xlib}"
1576 if test    "x${have_ecore_imf}" = "xyes" \
1577         -a "x${have_ecore_x_xlib}" = "xyes" \
1578         -a "x${have_ecore_input}" = "xyes" ; then
1579    ecore_imf_xim_deps="yes"
1580    AC_DEFINE(BUILD_ECORE_IMF_XIM, 1, [Ecore Imf XIM Support])
1581 fi
1582
1583 ECORE_CHECK_MODULE([imf-xim], [${want_ecore_imf}], [Imf_XIM], [${ecore_imf_xim_deps}],
1584    [requirements_ecore_imf_xim="ecore-imf >= 1.1.99 ecore-x >= 1.1.99 ecore-input >= 1.1.99 ${requirements_ecore_imf_xim}"])
1585
1586 # ecore_imf_scim
1587 PKG_CHECK_MODULES([SCIM], [scim], [have_scim="yes"], [have_scim="no"])
1588
1589 AM_CONDITIONAL(BUILD_ECORE_IMF_SCIM, false)
1590 ecore_imf_scim_deps="no"
1591 echo "have_ecore_x_xlib: ${have_ecore_x_xlib}"
1592 if test    "x${have_ecore_imf}" = "xyes" \
1593         -a "x${have_scim}" =  "xyes" \
1594         -a "x${have_ecore_input}" = "xyes" ; then
1595    ecore_imf_scim_deps="yes"
1596    AC_DEFINE(BUILD_ECORE_IMF_SCIM, 1, [Ecore Imf SCIM Support])
1597 fi
1598
1599 ECORE_CHECK_MODULE([imf-scim], [${want_ecore_imf}], [Imf_SCIM], [${ecore_imf_scim_deps}],
1600    [requirements_ecore_imf_scim="ecore-imf >= 1.1.0 ecore-x >= 1.1.0 ecore-input >= 1.1.0 ${requirements_ecore_imf_scim}"])
1601
1602 ## Graphic systems
1603
1604 # ecore_x{cb}
1605
1606 ecore_x_deps="no"
1607 if test "x${have_x}" = "xyes" -a \
1608         "x${have_ecore_input}" = "xyes" ; then
1609    ecore_x_deps="yes"
1610 fi
1611
1612 ECORE_CHECK_MODULE([x], [${want_ecore_x}], [X], [${ecore_x_deps}],
1613   [
1614    ecore_x_libs="$ecore_x_libs $x_libs"
1615    requirements_ecore_x="ecore-input >= 1.1.99 ${requirements_ecore_x}"
1616   ])
1617
1618 # ecore_win32
1619
1620 ECORE_CHECK_MODULE([win32], [${want_ecore_win32}], [Win32], [${have_ecore_input}],
1621    [
1622     ecore_win32_libs="-lole32 -lgdi32"
1623     requirements_ecore_win32="ecore-input >= 1.1.99 ${requirements_ecore_win32}"
1624    ])
1625 AC_SUBST(ecore_win32_libs)
1626
1627 # ecore_cocoa
1628
1629 ecore_cocoa_deps="no"
1630 if test "x${have_ecore_input}" = "xyes" -a "x${have_cocoa}" = "xyes" ; then
1631    ecore_cocoa_deps="yes"
1632 fi
1633
1634 ECORE_CHECK_MODULE([cocoa], [${want_ecore_cocoa}], [Cocoa], [${ecore_cocoa_deps}],
1635    [requirements_ecore_cocoa="ecore-input >= 1.1.99 ${requirements_ecore_cocoa}"])
1636
1637 # ecore_sdl
1638
1639 ecore_sdl_deps="no"
1640 if test "x${have_sdl}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
1641    ecore_sdl_deps="yes"
1642 fi
1643
1644 ECORE_CHECK_MODULE([sdl], [${want_ecore_sdl}], [Sdl], [${ecore_sdl_deps}],
1645    [requirements_ecore_sdl="ecore-input >= 1.1.99 ${requirements_ecore_sdl}"])
1646
1647 ECORE_CHECK_MODULE([psl1ght], [${want_ecore_psl1ght}], [psl1ght], [${ecore_psl1ght_deps}],
1648    [requirements_ecore_psl1ght="ecore-input >= 1.1.99 ${requirements_ecore_psl1ght}"])
1649
1650 # ecore_fb
1651 ECORE_CHECK_MODULE([fb], [${want_ecore_fb}], [FB], [$have_fb])
1652
1653 if test "x${have_ecore_fb}" = "xyes" ; then
1654    ECORE_CHECK_TSLIB([${want_tslib}],
1655       [
1656        have_tslib="yes"
1657        requirements_ecore_fb="${_tslib_requirement} ${requirements_ecore_fb}"
1658       ],
1659       [have_tslib="no"])
1660 fi
1661
1662 # ecore_directfb
1663
1664 ECORE_CHECK_MODULE([directfb], [${want_ecore_directfb}], [DirectFB], [${have_directfb}],
1665    [requirements_ecore_directfb="directfb ${requirements_ecore_directfb}"])
1666
1667 # ecore_wince
1668
1669 ECORE_CHECK_MODULE([wince], [${want_ecore_wince}], [WinCE], [${have_ecore_input}],
1670    [requirements_ecore_win32="ecore-input >= 1.1.99 ${requirements_ecore_win32}"])
1671
1672 ## Ecore Evas
1673
1674 # ecore_evas
1675
1676 ecore_evas_deps="no"
1677 if test "x${have_evas}" = "xyes" && test "x${have_ecore_input}" = "xyes" && test "x${have_ecore_input_evas}" = "xyes" ; then
1678    ecore_evas_deps="yes"
1679 fi
1680
1681 ECORE_CHECK_MODULE([evas], [${want_ecore_evas}], [Evas], [${ecore_evas_deps}],
1682   [requirements_ecore_evas="ecore-input >= 1.1.99 ecore-input-evas >= 1.1.99 evas >= 1.1.99 ${requirements_ecore_evas}"])
1683
1684 # ecore_evas_buffer
1685
1686 ECORE_EVAS_CHECK_MODULE([software-buffer],
1687    [${want_ecore_evas_software_buffer}],
1688    [Software Buffer],
1689    [yes])
1690
1691 # ecore_evas_x11
1692
1693 # ecore_evas_software_x11
1694
1695 ECORE_EVAS_CHECK_MODULE([software-x11],
1696    [${want_ecore_evas_software_x11}],
1697    [Software X11],
1698    [${have_ecore_x}])
1699
1700 have_ecore_evas_software_xlib="no"
1701 have_ecore_evas_software_xcb="no"
1702 if test "x$have_ecore_evas_software_x11" = "xyes" ; then
1703    have_ecore_evas_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
1704    if test "x${have_ecore_evas_software_xlib}" = "xstatic"; then
1705       have_ecore_evas_software_xlib="yes"
1706    fi
1707    if test "x${have_ecore_evas_software_xlib}" = "xyes" -a "x${have_ecore_x_xlib}" = "xyes" ; then
1708       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
1709    fi
1710    have_ecore_evas_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
1711    if test "x$have_ecore_evas_software_xcb" = "xstatic"; then
1712       have_ecore_evas_software_xcb="yes"
1713    fi
1714    if test "x$have_ecore_evas_software_xcb" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1715       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
1716    fi
1717 fi
1718
1719 # ecore_evas_opengl_x11
1720
1721 ECORE_EVAS_CHECK_MODULE([opengl-x11],
1722    [${want_ecore_evas_opengl_x11}],
1723    [OpenGL Xlib],
1724    [${have_ecore_x}])
1725
1726 have_ecore_evas_opengl_xlib="no"
1727 have_ecore_evas_opengl_xcb="no"
1728 if test "x${have_ecore_evas_opengl_x11}" = "xyes" -o "x${have_ecore_evas_opengl_x11}" = "xstatic" ; then
1729    have_ecore_evas_opengl_xlib=`${PKG_CONFIG} --variable=Xlib evas-opengl-x11`
1730    if test "x${have_ecore_evas_opengl_xlib}" = "xyes" ; then
1731       AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XLIB, 1, [OpenGL Xlib rendering backend])
1732    fi
1733
1734 # opengl does not work with xcb (yet)
1735    have_ecore_evas_opengl_xcb=`${PKG_CONFIG} --variable=XCB evas-opengl-x11`
1736    if test "x${have_ecore_evas_opengl_xcb}" = "xstatic"; then
1737       have_ecore_evas_opengl_xcb="yes"
1738    fi
1739    if test "x${have_ecore_evas_opengl_xcb}" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1740       PKG_CHECK_MODULES(XCB_X11, x11-xcb,
1741         [ have_ecore_x_opengl_xcb="yes"
1742           requirements_ecore_x="x11-xcb ${requirements_ecore_x}"
1743           AC_DEFINE(BUILD_ECORE_X_OPENGL_XCB, 1, [Build support for XCB-based OpenGL])
1744           AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XCB, 1, [OpenGL XCB rendering backend])
1745         ],
1746         [ have_ecore_x_opengl_xcb="no" ])
1747     else
1748       have_ecore_x_opengl_xcb="no"
1749       AC_MSG_NOTICE("XCB-based OpenGL explicitly disabled")
1750     fi
1751 fi
1752
1753 # ecore_evas_software_x11 16 bits
1754
1755 ECORE_EVAS_CHECK_MODULE([software-16-x11],
1756    [${want_ecore_evas_software_16_x11}],
1757    [Software Xlib 16 bits],
1758    [${have_ecore_x_xlib}])
1759
1760 ECORE_EVAS_CHECK_MODULE([software-8-x11],
1761     [$want_ecore_evas_software_8_x11],
1762     [Software 8bit X11],
1763     $have_ecore_x_xcb)
1764
1765
1766 if test "x$have_ecore_evas_software_x11" = "xyes" -o \
1767         "x$have_ecore_evas_opengl_x11" = "xyes" -o \
1768         "x$have_ecore_evas_software_8_x11" = "xyes" -o \
1769         "x$have_ecore_evas_software_16_x11" = "xyes" -o \
1770         "x$have_ecore_evas_software_xcb" = "xyes"; then
1771    AC_DEFINE(BUILD_ECORE_EVAS_X11, 1, [Support for X Window Engines in Ecore_Evas])
1772    requirements_ecore_evas="ecore-x >= 1.1.99 ${requirements_ecore_evas}"
1773 fi
1774
1775 # ecore_evas_win32
1776
1777 ECORE_EVAS_CHECK_MODULE([software-gdi],
1778    [${want_ecore_evas_software_gdi}],
1779    [Software GDI],
1780    [${have_ecore_win32}])
1781
1782 ECORE_EVAS_CHECK_MODULE([software-ddraw],
1783    [${want_ecore_evas_software_ddraw}],
1784    [Software DirectDraw],
1785    [${have_ecore_win32}])
1786
1787 ECORE_EVAS_CHECK_MODULE([direct3d],
1788    [${want_ecore_evas_direct3d}],
1789    [Direct3d],
1790    [${have_ecore_win32}])
1791
1792 ECORE_EVAS_CHECK_MODULE([opengl-glew],
1793    [${want_ecore_evas_opengl_glew}],
1794    [Glew OpenGL],
1795    [${have_ecore_win32}])
1796
1797 ECORE_EVAS_CHECK_MODULE([software-16-ddraw],
1798    [${want_ecore_evas_software_16_ddraw}],
1799    [16 bpp Software DirectDraw],
1800    [${have_ecore_win32}])
1801
1802 if test "x${have_ecore_evas_software_gdi}" = "xyes" -o \
1803         "x${have_ecore_evas_software_ddraw}" = "xyes" -o \
1804         "x${have_ecore_evas_direct3d}" = "xyes" -o \
1805         "x${have_ecore_evas_opengl_glew}" = "xyes" -o \
1806         "x${have_ecore_evas_software_16_ddraw}" = "xyes" ; then
1807    AC_DEFINE(BUILD_ECORE_EVAS_WIN32, 1, [Support for Win32 Engine in Ecore_Evas])
1808    requirements_ecore_evas="ecore-win32 >= 1.1.99 ${requirements_ecore_evas}"
1809 fi
1810
1811 # ecore_evas_software_sdl
1812
1813 ECORE_EVAS_CHECK_MODULE([software-sdl],
1814    [${want_ecore_evas_software_sdl}],
1815    [Software SDL],
1816    [${have_ecore_sdl}],
1817    [requirements_ecore_evas="ecore-sdl >= 1.1.99 ${requirements_ecore_evas}"])
1818
1819 # ecore_evas_gl_sdl
1820
1821 ECORE_EVAS_CHECK_MODULE([opengl-sdl],
1822    [${want_ecore_evas_gl_sdl}],
1823    [OpenGL SDL],
1824    [${have_ecore_sdl}],
1825    [requirements_ecore_evas="ecore-sdl >= 1.1.99 ${requirements_ecore_evas}"])
1826
1827 # ecore_evas_cocoa
1828
1829 ECORE_EVAS_CHECK_MODULE([opengl-cocoa],
1830    [${want_ecore_evas_gl_cocoa}],
1831    [OpenGL Cocoa],
1832    [${have_ecore_cocoa}],
1833    [requirements_ecore_evas="ecore-cocoa >= 1.1.99 ${requirements_ecore_evas}"])
1834
1835 # ecore_evas_directfb
1836
1837 ECORE_EVAS_CHECK_MODULE([directfb],
1838    [${want_ecore_evas_directfb}],
1839    [DirectFB],
1840    [${have_ecore_directfb}],
1841    [requirements_ecore_evas="ecore-directfb >= 1.1.99 ${requirements_ecore_evas}"])
1842
1843 # ecore_evas_fb
1844
1845 ECORE_EVAS_CHECK_MODULE([fb],
1846    [${want_ecore_evas_fb}],
1847    [Linux Framebuffer],
1848    [${have_ecore_fb}],
1849    [requirements_ecore_evas="ecore-fb >= 1.1.99 ${requirements_ecore_evas}"])
1850
1851 # ecore_evas_wince
1852
1853 ECORE_EVAS_CHECK_MODULE([software-16-wince],
1854    [${want_ecore_evas_software_16_wince}],
1855    [16 bpp Software Windows CE],
1856    [${have_ecore_wince}],
1857    [requirements_ecore_evas="ecore-wince >= 1.1.99 ${requirements_ecore_evas}"])
1858
1859 # ecore_evas_ews
1860
1861 ECORE_EVAS_CHECK_MODULE_FULL([ews], [software-buffer],
1862    [${want_ecore_evas_ews}],
1863    [Ecore Evas Single Process Windowing System],
1864    [yes], [])
1865
1866 # ecore_evas_extn
1867
1868 have_extn="yes"
1869 if test "x${have_ecore_ipc}" = "xno" || \
1870    test "x${have_ecore_evas_software_buffer}" = "xno" || \
1871    test "x${have_shm_open}" = "xno" ; then
1872    have_extn="no"
1873 fi
1874
1875 dnl THIS IS SPECIAL - dont use normal ECORE_EVAS_CHECK_MODULE
1876 have_ecore_evas_extn="no"
1877 if test "x${want_ecore_evas_extn}" = "xyes" && \
1878    test "x${have_ecore_evas}" = "xyes"; then
1879    AC_DEFINE([BUILD_ECORE_EVAS_EXTN], [1], [Support for Extn Engine in Ecore_Evas])
1880    have_ecore_evas_extn="yes"
1881 fi
1882
1883 # ecore_evas_psl1ght
1884
1885 ECORE_EVAS_CHECK_MODULE([psl1ght],
1886    [${want_ecore_evas_psl1ght}],
1887    [PSL1GHT],
1888    [${have_ecore_psl1ght}],
1889    [requirements_ecore_evas="ecore-psl1ght >= 1.1.99 ${requirements_ecore_evas}"])
1890
1891 ### WAYLAND
1892
1893 ecore_wayland_deps="no"
1894 have_wayland="no"
1895 if test "x${want_ecore_wayland}" = "xyes" ; then
1896   PKG_CHECK_MODULES([WAYLAND], [wayland-client xkbcommon], [have_wayland="yes"], [have_wayland="no"])
1897 fi
1898 if test "x${have_ecore_input}" = "xyes" -a "x${have_wayland}" = "xyes" ; then
1899   ecore_wayland_deps="yes"
1900 fi
1901
1902 ECORE_CHECK_MODULE([wayland], [${want_ecore_wayland}], [Wayland], [${ecore_wayland_deps}])
1903 if test "x${have_ecore_wayland}" = "xyes" ; then
1904   requirements_ecore_wayland="ecore-input >= 1.1.0 wayland-client xkbcommon ${requirements_ecore_wayland}"
1905 fi
1906
1907 ECORE_EVAS_CHECK_MODULE_FULL([wayland-shm], [wayland-shm],
1908    [${want_ecore_evas_wayland_shm}],
1909    [Wayland Shm],
1910    [${have_ecore_wayland}],
1911    [requirements_ecore_evas="${requirements_ecore_wayland} ${requirements_ecore_evas}"])
1912
1913 ECORE_EVAS_CHECK_MODULE_FULL([wayland-egl], [wayland-egl],
1914    [${want_ecore_evas_wayland_egl}],
1915    [Wayland Egl],
1916    [${have_ecore_wayland}],
1917    [
1918       PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [have_wayland_egl="yes"], [have_wayland_egl="no"])
1919       if test "x${have_wayland_egl}" = "xyes" ; then
1920          requirements_ecore_evas="wayland-egl egl ${requirements_ecore_wayland} ${requirements_ecore_evas}"
1921       fi
1922    ])
1923
1924 ### install and build examples
1925
1926 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
1927 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
1928
1929 ### requirements
1930
1931 AC_SUBST(requirements_ecore)
1932 AC_SUBST(requirements_ecore_con)
1933 #AC_SUBST(requirements_ecore_config)
1934 AC_SUBST(requirements_ecore_directfb)
1935 AC_SUBST(requirements_ecore_evas)
1936 AC_SUBST(requirements_ecore_fb)
1937 AC_SUBST(requirements_ecore_file)
1938 AC_SUBST(requirements_ecore_imf)
1939 AC_SUBST(requirements_ecore_imf_evas)
1940 AC_SUBST(requirements_ecore_input)
1941 AC_SUBST(requirements_ecore_input_evas)
1942 AC_SUBST(requirements_ecore_ipc)
1943 AC_SUBST(requirements_ecore_cocoa)
1944 AC_SUBST(requirements_ecore_sdl)
1945 AC_SUBST(requirements_ecore_psl1ght)
1946 AC_SUBST(requirements_ecore_x)
1947 AC_SUBST(requirements_ecore_win32)
1948 AC_SUBST(requirements_ecore_wince)
1949 AC_SUBST(requirements_ecore_imf_xim)
1950 AC_SUBST(requirements_ecore_imf_scim)
1951 AC_SUBST(requirements_ecore_wayland)
1952
1953 AC_CONFIG_FILES([
1954 Makefile
1955 ecore-con.pc
1956 ecore-config.pc
1957 ecore-directfb.pc
1958 ecore-evas.pc
1959 ecore-fb.pc
1960 ecore-file.pc
1961 ecore-imf.pc
1962 ecore-imf-evas.pc
1963 ecore-ipc.pc
1964 ecore-x.pc
1965 ecore-input.pc
1966 ecore-input-evas.pc
1967 ecore-win32.pc
1968 ecore-sdl.pc
1969 ecore-cocoa.pc
1970 ecore-psl1ght.pc
1971 ecore-wince.pc
1972 ecore-wayland.pc
1973 ecore.pc
1974 doc/ecore.dox
1975 doc/Makefile
1976 doc/Doxyfile
1977 src/Makefile
1978 src/util/Makefile
1979 src/bin/Makefile
1980 src/lib/Makefile
1981 src/lib/ecore/Makefile
1982 src/lib/ecore_con/Makefile
1983 src/lib/ecore_config/Makefile
1984 src/lib/ecore_directfb/Makefile
1985 src/lib/ecore_evas/Makefile
1986 src/lib/ecore_fb/Makefile
1987 src/lib/ecore_file/Makefile
1988 src/lib/ecore_cocoa/Makefile
1989 src/lib/ecore_sdl/Makefile
1990 src/lib/ecore_psl1ght/Makefile
1991 src/lib/ecore_imf/Makefile
1992 src/lib/ecore_imf_evas/Makefile
1993 src/lib/ecore_input/Makefile
1994 src/lib/ecore_input_evas/Makefile
1995 src/lib/ecore_ipc/Makefile
1996 src/lib/ecore_win32/Makefile
1997 src/lib/ecore_wince/Makefile
1998 src/lib/ecore_x/Makefile
1999 src/lib/ecore_x/xlib/Makefile
2000 src/lib/ecore_x/xcb/Makefile
2001 src/lib/ecore_wayland/Makefile
2002 src/examples/Makefile
2003 src/tests/Makefile
2004 src/modules/Makefile
2005 src/modules/immodules/Makefile
2006 src/modules/immodules/xim/Makefile
2007 src/modules/immodules/scim/Makefile
2008 ecore.spec
2009 $po_makefile_in
2010 ])
2011
2012 AC_OUTPUT
2013
2014 echo
2015 echo "$PACKAGE $VERSION"
2016 echo
2017 echo "Optional Modules:"
2018 echo
2019 echo " Core:"
2020 echo
2021 echo "  Ecore........................: always"
2022 echo "    Thread support.............: $have_threads"
2023 echo "    Thread safety..............: $want_thread_safety"
2024 echo "    GLib support...............: $have_glib"
2025 echo "    Always integrate GLib......: $want_glib_integration_always"
2026 echo "    Use g_main_loop............: $want_g_main_loop"
2027 echo "    Gathering memory statistic.: $have_mallinfo"
2028 echo "    Gathering timer allocation.: $want_ecore_timer_dump"
2029 echo "  Ecore_Con....................: $have_ecore_con"
2030 if test "x$have_ecore_con" = "xyes" ; then
2031   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
2032 if test "x$have_gnutls" = "xyes" ; then
2033   echo " (disabled)"
2034 else
2035   echo
2036 fi
2037   echo "    IPv6.......................: $have_ipv6"
2038   echo "    GnuTLS.....................: $have_gnutls"
2039   echo "    CURL.......................: $have_curl"
2040   echo "    Local Sockets..............: $want_ecore_con_local_sockets"
2041 if test "x$want_ecore_con_local_sockets" = "xyes" ; then
2042   echo "      Abstract Sockets.........: $want_ecore_con_abstract_sockets"
2043 fi
2044   echo "    c-ares.....................: $have_cares"
2045 fi
2046 echo "  Ecore_Ipc....................: $have_ecore_ipc"
2047 if test "x$have_ecore_ipc" = "xyes" ; then
2048   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
2049 if test "x$have_gnutls" = "xyes" ; then
2050   echo " (disabled)"
2051 else
2052   echo
2053 fi
2054   echo "    GnuTLS.....................: $have_gnutls"
2055 fi
2056 echo "  Ecore_File...................: $have_ecore_file"
2057 if test "x$have_ecore_file" = "xyes" ; then
2058   echo "    Inotify....................: $have_inotify"
2059   echo "    Windows notification.......: $have_notify_win32"
2060   echo "    Poll.......................: $have_poll"
2061   echo "    CURL.......................: $have_curl"
2062 fi
2063 #echo "  Ecore_Config.................: $have_ecore_config (deprecated)"
2064 echo "  Ecore_IMF....................: $have_ecore_imf"
2065 echo "    XIM........................: $have_ecore_imf_xim"
2066 echo "    SCIM.......................: $have_ecore_imf_scim"
2067 echo "  Ecore_IMF_Evas...............: $have_ecore_imf_evas"
2068 echo "  Ecore_Input..................: $have_ecore_input"
2069 echo "  Ecore_Input_Evas.............: $have_ecore_input_evas"
2070
2071 echo
2072 echo " Graphic systems:"
2073 echo
2074
2075 if test "x$have_ecore_x" = "xyes" ; then
2076   if test "x$have_ecore_x_xcb" = "xyes" ; then
2077     echo "  Ecore_X (XCB backend)........: $have_ecore_x_xcb"
2078     echo "    Xprint.....................: $have_ecore_x_xcb_xprint"
2079     echo "    Xinerama...................: $have_ecore_x_xcb_xinerama"
2080     echo "    Xrandr.....................: $have_ecore_x_xcb_randr"
2081     echo "    Xscreensaver...............: $have_ecore_x_xcb_screensaver"
2082     echo "    Xshape.....................: $have_ecore_x_xcb_shape"
2083     echo "    Xgesture...................: $have_ecore_x_xcb_gesture"
2084     echo "    Xsync......................: $have_ecore_x_xcb_sync"
2085     echo "    Xrender....................: $have_ecore_x_xcb_render"
2086     echo "    Xcomposite.................: $have_ecore_x_xcb_composite"
2087     echo "    Xfixes.....................: $have_ecore_x_xcb_xfixes"
2088     echo "    Xdamage....................: $have_ecore_x_xcb_damage"
2089     echo "    Xdpms......................: $have_ecore_x_xcb_dpms"
2090     echo "    Xtest......................: $have_ecore_x_xcb_xtest"
2091   else
2092     echo "  Ecore_X (Xlib backend).......: $have_ecore_x"
2093     echo "    Xcursor....................: $use_Xcursor"
2094     echo "    Xkb........................: $use_xkb"
2095     echo "    Xprint.....................: $use_xprint"
2096     echo "    Xinerama...................: $use_xinerama"
2097     echo "    Xrandr.....................: $use_xrandr"
2098     echo "    Xgesture...................: $use_xgesture"
2099     echo "    Xscreensaver...............: $use_xss"
2100     echo "    Xrender....................: $use_xrender"
2101     echo "    Xcomposite.................: $use_xcomposite"
2102     echo "    Xfixes.....................: $use_xfixes"
2103     echo "    Xdamage....................: $use_xdamage"
2104     echo "    Xdpms......................: $use_xdpms"
2105     echo "    Xtest......................: $use_xtest"
2106     echo "    XIM........................: $want_xim"
2107     echo "    Xi2........................: $use_xi2"
2108   fi
2109 else
2110   echo "  Ecore_X......................: $have_ecore_x"
2111 fi
2112 echo "  Ecore_Win32..................: $have_ecore_win32"
2113 echo "  Ecore_Cocoa..................: $have_ecore_cocoa"
2114 echo "  Ecore_SDL....................: $have_ecore_sdl"
2115 echo "  Ecore_FB.....................: $have_ecore_fb"
2116 if test "x${have_ecore_fb}" = "xyes" ; then
2117   echo "    Touchscreen................: $have_tslib"
2118 fi
2119 echo "  Ecore_DirectFB...............: $have_ecore_directfb"
2120 echo "  Ecore_WinCE..................: $have_ecore_wince"
2121 echo "  Ecore_PSL1GHT................: $have_ecore_psl1ght"
2122 echo "  Ecore_Wayland................: $have_ecore_wayland"
2123
2124 echo
2125 echo " Ecore Evas:"
2126 echo
2127
2128 echo "  Ecore_Evas...................: $have_ecore_evas"
2129 if test "x${have_ecore_evas}" = "xyes" ; then
2130   echo "    Software Memory Buffer.....: $have_ecore_evas_software_buffer"
2131   if test "x${have_ecore_evas_software_x11}" = "xyes" ; then
2132     echo "    Software X11...............: $have_ecore_evas_software_x11 (Xlib=${have_ecore_evas_software_xlib}) (XCB=${have_ecore_evas_software_xcb})"
2133   else
2134     echo "    Software X11...............: $have_ecore_evas_software_x11"
2135   fi
2136   if test "x${have_ecore_evas_opengl_x11}" = "xyes" ; then
2137     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11 (Xlib=${have_ecore_evas_opengl_xlib}) (XCB=${have_ecore_evas_opengl_xcb})"
2138   else
2139     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11"
2140   fi
2141   echo "    Software GDI...............: $have_ecore_evas_software_gdi"
2142   echo "    Software DirectDraw........: $have_ecore_evas_software_ddraw"
2143   echo "    Direct3D...................: $have_ecore_evas_direct3d"
2144   echo "    OpenGL Glew................: $have_ecore_evas_opengl_glew"
2145   echo "    Software SDL...............: $have_ecore_evas_software_sdl"
2146   echo "    OpenGL SDL.................: $have_ecore_evas_opengl_sdl"
2147   echo "    OpenGL Cocoa...............: $have_ecore_evas_opengl_cocoa"
2148   echo "    DirectFB...................: $have_ecore_evas_directfb"
2149   echo "    PSL1GHT....................: $have_ecore_evas_psl1ght"
2150   echo "    Software Framebuffer.......: $have_ecore_evas_fb"
2151   echo "    Software 8bit grayscale XCB: $have_ecore_evas_software_8_x11"
2152   echo "    Software 16bit X11.........: $have_ecore_evas_software_16_x11"
2153   echo "    Software 16bit DirectDraw..: $have_ecore_evas_software_16_ddraw"
2154   echo "    Software 16bit WinCE.......: $have_ecore_evas_software_16_wince"
2155   echo "    Sing.Proc. Windowing System: $have_ecore_evas_ews"
2156   echo "    Wayland Shm................: $have_ecore_evas_wayland_shm"
2157   echo "    Wayland Egl................: $have_ecore_evas_wayland_egl"
2158   echo "    Extn (Plug/socket Extn)....: $have_ecore_evas_extn"
2159 fi
2160 echo
2161 echo "  Tests................: ${enable_tests}"
2162 echo "  Maximum log level....: ${with_max_log_level}"
2163 echo "Documentation..........: ${build_doc}"
2164 echo
2165 echo "Compilation............: make (or gmake)"
2166 echo "  CPPFLAGS.............: $CPPFLAGS"
2167 echo "  CFLAGS...............: $CFLAGS"
2168 echo "  CXXFLAGS.............: $CXXFLAGS"
2169 echo "  LDFLAGS..............: $LDFLAGS"
2170 echo
2171 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
2172 echo "  prefix...............: $prefix"
2173 echo