configure.ac

   1 m4_define(LIBUSB_MAJOR, [1])
   2 m4_define(LIBUSB_MINOR, [0])
   3 m4_define(LIBUSB_MICRO, [8])
   4
   5 AC_INIT([libusb], LIBUSB_MAJOR.LIBUSB_MINOR.LIBUSB_MICRO, [libusb-devel@lists.sourceforge.net], [libusb], [http://www.libusb.org/])
   6
   7 AC_SUBST([LIBUSB_VERSION_MAJOR], [LIBUSB_MAJOR])
   8 AC_SUBST([LIBUSB_VERSION_MINOR], [LIBUSB_MINOR])
   9 AC_SUBST([LIBUSB_VERSION_MICRO], [LIBUSB_MICRO])
  10
  11 # Library versioning
  12 # These numbers should be tweaked on every release. Read carefully:
  13 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  14 # http://sourceware.org/autobook/autobook/autobook_91.html
  15 lt_current="1"
  16 lt_revision="0"
  17 lt_age="1"
  18 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  19
  20 AM_INIT_AUTOMAKE
  21 AM_MAINTAINER_MODE
  22
  23 AC_CONFIG_SRCDIR([libusb/core.c])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AM_CONFIG_HEADER([config.h])
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_PREREQ([2.50])
  29 AC_PROG_CC
  30 AC_PROG_LIBTOOL
  31 AC_C_INLINE
  32 AM_PROG_CC_C_O
  33 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  34
  35 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  36
  37 AC_MSG_CHECKING([operating system])
  38 case $host in
  39 *-linux*)
  40         AC_DEFINE(OS_LINUX, 1, [Linux backend])
  41         AC_SUBST(OS_LINUX)
  42         AC_MSG_RESULT([Linux])
  43         backend="linux"
  44         AC_CHECK_LIB(rt, clock_gettime, PC_LIBS_PRIVATE="-lrt")
  45         threads="posix"
  46         THREAD_CFLAGS="-pthread"
  47         PC_LIBS_PRIVATE="${PC_LIBS_PRIVATE} -pthread"
  48         AC_CHECK_HEADERS([poll.h])
  49         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
  50         ;;
  51 *-darwin*)
  52         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
  53         AC_SUBST(OS_DARWIN)
  54         AC_MSG_RESULT([Darwin/Mac OS X])
  55         backend="darwin"
  56         threads="posix"
  57         PC_LIBS_PRIVATE="-Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
  58         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
  59         AC_CHECK_HEADERS([poll.h])
  60         AC_CHECK_TYPE([nfds_t],
  61                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
  62                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
  63                 [#include <poll.h>])
  64         ;;
  65 *-mingw*)
  66         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
  67         AC_SUBST(OS_WINDOWS)
  68         AC_MSG_RESULT([Windows])
  69         backend="windows"
  70         PC_LIBS_PRIVATE="-lsetupapi -lole32 -ladvapi32"
  71         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
  72         AC_CHECK_TOOL(RC, windres, no)
  73         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
  74         ;;
  75 *-cygwin*)
  76         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
  77         AC_SUBST(OS_WINDOWS)
  78         AC_MSG_RESULT([Cygwin (using Windows backend)])
  79         backend="windows"
  80         threads="posix"
  81         PC_LIBS_PRIVATE="-lsetupapi -lole32 -ladvapi32"
  82         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
  83         AC_CHECK_TOOL(RC, windres, no)
  84         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
  85         ;;
  86 *)
  87         AC_MSG_ERROR([unsupported operating system])
  88 esac
  89 AC_SUBST(THREAD_CFLAGS)
  90 AC_SUBST(PC_LIBS_PRIVATE)
  91 LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
  92
  93 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
  94 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
  95 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
  96 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
  97 if test "$threads" = posix; then
  98         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
  99 fi
 100
 101 # timerfd
 102 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 103 AC_ARG_ENABLE([timerfd],
 104         [AS_HELP_STRING([--enable-timerfd],
 105                 [use timerfd for timing (default auto)])],
 106         [use_timerfd=$enableval], [use_timerfd='auto'])
 107
 108 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 109         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 110 fi
 111
 112 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 113 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 114         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 115 fi
 116
 117 AC_MSG_CHECKING([whether to use timerfd for timing])
 118 if test "x$use_timerfd" = "xno"; then
 119         AC_MSG_RESULT([no (disabled by user)])
 120 else
 121         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 122                 AC_MSG_RESULT([yes])
 123                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 124         else
 125                 AC_MSG_RESULT([no (header not available)])
 126         fi
 127 fi
 128
 129 AC_CHECK_TYPES(struct timespec)
 130
 131 # Message logging
 132 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 133         [log_enabled=$enableval],
 134         [log_enabled='yes'])
 135 if test "x$log_enabled" != "xno"; then
 136         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 137 fi
 138
 139 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 140         [enable debug logging (default n)])],
 141         [debug_log_enabled=$enableval],
 142         [debug_log_enabled='no'])
 143 if test "x$debug_log_enabled" != "xno"; then
 144         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
 145 fi
 146
 147 # Examples build
 148 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 149         [build example applications (default n)])],
 150         [build_examples=$enableval],
 151         [build_examples='no'])
 152 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 153
 154 # Restore gnu89 inline semantics on gcc 4.3 and newer
 155 saved_cflags="$CFLAGS"
 156 CFLAGS="$CFLAGS -fgnu89-inline"
 157 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])], inline_cflags="-fgnu89-inline", inline_cflags="")
 158 CFLAGS="$saved_cflags"
 159
 160 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 161 saved_cflags="$CFLAGS"
 162 # -Werror required for cygwin
 163 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 164 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 165         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 166          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 167         [ VISIBILITY_CFLAGS=""
 168          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 169         ])
 170 CFLAGS="$saved_cflags"
 171
 172 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 173 saved_cflags="$CFLAGS"
 174 CFLAGS="$CFLAGS -Wno-pointer-sign"
 175 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 176         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 177 CFLAGS="$saved_cflags"
 178
 179 # sigaction not available on MinGW
 180 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 181 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 182
 183 # headers not available on all platforms but required on others
 184 AC_CHECK_HEADERS([sys/time.h])
 185
 186 AM_CFLAGS="-std=gnu99 $inline_cflags -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 187
 188 AC_SUBST(VISIBILITY_CFLAGS)
 189 AC_SUBST(AM_CFLAGS)
 190 AC_SUBST(LTLDFLAGS)
 191
 192 AC_CONFIG_FILES([libusb-1.0.pc])
 193 AC_CONFIG_FILES([Makefile])
 194 AC_CONFIG_FILES([libusb/Makefile])
 195 AC_CONFIG_FILES([libusb/libusb-1.0.rc])
 196 AC_CONFIG_FILES([examples/Makefile])
 197 AC_CONFIG_FILES([doc/Makefile])
 198 AC_CONFIG_FILES([doc/doxygen.cfg])
 199 AC_OUTPUT