configure.ac

   1 AC_INIT([btrfs-progs],
   2         m4_esyscmd([./version.sh --configure]),
   3         [linux-btrfs@vger.kernel.org],,
   4         [http://btrfs.wiki.kernel.org])
   5
   6 if test "x$PACKAGE_URL" = "x"; then
   7         AC_DEFINE([PACKAGE_URL], ["http://btrfs.wiki.kernel.org"], [URL])
   8 fi
   9
  10 dnl library version
  11 LIBBTRFS_MAJOR=0
  12 LIBBTRFS_MINOR=1
  13 LIBBTRFS_PATCHLEVEL=1
  14
  15 CFLAGS=${CFLAGS:-"-g -O1 -Wall -D_FORTIFY_SOURCE=2"}
  16 AC_SUBST([CFLAGS])
  17
  18 AC_PREREQ([2.60])
  19
  20 AC_CONFIG_AUX_DIR([config])
  21 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  22 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  23 AC_USE_SYSTEM_EXTENSIONS
  24
  25 AC_CONFIG_SRCDIR([btrfs.c])
  26 AC_PREFIX_DEFAULT([/usr/local])
  27
  28 AC_PROG_CC
  29 AC_CANONICAL_HOST
  30 AC_C_CONST
  31 AC_C_VOLATILE
  32 AC_C_BIGENDIAN
  33
  34 AC_SYS_LARGEFILE
  35
  36 AC_PROG_INSTALL
  37 AC_PROG_LN_S
  38 AC_CHECK_TOOL([AR], [ar])
  39 AC_PATH_PROG([RM], [rm], [rm])
  40 AC_PATH_PROG([RMDIR], [rmdir], [rmdir])
  41
  42 AC_CHECK_FUNCS([openat], [],
  43         [AC_MSG_ERROR([cannot find openat() function])])
  44
  45 m4_ifndef([PKG_PROG_PKG_CONFIG],
  46   [m4_fatal([Could not locate the pkg-config autoconf
  47     macros. These are usually located in /usr/share/aclocal/pkg.m4.
  48     If your macros are in a different location, try setting the
  49     environment variable AL_OPTS="-I/other/macro/dir" before running
  50     ./autogen.sh or autoreconf again.])])
  51 PKG_PROG_PKG_CONFIG
  52
  53
  54 dnl
  55 dnl Calls pkg-config --static
  56 dnl
  57 AC_DEFUN([PKG_STATIC], [
  58   if AC_RUN_LOG([pkg-config --exists --print-errors "$2"]); then
  59     $1=`pkg-config --libs --static "$2"`
  60     AC_SUBST([$1])
  61   else
  62     AC_MSG_ERROR([pkg-config description of $2, needed for static build, is not available])
  63   fi
  64 ])
  65
  66
  67 AC_ARG_ENABLE([backtrace],
  68   AS_HELP_STRING([--disable-backtrace], [disable btrfs backtrace]),
  69   [], [enable_backtrace=yes]
  70 )
  71
  72 AS_IF([test "x$enable_backtrace" = xno], [
  73   AC_DEFINE([BTRFS_DISABLE_BACKTRACE], [1], [disable backtrace stuff in kerncompat.h ])
  74 ])
  75
  76 if test "x$enable_backtrace" = xyes; then
  77         AC_CHECK_HEADERS([execinfo.h])
  78         AC_CHECK_FUNCS([backtrace backtrace_symbols_fd], [],
  79               AC_MSG_ERROR([standard library does not have backtrace support]))
  80 fi
  81
  82
  83 AC_ARG_ENABLE([documentation],
  84               AS_HELP_STRING([--disable-documentation], [do not build domumentation]),
  85   [], [enable_documentation=yes]
  86 )
  87 AS_IF([test "x$enable_documentation" = xyes], [DISABLE_DOCUMENTATION=0], [DISABLE_DOCUMENTATION=1])
  88 AC_SUBST([DISABLE_DOCUMENTATION])
  89
  90 dnl detect tools to build documentation
  91 if test "x$enable_documentation" = xyes; then
  92         AC_PATH_PROG([ASCIIDOC], [asciidoc], [asciidoc])
  93         AC_PATH_PROG([XMLTO], [xmlto], [xmlto])
  94         AC_PATH_PROG([GZIP], [gzip], [gzip])
  95         AC_PATH_PROG([MV], [mv], [mv])
  96         AC_PROG_SED
  97 fi
  98
  99 AC_ARG_ENABLE([convert],
 100               AS_HELP_STRING([--disable-convert], [do not build btrfs-convert]),
 101   [], [enable_convert=yes]
 102 )
 103
 104 AS_IF([test "x$enable_convert" = xyes], [DISABLE_BTRFSCONVERT=0], [DISABLE_BTRFSCONVERT=1])
 105 AC_SUBST([DISABLE_BTRFSCONVERT])
 106
 107 AC_ARG_WITH([convert],
 108             AS_HELP_STRING([[[]--with-convert[[=auto]]]], [built-in filesystems for convert (default: auto)
 109 supported (comma separated list): ext2]),
 110   [], [with_convert=auto]
 111 )
 112
 113 if test "$with_convert" = "yes"; then
 114         with_convert=auto
 115 fi
 116
 117 if test "$with_convert" = "no"; then
 118         with_convert=
 119 fi
 120
 121 convertfs=
 122 BTRFSCONVERT_EXT2=0
 123 if test "x$enable_convert" = xyes; then
 124         if test "x$with_convert" = "xauto" || echo "$with_convert" | grep -q "ext2"; then
 125                 PKG_CHECK_MODULES(EXT2FS, [ext2fs >= 1.42],,
 126                         [PKG_CHECK_MODULES(EXT2FS, [ext2fs],
 127                                 [AC_DEFINE([HAVE_OLD_E2FSPROGS], [1],
 128                                           [E2fsprogs does not support BIGALLOC])]
 129                                 )])
 130                 PKG_CHECK_MODULES(COM_ERR, [com_err])
 131                 convertfs="${convertfs:+$convertfs,}ext2"
 132                 BTRFSCONVERT_EXT2=1
 133         fi
 134 fi
 135 AC_SUBST([BTRFSCONVERT_EXT2])
 136
 137 # catch typos
 138 tmp=$(echo "$with_convert" | sed -e 's/auto//' | sed -e 's/ext2//' | sed -e 's/,\+/,/')
 139 if ! test "x$tmp" = "x"; then
 140         AC_MSG_ERROR([unknown tokens for --with-convert: $tmp])
 141 fi
 142
 143 if test "$DISABLE_BTRFSCONVERT" = 0 && test "x$convertfs" = "x"; then
 144         AC_MSG_ERROR([no filesystems for convert, use --disable-convert instead])
 145 fi
 146
 147 AX_CHECK_DEFINE([linux/fiemap.h], [FIEMAP_EXTENT_SHARED], [],
 148                 [AC_MSG_ERROR([no definition of FIEMAP_EXTENT_SHARED found])])
 149
 150 dnl Define <NAME>_LIBS= and <NAME>_CFLAGS= by pkg-config
 151 dnl
 152 dnl The default PKG_CHECK_MODULES() action-if-not-found is end the
 153 dnl execution with error. The static libs are optional.
 154
 155 PKG_CHECK_MODULES(BLKID, [blkid])
 156 PKG_STATIC(BLKID_LIBS_STATIC, [blkid])
 157
 158 PKG_CHECK_MODULES(UUID, [uuid])
 159 PKG_STATIC(UUID_LIBS_STATIC, [uuid])
 160
 161 PKG_CHECK_MODULES(ZLIB, [zlib])
 162 PKG_STATIC(ZLIB_LIBS_STATIC, [zlib])
 163
 164 UDEVDIR="$(pkg-config udev --variable=udevdir)"
 165 AC_SUBST(UDEVDIR)
 166
 167 dnl lzo library does not provide pkg-config, let use classic way
 168 AC_CHECK_LIB([lzo2], [lzo_version], [
 169         LZO2_LIBS="-llzo2"
 170         LZO2_CFLAGS=""
 171         LZO2_LIBS_STATIC="-llzo2"],[
 172         AC_MSG_ERROR([cannot find lzo2 library])
 173 ])
 174 AC_SUBST([LZO2_LIBS])
 175 AC_SUBST([LZO2_LIBS_STATIC])
 176 AC_SUBST([LZO2_CFLAGS])
 177
 178
 179 dnl library stuff
 180 AC_SUBST([LIBBTRFS_MAJOR])
 181 AC_SUBST([LIBBTRFS_MINOR])
 182 AC_SUBST([LIBBTRFS_PATCHLEVEL])
 183
 184 AC_CONFIG_HEADERS([config.h])
 185
 186 AC_CONFIG_FILES([
 187 Makefile
 188 Documentation/Makefile
 189 version.h
 190 ])
 191
 192 AC_OUTPUT
 193
 194 AC_MSG_RESULT([
 195         ${PACKAGE_NAME} ${PACKAGE_VERSION}
 196
 197         prefix:            ${prefix}
 198         exec prefix:       ${exec_prefix}
 199
 200         bindir:            ${bindir}
 201         libdir:            ${libdir}
 202         includedir:        ${includedir}
 203
 204         compiler:          ${CC}
 205         cflags:            ${CFLAGS}
 206         ldflags:           ${LDFLAGS}
 207
 208         documentation:     ${enable_documentation}
 209         backtrace support: ${enable_backtrace}
 210         btrfs-convert:     ${enable_convert} ${convertfs:+($convertfs)}
 211
 212         Type 'make' to compile.
 213 ])
 214