configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.26],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  33 AM_MAINTAINER_MODE([enable])
  34
  35 # Enable quiet compiles on automake 1.11.
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 # Check for programs
  39 AC_PROG_CC
  40
  41 AC_USE_SYSTEM_EXTENSIONS
  42 AC_SYS_LARGEFILE
  43 AC_FUNC_ALLOCA
  44
  45 # Initialize libtool
  46 LT_PREREQ([2.2])
  47 LT_INIT([disable-static])
  48
  49
  50 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  51 AC_SUBST(PTHREADSTUBS_CFLAGS)
  52 AC_SUBST(PTHREADSTUBS_LIBS)
  53
  54 PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
  55 AC_SUBST(PCIACCESS_CFLAGS)
  56 AC_SUBST(PCIACCESS_LIBS)
  57
  58 pkgconfigdir=${libdir}/pkgconfig
  59 AC_SUBST(pkgconfigdir)
  60 AC_ARG_ENABLE([udev],
  61               [AS_HELP_STRING([--enable-udev],
  62                               [Enable support for using udev instead of mknod (default: disabled)])],
  63               [UDEV=$enableval], [UDEV=no])
  64
  65 AC_ARG_ENABLE(libkms,
  66               AS_HELP_STRING([--disable-libkms],
  67               [Disable KMS mm abstraction library (default: auto)]),
  68               [LIBKMS=$enableval], [LIBKMS=auto])
  69
  70 AC_ARG_ENABLE(intel,
  71               AS_HELP_STRING([--disable-intel],
  72               [Enable support for intel's KMS API (default: auto)]),
  73               [INTEL=$enableval], [INTEL=auto])
  74
  75 AC_ARG_ENABLE(radeon,
  76               AS_HELP_STRING([--disable-radeon],
  77               [Enable support for radeon's KMS API (default: auto)]),
  78               [RADEON=$enableval], [RADEON=auto])
  79
  80 AC_ARG_ENABLE(vmwgfx-experimental-api,
  81               AS_HELP_STRING([--enable-vmwgfx-experimental-api],
  82               [Install vmwgfx's experimental kernel API header (default: disabled)]),
  83               [VMWGFX=$enableval], [VMWGFX=no])
  84
  85 AC_ARG_ENABLE(nouveau-experimental-api,
  86               AS_HELP_STRING([--enable-nouveau-experimental-api],
  87               [Enable support for nouveau's experimental API (default: disabled)]),
  88               [NOUVEAU=$enableval], [NOUVEAU=no])
  89
  90
  91 dnl ===========================================================================
  92 dnl check compiler flags
  93 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
  94   AC_MSG_CHECKING([whether $CC supports $1])
  95
  96   libdrm_save_CFLAGS="$CFLAGS"
  97   CFLAGS="$CFLAGS $1"
  98
  99   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
 100   CFLAGS="$libdrm_save_CFLAGS"
 101
 102   if test "x$libdrm_cc_flag" = "xyes"; then
 103     ifelse([$2], , :, [$2])
 104   else
 105     ifelse([$3], , :, [$3])
 106   fi
 107   AC_MSG_RESULT([$libdrm_cc_flag])
 108 ])
 109
 110 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 111
 112 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 113                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 114                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 115 AC_SUBST([CLOCK_LIB])
 116
 117 dnl Use lots of warning flags with with gcc and compatible compilers
 118
 119 dnl Note: if you change the following variable, the cache is automatically
 120 dnl skipped and all flags rechecked.  So there's no need to do anything
 121 dnl else.  If for any reason you need to force a recheck, just change
 122 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 123
 124 MAYBE_WARN="-Wall -Wextra \
 125 -Wsign-compare -Werror-implicit-function-declaration \
 126 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 127 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 128 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 129 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
 130 -Wdeclaration-after-statement -Wold-style-definition \
 131 -Wno-missing-field-initializers -Wno-unused-parameter \
 132 -Wno-attributes -Wno-long-long -Winline"
 133
 134 # invalidate cached value if MAYBE_WARN has changed
 135 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 136         unset libdrm_cv_warn_cflags
 137 fi
 138 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 139         echo
 140         WARN_CFLAGS=""
 141
 142         # Some warning options are not supported by all versions of
 143         # gcc, so test all desired options against the current
 144         # compiler.
 145         #
 146         # Note that there are some order dependencies
 147         # here. Specifically, an option that disables a warning will
 148         # have no net effect if a later option then enables that
 149         # warnings, (perhaps implicitly). So we put some grouped
 150         # options (-Wall and -Wextra) up front and the -Wno options
 151         # last.
 152
 153         for W in $MAYBE_WARN; do
 154                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 155         done
 156
 157         libdrm_cv_warn_cflags=$WARN_CFLAGS
 158         libdrm_cv_warn_maybe=$MAYBE_WARN
 159
 160         AC_MSG_CHECKING([which warning flags were supported])])
 161 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 162
 163 if test "x$UDEV" = xyes; then
 164         AC_DEFINE(UDEV, 1, [Have UDEV support])
 165 fi
 166
 167 AC_CANONICAL_HOST
 168 if test "x$LIBKMS" = xauto ; then
 169         case $host_os in
 170                 linux*)         LIBKMS="yes" ;;
 171                 *)              LIBKMS="no" ;;
 172         esac
 173 fi
 174
 175 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 176
 177 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 178 if test "x$VMWGFX" = xyes; then
 179         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 180 fi
 181
 182 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 183 if test "x$NOUVEAU" = xyes; then
 184         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 185 fi
 186
 187 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 188 if test "x$HAVE_CAIRO" = xyes; then
 189         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
 190 fi
 191 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
 192
 193 # For enumerating devices in test case
 194 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 195 if test "x$HAVE_LIBUDEV" = xyes; then
 196         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 197 fi
 198 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 199
 200 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno"; then
 201     # Check for atomic intrinsics
 202     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
 203     [
 204             drm_cv_atomic_primitives="none"
 205
 206             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 207     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 208     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 209                                             ]],[[]])],
 210                            [drm_cv_atomic_primitives="Intel"],[])
 211
 212             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 213                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 214             fi
 215
 216             # atomic functions defined in <atomic.h> & libc on Solaris
 217             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 218                     AC_CHECK_FUNC([atomic_cas_uint],
 219                                   drm_cv_atomic_primitives="Solaris")
 220             fi
 221
 222     ])
 223     if test "x$drm_cv_atomic_primitives" = xIntel; then
 224             AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 225                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
 226     fi
 227     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 228             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 229     fi
 230
 231     if test "x$drm_cv_atomic_primitives" = "xnone"; then
 232            if test "x$INTEL" != "xauto"; then
 233                    if test "x$INTEL" != "xno"; then
 234                         AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
 235                    fi
 236            else
 237                    AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 238                    INTEL=no
 239            fi
 240            if test "x$RADEON" != "xauto"; then
 241                    if test "x$RADEON" != "xno"; then
 242                         AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
 243                    fi
 244            else
 245                    AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 246                    RADEON=no
 247            fi
 248
 249     else
 250            if test "x$INTEL" != "xno"; then
 251                    INTEL=yes
 252            fi
 253            if test "x$RADEON" != "xno"; then
 254                    RADEON=yes
 255            fi
 256     fi
 257 fi
 258
 259 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
 260 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" != "xno"])
 261 if test "x$RADEON" = xyes; then
 262         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 263 fi
 264
 265 AC_ARG_WITH([kernel-source],
 266             [AS_HELP_STRING([--with-kernel-source],
 267               [specify path to linux kernel source])],
 268             [kernel_source="$with_kernel_source"])
 269 AC_SUBST(kernel_source)
 270
 271 AC_SUBST(WARN_CFLAGS)
 272 AC_CONFIG_FILES([
 273         Makefile
 274         libkms/Makefile
 275         libkms/libkms.pc
 276         intel/Makefile
 277         intel/libdrm_intel.pc
 278         radeon/Makefile
 279         radeon/libdrm_radeon.pc
 280         nouveau/Makefile
 281         nouveau/libdrm_nouveau.pc
 282         tests/Makefile
 283         tests/modeprint/Makefile
 284         tests/modetest/Makefile
 285         tests/kmstest/Makefile
 286         tests/vbltest/Makefile
 287         include/Makefile
 288         include/drm/Makefile
 289         libdrm.pc])
 290 AC_OUTPUT
 291
 292 echo ""
 293 echo "$PACKAGE_STRING will be compiled with:"
 294 echo ""
 295 echo "  libkms         $LIBKMS"
 296 echo "  Intel API      $INTEL"
 297 echo "  vmwgfx API     $VMWGFX"
 298 echo "  Radeon API     $RADEON"
 299 echo "  Nouveau API    $NOUVEAU"
 300 echo ""