configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v exported || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])],
  15 [m4_define([v_ver], [v_maj.v_min.v_mic])])
  16 m4_define([lt_rev], m4_eval(v_maj + v_min))
  17 m4_define([lt_cur], v_mic)
  18 m4_define([lt_age], v_min)
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  21
  22 AC_INIT([e_dbus], [v_ver-alpha], [enlightenment-devel@lists.sourceforge.net])
  23 AC_PREREQ([2.52])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_MACRO_DIR([m4])
  26 AC_CANONICAL_BUILD
  27 AC_CANONICAL_HOST
  28
  29 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  30 AM_CONFIG_HEADER([config.h])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 AC_LIBTOOL_WIN32_DLL
  34 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  35 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  36 AC_PROG_LIBTOOL
  37
  38 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  41 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  42 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  43 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  44 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  45 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  46 version_info="lt_rev:lt_cur:lt_age"
  47 release_info="v_rel"
  48 AC_SUBST(version_info)
  49 AC_SUBST(release_info)
  50 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 VMAJ=v_maj
  53 AC_SUBST(VMAJ)
  54
  55 ### Needed information
  56
  57 want_ebluez="yes"
  58 want_econnman="yes"
  59 want_ehal="yes"
  60 want_enotify="yes"
  61 want_eofono="yes"
  62 want_eukit="yes"
  63
  64 case "$host_os" in
  65    mingw*)
  66       want_ebluez="no"
  67       want_econnman="no"
  68       want_ehal="no"
  69       want_enotify="no"
  70       want_eofono="no"
  71       want_eukit="no"
  72       ;;
  73 esac
  74
  75 requirement_ebluez="edbus >= 1.0.0"
  76 requirement_econnman="edbus >= 1.0.0"
  77 requirement_edbus="ecore >= 1.0.0 eina >= 1.0.0 dbus-1"
  78 requirement_ehal="edbus >= 1.0.0"
  79 requirement_enotify="edbus >= 1.0.0"
  80 requirement_eofono="edbus >= 1.0.0"
  81 requirement_eukit="edbus >= 1.0.0"
  82
  83 ### Additional options to configure
  84
  85 dnl Check enabled modules to build
  86
  87 AC_ARG_ENABLE([ebluez],
  88    [AC_HELP_STRING([--enable-ebluez], [Enable ebluez build])],
  89    [enable_ebluez=$enableval],
  90    [enable_ebluez="${want_ebluez}"])
  91
  92 AC_ARG_ENABLE([econnman],
  93    [AC_HELP_STRING([--enable-econnman], [Enable econnman build])],
  94    [enable_econnman=$enableval],
  95    [enable_econnman="${want_econnman}"])
  96
  97 AC_ARG_ENABLE([ehal],
  98    [AC_HELP_STRING([--disable-ehal], [Disable ehal build])],
  99    [enable_ehal=$enableval],
 100    [enable_ehal="${want_ehal}"])
 101
 102 AC_ARG_ENABLE([enotify],
 103    [AC_HELP_STRING([--disable-enotify], [Disable enotify build])],
 104    [enable_enotify=$enableval],
 105    [enable_enotify="${want_enotify}"])
 106
 107 AC_ARG_ENABLE([eofono],
 108    [AC_HELP_STRING([--enable-eofono], [Enable eofono build])],
 109    [enable_eofono=$enableval],
 110    [enable_eofono="${want_eofono}"])
 111
 112 AC_ARG_ENABLE([eukit],
 113    [AC_HELP_STRING([--disable-eukit], [Disable eukit build])],
 114    [enable_eukit=$enableval],
 115    [enable_eukit="${want_eukit}"])
 116
 117
 118 ### Checks for programs
 119
 120 AC_PROG_CC
 121 AM_PROG_CC_C_O
 122
 123 # pkg-config
 124 PKG_PROG_PKG_CONFIG
 125
 126 # Check whether pkg-config supports Requires.private
 127 if $PKG_CONFIG --atleast-pkgconfig-version 0.22 ; then
 128    pkgconfig_requires_private="Requires.private"
 129 else
 130    pkgconfig_requires_private="Requires"
 131 fi
 132 AC_SUBST(pkgconfig_requires_private)
 133
 134 # doxygen program for documentation building
 135 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 136
 137
 138 ### Checks for libraries
 139
 140 PKG_CHECK_MODULES([EDBUS], [ecore >= 1.0.0 eina >= 1.0.0 dbus-1 >= 0.62])
 141
 142 # Find out the version of DBUS we're using
 143 dbus_version=`pkg-config --modversion dbus-1`
 144 DBUS_VERSION_MAJOR=`echo $dbus_version | awk -F. '{print $1}'`
 145 DBUS_VERSION_MINOR=`echo $dbus_version | awk -F. '{print $2}'`
 146 DBUS_VERSION_MICRO=`echo $dbus_version | awk -F. '{print $3}'`
 147
 148 if test "z$DBUS_VERSION_MAJOR" = "z" ; then
 149    DBUS_VERSION_MAJOR="0"
 150 fi
 151
 152 if test "z$DBUS_VERSION_MINOR" = "z" ; then
 153    DBUS_VERSION_MINOR="0"
 154 fi
 155
 156 if test "z$DBUS_VERSION_MICRO" = "z" ; then
 157    DBUS_VERSION_MICRO="0"
 158 fi
 159
 160 DBUS_VERSION_CFLAGS="$DBUS_VERSION_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 161 DBUS_VERSION_CFLAGS="$DBUS_VERSION_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 162 DBUS_VERSION_CFLAGS="$DBUS_VERSION_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 163 AC_SUBST(DBUS_VERSION_CFLAGS)
 164
 165 # evas
 166 if test "x${enable_enotify}" = "xyes" ; then
 167    PKG_CHECK_MODULES(EVAS,
 168       [evas >= 1.0.0],
 169       [requirement_enotify="evas >= 1.0.0 ${requirement_enotify}"],
 170       [enable_enotify="no"])
 171 fi
 172
 173 AM_CONDITIONAL([BUILD_EBLUEZ],   [test "x${enable_ebluez}"   = "xyes"])
 174 AM_CONDITIONAL([BUILD_ECONNMAN], [test "x${enable_econnman}" = "xyes"])
 175 AM_CONDITIONAL([BUILD_EHAL],     [test "x${enable_ehal}"     = "xyes"])
 176 AM_CONDITIONAL([BUILD_ENOTIFY],  [test "x${enable_enotify}"  = "xyes"])
 177 AM_CONDITIONAL([BUILD_EOFONO],   [test "x${enable_eofono}"   = "xyes"])
 178 AM_CONDITIONAL([BUILD_EUKIT],    [test "x${enable_eukit}"    = "xyes"])
 179
 180
 181 ### Checks for header files
 182
 183
 184 ### Checks for types
 185
 186
 187 ### Checks for structures
 188
 189
 190 ### Checks for compiler characteristics
 191
 192 EFL_EDBUS_BUILD=""
 193 case "$host_os" in
 194    mingw*)
 195       EFL_EDBUS_BUILD="-DEFL_EDBUS_BUILD"
 196    ;;
 197 esac
 198 AC_SUBST(EFL_EDBUS_BUILD)
 199
 200 AC_HEADER_STDC
 201 AC_C___ATTRIBUTE__
 202
 203 if ! test "x${VMIC}" = "x" ; then
 204    EFL_COMPILER_FLAG([-Wall])
 205    EFL_COMPILER_FLAG([-W])
 206 fi
 207
 208 EFL_COMPILER_FLAG([-Wshadow])
 209
 210
 211 ### Checks for linker characteristics
 212
 213 lt_enable_auto_import=""
 214 case "$host_os" in
 215    mingw*)
 216       lt_enable_auto_import="-Wl,--enable-auto-import"
 217    ;;
 218 esac
 219 AC_SUBST(lt_enable_auto_import)
 220
 221
 222 ### Checks for library functions
 223
 224 AC_FUNC_ALLOCA
 225
 226
 227 AC_SUBST(requirement_ebluez)
 228 AC_SUBST(requirement_econnman)
 229 AC_SUBST(requirement_edbus)
 230 AC_SUBST(requirement_ehal)
 231 AC_SUBST(requirement_enotify)
 232 AC_SUBST(requirement_eofono)
 233 AC_SUBST(requirement_eukit)
 234
 235 AC_OUTPUT([
 236 e_dbus.spec
 237 Makefile
 238 doc/Makefile
 239 src/Makefile
 240 src/lib/Makefile
 241 src/lib/bluez/Makefile
 242 src/lib/connman/Makefile
 243 src/lib/dbus/Makefile
 244 src/lib/hal/Makefile
 245 src/lib/notification/Makefile
 246 src/lib/ofono/Makefile
 247 src/lib/ukit/Makefile
 248 src/bin/Makefile
 249 ebluez.pc
 250 econnman.pc
 251 edbus.pc
 252 ehal.pc
 253 enotify.pc
 254 eofono.pc
 255 eukit.pc
 256 ])
 257
 258
 259 #####################################################################
 260 ## Info
 261
 262 echo
 263 echo
 264 echo
 265 echo "------------------------------------------------------------------------"
 266 echo "$PACKAGE $VERSION"
 267 echo "------------------------------------------------------------------------"
 268 echo
 269 echo "Configuration Options Summary:"
 270 echo
 271 echo "  Modules:"
 272 echo
 273 echo "    EBluez.............: $enable_ebluez"
 274 echo "    EConnman...........: $enable_econnman"
 275 echo "    EHal...............: $enable_ehal"
 276 echo "    ENotify............: $enable_enotify"
 277 echo "    EOfono.............: $enable_eofono"
 278 echo "    EUkit..............: $enable_eukit"
 279 echo
 280 echo "Documentation..........: ${build_doc}"
 281 echo
 282 echo "Compilation............: make (or gmake)"
 283 echo "  CPPFLAGS.............: $CPPFLAGS"
 284 echo "  CFLAGS...............: $CFLAGS"
 285 echo "  LDFLAGS..............: $LDFLAGS"
 286 echo
 287 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 288 echo "  prefix...............: $prefix"
 289 echo