configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23 AC_INIT([polypaudio],[0.8],[mzcbylcnhqvb (at) 0pointer (dot) de])
  24 AC_CONFIG_SRCDIR([polyp/main.c])
  25 AC_CONFIG_HEADERS([config.h])
  26 AM_INIT_AUTOMAKE([foreign -Wall])
  27
  28 AC_SUBST(PA_MAJORMINOR, "$PACKAGE_VERSION")
  29 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  30
  31 AC_SUBST(PA_API_VERSION, 8)
  32
  33 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  34    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  35    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  36 fi
  37
  38 #### Checks for programs. ####
  39
  40 # CC
  41
  42 AC_PROG_CC
  43 AC_PROG_GCC_TRADITIONAL
  44 AC_GNU_SOURCE
  45
  46 # If using GCC specify some additional parameters
  47 if test "x$GCC" = "xyes" ; then
  48    CFLAGS="$CFLAGS -pipe -W -Wall -pedantic"
  49
  50    AC_LANG_CONFTEST([int main() {}])
  51    $CC -c conftest.c -std=gnu9x -Wno-unused-parameter $CFLAGS > /dev/null 2> /dev/null && CFLAGS="$CFLAGS -std=gnu9x -Wno-unused-parameter"
  52    rm -f conftest.o
  53 fi
  54
  55 # M4
  56
  57 AC_PATH_PROG([M4], [m4 gm4], [no])
  58 if test "x$M4" = xno ; then
  59    AC_MSG_ERROR([m4 missing])
  60 fi
  61
  62 # GCC flags
  63
  64 test_gcc_flag() {
  65     AC_LANG_CONFTEST([int main() {}])
  66     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  67     ret=$?
  68     rm -f conftest.o
  69     return $ret
  70 }
  71
  72 # If using GCC specify some additional parameters
  73 if test "x$GCC" = "xyes" ; then
  74
  75     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
  76
  77     if test "x$HAVE_NETLINK" = "xyes" ; then
  78         # Test whether rtnetlink.h can be included when compiled with -std=c99
  79         # some distributions (e.g. archlinux) have broken headers that dont
  80         # define __u64 with -std=c99
  81         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
  82         OLDCFLAGS="$CFLAGS"
  83         CFLAGS="-std=c99"
  84         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
  85             use_stdc99=yes, use_stdc99=no)
  86
  87         if test x"$use_stdc99" = xyes; then
  88             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
  89             AC_MSG_RESULT([yes])
  90         else
  91             AC_MSG_RESULT([no])
  92         fi
  93
  94         CFLAGS="$OLDCFLAGS"
  95     else
  96         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
  97     fi
  98
  99     for flag in $DESIRED_FLAGS ; do
 100         AC_MSG_CHECKING([whether $CC accepts $flag])
 101         if test_gcc_flag $flag ; then
 102            CFLAGS="$CFLAGS $flag"
 103            AC_MSG_RESULT([yes])
 104         else
 105            AC_MSG_RESULT([no])
 106         fi
 107     done
 108 fi
 109
 110 # LYNX documentation generation
 111 AC_ARG_ENABLE(lynx,
 112         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
 113 [case "${enableval}" in
 114   yes) lynx=yes ;;
 115   no)  lynx=no ;;
 116   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
 117 esac],[lynx=yes])
 118
 119 if test x$lynx = xyes ; then
 120    AC_CHECK_PROG(have_lynx, lynx, yes, no)
 121
 122    if test x$have_lynx = xno ; then
 123      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 124    fi
 125 fi
 126
 127 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 128
 129 #### libtool stuff ####
 130
 131 AC_LTDL_ENABLE_INSTALL
 132 AC_LIBLTDL_INSTALLABLE
 133 AC_SUBST(LTDLINCL)
 134 AC_SUBST(LIBLTDL)
 135 AC_LIBTOOL_DLOPEN
 136 AC_LIBTOOL_WIN32_DLL
 137 AC_PROG_LIBTOOL
 138 AC_CONFIG_SUBDIRS(libltdl)
 139
 140 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 141     AC_MSG_ERROR([[
 142
 143         *** Cannot find the libltdl development files.
 144         *** Maybe you need to install the libltdl-dev package.
 145         ]])
 146 fi
 147
 148 #### Determine build environment ####
 149
 150 os_is_win32=0
 151
 152 case "$host_os" in
 153         mingw*)
 154         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 155         os_is_win32=1
 156                 ;;
 157         esac
 158
 159 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 160
 161 ###################################
 162 #   Basic environment checks      #
 163 ###################################
 164
 165 #### Checks for header files. ####
 166
 167 # ISO
 168 AC_HEADER_STDC
 169
 170 # POSIX
 171 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 172     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 173     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 174     syslog.h])
 175 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 176 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 177
 178 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 179 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 180
 181 # XPG4-UNIX
 182 AC_CHECK_HEADERS([sys/poll.h])
 183
 184 # Linux
 185 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 186
 187 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 188
 189 # Windows
 190 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 191
 192 # Other
 193 AC_CHECK_HEADERS([sys/ioctl.h])
 194
 195 #### Typdefs, structures, etc. ####
 196
 197 AC_C_CONST
 198 AC_C_BIGENDIAN
 199 AC_TYPE_PID_T
 200 AC_TYPE_SIZE_T
 201 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 202     [Define ssize_t if it is not done by the standard libs.])])
 203 AC_TYPE_OFF_T
 204 AC_TYPE_SIGNAL
 205 AC_TYPE_UID_T
 206
 207 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 208 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 209
 210 # Solaris lacks this
 211 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 212     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 213
 214 #### Check for libs ####
 215
 216 # ISO
 217 AC_CHECK_LIB([m], [pow])
 218
 219 # POSIX
 220 AC_CHECK_LIB([rt], [sched_setscheduler])
 221
 222 # BSD
 223 AC_CHECK_LIB([socket], [connect])
 224
 225 # Non-standard
 226
 227 # This magic is needed so we do not needlessly add static libs to the win32
 228 # build, disabling its ability to make dlls.
 229 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 230
 231 #### Check for functions ####
 232
 233 # POSIX
 234 AC_FUNC_FORK
 235 AC_FUNC_GETGROUPS
 236 AC_FUNC_SELECT_ARGTYPES
 237 AC_CHECK_FUNCS([getaddrinfo getgrgid_r getpwuid_r gettimeofday getuid \
 238     inet_ntop nanosleep setpgid setsid sigaction sleep])
 239 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 240
 241 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 242
 243 # X/OPEN
 244 AC_CHECK_FUNCS([readlink])
 245
 246 # SUSv2
 247 AC_CHECK_FUNCS([ctime_r usleep])
 248
 249 # BSD
 250 AC_CHECK_FUNCS([lstat])
 251
 252 # Non-standard
 253
 254 AC_CHECK_FUNCS(setresuid)
 255 AC_CHECK_FUNCS(setreuid)
 256
 257 #### POSIX threads ####
 258
 259 ACX_PTHREAD
 260
 261 ###################################
 262 #      External libraries         #
 263 ###################################
 264
 265 #### X11 (optional) ####
 266
 267 HAVE_X11=0
 268
 269 # The macro tests the host, not the build target
 270 if test "x$os_is_win32" != "x1" ; then
 271     AC_PATH_XTRA
 272     test "x$no_x" != "xyes" && HAVE_X11=1
 273 fi
 274
 275 AC_SUBST(HAVE_X11)
 276 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 277 if test "x$HAVE_X11" = "x1" ; then
 278     AC_DEFINE([HAVE_X11], 1, [Have X11])
 279 fi
 280
 281 #### Capabilities (optional) ####
 282
 283 CAP_LIBS=''
 284
 285 AC_ARG_WITH(
 286         [caps],
 287         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 288
 289 if test "x${with_caps}" != "xno"; then
 290     AC_CHECK_LIB(cap, cap_init, [CAP_LIBS='-lcap'], [CAP_LIBS=''])
 291     AC_CHECK_HEADERS([sys/capability.h])
 292 fi
 293 AC_SUBST(CAP_LIBS)
 294
 295 #### pkg-config ####
 296
 297 # Check for pkg-config manually first, as if its not installed the
 298 # PKG_PROG_PKG_CONFIG macro won't be defined.
 299 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 300
 301 if test x"$have_pkg_config" = "xno"; then
 302     AC_MSG_ERROR(pkg-config is required to install this program)
 303 fi
 304
 305 PKG_PROG_PKG_CONFIG
 306
 307 #### Sample rate conversion ####
 308
 309 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 310 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 311 AC_SUBST(LIBSAMPLERATE_LIBS)
 312
 313 #### Sound file ####
 314
 315 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 316 AC_SUBST(LIBSNDFILE_CFLAGS)
 317 AC_SUBST(LIBSNDFILE_LIBS)
 318
 319 #### OSS support (optional) ####
 320
 321 AC_CHECK_HEADERS([sys/soundcard.h], [HAVE_OSS=1], [HAVE_OSS=0])
 322 AC_SUBST(HAVE_OSS)
 323 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 324
 325 #### ALSA support (optional) ####
 326
 327 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [HAVE_ALSA=1], [HAVE_ALSA=0])
 328 AC_SUBST(ASOUNDLIB_CFLAGS)
 329 AC_SUBST(ASOUNDLIB_LIBS)
 330 AC_SUBST(HAVE_ALSA)
 331 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 332
 333 #### Solaris audio support (optional) ####
 334
 335 AC_CHECK_HEADERS([sys/audio.h], [HAVE_SOLARIS=1], [HAVE_SOLARIS=0])
 336 AC_SUBST(HAVE_SOLARIS)
 337 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 338
 339 #### GLib 2 support (optional) ####
 340
 341 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 342 AC_SUBST(GLIB20_CFLAGS)
 343 AC_SUBST(GLIB20_LIBS)
 344 AC_SUBST(HAVE_GLIB20)
 345 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 346
 347 #### GLib 1 support (optional) ####
 348
 349 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 350 AC_SUBST(GLIB12_CFLAGS)
 351 AC_SUBST(GLIB12_LIBS)
 352 AC_SUBST(HAVE_GLIB12)
 353 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 354
 355 #### Howl support (optional) ####
 356
 357 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 358 AC_SUBST(HOWL_CFLAGS)
 359 AC_SUBST(HOWL_LIBS)
 360 AC_SUBST(HAVE_HOWL)
 361 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 362
 363 #### Async DNS support (optional) ####
 364
 365 PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)
 366 AC_SUBST(LIBASYNCNS_CFLAGS)
 367 AC_SUBST(LIBASYNCNS_LIBS)
 368 AC_SUBST(HAVE_LIBASYNCNS)
 369 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 370
 371 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 372    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 373 fi
 374
 375 #### TCP wrappers (optional) ####
 376
 377 ACX_LIBWRAP
 378 AC_SUBST(LIBWRAP_LIBS)
 379
 380 #### LIRC support (optional) ####
 381
 382 ACX_LIRC
 383 AC_SUBST(LIRC_CFLAGS)
 384 AC_SUBST(LIRC_LIBS)
 385 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 386
 387 ###################################
 388 #            Output               #
 389 ###################################
 390
 391 AC_ARG_ENABLE(
 392         [static-bins],
 393         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 394         [STATIC_BINS=1], [STATIC_BINS=0])
 395 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 396
 397 AC_ARG_WITH(
 398         [preopen-mods],
 399         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 400         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 401 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 402 if test "x$PREOPEN_MODS" != "xall" ; then
 403     tmpLIBS=""
 404     for mod in $PREOPEN_MODS; do
 405         tmpLIBS="$tmpLIBS module-$mod.la"
 406     done
 407     PREOPEN_MODS="$tmpLIBS"
 408     AC_SUBST(PREOPEN_MODS)
 409 fi
 410
 411 AC_CONFIG_FILES([
 412 Makefile
 413 polyp/Makefile
 414 polyplib.pc
 415 polyplib-simple.pc
 416 polyplib-mainloop.pc
 417 polyplib-browse.pc
 418 polyplib-error.pc
 419 polyplib-glib-mainloop.pc
 420 polyplib-glib12-mainloop.pc
 421 doc/Makefile
 422 doc/README.html
 423 doc/cli.html
 424 doc/daemon.html
 425 doc/modules.html
 426 doxygen/Makefile
 427 doxygen/doxygen.conf
 428 polyp/polyplib-version.h
 429 doc/FAQ.html
 430 ])
 431 AC_OUTPUT