configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [7])
   6 m4_define([folks_micro_version], [2])
   7 m4_define([folks_nano_version], [2])
   8
   9 # If library source has changed since last release, increment revision
  10 # If public symbols have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If public symbols have been added since last release, increment age
  13 # If public symbols have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [35])
  15 m4_define([folks_lt_revision], [0])
  16 m4_define([folks_lt_age], [10])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-xz no-define
  46                   no-dist-gzip tar-ustar -Wno-portability])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54 GLIB_GSETTINGS
  55
  56 AC_SUBST([CFLAGS])
  57 AC_SUBST([CPPFLAGS])
  58 AC_SUBST([LDFLAGS])
  59
  60 LT_CURRENT=folks_lt_current
  61 LT_REVISION=folks_lt_revision
  62 LT_AGE=folks_lt_age
  63 AC_SUBST([LT_CURRENT])
  64 AC_SUBST([LT_REVISION])
  65 AC_SUBST([LT_AGE])
  66
  67 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  68 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  69
  70 API_VERSION=0.6
  71 AC_SUBST([API_VERSION])
  72
  73 AC_ARG_ENABLE(tracker-backend,
  74         AC_HELP_STRING([--enable-tracker-backend],
  75                        [ build the Tracker backend]),
  76         enable_tracker_backend=$enableval,
  77         enable_tracker_backend=no )
  78
  79 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  80
  81 if test "x$enable_tracker_backend" = "xyes"; then
  82         AC_DEFINE(HAVE_TRACKER, [1],
  83                   [Define as 1 if you have the Tracker backend])
  84 else
  85         AC_DEFINE(HAVE_TRACKER, [0],
  86                   [Define as 1 if you have the Tracker backend])
  87 fi
  88
  89 AC_ARG_ENABLE(eds-backend,
  90         AC_HELP_STRING([--enable-eds-backend],
  91                        [ build the E-D-S backend]),
  92         enable_eds_backend=$enableval,
  93         enable_eds_backend=yes )
  94
  95 if test "x$enable_eds_backend" = "xyes"; then
  96         AC_DEFINE(HAVE_EDS, [1], [Define as 1 if you have the eds backend])
  97 else
  98         AC_DEFINE(HAVE_EDS, [0], [Define as 1 if you have the eds backend])
  99 fi
 100
 101
 102 AM_CONDITIONAL([ENABLE_EDS], [test "x$enable_eds_backend" = "xyes"])
 103
 104 # Automatically check the dependencies for the libsocialweb backend
 105 SW_CLIENT_REQUIRED=0.25.20
 106 AC_ARG_ENABLE(libsocialweb-backend,
 107         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
 108                        [build the Libsocialweb backend (default: auto)]),
 109         enable_libsocialweb_backend=$enableval,
 110         enable_libsocialweb_backend=auto )
 111
 112 # this may be overwritten farther down
 113 AC_DEFINE(HAVE_LIBSOCIALWEB, [0],
 114           [Define as 1 if you have the libsocialweb backend])
 115 if test "x$enable_libsocialweb_backend" != "xno"; then
 116   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
 117       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
 118   if test "x$have_libsocialweb_backend" = "xyes" -a \
 119           "x$enable_vala" = "xyes"; then
 120     VALA_CHECK_PACKAGES([telepathy-glib
 121                          gio-2.0
 122                          gee-0.8
 123                          libsocialweb-client],
 124         ,
 125         have_libsocialweb_backend="no")
 126   fi
 127
 128   if test "x$have_libsocialweb_backend" = "xyes"; then
 129     AC_DEFINE(HAVE_LIBSOCIALWEB, [1],
 130               [Define if you have the libsocialweb backend])
 131   fi
 132 else
 133    have_libsocialweb_backend=no
 134 fi
 135
 136 if test "x$enable_libsocialweb_backend" = "xyes" -a \
 137   "x$have_libsocialweb_backend" != "xyes"; then
 138     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 139 fi
 140
 141 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 142         [test "x$have_libsocialweb_backend" = "xyes"])
 143
 144 # -----------------------------------------------------------
 145 # Dependencies
 146 # -----------------------------------------------------------
 147
 148 GLIB_REQUIRED=2.26.0
 149 VALA_REQUIRED=0.15.2
 150 VALADOC_REQUIRED=0.3.1
 151 TRACKER_SPARQL_MAJOR=0.14
 152 TRACKER_SPARQL_REQUIRED=0.13.1
 153 EBOOK_REQUIRED=3.5.3
 154 EDATASERVER_REQUIRED=3.5.3.1
 155 ZEITGEIST_REQUIRED=0.3.14
 156
 157 AC_SUBST([TRACKER_SPARQL_MAJOR])
 158
 159 PKG_CHECK_MODULES([GLIB],
 160                   [glib-2.0 >= $GLIB_REQUIRED
 161                    gobject-2.0 >= $GLIB_REQUIRED])
 162 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 163 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 164 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1])
 165
 166 PKG_CHECK_MODULES([GEE], [gee-0.8])
 167
 168 TP_GLIB_REQUIRED=0.19.0
 169 PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 170
 171 # Ignore post 0.20 deprecations
 172 TP_GLIB_CFLAGS="$TP_GLIB_CFLAGS -DTP_VERSION_MIN_REQUIRED=TP_VERSION_0_20"
 173 # Prevent post 0.20 APIs
 174 TP_GLIB_CFLAGS="$TP_GLIB_CFLAGS -DTP_VERSION_MAX_ALLOWED=TP_VERSION_0_20"
 175
 176 if test x$enable_tracker_backend = xyes; then
 177         PKG_CHECK_MODULES([TRACKER_SPARQL],
 178                           [tracker-sparql-$TRACKER_SPARQL_MAJOR >= \
 179                            $TRACKER_SPARQL_REQUIRED])
 180 fi
 181
 182 if test x$enable_eds_backend = xyes; then
 183         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED])
 184         PKG_CHECK_MODULES([EDATASERVER], [libedataserver-1.2 >= $EDATASERVER_REQUIRED])
 185 fi
 186
 187 PKG_CHECK_MODULES([ZEITGEIST], [zeitgeist-1.0 >= $ZEITGEIST_REQUIRED])
 188
 189 #
 190 # Vala building options -- allows tarball builds without installing Vala
 191 #
 192 AC_ARG_ENABLE([vala],
 193               AS_HELP_STRING([--enable-vala],
 194                              [Enable building from the Vala sources]),
 195               [enable_vala=$enableval],
 196               [enable_vala=no])
 197
 198 # will be re-set as necessary below
 199 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 200 sd=${srcdir}/
 201
 202 # Force Vala for non-release builds
 203 m4_if(folks_released, [1], [],
 204     [
 205         enable_vala=yes
 206         echo "Vala compiler required for non-release builds; requiring Vala..."
 207     ])
 208
 209 # Force Vala if generated source is missing or outdated
 210 if test \
 211         ! -e ${sd}tools/folks_import_vala.stamp -o \
 212         ! -e ${sd}tests/folks/abstract_field_details_vala.stamp -o \
 213         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 214         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 215         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 216         ! -e ${sd}tests/lib/folks-test.vapi -o \
 217         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 218         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 219         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 220         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 221         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 222         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 223         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 224         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 225         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 226         ! -e ${sd}backends/key-file/key_file_la_vala.stamp -o \
 227         ! -e ${sd}backends/telepathy/telepathy_la_vala.stamp \
 228                 -o \
 229         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 230         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 231         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 232         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 233         ! -e ${sd}folks/folks-internal.h -o \
 234         ! -e ${sd}folks/folks-internal.vapi -o \
 235         ! -e ${sd}folks/libfolks_internal_la_vala.stamp -o \
 236         ! -e ${sd}folks/folks.vapi -o \
 237         ! -e ${sd}folks/libfolks_la_vala.stamp ; then
 238         enable_vala=yes
 239         echo "Vala source needs to be re-compiled; requiring Vala..."
 240 fi
 241
 242 if test "x$enable_vala" = "xyes" ; then
 243         AM_PROG_VALAC([$VALA_REQUIRED])
 244         if test "x$VALAC" = "x"; then
 245               AC_MSG_ERROR([Vala requested but valac is not installed])
 246         fi
 247
 248         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 249         if test "x$VAPIGEN" = "x"; then
 250               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 251         fi
 252
 253         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 254         # automatically
 255         VALAFLAGS="$VALAFLAGS --target-glib=2.24"
 256         AC_SUBST([VALAFLAGS])
 257         AC_SUBST([VAPIGENFLAGS])
 258         AC_SUBST([VAPIDIR])
 259
 260         VALA_CHECK_PACKAGES([telepathy-glib
 261                              gio-2.0
 262                              gee-0.8
 263                              zeitgeist-1.0])
 264
 265         if test x$enable_tracker_backend = xyes; then
 266           VALA_CHECK_PACKAGES([tracker-sparql-$TRACKER_SPARQL_MAJOR])
 267         fi
 268
 269         if test x$enable_eds_backend = xyes; then
 270           VALA_CHECK_PACKAGES([libebook-1.2 libedataserver-1.2 libxml-2.0])
 271         fi
 272 fi
 273
 274 # this will set HAVE_INTROSPECTION
 275 GOBJECT_INTROSPECTION_REQUIRE([1.30])
 276
 277 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 278
 279 # Various functions that we need (used in C code generated from Vala)
 280 AC_CHECK_FUNCS([memset])
 281 AC_CHECK_FUNCS([strstr])
 282
 283 # -----------------------------------------------------------
 284 # Backends
 285 # -----------------------------------------------------------
 286
 287 FOLKS_MODULE_VERSION=folks_module_version
 288 AC_SUBST([FOLKS_MODULE_VERSION])
 289 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 290
 291 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 292 AC_SUBST([BACKEND_DIR])
 293
 294 BACKEND_KF='$(top_builddir)/backends/key-file/.libs/key-file.so'
 295 AC_SUBST([BACKEND_KF])
 296 BACKEND_TP='$(top_builddir)/backends/telepathy/.libs/telepathy.so'
 297 AC_SUBST([BACKEND_TP])
 298
 299 if test x$have_libsocialweb_backend = xyes; then
 300   BACKEND_LIBSOCIALWEB='$(top_builddir)/backends/libsocialweb/.libs/libsocialweb.so'
 301   AC_SUBST([BACKEND_LIBSOCIALWEB])
 302 fi
 303
 304 if test x$enable_tracker_backend = xyes; then
 305   BACKEND_TRACKER='$(top_builddir)/backends/tracker/.libs/tracker.so'
 306   AC_SUBST([BACKEND_TRACKER])
 307 fi
 308
 309 if test x$enable_eds_backend = xyes; then
 310   BACKEND_EDS='$(top_builddir)/backends/eds/.libs/eds.so'
 311   AC_SUBST([BACKEND_EDS])
 312 fi
 313
 314 # All of the backend libraries in our tree; to be used by the tests
 315 BACKEND_UNINST_PATH='$(BACKEND_KF):$(BACKEND_TP)'
 316 if test x$have_libsocialweb_backend = xyes; then
 317   LIBSOCIALWEB_BACKEND_UNINST_PATH='$(BACKEND_LIBSOCIALWEB)'
 318   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$LIBSOCIALWEB_BACKEND_UNINST_PATH"
 319 fi
 320 if test x$enable_tracker_backend = xyes; then
 321   TRACKER_BACKEND_UNINST_PATH='$(BACKEND_TRACKER)'
 322   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$TRACKER_BACKEND_UNINST_PATH"
 323 fi
 324 if test x$enable_eds_backend = xyes; then
 325   EDS_BACKEND_UNINST_PATH='$(BACKEND_EDS)'
 326   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$EDS_BACKEND_UNINST_PATH"
 327 fi
 328 AC_SUBST([BACKEND_UNINST_PATH])
 329
 330 # -----------------------------------------------------------
 331 # Tools
 332 # -----------------------------------------------------------
 333
 334 AC_ARG_ENABLE([import-tool],
 335               AS_HELP_STRING([--enable-import-tool],
 336                              [Enable building the meta-contact import tool]),
 337               [enable_import_tool=$enableval with_import_tool=$enableval],
 338               [enable_import_tool=maybe with_import_tool=no])
 339 AS_IF([test "$enable_import_tool" != "no"],
 340       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 341                          [with_import_tool=yes], [with_import_tool=no])])
 342 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 343       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 344 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 345
 346 # Readline's required for the folks-inspect program
 347 AC_ARG_ENABLE([inspect-tool],
 348               AS_HELP_STRING([--enable-inspect-tool],
 349                              [Enable building the data inspection tool]),
 350               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 351               [enable_inspect_tool=maybe with_inspect_tool=no])
 352 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 353       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 354                      using --enable-vala])])
 355 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 356       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 357                       --enable-vala])])
 358 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 359       [AC_CHECK_LIB([readline], [main],
 360                     [with_inspect_tool=yes], [with_inspect_tool=no],
 361                     [-lncurses])])
 362 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 363        "x$enable_vala" = "xyes"],
 364       [VALA_CHECK_PACKAGES([readline])
 365        LIBREADLINE="-lreadline -lncurses"
 366        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 367        AC_SUBST([LIBREADLINE])])
 368 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 369       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 370 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 371
 372 # -----------------------------------------------------------
 373 # Documentation
 374 # -----------------------------------------------------------
 375
 376 AC_ARG_ENABLE([docs],
 377               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 378               [enable_docs=$enableval], [enable_docs=no])
 379 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 380
 381 have_valadoc=no
 382 if test x$enable_docs = xyes; then
 383   # make sure the library is new enough and the program exists
 384   PKG_CHECK_MODULES([VALADOC], [valadoc-1.0 >= $VALADOC_REQUIRED])
 385   AC_PATH_PROG([VALADOC], [valadoc], [:])
 386   AS_IF([test "$VALADOC" != :], have_valadoc=yes)
 387 fi
 388 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 389
 390 if test "x$enable_docs" = "xyes" -a "x$have_valadoc" != "xyes"; then
 391     AC_MSG_ERROR([Doc building requested but valadoc not installed.])
 392 fi
 393
 394 # -----------------------------------------------------------
 395 # Gettext
 396 # -----------------------------------------------------------
 397
 398 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 399 AC_SUBST(GETTEXT_PACKAGE)
 400 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 401 IT_PROG_INTLTOOL([0.50.0])
 402
 403 # -----------------------------------------------------------
 404 # Error flags
 405 # -----------------------------------------------------------
 406
 407 # Disable GLib deprecation warnings for now (#670196); GValueArray is deprecated
 408 # but we need it for dbus-glib. Porting to GDBus will solve this (#653198)
 409 AC_DEFINE(GLIB_DISABLE_DEPRECATION_WARNINGS, 1, [Build with GLib deprecated])
 410
 411 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 412 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 413
 414 AC_ARG_ENABLE([debug],
 415               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 416               [enable_debug=$enableval], [enable_debug=yes])
 417
 418 AC_ARG_ENABLE([Werror],
 419               AS_HELP_STRING([--disable-Werror],
 420                              [compile without -Werror (normally enabled in
 421                               development builds)]),
 422               [werror=$enableval], [werror=yes])
 423
 424 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 425 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 426                  [wno_missing_field_initializers=yes],
 427                  [wno_missing_field_initializers=no])
 428 AS_COMPILER_FLAG([-Wno-unused-parameter],
 429                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 430
 431 m4_if(folks_released, [1], [],
 432     [
 433         if test x$werror = xyes; then
 434             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 435         fi
 436         if test x$wextra = xyes -a \
 437             x$wno_missing_field_initializers = xyes -a \
 438             x$wno_unused_parameter = xyes; then
 439             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 440                 -Wno-missing-field-initializers -Wno-unused-parameter"
 441         fi
 442     ])
 443
 444 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 445 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 446 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 447 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 448                                           -Wmissing-prototypes"])
 449 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 450                                             -Wmissing-declarations"])
 451 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 452                                          -Wstrict-prototypes"])
 453
 454 AC_SUBST([ERROR_CFLAGS])
 455
 456 # -----------------------------------------------------------
 457 # Code coverage flags
 458 # -----------------------------------------------------------
 459
 460 AC_ARG_ENABLE([code-coverage],
 461               AS_HELP_STRING([--enable-code-coverage],
 462                              [compile with code coverage code]),
 463               [enable_code_coverage=$enableval], [enable_code_coverage=no])
 464
 465 # Only enable code coverage if this isn't a release.
 466 m4_if(folks_released, [1], [],
 467     [
 468         if test "x$GCC" = "xyes"; then
 469             if test "x$enable_code_coverage" = "xyes"; then
 470                 CODE_COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage -O0 -ggdb"
 471                 CODE_COVERAGE_LDFLAGS="-lgcov"
 472             fi
 473         fi
 474     ])
 475
 476 AC_SUBST([CODE_COVERAGE_CFLAGS])
 477 AC_SUBST([CODE_COVERAGE_LDFLAGS])
 478
 479 # Vala-related flags
 480 AC_ARG_ENABLE([fatal-warnings],
 481               AS_HELP_STRING([--disable-fatal-warnings],
 482                              [Make warnings from valac and g-ir-scanner non-fatal]),
 483               [enable_fatal_warnings=$enableval], [enable_fatal_warnings=yes])
 484 AS_IF([test "x$enable_vala" = "xyes" && test "x$enable_fatal_warnings" = "xyes"],
 485       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 486                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 487        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 488
 489 # Disable -g if we're building with code coverage enabled, since Vala's
 490 # insertion of #line directives into .c files confuses lcov. For the moment,
 491 # we'll have to do with looking at code coverage of the generated C files only.
 492 # We set the debug flags in CODE_COVERAGE_CFLAGS instead in that case.
 493 m4_if(folks_released, [1], [],
 494     [
 495         if test "x$enable_code_coverage" != "xyes" -o "x$GCC" != "xyes"; then
 496             ERROR_VALAFLAGS="$ERROR_VALAFLAGS -g"
 497         fi
 498     ])
 499
 500 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 501 AC_SUBST([ERROR_VALAFLAGS])
 502
 503 # -----------------------------------------------------------
 504 # Profiling
 505 # -----------------------------------------------------------
 506
 507 AC_ARG_ENABLE([profiling],
 508               AS_HELP_STRING([--enable-profiling],
 509                              [Enable building profiling points]),
 510               [enable_profiling=$enableval],
 511               [enable_profiling=no])
 512 AM_CONDITIONAL([ENABLE_PROFILING], [test "$enable_profiling" = "yes"])
 513
 514 # -----------------------------------------------------------
 515 # Final output
 516 # -----------------------------------------------------------
 517
 518 # FIXME: We can't remove gconf.path until bgo#635379 is fixed, since we need to
 519 # safely contain EDS' use of GConf for the EDS backend tests.
 520 # Note that our use of gconf.path doesn't actually need GConf to be installed,
 521 # though, so it's not a hard dependency of folks.
 522
 523 AC_CONFIG_FILES([
 524     backends/telepathy/lib/folks-telepathy.pc
 525     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 526     backends/tracker/lib/folks-tracker.deps
 527     backends/tracker/lib/folks-tracker.pc
 528     backends/tracker/lib/folks-tracker-uninstalled.pc
 529     backends/eds/lib/folks-eds.pc
 530     backends/eds/lib/folks-eds-uninstalled.pc
 531     folks/folks.pc
 532     folks/folks-uninstalled.pc
 533     folks/org.freedesktop.folks.gschema.xml
 534     Makefile
 535     backends/Makefile
 536     backends/key-file/Makefile
 537     backends/libsocialweb/Makefile
 538     backends/libsocialweb/lib/Makefile
 539     backends/libsocialweb/lib/folks-libsocialweb.pc
 540     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 541     backends/telepathy/Makefile
 542     backends/telepathy/lib/Makefile
 543     backends/tracker/Makefile
 544     backends/tracker/lib/Makefile
 545     backends/eds/Makefile
 546     backends/eds/lib/Makefile
 547     folks/Makefile
 548     docs/Makefile
 549     po/Makefile.in
 550     tests/Makefile
 551     tests/data/Makefile
 552     tests/data/gconf.path
 553     tests/eds/Makefile
 554     tests/folks/Makefile
 555     tests/key-file/Makefile
 556     tests/libsocialweb/Makefile
 557     tests/telepathy/Makefile
 558     tests/tracker/Makefile
 559     tests/lib/Makefile
 560     tests/lib/folks-test-uninstalled.pc
 561     tests/lib/eds/Makefile
 562     tests/lib/key-file/Makefile
 563     tests/lib/libsocialweb/Makefile
 564     tests/lib/libsocialweb/session.conf
 565     tests/lib/telepathy/Makefile
 566     tests/lib/tracker/Makefile
 567     tests/lib/telepathy/contactlist/Makefile
 568     tests/lib/telepathy/contactlist/session.conf
 569     tests/tools/Makefile
 570     tools/Makefile
 571     tools/inspect/Makefile
 572 ])
 573
 574 AC_OUTPUT
 575
 576 echo "
 577 Configure summary:
 578
 579         Vala........................:  ${enable_vala}
 580         Vala Compiler...............:  ${VALAC}
 581         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS} ${CODE_COVERAGE_CFLAGS}
 582         Linker Flags................:  ${LDFLAGS} ${CODE_COVERAGE_LDFLAGS}
 583         Prefix......................:  ${prefix}
 584         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 585         Documentation...............:  ${have_valadoc}
 586         Import tool.................:  ${with_import_tool}
 587         Inspector tool..............:  ${with_inspect_tool}
 588         Tracker backend.............:  ${enable_tracker_backend}
 589         Libsocialweb backend........:  ${have_libsocialweb_backend}
 590         E-D-S backend...............:  ${enable_eds_backend}
 591
 592 "