configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([harfbuzz],
   3         [0.5.0],
   4         [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz],
   5         [harfbuzz],
   6         [http://freedesktop.org/wiki/Software/harfbuzz])
   7
   8 AC_CONFIG_SRCDIR([harfbuzz.pc.in])
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AM_INIT_AUTOMAKE([1.11.1 gnu dist-bzip2 no-dist-gzip -Wall no-define])
  12 AM_SILENT_RULES([yes])
  13
  14 # Check for programs
  15 AC_PROG_CC
  16 AM_PROG_CC_C_O
  17 AC_PROG_CXX
  18
  19 # Initialize libtool
  20 LT_PREREQ([2.2])
  21 LT_INIT([disable-static])
  22
  23 # Version
  24 m4_define(version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
  25 HB_VERSION_MAJOR=m4_argn(1,version_triplet)
  26 HB_VERSION_MINOR=m4_argn(2,version_triplet)
  27 HB_VERSION_MICRO=m4_argn(3,version_triplet)
  28 HB_VERSION=AC_PACKAGE_VERSION
  29
  30 AC_SUBST(HB_VERSION_MAJOR)
  31 AC_SUBST(HB_VERSION_MINOR)
  32 AC_SUBST(HB_VERSION_MICRO)
  33 AC_SUBST(HB_VERSION)
  34
  35
  36 # Functions and headers
  37 AC_CHECK_FUNCS(mprotect sysconf getpagesize)
  38 AC_CHECK_HEADERS(unistd.h sys/mman.h)
  39
  40 # Compiler flags
  41 AC_CANONICAL_HOST
  42 if test "x$GCC" = "xyes"; then
  43
  44         # Make symbols link locally
  45         LDFLAGS="$LDFLAGS -Bsymbolic-functions"
  46
  47         # Make sure we don't link to libstdc++
  48         CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
  49
  50         case "$host" in
  51                 arm-*-*)
  52                         # Request byte alignment on arm
  53                         CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
  54                 ;;
  55         esac
  56 fi
  57
  58 dnl ==========================================================================
  59
  60 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.16, have_glib=true, have_glib=false)
  61 if $have_glib; then
  62         AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
  63 fi
  64 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
  65
  66 dnl ==========================================================================
  67
  68 PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, have_cairo=false)
  69 if $have_cairo; then
  70         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
  71 fi
  72 AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
  73
  74 PKG_CHECK_MODULES(CAIRO_PNG, cairo-png, have_cairo_png=true, have_cairo_png=false)
  75 if $have_cairo_png; then
  76         AC_DEFINE(HAVE_CAIRO_PNG, 1, [Have cairo-png support in cairo graphics library])
  77 fi
  78 AM_CONDITIONAL(HAVE_CAIRO_PNG, $have_cairo_png)
  79
  80 PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, have_cairo_ft=false)
  81 if $have_cairo_ft; then
  82         AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
  83 fi
  84 AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
  85
  86 dnl ==========================================================================
  87
  88 PKG_CHECK_MODULES(ICU, icu, have_icu=true, [
  89         AC_CHECK_PROG([have_icu], [icu-config], [true], [false])
  90         if $have_icu; then
  91                 icu_cflags=`icu-config --cppflags`
  92                 icu_libs=`icu-config --ldflags-libsonly`
  93                 AC_SUBST(ICU_CFLAGS, [$icu_cflags])
  94                 AC_SUBST(ICU_LIBS, [$icu_libs])
  95         fi
  96 ])
  97 if $have_icu; then
  98         AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
  99 fi
 100 AM_CONDITIONAL(HAVE_ICU, $have_icu)
 101
 102 dnl ==========================================================================
 103
 104 PKG_CHECK_MODULES(FREETYPE, freetype2, have_freetype=true, have_freetype=false)
 105 if $have_freetype; then
 106         AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
 107         _save_libs="$LIBS"
 108         _save_cflags="$CFLAGS"
 109         LIBS="$LIBS $FREETYPE_LIBS"
 110         CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 111         AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
 112         LIBS="$_save_libs"
 113         CFLAGS="$_save_cflags"
 114 fi
 115 AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
 116
 117 dnl ===========================================================================
 118
 119 AC_CONFIG_FILES([
 120 Makefile
 121 harfbuzz.pc
 122 src/Makefile
 123 src/hb-version.h
 124 test/Makefile
 125 ])
 126
 127 AC_OUTPUT