configure.ac

   1 m4_define([weston_major_version], [3])
   2 m4_define([weston_minor_version], [0])
   3 m4_define([weston_micro_version], [90])
   4 m4_define([weston_version],
   5           [weston_major_version.weston_minor_version.weston_micro_version])
   6 m4_define([libweston_major_version], [3])
   7 m4_define([libweston_minor_version], [0])
   8 m4_define([libweston_patch_version], [90])
   9
  10 AC_PREREQ([2.64])
  11 AC_INIT([weston],
  12         [weston_version],
  13         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=weston&version=weston_version],
  14         [weston],
  15         [http://wayland.freedesktop.org])
  16
  17 WAYLAND_PREREQ_VERSION="1.12.0"
  18
  19 AC_SUBST([WESTON_VERSION_MAJOR], [weston_major_version])
  20 AC_SUBST([WESTON_VERSION_MINOR], [weston_minor_version])
  21 AC_SUBST([WESTON_VERSION_MICRO], [weston_micro_version])
  22 AC_SUBST([WESTON_VERSION], [weston_version])
  23 AC_SUBST([LIBWESTON_MAJOR], [libweston_major_version])
  24 # We use minor as current and age since on ABI/API break/removal we bump major
  25 # so minor will be reset to 0.
  26 m4_define([lt_current], [libweston_minor_version])
  27 m4_define([lt_revision], [libweston_patch_version])
  28 m4_define([lt_age], [libweston_minor_version])
  29 AC_SUBST([LT_VERSION_INFO], [lt_current:lt_revision:lt_age])
  30
  31 AC_CONFIG_AUX_DIR([build-aux])
  32 AC_CONFIG_HEADERS([config.h])
  33 AC_CONFIG_MACRO_DIR([m4])
  34
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_SYS_LARGEFILE
  37
  38 AM_INIT_AUTOMAKE([1.11 parallel-tests foreign no-dist-gzip dist-xz color-tests subdir-objects])
  39
  40 AM_SILENT_RULES([yes])
  41
  42 # Check Weston and libweston version consistency
  43 m4_if(m4_cmp(weston_micro_version, [90]), [-1],
  44       [
  45         dnl micro < 90
  46         dnl A final or stable release, not a pre-release:
  47         dnl Weston and libweston versions must match.
  48         m4_if(weston_version, libweston_major_version[.]libweston_minor_version[.]libweston_patch_version,
  49               [],
  50               [AC_MSG_ERROR([Weston and libweston version mismatch for a final release])])
  51       ],
  52       [
  53         dnl A pre-release:
  54         dnl libweston must be equal or greater than weston.
  55         m4_case(m4_list_cmp([weston_major_version, weston_minor_version, weston_micro_version],
  56                              [libweston_major_version, libweston_minor_version, libweston_patch_version]),
  57                  [-1], [
  58                         dnl weston < libweston
  59                         dnl libweston must be weston_major+1.0.0
  60                         m4_if(m4_eval(weston_major_version+1)[.0.0],
  61                               libweston_major_version[.]libweston_minor_version[.]libweston_patch_version,
  62                               [],
  63                               [AC_MSG_ERROR([libweston version is greater but not (weston_major+1).0.0])])
  64                  ],
  65                  [0], [
  66                         dnl weston == libweston, all ok
  67                  ],
  68                  [1], [
  69                         dnl weston > libweston, wrong
  70                         AC_MSG_ERROR([Weston version is greater than libweston.])
  71                  ])
  72        ])
  73
  74 # Check for programs
  75 AC_PROG_CC
  76 AC_PROG_SED
  77
  78 # Initialize libtool
  79 LT_PREREQ([2.2])
  80 LT_INIT([disable-static])
  81
  82 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  83            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  84 AC_ARG_VAR([WESTON_SHELL_CLIENT],
  85            [Set the default desktop shell client to load if none is specified in weston.ini. @<:@default=weston-desktop-shell@:>@])
  86
  87 PKG_PROG_PKG_CONFIG()
  88
  89 # Check for dlsym instead of dlopen because ASAN hijacks the latter
  90 WESTON_SEARCH_LIBS([DL], [dl], [dlsym])
  91
  92 # In old glibc versions (< 2.17) clock_gettime() and clock_getres() are in librt
  93 WESTON_SEARCH_LIBS([CLOCK_GETTIME], [rt], [clock_gettime])
  94 WESTON_SEARCH_LIBS([CLOCK_GETRES], [rt], [clock_getres])
  95
  96 AC_CHECK_DECL(SFD_CLOEXEC,[],
  97               [AC_MSG_ERROR("SFD_CLOEXEC is needed to compile weston")],
  98               [[#include <sys/signalfd.h>]])
  99 AC_CHECK_DECL(TFD_CLOEXEC,[],
 100               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile weston")],
 101               [[#include <sys/timerfd.h>]])
 102 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
 103               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile weston")],
 104               [[#include <time.h>]])
 105 AC_CHECK_HEADERS([execinfo.h])
 106
 107 AC_CHECK_FUNCS([mkostemp strchrnul initgroups posix_fallocate])
 108
 109 # check for libdrm as a build-time dependency only
 110 # libdrm 2.4.30 introduced drm_fourcc.h.
 111 PKG_CHECK_MODULES(LIBDRM, [libdrm >= 2.4.30], [], [AC_MSG_ERROR([
 112      libdrm is a hard build-time dependency for libweston core,
 113      but a sufficient version was not found. However, libdrm
 114      is not a runtime dependency unless you have features
 115      enabled that require it.])])
 116
 117 COMPOSITOR_MODULES="wayland-server >= $WAYLAND_PREREQ_VERSION pixman-1 >= 0.25.2"
 118
 119 AC_CONFIG_FILES([doc/doxygen/tools.doxygen doc/doxygen/tooldev.doxygen])
 120
 121 AC_ARG_ENABLE(devdocs,
 122               AS_HELP_STRING([--disable-devdocs],
 123                              [do not enable building of developer documentation]),,
 124               enable_devdocs=auto)
 125 if test "x$enable_devdocs" != "xno"; then
 126         AC_CHECK_PROGS([DOXYGEN], [doxygen])
 127         if test "x$DOXYGEN" = "x" -a "x$enable_devdocs" = "xyes"; then
 128                 AC_MSG_ERROR([Developer documentation explicitly requested, but Doxygen couldn't be found])
 129         fi
 130         if test "x$DOXYGEN" != "x"; then
 131                 enable_devdocs=yes
 132         else
 133                 enable_devdocs=no
 134         fi
 135 fi
 136 AM_CONDITIONAL(ENABLE_DEVDOCS, test "x$enable_devdocs" = "xyes")
 137
 138 AC_ARG_ENABLE(egl, [  --disable-egl],,
 139               enable_egl=yes)
 140 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
 141 if test x$enable_egl = xyes; then
 142         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
 143         PKG_CHECK_MODULES(EGL, [egl glesv2])
 144         PKG_CHECK_MODULES([EGL_TESTS], [egl glesv2 wayland-client wayland-egl])
 145         AC_CHECK_HEADERS([linux/sync_file.h])
 146 fi
 147
 148 COMPOSITOR_MODULES="$COMPOSITOR_MODULES xkbcommon >= 0.3.0"
 149
 150 PKG_CHECK_MODULES(XKBCOMMON_COMPOSE, [xkbcommon >= 0.5.0],
 151                   [AC_DEFINE(HAVE_XKBCOMMON_COMPOSE, 1,
 152                      [Define if xkbcommon is 0.5.0 or newer])],true)
 153
 154 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
 155               enable_setuid_install=yes)
 156 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
 157
 158
 159 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
 160               enable_xwayland=yes)
 161 AC_ARG_ENABLE(xwayland-test, [  --enable-xwayland-test],,
 162               enable_xwayland_test=yes)
 163 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
 164 AM_CONDITIONAL(ENABLE_XWAYLAND_TEST, test x$enable_xwayland = xyes -a x$enable_xwayland_test = xyes)
 165 if test x$enable_xwayland = xyes; then
 166   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcb-composite xcursor cairo-xcb)
 167   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
 168
 169   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
 170               [Path to X server]), [XSERVER_PATH="$withval"],
 171               [XSERVER_PATH="/usr/bin/Xwayland"])
 172   AC_SUBST([XSERVER_PATH])
 173   if test x$enable_xwayland_test = xyes; then
 174     PKG_CHECK_MODULES([XWAYLAND_TEST], x11)
 175   fi
 176 fi
 177
 178 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
 179               enable_x11_compositor=yes)
 180 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
 181 have_xcb_xkb=no
 182 if test x$enable_x11_compositor = xyes; then
 183   PKG_CHECK_MODULES([XCB], xcb >= 1.8)
 184   X11_COMPOSITOR_MODULES="x11 x11-xcb xcb-shm"
 185
 186   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb >= 1.9],
 187                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
 188   if test "x$have_xcb_xkb" = xyes; then
 189         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
 190         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
 191   fi
 192
 193   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
 194   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
 195 fi
 196
 197
 198 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 199               enable_drm_compositor=yes)
 200 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes)
 201 if test x$enable_drm_compositor = xyes; then
 202   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 203   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm])
 204   PKG_CHECK_MODULES(DRM_COMPOSITOR_GBM, [gbm >= 10.2],
 205                     [AC_DEFINE([HAVE_GBM_FD_IMPORT], 1, [gbm supports dmabuf import])],
 206                     [AC_MSG_WARN([gbm does not support dmabuf import, will omit that capability])])
 207 fi
 208
 209
 210 PKG_CHECK_MODULES(LIBINPUT_BACKEND, [libinput >= 0.8.0])
 211 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
 212
 213 PKG_CHECK_MODULES(WAYLAND_PROTOCOLS, [wayland-protocols >= 1.8],
 214                   [ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`])
 215 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
 216
 217 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 218               enable_wayland_compositor=yes)
 219 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 220                test x$enable_wayland_compositor = xyes)
 221 if test x$enable_wayland_compositor = xyes; then
 222   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 223             [Build the Wayland (nested) compositor])
 224   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client >= $WAYLAND_PREREQ_VERSION wayland-cursor])
 225   if test x$enable_egl = xyes; then
 226     PKG_CHECK_MODULES(WAYLAND_COMPOSITOR_EGL, [wayland-egl])
 227   fi
 228 fi
 229
 230
 231 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 232               enable_headless_compositor=yes)
 233 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 234                test x$enable_headless_compositor = xyes)
 235 if test x$enable_headless_compositor = xyes; then
 236   AC_DEFINE([BUILD_HEADLESS_COMPOSITOR], [1], [Build the headless compositor])
 237 fi
 238
 239
 240 AC_ARG_ENABLE([fbdev-compositor], [  --enable-fbdev-compositor],,
 241               enable_fbdev_compositor=yes)
 242 AM_CONDITIONAL([ENABLE_FBDEV_COMPOSITOR],
 243                [test x$enable_fbdev_compositor = xyes])
 244 AS_IF([test x$enable_fbdev_compositor = xyes], [
 245   AC_DEFINE([BUILD_FBDEV_COMPOSITOR], [1], [Build the fbdev compositor])
 246   PKG_CHECK_MODULES([FBDEV_COMPOSITOR], [libudev >= 136])
 247 ])
 248
 249 AC_ARG_ENABLE([rdp-compositor], [  --enable-rdp-compositor],,
 250               enable_rdp_compositor=no)
 251 AM_CONDITIONAL([ENABLE_RDP_COMPOSITOR],
 252                [test x$enable_rdp_compositor = xyes])
 253 if test x$enable_rdp_compositor = xyes; then
 254   AC_DEFINE([BUILD_RDP_COMPOSITOR], [1], [Build the RDP compositor])
 255   PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp2 >= 2.0.0],
 256     [],
 257     [PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp >= 1.1.0],[])]
 258   )
 259
 260   SAVED_CPPFLAGS="$CPPFLAGS"
 261   CPPFLAGS="$CPPFLAGS $RDP_COMPOSITOR_CFLAGS"
 262   AC_CHECK_HEADERS([freerdp/version.h])
 263   CPPFLAGS="$SAVED_CPPFLAGS"
 264 fi
 265
 266 AC_ARG_ENABLE([screen-sharing], [  --enable-screen-sharing],,
 267               enable_screen_sharing=no)
 268 AM_CONDITIONAL([ENABLE_SCREEN_SHARING],
 269                [test x$enable_screen_sharing = xyes])
 270 if test x$enable_screen_sharing = xyes; then
 271   PKG_CHECK_MODULES(SCREEN_SHARE, [wayland-client])
 272
 273   if test x$enable_rdp_compositor != xyes; then
 274     AC_MSG_WARN([The screen-share.so module requires the RDP backend.])
 275   fi
 276 fi
 277
 278 AC_ARG_WITH(cairo,
 279             AS_HELP_STRING([--with-cairo=@<:@image|gl|glesv2@:>@]
 280                            [Which Cairo renderer to use for the clients]),
 281                            [],[with_cairo="image"])
 282
 283 if test "x$with_cairo" = "ximage"; then
 284         cairo_modules="cairo"
 285 else
 286 if test "x$with_cairo" = "xgl"; then
 287         cairo_modules="cairo-gl"
 288         AC_MSG_WARN([The --with-cairo=gl option can cause increased resource usage and potential instability, and thus is not recommended.  It is needed only for a few special demo programs.])
 289 else
 290 if test "x$with_cairo" = "xglesv2"; then
 291         cairo_modules="cairo-glesv2"
 292         AC_MSG_WARN([The --with-cairo=gles2 option can cause increased resource usage and potential instability, and thus is not recommended.  It is needed only for a few special demo programs.])
 293 else
 294         AC_ERROR([Unknown cairo renderer requested])
 295 fi
 296 fi
 297 fi
 298
 299 # Included for legacy compat
 300 AC_ARG_WITH(cairo-glesv2,
 301             AS_HELP_STRING([--with-cairo-glesv2],
 302                            [Use GLESv2 cairo]))
 303 if test "x$with_cairo_glesv2" = "xyes"; then
 304   cairo_modules="cairo-glesv2"
 305   with_cairo="glesv2"
 306 fi
 307
 308 if test "x$cairo_modules" = "xcairo-glesv2"; then
 309 AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 310 fi
 311
 312 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 313 PKG_CHECK_MODULES(PNG, [libpng])
 314
 315 AC_ARG_WITH([jpeg],
 316             AS_HELP_STRING([--without-jpeg],
 317                            [Use jpeglib for JPEG decoding support [default=auto]]))
 318 AS_IF([test "x$with_jpeg" != "xno"],
 319       [WESTON_SEARCH_LIBS([JPEG], [jpeg], [jpeg_CreateDecompress], [have_jpeglib=yes], [have_jpeglib=no])],
 320       [have_jpeglib=no])
 321 AS_IF([test "x$have_jpeglib" = "xyes"],
 322       [AC_DEFINE([HAVE_JPEG], [1], [Have jpeglib])],
 323       [AS_IF([test "x$with_jpeg" = "xyes"],
 324              [AC_MSG_ERROR([JPEG support explicitly requested, but jpeglib couldn't be found])])])
 325
 326 AC_ARG_WITH([webp],
 327             AS_HELP_STRING([--without-webp],
 328                            [Use libwebp for WebP decoding support [default=auto]]))
 329 AS_IF([test "x$with_webp" != "xno"],
 330       [PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])],
 331       [have_webp=no])
 332 AS_IF([test "x$have_webp" = "xyes"],
 333       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])],
 334       [AS_IF([test "x$with_webp" = "xyes"],
 335              [AC_MSG_ERROR([WebP support explicitly requested, but libwebp couldn't be found])])])
 336
 337 AC_ARG_ENABLE(vaapi-recorder, [  --enable-vaapi-recorder],,
 338               enable_vaapi_recorder=auto)
 339 have_libva=no
 340 if test x$enable_vaapi_recorder != xno; then
 341   PKG_CHECK_MODULES(LIBVA, [libva >= 0.34.0 libva-drm >= 0.34.0],
 342                     [have_libva=yes], [have_libva=no])
 343   if test "x$have_libva" = "xno" -a "x$enable_vaapi_recorder" = "xyes"; then
 344     AC_MSG_ERROR([vaapi-recorder explicitly enabled, but libva couldn't be found])
 345   fi
 346   AS_IF([test "x$have_libva" = "xyes"],
 347         [AC_DEFINE([BUILD_VAAPI_RECORDER], [1], [Build the vaapi recorder])])
 348 fi
 349 AM_CONDITIONAL(ENABLE_VAAPI_RECORDER, test "x$have_libva" = xyes)
 350
 351 PKG_CHECK_MODULES(CAIRO, [cairo])
 352
 353 PKG_CHECK_MODULES(TEST_CLIENT, [wayland-client >= $WAYLAND_PREREQ_VERSION pixman-1])
 354
 355 AC_ARG_ENABLE(simple-clients,
 356               AS_HELP_STRING([--disable-simple-clients],
 357                              [do not build the simple wl_shm clients]),,
 358               enable_simple_clients=yes)
 359 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 360 if test x$enable_simple_clients = xyes; then
 361   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 362 fi
 363
 364 AC_ARG_ENABLE(simple-egl-clients,
 365               AS_HELP_STRING([--disable-simple-egl-clients],
 366                              [do not build the simple EGL clients]),,
 367               enable_simple_egl_clients="$enable_egl")
 368 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes")
 369 if test x$enable_simple_egl_clients = xyes; then
 370   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 371                     [egl glesv2 wayland-client wayland-egl wayland-cursor])
 372 fi
 373
 374 AC_ARG_ENABLE(simple-dmabuf-drm-client,
 375               AS_HELP_STRING([--disable-simple-dmabuf-drm-client],
 376                              [do not build the simple dmabuf drm client]),,
 377               enable_simple_dmabuf_drm_client="auto")
 378 if ! test "x$enable_simple_dmabuf_drm_client" = "xno"; then
 379   PKG_CHECK_MODULES(SIMPLE_DMABUF_DRM_CLIENT, [wayland-client libdrm egl],
 380     [PKG_CHECK_MODULES(LIBDRM_PLATFORM, [libdrm_freedreno],
 381       AC_DEFINE([HAVE_LIBDRM_FREEDRENO], [1], [Build freedreno dmabuf client]) have_simple_dmabuf_drm_client=freedreno,
 382     [PKG_CHECK_MODULES(LIBDRM_PLATFORM, [libdrm_intel],
 383       AC_DEFINE([HAVE_LIBDRM_INTEL], [1], [Build intel dmabuf client]) have_simple_dmabuf_drm_client=intel,
 384     have_simple_dmabuf_drm_client=unsupported)])],
 385   have_simple_dmabuf_drm_client=unsupported)
 386
 387   if test "x$have_simple_dmabuf_drm_client" = "xunsupported" -a "x$enable_simple_dmabuf_drm_client" = "xyes"; then
 388     AC_MSG_ERROR([DRM dmabuf client explicitly enabled, but libdrm_intel or libdrm_freedreno not found])
 389   fi
 390
 391   if test "x$have_simple_dmabuf_drm_client" = "xfreedreno" -o "x$have_simple_dmabuf_drm_client" = "xintel"; then
 392     enable_simple_dmabuf_drm_client="yes"
 393   fi
 394 fi
 395 AM_CONDITIONAL(BUILD_SIMPLE_DMABUF_DRM_CLIENT, test "x$enable_simple_dmabuf_drm_client" = "xyes")
 396
 397 AC_ARG_ENABLE(simple-dmabuf-v4l-client,
 398               AS_HELP_STRING([--disable-simple-dmabuf-v4l-client],
 399                              [do not build the simple dmabuf v4l client]),,
 400               enable_simple_dmabuf_v4l_client="auto")
 401 if ! test "x$enable_simple_dmabuf_v4l_client" = "xno"; then
 402   PKG_CHECK_MODULES(SIMPLE_DMABUF_V4L_CLIENT, [wayland-client libdrm],
 403                     have_simple_dmabuf_v4l_client=yes, have_simple_dmabuf_v4l_client=no)
 404   if test "x$have_simple_dmabuf_v4l_client" = "xno" -a "x$enable_simple_dmabuf_v4l_client" = "xyes"; then
 405     AC_MSG_ERROR([V4L dmabuf client explicitly enabled, but libdrm couldn't be found])
 406   fi
 407   enable_simple_dmabuf_v4l_client="$have_simple_dmabuf_v4l_client"
 408 fi
 409 AM_CONDITIONAL(BUILD_SIMPLE_DMABUF_V4L_CLIENT, test "x$enable_simple_dmabuf_v4l_client" = "xyes")
 410
 411 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 412 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 413 have_cairo_egl=no
 414 if test x$enable_clients = xyes; then
 415   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 416
 417   PKG_CHECK_MODULES(CLIENT, [wayland-client >= $WAYLAND_PREREQ_VERSION cairo >= 1.10.0 xkbcommon wayland-cursor])
 418   PKG_CHECK_MODULES(SERVER, [wayland-server])
 419   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client >= $WAYLAND_PREREQ_VERSION])
 420
 421   # Only check for cairo-egl if a GL or GLES renderer requested
 422   AS_IF([test "x$cairo_modules" = "xcairo-gl" -o "x$cairo_modules" = "xcairo-glesv2"], [
 423     PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl cairo-egl >= 1.11.3 $cairo_modules],
 424                       [have_cairo_egl=yes], [have_cairo_egl=no])
 425     AS_IF([test "x$have_cairo_egl" = "xyes"],
 426           [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 427           [AC_ERROR([cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])],
 428   [have_cairo_egl=no])
 429
 430   PKG_CHECK_MODULES(PANGO, [pangocairo pango glib-2.0 >= 2.36], [have_pango=yes], [have_pango=no])
 431 fi
 432
 433 AC_ARG_ENABLE(resize-optimization,
 434               AS_HELP_STRING([--disable-resize-optimization],
 435                              [disable resize optimization allocating a big buffer in toytoolkit]),,
 436               enable_resize_optimization=yes)
 437 AS_IF([test "x$enable_resize_optimization" = "xyes"],
 438       [AC_DEFINE([USE_RESIZE_POOL], [1], [Use resize memory pool as a performance optimization])])
 439
 440 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 441 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch = xyes)
 442 if test x$enable_weston_launch = xyes; then
 443   WESTON_SEARCH_LIBS([PAM], [pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 444   if test x$have_pam = xno; then
 445     AC_ERROR([weston-launch requires pam])
 446   fi
 447 fi
 448
 449 AM_CONDITIONAL(HAVE_PANGO, test "x$have_pango" = "xyes")
 450
 451 AM_CONDITIONAL(HAVE_CAIRO_GLESV2,
 452                [test "x$have_cairo_egl" = "xyes" -a "x$cairo_modules" = "xcairo-glesv2" -a "x$enable_egl" = "xyes"])
 453
 454 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 455                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 456
 457 AM_CONDITIONAL(BUILD_SUBSURFACES_CLIENT,
 458                [test '(' "x$have_cairo_egl" != "xyes" -o "x$cairo_modules" = "xcairo-glesv2" ')' -a "x$enable_simple_egl_clients" = "xyes"])
 459
 460 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 461
 462 AC_ARG_ENABLE(fullscreen-shell,
 463               AS_HELP_STRING([--disable-fullscreen-shell],
 464                              [do not build fullscreen-shell server plugin]),,
 465               enable_fullscreen_shell=yes)
 466 AM_CONDITIONAL(ENABLE_FULLSCREEN_SHELL,
 467                test "x$enable_fullscreen_shell" = "xyes")
 468
 469 # CMS modules
 470 AC_ARG_ENABLE(colord,
 471               AS_HELP_STRING([--disable-colord],
 472                              [do not build colord CMS support]),,
 473               enable_colord=auto)
 474 have_colord=no
 475 if test "x$enable_colord" != "xno"; then
 476         PKG_CHECK_MODULES(COLORD,
 477                           colord >= 0.1.27,
 478                           have_colord=yes,
 479                           have_colord=no)
 480         if test "x$have_colord" = "xno" -a "x$enable_colord" = "xyes"; then
 481           AC_MSG_ERROR([colord support explicitly requested, but colord couldn't be found])
 482         fi
 483         if test "x$have_colord" = "xyes"; then
 484              enable_colord=yes
 485         fi
 486 fi
 487 AM_CONDITIONAL(ENABLE_COLORD, test "x$enable_colord" = "xyes")
 488
 489 # dbus support
 490 AC_ARG_ENABLE(dbus,
 491               AS_HELP_STRING([--disable-dbus],
 492                              [do not build with dbus support]),,
 493               enable_dbus=auto)
 494 if test "x$enable_dbus" != "xno"; then
 495         PKG_CHECK_MODULES(DBUS,
 496                           dbus-1 >= 1.6,
 497                           have_dbus=yes,
 498                           have_dbus=no)
 499         if test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"; then
 500                 AC_MSG_ERROR([dbus support explicitly requested, but libdbus couldn't be found])
 501         fi
 502         if test "x$have_dbus" = "xyes"; then
 503                 enable_dbus=yes
 504                 AC_DEFINE([HAVE_DBUS], [1], [Build with dbus support])
 505         else
 506                 enable_dbus=no
 507         fi
 508 fi
 509 AM_CONDITIONAL(ENABLE_DBUS, test "x$enable_dbus" = "xyes")
 510
 511 # systemd-login support
 512 AC_ARG_ENABLE(systemd-login,
 513               AS_HELP_STRING([--enable-systemd-login],
 514                              [Enable logind support]),,
 515               enable_systemd_login=auto)
 516 if test x$enable_systemd_login != xno -a x$have_dbus != xno; then
 517   PKG_CHECK_MODULES(SYSTEMD_LOGIN,
 518                     [libsystemd >= 209],
 519                     [have_systemd_login_209=yes;have_systemd_login=yes],
 520                     [have_systemd_login_209=no;have_systemd_login=no])
 521
 522   # Older versions of systemd package systemd-login separately. Fall back on that
 523   AS_IF([test x$have_systemd_login != xyes],[
 524         PKG_CHECK_MODULES(SYSTEMD_LOGIN,
 525                           [libsystemd-login >= 198],
 526                           [have_systemd_login=yes],
 527                           [have_systemd_login=no])
 528         ])
 529 else
 530   have_systemd_login=no
 531 fi
 532
 533 if test "x$have_systemd_login" = "xno" -a "x$enable_systemd_login" = "xyes"; then
 534   AC_MSG_ERROR([systemd-login support explicitly enabled, but can't find libsystemd>=209, libsystemd-login or dbus])
 535 fi
 536
 537 AS_IF([test "x$have_systemd_login" = "xyes"],
 538       [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 539 AM_CONDITIONAL(HAVE_SYSTEMD_LOGIN, test "x$have_systemd_login" = "xyes")
 540
 541 AS_IF([test "x$have_systemd_login_209" = "xyes"],
 542       [AC_DEFINE([HAVE_SYSTEMD_LOGIN_209], [1], [Have systemd-login >= 209])])
 543
 544
 545 # Note that other features might want libxml2, or this feature might use
 546 # alternative xml libraries at some point. Therefore the feature and
 547 # pre-requisite concepts are split.
 548 AC_ARG_ENABLE(junit_xml,
 549               AS_HELP_STRING([--disable-junit-xml],
 550                              [do not build with JUnit XML output]),,
 551               enable_junit_xml=auto)
 552 if test "x$enable_junit_xml" != "xno"; then
 553         PKG_CHECK_MODULES(LIBXML2,
 554                           [libxml-2.0 >= 2.6],
 555                           have_libxml2=yes,
 556                           have_libxml2=no)
 557         if test "x$have_libxml2" = "xno" -a "x$enable_junit_xml" = "xyes"; then
 558                 AC_MSG_ERROR([JUnit XML support explicitly requested, but libxml2 couldn't be found])
 559         fi
 560         if test "x$have_libxml2" = "xyes"; then
 561                 enable_junit_xml=yes
 562                 AC_DEFINE(ENABLE_JUNIT_XML, [1], [Build Weston with JUnit output support])
 563         else
 564                 enable_junit_xml=no
 565         fi
 566 fi
 567 AM_CONDITIONAL(ENABLE_JUNIT_XML, test "x$enable_junit_xml" = "xyes")
 568
 569 # ivi-shell support
 570 AC_ARG_ENABLE(ivi-shell,
 571               AS_HELP_STRING([--disable-ivi-shell],
 572                              [do not build ivi-shell server plugin and client]),,
 573               enable_ivi_shell=yes)
 574 AM_CONDITIONAL(ENABLE_IVI_SHELL, test "x$enable_ivi_shell" = "xyes")
 575
 576 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 577 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 578 if test x$enable_wcap_tools = xyes; then
 579   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 580   PKG_CHECK_MODULES(WCAP, [cairo])
 581   WCAP_LIBS="$WCAP_LIBS -lm"
 582 fi
 583
 584 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 585 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 586
 587 if test "x$GCC" = "xyes"; then
 588         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter \
 589                 -Wno-shift-negative-value -Wno-missing-field-initializers \
 590                 -g -fvisibility=hidden \
 591                 -Wstrict-prototypes -Wmissing-prototypes -Wsign-compare"
 592 fi
 593 AC_SUBST(GCC_CFLAGS)
 594
 595 AC_ARG_ENABLE(libunwind,
 596               AS_HELP_STRING([--disable-libunwind],
 597                              [Disable libunwind usage for backtraces]),,
 598               enable_libunwind=auto)
 599 AM_CONDITIONAL(HAVE_LIBUNWIND, [test "x$enable_libunwind" = xyes])
 600 have_libunwind=no
 601 if test "x$enable_libunwind" != "xno"; then
 602         PKG_CHECK_MODULES(LIBUNWIND,
 603                           libunwind,
 604                           have_libunwind=yes,
 605                           have_libunwind=no)
 606         if test "x$have_libunwind" = "xno" -a "x$enable_libunwind" = "xyes"; then
 607           AC_MSG_ERROR([libunwind support explicitly requested, but libunwind couldn't be found])
 608         fi
 609         if test "x$have_libunwind" = "xyes"; then
 610              enable_libunwind=yes
 611              AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
 612         fi
 613 fi
 614
 615
 616 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 617         WESTON_NATIVE_BACKEND="drm-backend.so"
 618 fi
 619 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 620 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 621                    [The default backend to load, if not wayland nor x11.])
 622
 623 if test "x$WESTON_SHELL_CLIENT" = "x"; then
 624         WESTON_SHELL_CLIENT="weston-desktop-shell"
 625 fi
 626 AC_MSG_NOTICE([Weston's default desktop shell client: $WESTON_SHELL_CLIENT])
 627 AC_DEFINE_UNQUOTED([WESTON_SHELL_CLIENT], ["$WESTON_SHELL_CLIENT"],
 628                    [The default desktop shell client to load.])
 629
 630 AC_ARG_ENABLE(demo-clients-install,
 631               AS_HELP_STRING([--enable-demo-clients-install],
 632                              [Install demo clients built with weston]),,
 633                              enable_demo_clients_install=no)
 634 AM_CONDITIONAL(INSTALL_DEMO_CLIENTS, [test "x$enable_demo_clients_install" = "xyes"])
 635
 636 AC_ARG_ENABLE(lcms,
 637               AS_HELP_STRING([--disable-lcms],
 638                              [Disable lcms support]),,
 639               enable_lcms=auto)
 640 have_lcms=no
 641 if test "x$enable_lcms" != "xno"; then
 642         PKG_CHECK_MODULES(LCMS,
 643                           lcms2,
 644                           have_lcms=yes,
 645                           have_lcms=no)
 646         if test "x$have_lcms" = "xno" -a "x$enable_lcms" = "xyes"; then
 647           AC_MSG_ERROR([lcms support explicitly requested, but lcms couldn't be found])
 648         fi
 649         if test "x$have_lcms" = "xyes"; then
 650                 enable_lcms=yes
 651                 AC_DEFINE(HAVE_LCMS, 1, [Have lcms support])
 652         fi
 653 fi
 654 AM_CONDITIONAL(HAVE_LCMS, [test "x$enable_lcms" = xyes])
 655
 656 AC_PATH_PROG([wayland_scanner], [wayland-scanner])
 657 if test x$wayland_scanner = x; then
 658         PKG_CHECK_MODULES(WAYLAND_SCANNER, [wayland-scanner])
 659         wayland_scanner=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`
 660 fi
 661
 662 AC_ARG_ENABLE(systemd_notify,
 663               AS_HELP_STRING([--enable-systemd-notify],
 664                              [Enables systemd notifications to
 665                               notify systemd about weston state
 666                               and update watchdog.
 667                               Also sockets provided by systemd
 668                               in case of socket-base activation
 669                               are added to wayland display]),,
 670               enable_systemd_notify=no)
 671 AM_CONDITIONAL(SYSTEMD_NOTIFY_SUPPORT, test x$enable_systemd_notify = xyes)
 672 if test "x$enable_systemd_notify" = "xyes"; then
 673   AC_DEFINE([SYSTEMD_NOTIFY_SUPPORT], [1], [Build the systemd sd_notify support])
 674   PKG_CHECK_MODULES(SYSTEMD_DAEMON, [libsystemd])
 675 fi
 676
 677 AC_CONFIG_FILES([Makefile libweston/version.h compositor/weston.pc])
 678
 679 # AC_CONFIG_FILES needs the full name when running autoconf, so we need to use
 680 # libweston_abi_version here, and outside [] because of m4 quoting rules
 681 AC_CONFIG_FILES([libweston/libweston-]libweston_major_version[.pc:libweston/libweston.pc.in])
 682 AC_CONFIG_FILES([libweston/libweston-]libweston_major_version[-uninstalled.pc:libweston/libweston-uninstalled.pc.in])
 683 AC_CONFIG_FILES([libweston-desktop/libweston-desktop-]libweston_major_version[.pc:libweston-desktop/libweston-desktop.pc.in])
 684 AC_CONFIG_FILES([libweston-desktop/libweston-desktop-]libweston_major_version[-uninstalled.pc:libweston-desktop/libweston-desktop-uninstalled.pc.in])
 685
 686 AM_CONDITIONAL([HAVE_GIT_REPO], [test -f $srcdir/.git/logs/HEAD])
 687
 688 AC_OUTPUT
 689
 690 AC_MSG_RESULT([
 691         Native Backend                  ${WESTON_NATIVE_BACKEND}
 692         setuid Install                  ${enable_setuid_install}
 693
 694         Cairo Renderer                  ${with_cairo}
 695         EGL                             ${enable_egl}
 696         xcb_xkb                         ${have_xcb_xkb}
 697         XWayland                        ${enable_xwayland}
 698         dbus                            ${enable_dbus}
 699
 700         ivi-shell                       ${enable_ivi_shell}
 701
 702         Build wcap utility              ${enable_wcap_tools}
 703         Build Fullscreen Shell          ${enable_fullscreen_shell}
 704         Enable developer documentation  ${enable_devdocs}
 705
 706         weston-launch utility           ${enable_weston_launch}
 707         systemd-login support           ${have_systemd_login}
 708         systemd notify support          ${enable_systemd_notify}
 709
 710         DRM Compositor                  ${enable_drm_compositor}
 711         X11 Compositor                  ${enable_x11_compositor}
 712         Wayland Compositor              ${enable_wayland_compositor}
 713         Headless Compositor             ${enable_headless_compositor}
 714         FBDEV Compositor                ${enable_fbdev_compositor}
 715         RDP Compositor                  ${enable_rdp_compositor}
 716         Screen Sharing                  ${enable_screen_sharing}
 717         JUnit XML output                ${enable_junit_xml}
 718
 719         Build Clients                   ${enable_clients}
 720         Build EGL Clients               ${have_cairo_egl}
 721         Build Simple Clients            ${enable_simple_clients}
 722         Build Simple EGL Clients        ${enable_simple_egl_clients}
 723
 724         Install Demo Clients            ${enable_demo_clients_install}
 725
 726         Colord Support                  ${have_colord}
 727         LCMS2 Support                   ${have_lcms}
 728         libjpeg Support                 ${have_jpeglib}
 729         libwebp Support                 ${have_webp}
 730         libunwind Support               ${have_libunwind}
 731         VA H.264 encoding Support       ${have_libva}
 732 ])