configure.ac

   1 dnl *******************************************
   2 dnl *** Initialize automake and set version ***
   3 dnl *******************************************
   4
   5 AC_PREREQ(2.63)
   6 AC_INIT([libsoup],[2.40.0],[http://bugzilla.gnome.org/enter_bug.cgi?product=libsoup])
   7 AC_CONFIG_SRCDIR([libsoup-2.4.pc.in])
   8 AC_CONFIG_MACRO_DIR([m4])
   9
  10 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz -Wno-portability])
  11 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  12
  13 AC_PROG_MAKE_SET
  14
  15 SOUP_API_VERSION=2.4
  16 AC_SUBST(SOUP_API_VERSION)
  17
  18 # Increment on interface addition. Reset on removal.
  19 SOUP_AGE=5
  20
  21 # Increment on interface add, remove, or change.
  22 SOUP_CURRENT=6
  23
  24 # Increment on source change. Reset when CURRENT changes.
  25 SOUP_REVISION=0
  26
  27 AC_SUBST(SOUP_CURRENT)
  28 AC_SUBST(SOUP_REVISION)
  29 AC_SUBST(SOUP_AGE)
  30
  31 dnl ***************************
  32 dnl *** Set debugging flags ***
  33 dnl ***************************
  34
  35 debug_default=minimum
  36
  37 # Declare --enable-* args and collect ac_help strings
  38 AC_ARG_ENABLE(debug,
  39               AS_HELP_STRING([--enable-debug=[no/minimum/yes]],
  40                              [turn on debugging (default=$debug_default)]),,
  41               enable_debug=$debug_default)
  42
  43 # Set the debug flags
  44 if test "x$enable_debug" = "xyes"; then
  45         test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  46         SOUP_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
  47 else
  48         if test "x$enable_debug" = "xno"; then
  49                 SOUP_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
  50         fi
  51 fi
  52
  53 AC_SUBST(SOUP_DEBUG_FLAGS)
  54
  55 # Set the maintainer flags
  56 #if test -d .git; then
  57 #       SOUP_MAINTAINER_FLAGS="-DG_DISABLE_DEPRECATED"
  58 #fi
  59 AC_SUBST(SOUP_MAINTAINER_FLAGS)
  60
  61 dnl ***************************
  62 dnl *** Checks for programs ***
  63 dnl ***************************
  64
  65 AC_PROG_CC
  66 AC_PROG_INSTALL
  67
  68 # Initialize libtool
  69 LT_INIT([win32-dll])
  70
  71 dnl ***********************
  72 dnl *** Checks for glib ***
  73 dnl ***********************
  74
  75 GLIB_REQUIRED=2.33.1
  76 AM_PATH_GLIB_2_0($GLIB_REQUIRED,,,gobject gio)
  77 if test "$GLIB_LIBS" = ""; then
  78    AC_MSG_ERROR(GLIB $GLIB_REQUIRED or later is required to build libsoup)
  79 fi
  80 GLIB_CFLAGS="$GLIB_CFLAGS -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_34"
  81
  82 GLIB_MAKEFILE='$(top_srcdir)/Makefile.glib'
  83 AC_SUBST(GLIB_MAKEFILE)
  84
  85 PKG_CHECK_MODULES(XML, libxml-2.0)
  86 AC_SUBST(XML_CFLAGS)
  87 AC_SUBST(XML_LIBS)
  88
  89 dnl ***********************
  90 dnl *** Check for Win32 ***
  91 dnl ***********************
  92
  93 AC_MSG_CHECKING([for Win32])
  94 case "$host" in
  95   *-*-mingw*)
  96     os_win32=yes
  97     CFLAGS="$CFLAGS -D_REENTRANT"
  98     ;;
  99   *)
 100     os_win32=no
 101     ;;
 102 esac
 103 AC_MSG_RESULT([$os_win32])
 104 AM_CONDITIONAL(OS_WIN32, [test $os_win32 = yes])
 105
 106 dnl ************************
 107 dnl *** gettext/intltool ***
 108 dnl ************************
 109 IT_PROG_INTLTOOL([0.35.0])
 110 GETTEXT_PACKAGE=libsoup
 111 AC_SUBST([GETTEXT_PACKAGE])
 112 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[The gettext domain name])
 113 AM_GLIB_GNU_GETTEXT
 114
 115 dnl *******************
 116 dnl *** Misc checks ***
 117 dnl *******************
 118 AC_CHECK_FUNCS(gmtime_r)
 119 AC_CHECK_FUNCS(mmap)
 120 AC_CHECK_FUNC(socket, , AC_CHECK_LIB(socket, socket))
 121
 122 dnl *********************
 123 dnl *** GNOME support ***
 124 dnl *********************
 125 AC_MSG_CHECKING(whether to build libsoup-gnome)
 126 AC_ARG_WITH(gnome,
 127             AS_HELP_STRING([--without-gnome], [Do not build libsoup-gnome]),
 128             :, [if test $os_win32 = yes; then with_gnome=no; else with_gnome=yes; fi])
 129 AC_MSG_RESULT($with_gnome)
 130
 131 if test $with_gnome != no -a $os_win32 != yes; then
 132         PKG_CHECK_MODULES(GNOME_KEYRING, gnome-keyring-1, :,
 133                           AC_MSG_ERROR(
 134 [Could not find gnome-keyring devel files.
 135 Configure with --without-gnome if you wish to build only libsoup
 136 without GNOME-specific features.]))
 137 fi
 138 AC_SUBST(GNOME_KEYRING_CFLAGS)
 139 AC_SUBST(GNOME_KEYRING_LIBS)
 140
 141 AM_CONDITIONAL(BUILD_LIBSOUP_GNOME, test $with_gnome != no)
 142
 143 if test $with_gnome != no; then
 144         AC_DEFINE(HAVE_GNOME, 1, [Defined if GNOME support is enabled])
 145
 146         PKG_CHECK_MODULES(SQLITE, sqlite3, :, [AC_MSG_ERROR(dnl
 147 [Could not find sqlite3 devel files:
 148
 149 $SQLITE_PKG_ERRORS
 150
 151 Pass "--without-gnome" to configure if you want to build libsoup
 152 without GNOME support.])])
 153 fi
 154 AC_SUBST(HAVE_GNOME)
 155 AC_SUBST(SQLITE_CFLAGS)
 156 AC_SUBST(SQLITE_LIBS)
 157
 158
 159 dnl ***************
 160 dnl *** gtk-doc ***
 161 dnl ***************
 162 GTK_DOC_CHECK([1.10])
 163
 164 dnl *****************************
 165 dnl *** gobject-introspection ***
 166 dnl *****************************
 167 GOBJECT_INTROSPECTION_CHECK([0.9.5])
 168
 169 AC_MSG_CHECKING([for glib-networking (glib TLS implementation)])
 170 save_CFLAGS="$CFLAGS"
 171 save_LIBS="$LIBS"
 172 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 173 LIBS="$LIBS $GLIB_LIBS"
 174 AC_RUN_IFELSE([AC_LANG_PROGRAM([#include <gio/gio.h>],
 175                                [g_type_init (); return !g_tls_backend_supports_tls (g_tls_backend_get_default ());])],
 176               [have_glib_networking=yes],
 177               [have_glib_networking=no],
 178               [have_glib_networking="unknown (cross-compiling)"])
 179 CFLAGS="$save_CFLAGS"
 180 LIBS="$save_LIBS"
 181 AC_MSG_RESULT($have_glib_networking)
 182
 183 AC_ARG_ENABLE(tls-check,
 184               AS_HELP_STRING([--disable-tls-check], [Don't error out if glib-networking is unavailable]))
 185 if test "$enable_tls_check" != "no" -a "$have_glib_networking" = "no"; then
 186         AC_MSG_ERROR([libsoup requires glib-networking for TLS support.
 187
 188 If you are building a package, you can pass --disable-tls-check to
 189 allow building libsoup anyway (since glib-networking is not actually
 190 required at compile time), but you should be sure to add a runtime
 191 dependency on it.])
 192 fi
 193
 194 dnl ******************************
 195 dnl *** Stuff for regression tests
 196 dnl ******************************
 197 AC_MSG_NOTICE([checking for programs needed for regression tests])
 198 MISSING_REGRESSION_TEST_PACKAGES=""
 199
 200 if test "$have_glib_networking" = "no"; then
 201         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES glib-networking"
 202 fi
 203
 204 AC_ARG_WITH(apache-httpd,
 205             AS_HELP_STRING([--with-apache-httpd], [Path to apache httpd (for tests)]),
 206             APACHE_HTTPD="$withval",
 207             [AC_PATH_PROGS(APACHE_HTTPD, httpd2 httpd apache2 apache, no, ${PATH}:/usr/sbin)])
 208 if test "$APACHE_HTTPD" != "no"; then
 209     AC_MSG_CHECKING([Apache version])
 210     apache_version=`$APACHE_HTTPD -v 2>/dev/null | sed -ne 's/Server version: Apache\///p'`
 211     case $apache_version in
 212     2.2.*)
 213         AC_MSG_RESULT([$apache_version (ok)])
 214         ;;
 215     *)
 216         AC_MSG_RESULT([$apache_version (ignoring)])
 217         APACHE_HTTPD="no"
 218         ;;
 219     esac
 220 fi
 221 AC_SUBST(APACHE_HTTPD)
 222 AC_DEFINE_UNQUOTED(APACHE_HTTPD, "$APACHE_HTTPD", [Apache httpd])
 223
 224 if test "$APACHE_HTTPD" != "no"; then
 225     AC_MSG_CHECKING([for Apache module directory])
 226     AC_ARG_WITH(apache-module-dir,
 227                 AS_HELP_STRING([--with-apache-module-dir], [Apache modules dirs (for tests)]),
 228                 apache_module_dirs="$withval",
 229                 [apache_prefix=`dirname \`dirname $APACHE_HTTPD\``
 230                 mpm=`$APACHE_HTTPD -V | sed -ne 's/^Server MPM: */-/p' | tr 'A-Z' 'a-z'`
 231                 # This only works with bash, but should fail harmlessly in sh
 232                 apache_module_dirs=`echo $apache_prefix/lib{64,}/{apache,apache2,http,http2,httpd}{$mpm,}{/modules,}`])
 233     for dir in $apache_module_dirs; do
 234         if test -f $dir/mod_auth_digest.so; then
 235             APACHE_MODULE_DIR="$dir"
 236         fi
 237         if test -f $dir/mod_ssl.so; then
 238             APACHE_SSL_MODULE_DIR="$dir"
 239             IF_HAVE_APACHE_SSL=""
 240         fi
 241         if test -f $dir/mod_php5.so; then
 242             APACHE_PHP_MODULE_DIR="$dir"
 243             APACHE_PHP_MODULE=mod_php5.so
 244         fi
 245         if test -f $dir/libphp5.so; then
 246             APACHE_PHP_MODULE_DIR="$dir"
 247             APACHE_PHP_MODULE=libphp5.so
 248         fi
 249     done
 250     AC_MSG_RESULT($APACHE_MODULE_DIR)
 251     AC_SUBST(APACHE_MODULE_DIR)
 252     AC_SUBST(APACHE_SSL_MODULE_DIR)
 253     AC_SUBST(APACHE_PHP_MODULE_DIR)
 254     AC_SUBST(APACHE_PHP_MODULE)
 255 fi
 256
 257 if test "$APACHE_HTTPD" != "no" -a -n "$APACHE_MODULE_DIR" -a -n "$APACHE_SSL_MODULE_DIR"; then
 258     AC_DEFINE(HAVE_APACHE, 1, [Whether or not apache can be used for tests])
 259     have_apache=1
 260     if test -z "$APACHE_PHP_MODULE_DIR"; then
 261         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES mod_php5"
 262     fi
 263 else
 264     have_apache=0
 265     if test "$APACHE_HTTPD" = "no" -o -z "$APACHE_MODULE_DIR"; then
 266         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES apache"
 267     else
 268         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES mod_ssl"
 269     fi
 270 fi
 271 AM_CONDITIONAL(HAVE_APACHE, test $have_apache = 1)
 272
 273 if test "$have_apache" = 1; then
 274     AC_CHECK_PROGS(PHP, php php5)
 275
 276     AC_MSG_CHECKING([for Apache PHP module])
 277     if test -f $APACHE_PHP_MODULE_DIR/$APACHE_PHP_MODULE; then
 278         have_php=yes
 279         IF_HAVE_PHP=""
 280     else
 281         have_php=no
 282         IF_HAVE_PHP="#"
 283         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES php5"
 284     fi
 285     AC_MSG_RESULT($have_php)
 286
 287     if test "$have_php" = yes; then
 288         AC_MSG_CHECKING([for xmlrpc-epi-php])
 289         if $PHP --rf xmlrpc_server_create | grep -q "does not exist"; then
 290             have_xmlrpc_epi_php=no
 291             MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES php-xmlrpc"
 292         else
 293             have_xmlrpc_epi_php=yes
 294         fi
 295         AC_MSG_RESULT($have_xmlrpc_epi_php)
 296     fi
 297 fi
 298
 299 AC_SUBST(IF_HAVE_PHP)
 300 AM_CONDITIONAL(HAVE_XMLRPC_EPI_PHP, test "$have_xmlrpc_epi_php" = yes)
 301
 302 AC_PATH_PROG(CURL, curl, no)
 303 if test "$CURL" != no; then
 304     AC_DEFINE(HAVE_CURL, 1, [Whether or not curl can be used for tests])
 305 else
 306     MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES curl"
 307 fi
 308 AM_CONDITIONAL(HAVE_CURL, test "$CURL" != no)
 309
 310 AC_SUBST(MISSING_REGRESSION_TEST_PACKAGES)
 311 AM_CONDITIONAL(MISSING_REGRESSION_TEST_PACKAGES, test -n "$MISSING_REGRESSION_TEST_PACKAGES")
 312
 313 dnl **********************************************************
 314 dnl *** path of NTLM single-sign-on helper ntlm_auth
 315 dnl **********************************************************
 316 AC_ARG_WITH(ntlm-auth,
 317             AC_HELP_STRING([--with-ntlm-auth=PATH],[Where to look for ntlm_auth, path points to ntlm_auth installation (default: /usr/bin/ntlm_auth)]),
 318             ntlm_auth="$withval",
 319             [if test $os_win32 = yes; then ntlm_auth="no"; else ntlm_auth="/usr/bin/ntlm_auth"; fi])
 320 if test "$ntlm_auth" != "no"; then
 321     AC_DEFINE(USE_NTLM_AUTH, 1, [Whether or not use Samba's 'winbind' daemon helper 'ntlm_auth' for NTLM single-sign-on])
 322     if test "$ntlm_auth" = "yes"; then
 323         dnl --with-ntlm-auth (without path) used, use default path
 324         ntlm_auth="/usr/bin/ntlm_auth"
 325     fi
 326 fi
 327 AC_SUBST(ntlm_auth)
 328 AC_DEFINE_UNQUOTED(NTLM_AUTH, "$ntlm_auth", [Samba's 'winbind' daemon helper 'ntlm_auth' which can be used for NTLM single-sign-on])
 329
 330 dnl ****************************************************
 331 dnl *** Warnings to show if using GCC                ***
 332 dnl *** (do this last so -Werror won't mess up tests ***
 333 dnl ****************************************************
 334
 335 AC_ARG_ENABLE(more-warnings,
 336               AS_HELP_STRING([--disable-more-warnings], [Inhibit compiler warnings]),
 337               set_more_warnings=no)
 338
 339 if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
 340         CFLAGS="$CFLAGS \
 341                 -Wall -Wstrict-prototypes -Werror=missing-prototypes \
 342                 -Werror=implicit-function-declaration \
 343                 -Werror=pointer-arith -Werror=init-self -Werror=format=2 \
 344                 -Werror=missing-include-dirs -Werror=aggregate-return \
 345                 -Werror=declaration-after-statement"
 346 fi
 347
 348 dnl *************************
 349 dnl *** Output Everything ***
 350 dnl *************************
 351
 352 AC_CONFIG_HEADERS([config.h])
 353 AC_CONFIG_FILES([
 354         libsoup-2.4.pc
 355         libsoup-gnome-2.4.pc
 356         Makefile
 357         libsoup-zip
 358         libsoup/Makefile
 359         po/Makefile.in
 360         po/Makefile
 361         tests/Makefile
 362         tests/httpd.conf
 363         docs/Makefile
 364         docs/reference/Makefile
 365         ])
 366 AC_OUTPUT
 367
 368 if test -n "$MISSING_REGRESSION_TEST_PACKAGES"; then
 369     echo ""
 370     echo Some regression tests will not be run due to missing packages:
 371     echo $MISSING_REGRESSION_TEST_PACKAGES
 372     echo ""
 373 fi