configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [229],
  24         [http://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(AARCH64, aarch64*)
  61
  62 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  64 AS_IF([test x"$intltool_found" != xyes],
  65       [AS_IF([test x"$enable_nls" = xyes],
  66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  67              [AS_IF([test x"$enable_nls" != xno],
  68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  69                      enable_nls=no])
  70              ])
  71       ])
  72
  73 AM_NLS
  74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  76 IT_PROG_INTLTOOL([0.40.0])
  77 ])
  78
  79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  82     AC_SUBST(INTLTOOL_POLICY_RULE)
  83 ])
  84
  85 GETTEXT_PACKAGE=systemd
  86 AC_SUBST(GETTEXT_PACKAGE)
  87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  88
  89 AC_PROG_MKDIR_P
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_GREP
  93 AC_PROG_AWK
  94
  95 AC_PATH_PROG([M4], [m4])
  96
  97 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  98 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
  99
 100 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap], [$PATH:/usr/sbin:/sbin])
 101
 102 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
 103
 104 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
 105
 106 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 107
 108 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 109
 110 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 111 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 112
 113 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 114
 115 M4_DEFINES=
 116
 117 AC_CHECK_TOOL(OBJCOPY, objcopy)
 118 AC_CHECK_TOOL(STRINGS, strings)
 119 AC_CHECK_TOOL(GPERF, gperf)
 120 if test -z "$GPERF" ; then
 121         AC_MSG_ERROR([*** gperf not found])
 122 fi
 123
 124 # ------------------------------------------------------------------------------
 125 address_sanitizer_cflags=
 126 address_sanitizer_cppflags=
 127 address_sanitizer_ldflags=
 128 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 129 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 130             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 131             AS_IF([test -z "$with_as_cflags"],
 132                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 133             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 134             address_sanitizer_cppflags="-DVALGRIND=1"
 135             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 136       ])
 137
 138 undefined_sanitizer_cflags=
 139 undefined_sanitizer_cppflags=
 140 undefined_sanitizer_ldflags=
 141 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 142 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 143             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 144             AS_IF([test -z "$with_us_cflags"],
 145                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 146             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 147             undefined_sanitizer_cppflags="-DVALGRIND=1"
 148             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 149       ])
 150
 151 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 152 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 153 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 154
 155 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 156         -pipe \
 157         -Wall \
 158         -Wextra \
 159         -Wundef \
 160         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 161         -Wlogical-op \
 162         -Wmissing-include-dirs \
 163         -Wold-style-definition \
 164         -Wpointer-arith \
 165         -Winit-self \
 166         -Wdeclaration-after-statement \
 167         -Wfloat-equal \
 168         -Wsuggest-attribute=noreturn \
 169         -Werror=missing-prototypes \
 170         -Werror=implicit-function-declaration \
 171         -Werror=missing-declarations \
 172         -Werror=return-type \
 173         -Wstrict-prototypes \
 174         -Wredundant-decls \
 175         -Wmissing-noreturn \
 176         -Wshadow \
 177         -Wendif-labels \
 178         -Wstrict-aliasing=2 \
 179         -Wwrite-strings \
 180         -Wno-unused-parameter \
 181         -Wno-missing-field-initializers \
 182         -Wno-unused-result \
 183         -Wno-format-signedness \
 184         -Werror=overflow \
 185         -Wdate-time \
 186         -Wnested-externs \
 187         -ffast-math \
 188         -fno-common \
 189         -fdiagnostics-show-option \
 190         -fno-strict-aliasing \
 191         -fvisibility=hidden \
 192         -fstack-protector \
 193         -fstack-protector-strong \
 194         -fPIE \
 195         --param=ssp-buffer-size=4])
 196
 197 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
 198 #include <time.h>
 199 #include <inttypes.h>
 200 typedef uint64_t usec_t;
 201 usec_t now(clockid_t clock);
 202 int main(void) {
 203         struct timespec now;
 204         return 0;
 205 }
 206 ])
 207
 208 AS_CASE([$CC], [*clang*],
 209         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 210                -Wno-typedef-redefinition \
 211                -Wno-gnu-variable-sized-type-not-at-end \
 212         ])])
 213
 214 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 215         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 216                -flto])],
 217         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 218 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 219
 220 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 221         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 222                -Wp,-D_FORTIFY_SOURCE=2])],
 223         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 224 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 225
 226 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 227         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 228                -Wl,--gc-sections])],
 229         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 230 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 231
 232 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 233         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 234                -ffunction-sections -fdata-sections])],
 235         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 236 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 237
 238 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 239         -Wl,--as-needed \
 240         -Wl,--no-undefined \
 241         -Wl,-z,relro \
 242         -Wl,-z,now \
 243         -pie \
 244         -Wl,-fuse-ld=gold])
 245 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 246
 247 AC_CHECK_SIZEOF(pid_t)
 248 AC_CHECK_SIZEOF(uid_t)
 249 AC_CHECK_SIZEOF(gid_t)
 250 AC_CHECK_SIZEOF(time_t)
 251 AC_CHECK_SIZEOF(dev_t)
 252 AC_CHECK_SIZEOF(rlim_t,,[
 253        #include <sys/time.h>
 254        #include <sys/resource.h>
 255 ])
 256
 257 # ------------------------------------------------------------------------------
 258 # we use python to build the man page index
 259 have_python=no
 260 AC_ARG_WITH([python],
 261         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 262
 263 have_lxml=no
 264 AS_IF([test "x$with_python" != "xno"], [
 265         AM_PATH_PYTHON(,, [:])
 266         AS_IF([test "x$PYTHON" != "x:"], [
 267                 AC_MSG_CHECKING([for python lxml module])
 268                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 269                 AC_MSG_RESULT([$have_lxml])
 270                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 271                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 272         ])
 273 ])
 274 AS_IF([test "$have_python" != "yes"], [
 275       AS_IF([test "$with_python" = "yes"],
 276             [AC_MSG_ERROR([*** python support requested but python support not found])])
 277       AS_IF([test "$with_python" != "no"],
 278             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 279 ])
 280 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 281
 282 # ------------------------------------------------------------------------------
 283
 284 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 285 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 286 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 287
 288 # unconditionally pull-in librt with old glibc versions
 289 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 290
 291 save_LIBS="$LIBS"
 292 LIBS=
 293 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 294 CAP_LIBS="$LIBS"
 295 LIBS="$save_LIBS"
 296 AC_SUBST(CAP_LIBS)
 297
 298 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 299 AC_CHECK_DECLS([
 300         memfd_create,
 301         gettid,
 302         pivot_root,
 303         name_to_handle_at,
 304         setns,
 305         getrandom,
 306         renameat2,
 307         kcmp,
 308         keyctl,
 309         LO_FLAGS_PARTSCAN,
 310         copy_file_range],
 311         [], [], [[
 312 #include <sys/types.h>
 313 #include <unistd.h>
 314 #include <sys/mount.h>
 315 #include <fcntl.h>
 316 #include <sched.h>
 317 #include <linux/loop.h>
 318 #include <linux/random.h>
 319 ]])
 320
 321 AC_CHECK_TYPES([char16_t, char32_t, key_serial_t],
 322                [], [], [[
 323 #include <uchar.h>
 324 ]])
 325
 326 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 327                 IFLA_MACVLAN_FLAGS,
 328                 IFLA_IPVLAN_MODE,
 329                 IFLA_VTI_REMOTE,
 330                 IFLA_PHYS_PORT_ID,
 331                 IFLA_BOND_AD_INFO,
 332                 IFLA_VLAN_PROTOCOL,
 333                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 334                 IFLA_IPTUN_ENCAP_DPORT,
 335                 IFLA_GRE_ENCAP_DPORT,
 336                 IFLA_BRIDGE_VLAN_INFO,
 337                 IFLA_BRPORT_PROXYARP,
 338                 IFLA_BRPORT_LEARNING_SYNC,
 339                 IFLA_BR_PRIORITY,
 340                 NDA_IFINDEX,
 341                 IFA_FLAGS],
 342 [], [], [[
 343 #include <inttypes.h>
 344 #include <netinet/in.h>
 345 #include <netinet/ether.h>
 346 #include <linux/rtnetlink.h>
 347 #include <net/if.h>
 348 #include <linux/ip.h>
 349 #include <linux/if_tunnel.h>
 350 #include <linux/if_link.h>
 351 #include <linux/if_bridge.h>
 352 #include <linux/if_addr.h>
 353 #include <linux/neighbour.h>
 354 ]])
 355
 356 # This makes sure pkg.m4 is available.
 357 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 358
 359 # ------------------------------------------------------------------------------
 360 have_dbus=no
 361 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 362 AS_IF([test "x$enable_dbus" != "xno"], [
 363         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 364                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 365                 [have_dbus=no])
 366         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 367                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 368 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 369
 370 # ------------------------------------------------------------------------------
 371 have_utmp=yes
 372 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 373         AS_CASE("x${enableval}",
 374                 [xyes], [have_utmp=yes],
 375                 [xno],  [have_utmp=no],
 376                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 377 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 378 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 379
 380 # ------------------------------------------------------------------------------
 381 have_coverage=no
 382 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 383 if test "x$enable_coverage" = "xyes" ; then
 384         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 385         if test "x$lcov_found" = xno ; then
 386                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 387         else
 388                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 389                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 390                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 391                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 392                 else
 393                         have_coverage=yes
 394                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 395                         -fprofile-arcs \
 396                         -ftest-coverage])
 397                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 398                 fi
 399         fi
 400 fi
 401 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 402
 403 # ------------------------------------------------------------------------------
 404 have_kmod=no
 405 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 406 if test "x$enable_kmod" != "xno"; then
 407         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 408         if test "x$have_kmod" = "xyes"; then
 409                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 410                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 411                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 412         fi
 413         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 414                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 415         fi
 416 fi
 417 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 418
 419 # ------------------------------------------------------------------------------
 420 have_xkbcommon=no
 421 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 422 if test "x$enable_xkbcommon" != "xno"; then
 423         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 424                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 425         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 426                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 427         fi
 428 fi
 429 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 430
 431 # ------------------------------------------------------------------------------
 432 have_blkid=no
 433 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 434 if test "x$enable_blkid" != "xno"; then
 435         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 436                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 437         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 438                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 439         fi
 440 fi
 441 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 442
 443 # ------------------------------------------------------------------------------
 444 have_libmount=no
 445 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.27 ],
 446         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 447 if test "x$have_libmount" = xno; then
 448         AC_MSG_ERROR([*** libmount support required but libraries not found])
 449 fi
 450 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 451
 452 # ------------------------------------------------------------------------------
 453 have_seccomp=no
 454 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 455 if test "x$enable_seccomp" != "xno"; then
 456         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 457                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 458                 have_seccomp=yes
 459                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 460                [have_seccomp=no])
 461         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 462                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 463         fi
 464 fi
 465 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 466
 467 # ------------------------------------------------------------------------------
 468 have_ima=yes
 469 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 470                 [case "${enableval}" in
 471                         yes) have_ima=yes ;;
 472                         no) have_ima=no ;;
 473                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 474                 esac],
 475                 [have_ima=yes])
 476
 477 if test "x${have_ima}" != xno ; then
 478         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 479 fi
 480
 481 # ------------------------------------------------------------------------------
 482 have_selinux=no
 483 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 484 if test "x$enable_selinux" != "xno"; then
 485         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 486                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 487                  have_selinux=yes
 488                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 489                 [have_selinux=no])
 490         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 491                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 492         fi
 493 fi
 494 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 495
 496 have_apparmor=no
 497 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 498 if test "x$enable_apparmor" != "xno"; then
 499         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 500                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 501                  have_apparmor=yes
 502                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 503                 [have_apparmor=no])
 504         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 505                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 506         fi
 507 fi
 508 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 509
 510 have_wheel_group=no
 511 AC_ARG_ENABLE(wheel-group, AS_HELP_STRING([--disable-wheel-group], [disable wheel group]))
 512 AS_IF([test "x$enable_wheel_group" != "xno"], [
 513         AC_DEFINE(ENABLE_WHEEL_GROUP, 1, [Define if the ACL for wheel group should be enabled])
 514         have_wheel_group=yes
 515         M4_DEFINES="$M4_DEFINES -DENABLE_WHEEL_GROUP"
 516 ])
 517
 518
 519 AC_ARG_WITH(debug-shell,
 520         AS_HELP_STRING([--with-debug-shell=PATH],
 521                 [Path to debug shell binary]),
 522         [SUSHELL="$withval"],[
 523         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 524
 525 AC_SUBST(SUSHELL)
 526
 527 AC_ARG_WITH([debug-tty],
 528         AS_HELP_STRING([--with-debug-tty=PATH],
 529                 [Specify the tty device for debug shell]),
 530         [DEBUGTTY="$withval"],
 531         [DEBUGTTY=/dev/tty9])
 532
 533 AC_SUBST(DEBUGTTY)
 534
 535 AC_ARG_WITH([certificate-root],
 536         AS_HELP_STRING([--with-certificate-root=PATH],
 537                 [Specify the prefix for TLS certificates [/etc/ssl]]),
 538         [CERTIFICATEROOT="$withval"],
 539         [CERTIFICATEROOT="/etc/ssl"])
 540
 541 AC_SUBST(CERTIFICATEROOT)
 542
 543 # ------------------------------------------------------------------------------
 544 have_xz=no
 545 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 546 AS_IF([test "x$enable_xz" != "xno"], [
 547         PKG_CHECK_MODULES(XZ, [ liblzma ],
 548                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available])
 549                  have_xz=yes],
 550                  have_xz=no)
 551         AS_IF([test "x$have_xz" = xno -a "x$enable_xz" = xyes],
 552               [AC_MSG_ERROR([*** XZ support requested but libraries not found])])
 553 ])
 554 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 555
 556 # ------------------------------------------------------------------------------
 557 have_zlib=no
 558 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [Disable optional ZLIB support]))
 559 AS_IF([test "x$enable_zlib" != "xno"], [
 560         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 561                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available])
 562                  have_zlib=yes],
 563                  have_zlib=no)
 564         AS_IF([test "x$have_zlib" = xno -a "x$enable_zlib" = xyes],
 565               [AC_MSG_ERROR([*** ZLIB support requested but libraries not found])])
 566 ])
 567 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 568
 569 # ------------------------------------------------------------------------------
 570 have_bzip2=no
 571 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--enable-bzip2], [Enable optional BZIP2 support]))
 572 AS_IF([test "x$enable_bzip2" != "xno"], [
 573         AC_CHECK_HEADERS(bzlib.h,
 574                 [AC_DEFINE(HAVE_BZIP2, 1, [Define if BZIP2 is available])
 575                  have_bzip2=yes],
 576                 [AS_IF([test "x$enable_bzip2" = xyes],
 577                        [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])]
 578         )
 579 ])
 580 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 581
 582 # ------------------------------------------------------------------------------
 583 have_lz4=no
 584 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--disable-lz4], [Disable optional LZ4 support]))
 585 AS_IF([test "x$enable_lz4" != "xno"], [
 586         PKG_CHECK_MODULES(LZ4, [ liblz4 >= 125 ],
 587                [AC_DEFINE(HAVE_LZ4, 1, [Define in LZ4 is available])
 588                 have_lz4=yes],
 589                 have_lz4=no)
 590         AS_IF([test "x$have_lz4" = xno -a "x$enable_lz4" = xyes],
 591               [AC_MSG_ERROR([*** LZ4 support requested but libraries not found])])
 592 ])
 593 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 594
 595 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 596
 597 # ------------------------------------------------------------------------------
 598 AC_ARG_ENABLE([pam],
 599         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 600                 [case "${enableval}" in
 601                         yes) have_pam=yes ;;
 602                         no) have_pam=no ;;
 603                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 604                 esac],
 605                 [have_pam=auto])
 606
 607 if test "x${have_pam}" != xno ; then
 608         AC_CHECK_HEADERS(
 609                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 610                 [have_pam=yes],
 611                 [if test "x$have_pam" = xyes ; then
 612                         AC_MSG_ERROR([*** PAM headers not found.])
 613                 fi])
 614
 615         AC_CHECK_LIB(
 616                 [pam],
 617                 [pam_syslog],
 618                 [have_pam=yes],
 619                 [if test "x$have_pam" = xyes ; then
 620                         AC_MSG_ERROR([*** libpam not found.])
 621                 fi])
 622
 623         if test "x$have_pam" = xyes ; then
 624                 PAM_LIBS="-lpam -lpam_misc"
 625                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 626                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 627         else
 628                 have_pam=no
 629         fi
 630 else
 631         PAM_LIBS=
 632 fi
 633 AC_SUBST(PAM_LIBS)
 634 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 635
 636 # ------------------------------------------------------------------------------
 637 AC_ARG_ENABLE([acl],
 638         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 639                 [case "${enableval}" in
 640                         yes) have_acl=yes ;;
 641                         no) have_acl=no ;;
 642                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 643                 esac],
 644                 [have_acl=auto])
 645
 646 if test "x${have_acl}" != xno ; then
 647         AC_CHECK_HEADERS(
 648                 [sys/acl.h acl/libacl.h],
 649                 [have_acl=yes],
 650                 [if test "x$have_acl" = xyes ; then
 651                         AC_MSG_ERROR([*** ACL headers not found.])
 652                 fi])
 653
 654         AC_CHECK_LIB(
 655                 [acl],
 656                 [acl_get_file],
 657                 [have_acl=yes],
 658                 [if test "x$have_acl" = xyes ; then
 659                         AC_MSG_ERROR([*** libacl not found.])
 660                 fi])
 661
 662         if test "x$have_acl" = xyes ; then
 663                 ACL_LIBS="-lacl"
 664                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 665                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 666         else
 667                 have_acl=no
 668         fi
 669 else
 670         ACL_LIBS=
 671 fi
 672 AC_SUBST(ACL_LIBS)
 673 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 674
 675 # ------------------------------------------------------------------------------
 676 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 677                 [case "${enableval}" in
 678                         yes) have_smack=yes ;;
 679                         no) have_smack=no ;;
 680                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 681                 esac],
 682                 [have_smack=auto])
 683
 684 if test "x${have_smack}" != xno; then
 685         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 686         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 687         have_smack=yes
 688 fi
 689
 690 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 691
 692 have_smack_run_label=no
 693 AC_ARG_WITH(smack-run-label,
 694 AS_HELP_STRING([--with-smack-run-label=STRING],
 695         [run systemd --system itself with a specific SMACK label]),
 696         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
 697         [])
 698
 699 if test "x${have_smack_run_label}" = xyes; then
 700         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
 701 fi
 702
 703 AC_ARG_WITH(smack-default-process-label,
 704 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 705         [default SMACK label for executed processes]),
 706         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 707         [])
 708
 709 # ------------------------------------------------------------------------------
 710 AC_ARG_ENABLE([gcrypt],
 711         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 712                 [case "${enableval}" in
 713                         yes) have_gcrypt=yes ;;
 714                         no) have_gcrypt=no ;;
 715                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 716                 esac],
 717                 [have_gcrypt=auto])
 718
 719 if test "x${have_gcrypt}" != xno ; then
 720         m4_define([AM_PATH_LIBGCRYPT_FAIL],
 721                 [{ test "x$have_gcrypt" != xyes || AC_MSG_ERROR([*** GCRYPT/GPG-ERROR headers not found.]); }]
 722         )
 723         m4_ifdef([AM_PATH_LIBGCRYPT], [AM_PATH_LIBGCRYPT(
 724                         [1.4.5],
 725                         [have_gcrypt=yes],
 726                         dnl  If we have the gcrypt m4 macros, but don't have
 727                         dnl  gcrypt, throw an error if gcrypt is explicitly
 728                         dnl  requested.
 729                         [AM_PATH_LIBGCRYPT_FAIL]
 730                 )],
 731                 dnl  If we don't have the gcrypt m4 macros, but build with
 732                 dnl  gcrypt explicitly requested, throw an error.
 733                 [AM_PATH_LIBGCRYPT_FAIL]
 734         )
 735
 736         have_gpg_error=no
 737         m4_ifdef([AM_PATH_GPG_ERROR], [AM_PATH_GPG_ERROR(
 738                         [1.12],
 739                         [have_gpg_error=yes],
 740                         [AM_PATH_LIBGCRYPT_FAIL]
 741                 )],
 742                 [AM_PATH_LIBGCRYPT_FAIL]
 743         )
 744
 745         if test "x$have_gcrypt" = xyes -a "x$have_gpg_error" = xyes ; then
 746                 GCRYPT_LIBS="$LIBGCRYPT_LIBS $GPG_ERROR_LIBS"
 747                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS $GPG_ERROR_CFLAGS"
 748                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 749         else
 750                 have_gcrypt=no
 751                 have_gpg_error=no
 752         fi
 753 else
 754         GCRYPT_LIBS=
 755         GCRYPT_CFLAGS=
 756 fi
 757 AC_SUBST(GCRYPT_LIBS)
 758 AC_SUBST(GCRYPT_CFLAGS)
 759 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 760
 761 # ------------------------------------------------------------------------------
 762 AC_ARG_ENABLE([audit],
 763         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 764                 [case "${enableval}" in
 765                         yes) have_audit=yes ;;
 766                         no) have_audit=no ;;
 767                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 768                 esac],
 769                 [have_audit=auto])
 770
 771 if test "x${have_audit}" != xno ; then
 772         AC_CHECK_HEADERS(
 773                 [libaudit.h],
 774                 [have_audit=yes],
 775                 [if test "x$have_audit" = xyes ; then
 776                         AC_MSG_ERROR([*** AUDIT headers not found.])
 777                 fi])
 778
 779         AC_CHECK_LIB(
 780                 [audit],
 781                 [audit_open],
 782                 [have_audit=yes],
 783                 [if test "x$have_audit" = xyes ; then
 784                         AC_MSG_ERROR([*** libaudit not found.])
 785                 fi])
 786
 787         if test "x$have_audit" = xyes ; then
 788                 AUDIT_LIBS="-laudit"
 789                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 790         else
 791                 have_audit=no
 792         fi
 793 else
 794         AUDIT_LIBS=
 795 fi
 796 AC_SUBST(AUDIT_LIBS)
 797 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 798
 799 # ------------------------------------------------------------------------------
 800 AC_ARG_ENABLE([elfutils],
 801         AS_HELP_STRING([--disable-elfutils],[Disable optional ELFUTILS support]),
 802                 [case "${enableval}" in
 803                         yes) have_elfutils=yes ;;
 804                         no) have_elfutils=no ;;
 805                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 806                 esac],
 807                 [have_elfutils=auto])
 808
 809 if test "x${have_elfutils}" != xno ; then
 810         AC_CHECK_HEADERS(
 811                 [elfutils/libdwfl.h],
 812                 [],
 813                 [if test "x$have_elfutils" = xyes ; then
 814                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 815                 fi])
 816
 817         AC_CHECK_LIB(
 818                 [dw],
 819                 [dwfl_core_file_attach],
 820                 [have_elfutils=yes],
 821                 [if test "x$have_elfutils" = xyes ; then
 822                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 823                 fi])
 824
 825         if test "x$have_elfutils" = xyes ; then
 826                 ELFUTILS_LIBS="-lelf -ldw"
 827                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 828         else
 829                 have_elfutils=no
 830         fi
 831 else
 832         ELFUTILS_LIBS=
 833 fi
 834 AC_SUBST(ELFUTILS_LIBS)
 835 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 836
 837 # ------------------------------------------------------------------------------
 838 have_libcryptsetup=no
 839 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 840 if test "x$enable_libcryptsetup" != "xno"; then
 841         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 842                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 843         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 844                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 845         fi
 846 fi
 847 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 848
 849 # ------------------------------------------------------------------------------
 850 have_qrencode=no
 851 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 852 if test "x$enable_qrencode" != "xno"; then
 853         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 854                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 855         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 856                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 857         fi
 858 fi
 859 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 860
 861 # ------------------------------------------------------------------------------
 862 have_gnutls=no
 863 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 864 if test "x$enable_gnutls" != "xno"; then
 865         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 866                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 867         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 868                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 869         fi
 870 fi
 871 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 872
 873 # ------------------------------------------------------------------------------
 874 have_microhttpd=no
 875 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 876 if test "x$enable_microhttpd" != "xno"; then
 877         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 878                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available])
 879                  have_microhttpd=yes
 880                  M4_DEFINES="$M4_DEFINES -DHAVE_MICROHTTPD"],
 881                 [have_microhttpd=no])
 882         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 883                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 884         fi
 885 fi
 886 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 887
 888 # ------------------------------------------------------------------------------
 889 have_libcurl=no
 890 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
 891 if test "x$enable_libcurl" != "xno"; then
 892         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.32.0],
 893                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available])
 894                  have_libcurl=yes
 895                  M4_DEFINES="$M4_DEFINES -DHAVE_LIBCURL"],
 896                 [have_libcurl=no])
 897         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
 898                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
 899         fi
 900 fi
 901 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 902
 903 # ------------------------------------------------------------------------------
 904 AM_CONDITIONAL(HAVE_REMOTE, [test "$have_microhttpd" = "yes" -o "$have_libcurl" = "yes"])
 905
 906 # ------------------------------------------------------------------------------
 907 have_libidn=no
 908 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [Disable optional LIBIDN support]))
 909 if test "x$enable_libidn" != "xno"; then
 910         PKG_CHECK_MODULES(LIBIDN, [libidn],
 911                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
 912                 have_libidn=yes
 913                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
 914                [have_libidn=no])
 915         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
 916                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
 917         fi
 918 fi
 919 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
 920
 921 # ------------------------------------------------------------------------------
 922 have_libiptc=no
 923 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [Disable optional LIBIPTC support]))
 924 if test "x$enable_libiptc" != "xno"; then
 925         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
 926                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
 927                 have_libiptc=yes
 928                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
 929                [have_libiptc=no])
 930         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
 931                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
 932         fi
 933 fi
 934 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
 935
 936 # ------------------------------------------------------------------------------
 937 have_binfmt=no
 938 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 939 if test "x$enable_binfmt" != "xno"; then
 940         have_binfmt=yes
 941 fi
 942 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 943
 944 # ------------------------------------------------------------------------------
 945 have_vconsole=no
 946 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 947 if test "x$enable_vconsole" != "xno"; then
 948         have_vconsole=yes
 949 fi
 950 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 951
 952 # ------------------------------------------------------------------------------
 953 have_quotacheck=no
 954 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 955 if test "x$enable_quotacheck" != "xno"; then
 956         have_quotacheck=yes
 957 fi
 958 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 959
 960 # ------------------------------------------------------------------------------
 961 have_tmpfiles=no
 962 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 963 if test "x$enable_tmpfiles" != "xno"; then
 964         have_tmpfiles=yes
 965 fi
 966 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 967
 968 # ------------------------------------------------------------------------------
 969 have_sysusers=no
 970 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
 971 if test "x$enable_sysusers" != "xno"; then
 972         have_sysusers=yes
 973 fi
 974 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
 975
 976 # ------------------------------------------------------------------------------
 977 have_firstboot=no
 978 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
 979 if test "x$enable_firstboot" != "xno"; then
 980         have_firstboot=yes
 981 fi
 982 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
 983
 984 # ------------------------------------------------------------------------------
 985 have_randomseed=no
 986 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 987 if test "x$enable_randomseed" != "xno"; then
 988         have_randomseed=yes
 989 fi
 990 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 991
 992 # ------------------------------------------------------------------------------
 993 have_backlight=no
 994 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
 995 if test "x$enable_backlight" != "xno"; then
 996         have_backlight=yes
 997 fi
 998 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
 999
1000 # ------------------------------------------------------------------------------
1001 have_rfkill=no
1002 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
1003 if test "x$enable_rfkill" != "xno"; then
1004         have_rfkill=yes
1005 fi
1006 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
1007
1008 # ------------------------------------------------------------------------------
1009 have_logind=no
1010 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
1011 if test "x$enable_logind" != "xno"; then
1012         have_logind=yes
1013 fi
1014 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
1015 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
1016
1017 # ------------------------------------------------------------------------------
1018 have_machined=no
1019 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
1020 if test "x$enable_machined" != "xno"; then
1021         have_machined=yes
1022         AC_DEFINE(HAVE_MACHINED, [1], [systemd-machined is enabled])
1023 fi
1024 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
1025
1026 # ------------------------------------------------------------------------------
1027 have_importd=no
1028 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
1029 if test "x$enable_importd" != "xno"; then
1030         have_importd=yes
1031 fi
1032 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
1033 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
1034
1035 # ------------------------------------------------------------------------------
1036 have_hostnamed=no
1037 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
1038 if test "x$enable_hostnamed" != "xno"; then
1039         have_hostnamed=yes
1040 fi
1041 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
1042
1043 # ------------------------------------------------------------------------------
1044 have_timedated=no
1045 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1046 if test "x$enable_timedated" != "xno"; then
1047         have_timedated=yes
1048 fi
1049 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1050
1051 # ------------------------------------------------------------------------------
1052 have_timesyncd=no
1053 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1054 if test "x$enable_timesyncd" != "xno"; then
1055         have_timesyncd=yes
1056         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1057 fi
1058 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1059
1060 AC_ARG_WITH(ntp-servers,
1061         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1062                 [Space-separated list of default NTP servers]),
1063         [NTP_SERVERS="$withval"],
1064         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"
1065         AC_MSG_WARN([*** Using Google NTP servers.
1066                         Do not ship OSes or devices with these default settings.
1067                         See DISTRO_PORTING for details!])])
1068
1069 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1070 AC_SUBST(NTP_SERVERS)
1071
1072 AC_ARG_WITH(time-epoch,
1073         AS_HELP_STRING([--with-time-epoch=SECONDS],
1074                 [Time epoch for time clients]),
1075         [TIME_EPOCH="$withval"],
1076         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1077
1078 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1079
1080 # ------------------------------------------------------------------------------
1081 AC_ARG_WITH(system-uid-max,
1082         AS_HELP_STRING([--with-system-uid-max=UID]
1083                 [Maximum UID for system users]),
1084         [SYSTEM_UID_MAX="$withval"],
1085         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1086
1087 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1088 AC_SUBST(SYSTEM_UID_MAX)
1089
1090 # ------------------------------------------------------------------------------
1091 AC_ARG_WITH(system-gid-max,
1092         AS_HELP_STRING([--with-system-gid-max=GID]
1093                 [Maximum GID for system groups]),
1094         [SYSTEM_GID_MAX="$withval"],
1095         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1096
1097 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1098 AC_SUBST(SYSTEM_GID_MAX)
1099
1100 # ------------------------------------------------------------------------------
1101 have_localed=no
1102 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1103 if test "x$enable_localed" != "xno"; then
1104         have_localed=yes
1105 fi
1106 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1107
1108 # ------------------------------------------------------------------------------
1109 have_coredump=no
1110 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1111 if test "x$enable_coredump" != "xno"; then
1112         have_coredump=yes
1113         M4_DEFINES="$M4_DEFINES -DENABLE_COREDUMP"
1114 fi
1115 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1116
1117 # ------------------------------------------------------------------------------
1118 have_polkit=no
1119 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1120 if test "x$enable_polkit" != "xno"; then
1121         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1122         have_polkit=yes
1123 fi
1124 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1125
1126 # ------------------------------------------------------------------------------
1127 have_resolved=no
1128 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1129 AS_IF([test "x$enable_resolved" != "xno"], [
1130         AC_CHECK_LIB([dl], [dlsym], [true], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
1131
1132         have_resolved=yes
1133         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1134         AC_DEFINE(HAVE_RESOLVED, [1], [systemd-resolved is enabled])
1135 ])
1136 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1137
1138 AC_ARG_WITH(dns-servers,
1139         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1140                 [Space-separated list of default DNS servers]),
1141         [DNS_SERVERS="$withval"],
1142         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1143
1144 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1145 AC_SUBST(DNS_SERVERS)
1146
1147 AC_ARG_WITH(default-dnssec,
1148         AS_HELP_STRING([--with-default-dnssec=MODE],
1149                [Default DNSSEC mode, defaults to "allow-downgrade"]),
1150         [DEFAULT_DNSSEC_MODE="$withval"],
1151         [DEFAULT_DNSSEC_MODE="allow-downgrade"])
1152
1153 AS_CASE("x${DEFAULT_DNSSEC_MODE}",
1154         [xno], [mode=DNSSEC_NO],
1155         [xyes], [mode=DNSSEC_YES],
1156         [xallow-downgrade], [mode=DNSSEC_ALLOW_DOWNGRADE],
1157         AC_MSG_ERROR(Bad DNSSEC mode ${DEFAULT_DNSSEC_MODE}))
1158 AC_DEFINE_UNQUOTED(DEFAULT_DNSSEC_MODE, [$mode], [Default DNSSEC mode])
1159 AC_SUBST(DEFAULT_DNSSEC_MODE)
1160
1161 # ------------------------------------------------------------------------------
1162 have_networkd=no
1163 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1164 AS_IF([test "x$enable_networkd" != "xno"], [
1165         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1166         have_networkd=yes
1167         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1168 ])
1169 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1170
1171 # ------------------------------------------------------------------------------
1172 have_efi=no
1173 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
1174 if test "x$enable_efi" != "xno"; then
1175         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
1176         have_efi=yes
1177 fi
1178 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1179
1180 # ------------------------------------------------------------------------------
1181 AC_CHECK_TOOL(EFI_CC, gcc)
1182
1183 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1184
1185 AM_COND_IF(ARCH_IA32, [
1186         EFI_ARCH=ia32
1187         EFI_MACHINE_TYPE_NAME=ia32])
1188
1189 AM_COND_IF(ARCH_X86_64, [
1190         EFI_MACHINE_TYPE_NAME=x64])
1191
1192 AM_COND_IF(ARCH_AARCH64, [
1193         EFI_MACHINE_TYPE_NAME=aa64])
1194
1195 AC_SUBST([EFI_ARCH])
1196 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1197
1198 have_gnuefi=no
1199 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [Enable optional gnuefi support]))
1200 AS_IF([test "x$enable_gnuefi" != "xno"], [
1201         AC_CHECK_HEADERS(efi/${EFI_ARCH}/efibind.h,
1202                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1203                  have_gnuefi=yes],
1204                 [AS_IF([test "x$enable_gnuefi" = xyes],
1205                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1206         ])
1207
1208         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1209
1210         EFI_LIB_DIR="$efiroot"
1211         AC_ARG_WITH(efi-libdir,
1212                 AS_HELP_STRING([--with-efi-libdir=PATH], [Path to EFI lib directory]),
1213                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1214         )
1215         AC_SUBST([EFI_LIB_DIR])
1216
1217         have_efi_lds=no
1218         AC_ARG_WITH(efi-ldsdir,
1219                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [Path to EFI lds directory]),
1220                 [EFI_LDS_DIR="$withval" && AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1221                         [have_efi_lds=yes])],
1222                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1223                         [AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1224                                        [have_efi_lds=yes && break])])])
1225         AS_IF([test "x$have_efi_lds" = xyes],
1226               [AC_SUBST([EFI_LDS_DIR])],
1227               [AS_IF([test "x$enable_gnuefi" = xyes],
1228                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1229                      [have_gnuefi=no])])
1230
1231         AC_ARG_WITH(efi-includedir,
1232                 AS_HELP_STRING([--with-efi-includedir=PATH], [Path to EFI include directory]),
1233                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1234         )
1235         AC_SUBST([EFI_INC_DIR])
1236 ])
1237 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1238
1239 # ------------------------------------------------------------------------------
1240 have_tpm=no
1241 AC_ARG_ENABLE([tpm], AS_HELP_STRING([--enable-tpm],[Enable optional TPM support]),
1242                 [case "${enableval}" in
1243                         yes) have_tpm=yes ;;
1244                         no) have_tpm=no ;;
1245                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tpm) ;;
1246                 esac],
1247                 [have_tpm=no])
1248
1249 if test "x${have_tpm}" != xno ; then
1250         AC_DEFINE(SD_BOOT_LOG_TPM, 1, [Define if TPM should be used to log events and extend the registers])
1251 fi
1252
1253 AC_ARG_WITH(tpm-pcrindex,
1254         AS_HELP_STRING([--with-tpm-pcrindex=<NUM>],
1255                 [TPM PCR register number to use]),
1256         [SD_TPM_PCR="$withval"],
1257         [SD_TPM_PCR="8"])
1258
1259 AC_DEFINE_UNQUOTED(SD_TPM_PCR, [$SD_TPM_PCR], [TPM PCR register number to use])
1260
1261 # ------------------------------------------------------------------------------
1262 have_kdbus=no
1263 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
1264 if test "x$enable_kdbus" != "xno"; then
1265         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
1266         have_kdbus=yes
1267         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
1268 fi
1269 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
1270
1271 # ------------------------------------------------------------------------------
1272 AC_ARG_WITH(rc-local-script-path-start,
1273         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1274                 [Path to /etc/rc.local]),
1275         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1276         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1277
1278 AC_ARG_WITH(rc-local-script-path-stop,
1279         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1280                 [Path to /usr/sbin/halt.local]),
1281         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1282         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1283
1284 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1285 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1286
1287 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1288 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1289
1290 # ------------------------------------------------------------------------------
1291 AC_ARG_WITH(kbd-loadkeys,
1292         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1293                 [Path to loadkeys]),
1294         [KBD_LOADKEYS="$withval"],
1295         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1296
1297 AC_ARG_WITH(kbd-setfont,
1298         AS_HELP_STRING([--with-kbd-setfont=PATH],
1299                 [Path to setfont]),
1300         [KBD_SETFONT="$withval"],
1301         [KBD_SETFONT="/usr/bin/setfont"])
1302
1303 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1304 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1305
1306 AC_SUBST(KBD_LOADKEYS)
1307 AC_SUBST(KBD_SETFONT)
1308
1309 AC_ARG_WITH(telinit,
1310         AS_HELP_STRING([--with-telinit=PATH],
1311                 [Path to telinit]),
1312         [TELINIT="$withval"],
1313         [TELINIT="/lib/sysvinit/telinit"])
1314
1315 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1316
1317 AC_SUBST(TELINIT)
1318
1319 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1320
1321 # ------------------------------------------------------------------------------
1322 have_myhostname=no
1323 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1324 if test "x$enable_myhostname" != "xno"; then
1325         AC_HEADER_STDC
1326         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1327
1328         AC_C_CONST
1329         AC_TYPE_SIZE_T
1330         AC_HEADER_TIME
1331
1332         AC_FUNC_SELECT_ARGTYPES
1333         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1334
1335         have_myhostname=yes
1336         AC_DEFINE(HAVE_MYHOSTNAME, [1], [nss-myhostname is enabled])
1337 fi
1338 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1339
1340 # ------------------------------------------------------------------------------
1341 AC_ARG_ENABLE(hwdb, [AC_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1342        enable_hwdb=$enableval, enable_hwdb=yes)
1343 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1344
1345 # ------------------------------------------------------------------------------
1346 have_manpages=no
1347 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1348 AC_PATH_PROG([XSLTPROC], [xsltproc])
1349 AS_IF([test "x$enable_manpages" != xno], [
1350        have_manpages=yes
1351        AS_IF([test -z "$XSLTPROC"],
1352              AC_MSG_ERROR([*** xsltproc is required for man pages]))
1353 ])
1354 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1355
1356 # ------------------------------------------------------------------------------
1357 AC_ARG_ENABLE(hibernate,
1358        [AC_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1359        enable_hibernate=$enableval, enable_hibernate=yes)
1360 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1361
1362 # ------------------------------------------------------------------------------
1363 AC_ARG_ENABLE(ldconfig,
1364        [AC_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1365        enable_ldconfig=$enableval, enable_ldconfig=yes)
1366 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1367
1368 # ------------------------------------------------------------------------------
1369 # Location of the init scripts as mandated by LSB
1370 SYSTEM_SYSVINIT_PATH=/etc/init.d
1371 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1372
1373 AC_ARG_WITH([sysvinit-path],
1374         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1375                 [Specify the path to where the SysV init scripts are located])],
1376         [SYSTEM_SYSVINIT_PATH="$withval"],
1377         [])
1378
1379 AC_ARG_WITH([sysvrcnd-path],
1380         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1381                 [Specify the path to the base directory for the SysV rcN.d directories])],
1382         [SYSTEM_SYSVRCND_PATH="$withval"],
1383         [])
1384
1385 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1386         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1387         SYSTEM_SYSV_COMPAT="yes"
1388         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1389 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1390         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1391 else
1392         SYSTEM_SYSV_COMPAT="no"
1393 fi
1394
1395 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1396 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1397 AC_SUBST(M4_DEFINES)
1398
1399 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1400
1401 AC_ARG_WITH([tty-gid],
1402         [AS_HELP_STRING([--with-tty-gid=GID],
1403                 [Specify the numeric GID of the 'tty' group])],
1404         [TTY_GID="$withval"],
1405         [TTY_GID="5"])
1406
1407 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1408 AC_SUBST(TTY_GID)
1409
1410 AC_ARG_WITH([dbuspolicydir],
1411         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1412         [],
1413         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
1414 AX_NORMALIZE_PATH([with_dbuspolicydir])
1415
1416 AC_ARG_WITH([dbussessionservicedir],
1417         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1418         [],
1419         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1420 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1421
1422 AC_ARG_WITH([dbussystemservicedir],
1423         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1424         [],
1425         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1426 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1427
1428 AC_ARG_WITH([bashcompletiondir],
1429         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
1430         [],
1431         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1432                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1433         ] , [
1434                 with_bashcompletiondir=${datadir}/bash-completion/completions
1435         ])])
1436 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
1437 AX_NORMALIZE_PATH([with_bashcompletiondir])
1438
1439 AC_ARG_WITH([zshcompletiondir],
1440         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
1441         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1442 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
1443 AX_NORMALIZE_PATH([with_zshcompletiondir])
1444
1445 AC_ARG_WITH([rootprefix],
1446         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1447         [], [with_rootprefix=${ac_default_prefix}])
1448 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1449 # defaults those to ".", solve that here for now until we can find a suitable
1450 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1451 # See: https://github.com/systemd/systemd/issues/54
1452 if test "x${with_rootprefix}" = "x"; then
1453         with_rootprefix="/"
1454 fi
1455 AX_NORMALIZE_PATH([with_rootprefix])
1456
1457 AC_ARG_WITH([rootlibdir],
1458         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
1459         [],
1460         [with_rootlibdir=${libdir}])
1461 AX_NORMALIZE_PATH([with_rootlibdir])
1462
1463 AC_ARG_WITH([pamlibdir],
1464         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
1465         [],
1466         [with_pamlibdir=${with_rootlibdir}/security])
1467 AX_NORMALIZE_PATH([with_pamlibdir])
1468
1469 AC_ARG_WITH([pamconfdir],
1470         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
1471         [],
1472         [with_pamconfdir=${sysconfdir}/pam.d])
1473 AX_NORMALIZE_PATH([with_pamconfdir])
1474
1475 AC_ARG_ENABLE([split-usr],
1476         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
1477         [],
1478         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1479                 enable_split_usr=yes
1480         ], [
1481                 enable_split_usr=no
1482         ])])
1483
1484 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1485         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1486 ])
1487 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1488
1489 # work around intltool-update issues during 'make distcheck'
1490 AS_IF([test "x$0" != "x./configure"], [
1491         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1492 ])
1493
1494 # QEMU and OVMF UEFI firmware
1495 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1496         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1497         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1498                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1499         AC_SUBST([QEMU_BIOS])
1500 ])
1501
1502 AC_ARG_ENABLE(tests,
1503         [AC_HELP_STRING([--disable-tests], [disable tests, or enable extra tests with =unsafe])],
1504         enable_tests=$enableval, enable_tests=yes)
1505 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes -o x$enable_tests = xunsafe])
1506 AM_CONDITIONAL(ENABLE_UNSAFE_TESTS, [test x$enable_tests = xunsafe])
1507
1508 AC_ARG_ENABLE(debug,
1509         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1510         [if test "x$enableval" = "xyes"; then
1511                 enableval="hashmap,mmap-cache"
1512         fi
1513         saved_ifs="$IFS"
1514         IFS="$IFS$PATH_SEPARATOR,"
1515         for name in $enableval; do
1516                 case $name in
1517                 hashmap)
1518                         enable_debug_hashmap=yes
1519                         ;;
1520                 mmap-cache)
1521                         enable_debug_mmap_cache=yes
1522                         ;;
1523                 esac
1524         done
1525         IFS="$saved_ifs"],[])
1526
1527 enable_debug=""
1528 AS_IF([test x$enable_debug_hashmap = xyes], [
1529         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1530         enable_debug="hashmap $enable_debug"
1531 ])
1532 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1533         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1534         enable_debug="mmap-cache $enable_debug"
1535 ])
1536 test -z "$enable_debug" && enable_debug="none"
1537
1538 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1539 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1540 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1541 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1542 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1543 AC_SUBST([pamlibdir], [$with_pamlibdir])
1544 AC_SUBST([pamconfdir], [$with_pamconfdir])
1545 AC_SUBST([rootprefix], [$with_rootprefix])
1546 AC_SUBST([rootlibdir], [$with_rootlibdir])
1547
1548 AC_CONFIG_FILES([
1549         Makefile
1550         po/Makefile.in
1551 ])
1552
1553 AC_OUTPUT
1554 AC_MSG_RESULT([
1555         $PACKAGE_NAME $VERSION
1556
1557         libcryptsetup:           ${have_libcryptsetup}
1558         PAM:                     ${have_pam}
1559         AUDIT:                   ${have_audit}
1560         IMA:                     ${have_ima}
1561         AppArmor:                ${have_apparmor}
1562         SELinux:                 ${have_selinux}
1563         SECCOMP:                 ${have_seccomp}
1564         SMACK:                   ${have_smack}
1565         ZLIB:                    ${have_zlib}
1566         XZ:                      ${have_xz}
1567         LZ4:                     ${have_lz4}
1568         BZIP2:                   ${have_bzip2}
1569         ACL:                     ${have_acl}
1570         GCRYPT:                  ${have_gcrypt}
1571         QRENCODE:                ${have_qrencode}
1572         MICROHTTPD:              ${have_microhttpd}
1573         GNUTLS:                  ${have_gnutls}
1574         libcurl:                 ${have_libcurl}
1575         libidn:                  ${have_libidn}
1576         libiptc:                 ${have_libiptc}
1577         ELFUTILS:                ${have_elfutils}
1578         binfmt:                  ${have_binfmt}
1579         vconsole:                ${have_vconsole}
1580         quotacheck:              ${have_quotacheck}
1581         tmpfiles:                ${have_tmpfiles}
1582         sysusers:                ${have_sysusers}
1583         firstboot:               ${have_firstboot}
1584         randomseed:              ${have_randomseed}
1585         backlight:               ${have_backlight}
1586         rfkill:                  ${have_rfkill}
1587         logind:                  ${have_logind}
1588         machined:                ${have_machined}
1589         importd:                 ${have_importd}
1590         hostnamed:               ${have_hostnamed}
1591         timedated:               ${have_timedated}
1592         timesyncd:               ${have_timesyncd}
1593         Default NTP servers:     ${NTP_SERVERS}
1594         time epoch:              ${TIME_EPOCH}
1595         localed:                 ${have_localed}
1596         networkd:                ${have_networkd}
1597         resolved:                ${have_resolved}
1598         Default DNS servers:     ${DNS_SERVERS}
1599         Default DNSSEC mode:     ${DEFAULT_DNSSEC_MODE}
1600         coredump:                ${have_coredump}
1601         polkit:                  ${have_polkit}
1602         efi:                     ${have_efi}
1603         gnuefi:                  ${have_gnuefi}
1604         efi arch:                ${EFI_ARCH}
1605         EFI machine type:        ${EFI_MACHINE_TYPE_NAME}
1606         EFI CC                   ${EFI_CC}
1607         EFI libdir:              ${EFI_LIB_DIR}
1608         EFI ldsdir:              ${EFI_LDS_DIR}
1609         EFI includedir:          ${EFI_INC_DIR}
1610         kmod:                    ${have_kmod}
1611         xkbcommon:               ${have_xkbcommon}
1612         blkid:                   ${have_blkid}
1613         libmount:                ${have_libmount}
1614         dbus:                    ${have_dbus}
1615         nss-myhostname:          ${have_myhostname}
1616         hwdb:                    ${enable_hwdb}
1617         tpm:                     ${have_tpm}
1618         kdbus:                   ${have_kdbus}
1619         Python:                  ${have_python}
1620         man pages:               ${have_manpages}
1621         test coverage:           ${have_coverage}
1622         Split /usr:              ${enable_split_usr}
1623         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1624         utmp/wtmp support:       ${have_utmp}
1625         ldconfig support:        ${enable_ldconfig}
1626         hibernate support:       ${enable_hibernate}
1627         extra debugging:         ${enable_debug}
1628         tests:                   ${enable_tests}
1629
1630         prefix:                  ${prefix}
1631         rootprefix:              ${with_rootprefix}
1632         sysconf dir:             ${sysconfdir}
1633         datarootdir:             ${datarootdir}
1634         includedir:              ${includedir}
1635         lib dir:                 ${libdir}
1636         rootlib dir:             ${with_rootlibdir}
1637         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1638         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1639         Build Python:            ${PYTHON}
1640         PAM modules dir:         ${with_pamlibdir}
1641         PAM configuration dir:   ${with_pamconfdir}
1642         D-Bus policy dir:        ${with_dbuspolicydir}
1643         D-Bus session dir:       ${with_dbussessionservicedir}
1644         D-Bus system dir:        ${with_dbussystemservicedir}
1645         Bash completions dir:    ${with_bashcompletiondir}
1646         Zsh completions dir:     ${with_zshcompletiondir}
1647         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1648         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1649         Wheel group:             ${have_wheel_group}
1650         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1651         TTY GID:                 ${TTY_GID}
1652         Maximum System UID:      ${SYSTEM_UID_MAX}
1653         Maximum System GID:      ${SYSTEM_GID_MAX}
1654         Certificate root:        ${CERTIFICATEROOT}
1655
1656         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1657         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1658         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1659 ])