configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.63)
  24
  25 AC_INIT([pulseaudio],[m4_esyscmd(./git-version-gen .tarball-version)],[pulseaudio-discuss (at) lists (dot) freedesktop (dot) org],[pulseaudio],[http://pulseaudio.org/])
  26 AC_CONFIG_SRCDIR([src/daemon/main.c])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_HEADERS([config.h])
  29 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules color-tests dist-xz tar-ustar])
  30
  31 AS_IF([! test -n "$VERSION"], [
  32    AC_MSG_ERROR([git-version-gen failed])
  33 ])
  34
  35 m4_define(pa_major, `echo $VERSION | cut -d. -f1 | cut -d- -f1`)
  36 m4_define(pa_minor, `echo $VERSION | cut -d. -f2 | cut -d- -f1`)
  37
  38 AC_SUBST(PA_MAJOR, pa_major)
  39 AC_SUBST(PA_MINOR, pa_minor)
  40 AC_SUBST(PA_MAJORMINOR, pa_major.pa_minor)
  41
  42 AC_SUBST(PA_API_VERSION, 12)
  43 AC_SUBST(PA_PROTOCOL_VERSION, 28)
  44
  45 # The stable ABI for client applications, for the version info x:y:z
  46 # always will hold y=z
  47 AC_SUBST(LIBPULSE_VERSION_INFO, [16:2:16])
  48
  49 # A simplified, synchronous, ABI-stable interface for client
  50 # applications, for the version info x:y:z always will hold y=z
  51 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:4:0])
  52
  53 # The ABI-stable GLib adapter for client applications, for the version
  54 # info x:y:z always will hold y=z
  55 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
  56
  57 AC_CANONICAL_HOST
  58 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  59
  60 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  61
  62 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  63     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  64     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  65 ])
  66
  67 AM_SILENT_RULES([yes])
  68
  69
  70 #### Checks for programs. ####
  71
  72 # mkdir -p
  73
  74 AC_PROG_MKDIR_P
  75
  76 # CC
  77
  78 AC_PROG_CC
  79 AC_PROG_CC_C99
  80 AM_PROG_CC_C_O
  81 # Only required if you want the WebRTC canceller -- no runtime dep on
  82 # libstdc++ otherwise
  83 AC_PROG_CXX
  84 AC_PROG_GCC_TRADITIONAL
  85 AC_USE_SYSTEM_EXTENSIONS
  86
  87 # M4
  88
  89 AC_CHECK_PROGS([M4], gm4 m4, no)
  90 AS_IF([test "x$M4" = "xno"], AC_MSG_ERROR([m4 missing]))
  91
  92 # pkg-config
  93
  94 PKG_PROG_PKG_CONFIG
  95
  96 # gettext
  97
  98 if test "x$enable_nls" != "xno"; then
  99 IT_PROG_INTLTOOL([0.35.0])
 100 GETTEXT_PACKAGE=pulseaudio
 101 AC_SUBST([GETTEXT_PACKAGE])
 102 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 103 AM_GLIB_GNU_GETTEXT
 104
 105 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 106 AX_DEFINE_DIR(PULSE_LOCALEDIR, pulselocaledir, [Gettext locale dir])
 107 else
 108 # workaround till an intltool m4 bug is fixed upstream
 109 # (https://bugs.launchpad.net/intltool/+bug/904647)
 110 USE_NLS=no
 111 AC_SUBST(USE_NLS)
 112 fi
 113
 114
 115 #### Determine host OS ####
 116
 117 os_is_linux=0
 118 os_is_win32=0
 119 os_is_darwin=0
 120
 121 AC_MSG_CHECKING([host operating system])
 122 case "$host_os" in
 123     linux*)
 124         AC_MSG_RESULT([linux])
 125         os_is_linux=1
 126     ;;
 127     darwin*)
 128         AC_MSG_RESULT([darwin])
 129         os_is_darwin=1
 130         AC_DEFINE([OS_IS_DARWIN], 1, [Build target is Darwin.])
 131     ;;
 132     mingw*)
 133         AC_MSG_RESULT([win32])
 134         os_is_win32=1
 135         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 136     ;;
 137     *)
 138         AC_MSG_RESULT([unknown])
 139     ;;
 140 esac
 141
 142 AM_CONDITIONAL(OS_IS_DARWIN, test "x$os_is_darwin" = "x1")
 143 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 144 AC_SUBST([OS_IS_WIN32], [$os_is_win32])
 145
 146 # Platform specific hacks
 147 case "$host_os" in
 148     darwin* )
 149         AC_DEFINE([_DARWIN_C_SOURCE], [200112L], [Needed to get NSIG on Mac OS X])
 150     ;;
 151     mingw* )
 152         AC_DEFINE([WIN32_LEAN_AND_MEAN], 1, [Needed to avoid including unnecessary headers on Windows])
 153     ;;
 154     solaris* )
 155         AC_DEFINE(_XOPEN_SOURCE,       600, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 156         AC_DEFINE(__EXTENSIONS__,        1, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 157     ;;
 158 esac
 159
 160
 161 #### Compiler flags ####
 162
 163 AX_APPEND_COMPILE_FLAGS(
 164     [-Wall -W -Wextra -pipe -Wno-long-long -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option],
 165     [], [-pedantic -Werror])
 166
 167 # Only enable fastpath asserts when doing a debug build, e.g. from bootstrap.sh.
 168 AS_CASE([" $CFLAGS "], [*" -O0 "*], [], [AX_APPEND_FLAG(["-DFASTPATH"], [CPPFLAGS])])
 169
 170
 171 #### Linker flags ####
 172
 173 # Check whether the linker supports the -version-script option.
 174 # The Make variable $(srcdir) needs to be in the LDFLAGS in that form,
 175 # so that it is expanded the right way in every subdir.
 176 AX_CHECK_LINK_FLAG(["-Wl,-version-script=${srcdir}/src/map-file"],
 177     [VERSIONING_LDFLAGS='-Wl,-version-script=$(abs_top_srcdir)/src/map-file'])
 178 AC_SUBST([VERSIONING_LDFLAGS])
 179
 180 # Use immediate (now) bindings; avoids the funky re-call in itself.
 181 # The -z now syntax is lifted from Sun's linker and works with GNU's too, other linkers might be added later.
 182 AX_APPEND_LINK_FLAGS([-Wl,-z,now], [IMMEDIATE_LDFLAGS])
 183 AC_SUBST([IMMEDIATE_LDFLAGS])
 184
 185 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 186 # so we request the nodelete flag to be enabled.
 187 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 188 AX_APPEND_LINK_FLAGS([-Wl,-z,nodelete], [NODELETE_LDFLAGS])
 189 AC_SUBST([NODELETE_LDFLAGS])
 190
 191 # Check for the proper way to build libraries that have no undefined symbols
 192 case $host in
 193     # FreeBSD (et al.) does not complete linking for shared objects when pthreads
 194     # are requested, as different implementations are present.
 195     *-freebsd* | *-openbsd*) ;;
 196     *)
 197         for possible_flag in "-Wl,--no-undefined" "-Wl,-z,defs"; do
 198             AX_CHECK_LINK_FLAG([$possible_flag], [NOUNDEFINED_LDFLAGS="$possible_flag"; break])
 199         done
 200     ;;
 201 esac
 202 AC_SUBST([NOUNDEFINED_LDFLAGS])
 203
 204
 205 #### Atomic operations ####
 206
 207 # Native atomic operation support
 208 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 209     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]))
 210
 211 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 212     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]))
 213
 214 if test "x$enable_atomic_arm_memory_barrier" = "xyes"; then
 215     AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers])
 216 fi
 217
 218 # If everything else fails use libatomic_ops
 219 need_libatomic_ops=yes
 220
 221 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 222     pulseaudio_cv_sync_bool_compare_and_swap, [
 223     AC_LINK_IFELSE(
 224         AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 225         [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 226         [pulseaudio_cv_sync_bool_compare_and_swap=no])
 227     ])
 228
 229 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 230     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 231     need_libatomic_ops=no
 232 else
 233     # HW specific atomic ops stuff
 234     AC_MSG_CHECKING([architecture for native atomic operations])
 235     case $host in
 236         arm*)
 237             AC_MSG_RESULT([arm])
 238             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 239             # The Linux kernel helper functions have been there since 2.6.16. However
 240             # compile time checking for kernel version in cross compile environment
 241             # (which is usually the case for arm cpu) is tricky (or impossible).
 242             if test "x$os_is_linux" = "x1" && test "x$enable_atomic_arm_linux_helpers" != "xno"; then
 243                 AC_MSG_RESULT([yes])
 244                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 245                 need_libatomic_ops=no
 246             else
 247                 AC_MSG_RESULT([no])
 248                 AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 249                     pulseaudio_cv_support_arm_atomic_ops, [
 250                     AC_COMPILE_IFELSE(
 251                         AC_LANG_PROGRAM([], [[
 252                             volatile int a=0;
 253                             int o=0, n=1, r;
 254                             asm volatile ("ldrex    %0, [%1]\n"
 255                                           "subs  %0, %0, %2\n"
 256                                           "strexeq %0, %3, [%1]\n"
 257                                           : "=&r" (r)
 258                                           : "r" (&a), "Ir" (o), "r" (n)
 259                                           : "cc");
 260                             return (a==1 ? 0 : -1);
 261                         ]]),
 262                         [pulseaudio_cv_support_arm_atomic_ops=yes],
 263                         [pulseaudio_cv_support_arm_atomic_ops=no])
 264                 ])
 265                 AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 266                     AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARM atomic instructions.])
 267                     need_libatomic_ops=no
 268                 ])
 269             fi
 270         ;;
 271         *-netbsdelf5*)
 272             AC_MSG_RESULT([yes])
 273             need_libatomic_ops=no
 274         ;;
 275         *-freebsd*)
 276             AC_MSG_RESULT([yes])
 277             need_libatomic_ops=no
 278         ;;
 279         *)
 280             AC_MSG_RESULT([unknown])
 281         ;;
 282     esac
 283 fi
 284
 285 # If we're on ARM, check for the ARMV6 instructions we need */
 286 case $host in
 287   arm*)
 288     AC_CACHE_CHECK([support for required armv6 instructions],
 289       pulseaudio_cv_support_armv6,
 290       [AC_COMPILE_IFELSE(
 291          AC_LANG_PROGRAM([],
 292            [[volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 293              asm volatile ("ldr r0, %2 \n"
 294                            "ldr r2, %3 \n"
 295                            "ldr r3, %4 \n"
 296                            "ssat r1, #8, r0 \n"
 297                            "str r1, %0 \n"
 298                            "pkhbt r1, r3, r2, LSL #8 \n"
 299                            "str r1, %1 \n"
 300                            : "=m" (a), "=m" (b)
 301                            : "m" (a), "m" (b), "m" (c)
 302                            : "r0", "r1", "r2", "r3", "cc");
 303              return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 304            ]]),
 305          [pulseaudio_cv_support_armv6=yes],
 306          [pulseaudio_cv_support_armv6=no])
 307       ])
 308     AS_IF([test "$pulseaudio_cv_support_armv6" = "yes"], [
 309         AC_DEFINE([HAVE_ARMV6], 1, [Have ARMv6 instructions.])
 310       ])
 311   ;;
 312   *)
 313   ;;
 314 esac
 315
 316 #### NEON optimisations ####
 317 AC_ARG_ENABLE([neon-opt],
 318     AS_HELP_STRING([--enable-neon-opt], [Enable NEON optimisations on ARM CPUs that support it]))
 319
 320 AS_IF([test "x$enable_neon_opt" != "xno"],
 321     [save_CFLAGS="$CFLAGS"; CFLAGS="$CFLAGS -mfpu=neon"
 322      AC_COMPILE_IFELSE(
 323         AC_LANG_PROGRAM([], []),
 324         [
 325          HAVE_NEON=1
 326          NEON_CFLAGS="-mfpu=neon"
 327         ],
 328         [
 329          HAVE_NEON=0
 330          NEON_CFLAGS=
 331         ])
 332      CFLAGS="$save_CFLAGS"
 333     ],
 334     [HAVE_NEON=0])
 335
 336 AS_IF([test "x$enable_neon_opt" = "xyes" && test "x$HAVE_NEON" = "x0"],
 337       [AC_MSG_ERROR([*** Compiler does not support -mfpu=neon])])
 338
 339 AC_SUBST(HAVE_NEON)
 340 AC_SUBST(NEON_CFLAGS)
 341 AM_CONDITIONAL([HAVE_NEON], [test "x$HAVE_NEON" = x1])
 342 AS_IF([test "x$HAVE_NEON" = "x1"], AC_DEFINE([HAVE_NEON], 1, [Have NEON support?]))
 343
 344
 345 #### libtool stuff ####
 346
 347 LT_PREREQ(2.4)
 348 LT_INIT([dlopen win32-dll disable-static])
 349
 350 dnl As an extra safety device, check for lt_dladvise_init() which is
 351 dnl only implemented in libtool 2.x, and refine as we go if we have
 352 dnl refined requirements.
 353 dnl
 354 dnl Check the header files first since the system may have a
 355 dnl libltdl.so for runtime, but no headers, and we want to bail out as
 356 dnl soon as possible.
 357 dnl
 358 dnl We don't need any special variable for this though, since the user
 359 dnl can give the proper place to find libltdl through the standard
 360 dnl variables like LDFLAGS and CPPFLAGS.
 361
 362 AC_CHECK_HEADER([ltdl.h],
 363     [AC_CHECK_LIB([ltdl], [lt_dladvise_init], [LIBLTDL=-lltdl], [LIBLTDL=])],
 364     [LIBLTDL=])
 365
 366 AS_IF([test "x$LIBLTDL" = "x"],
 367     [AC_MSG_ERROR([Unable to find libltdl version 2. Makes sure you have libtool 2.4 or later installed.])])
 368 AC_SUBST([LIBLTDL])
 369
 370
 371 ###################################
 372 #   Basic environment checks      #
 373 ###################################
 374
 375 #### Checks for header files. ####
 376
 377 # ISO
 378 AC_HEADER_STDC
 379
 380 # POSIX
 381 AC_CHECK_HEADERS_ONCE([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 382     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 383     sys/mman.h sys/select.h sys/socket.h sys/wait.h \
 384     sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 385 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 386                  [#include <sys/types.h>
 387                   #if HAVE_NETINET_IN_H
 388                   # include <netinet/in.h>
 389                   #endif
 390                   #if HAVE_NETINET_IN_SYSTM_H
 391                   # include <netinet/in_systm.h>
 392                   #endif
 393                  ])
 394 AC_CHECK_HEADERS([sys/resource.h], [HAVE_SYS_RESOURCE_H=1], [HAVE_SYS_RESOURCE_H=0])
 395 AC_SUBST(HAVE_SYS_RESOURCE_H)
 396 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 397 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 398 AC_SUBST(HAVE_AF_UNIX)
 399
 400 # Linux
 401 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 402 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 403
 404 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 405
 406 # Solaris
 407 AC_CHECK_HEADERS_ONCE([sys/filio.h])
 408
 409 # Windows
 410 AC_CHECK_HEADERS_ONCE([windows.h winsock2.h ws2tcpip.h])
 411
 412 # NetBSD
 413 AC_CHECK_HEADERS_ONCE([sys/atomic.h])
 414
 415 # Other
 416 AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
 417 AC_CHECK_HEADERS_ONCE([byteswap.h])
 418 AC_CHECK_HEADERS_ONCE([sys/syscall.h])
 419 AC_CHECK_HEADERS_ONCE([sys/eventfd.h])
 420 AC_CHECK_HEADERS_ONCE([execinfo.h])
 421 AC_CHECK_HEADERS_ONCE([langinfo.h])
 422 AC_CHECK_HEADERS_ONCE([regex.h pcreposix.h])
 423
 424
 425 #### Typdefs, structures, etc. ####
 426
 427 AC_C_CONST
 428 AC_C_BIGENDIAN
 429 AC_TYPE_PID_T
 430 AC_TYPE_SIZE_T
 431 AC_CHECK_TYPES(ssize_t, , AC_DEFINE([ssize_t], [signed long], [Define ssize_t if it is not done by the standard libs.]))
 432 AC_TYPE_OFF_T
 433
 434 AC_TYPE_UID_T
 435 AC_CHECK_DECLS(environ)
 436
 437 # SIGXCPU
 438 AX_CHECK_DEFINE([signal.h], [SIGXCPU], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 439 AS_IF([test "x$HAVE_SIGXCPU" = "x1"], AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?]))
 440 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 441
 442 # INADDR_NONE, Solaris lacks this
 443 AX_CHECK_DEFINE([netinet/in.h], [INADDR_NONE], [],
 444     [AX_CHECK_DEFINE([winsock2.h], [INADDR_NONE], [],
 445         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 446
 447
 448 # _Bool
 449 AC_CACHE_CHECK([whether $CC knows _Bool],
 450     pulseaudio_cv__Bool,
 451     [AC_COMPILE_IFELSE(
 452         AC_LANG_PROGRAM([], [[_Bool b;]]),
 453         [pulseaudio_cv__Bool=yes],
 454         [pulseaudio_cv__Bool=no])
 455     ])
 456
 457 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.]))
 458
 459
 460 #### Thread support ####
 461
 462 AX_TLS
 463 AS_IF([test "$ac_cv_tls" == "__thread"],
 464     AC_DEFINE([SUPPORT_TLS___THREAD], 1, [Define this if the compiler supports __thread for Thread-Local Storage]))
 465
 466 # Win32 build breaks with win32 pthread installed
 467 AS_IF([test "x$os_is_win32" != "x1"],
 468   [AX_PTHREAD])
 469
 470 AS_IF([test "x$ax_pthread_ok" == "xyes"],
 471     AC_DEFINE([_POSIX_PTHREAD_SEMANTICS], 1, [Needed on Solaris]))
 472
 473
 474 #### Check for libs ####
 475
 476 # ISO
 477 AC_SEARCH_LIBS([pow], [m])
 478
 479 # POSIX
 480 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 481 AC_SEARCH_LIBS([dlopen], [dl])
 482 AC_SEARCH_LIBS([shm_open], [rt])
 483 AC_SEARCH_LIBS([inet_ntop], [nsl])
 484 AC_SEARCH_LIBS([timer_create], [rt])
 485 AC_SEARCH_LIBS([pthread_setaffinity_np], [pthread])
 486 AC_SEARCH_LIBS([pthread_getname_np], [pthread])
 487 AC_SEARCH_LIBS([pthread_setname_np], [pthread])
 488
 489 # BSD
 490 AC_SEARCH_LIBS([connect], [socket])
 491 AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace])
 492
 493 # Darwin/OS X
 494 if test "x$os_is_darwin" = "x1" ; then
 495     AC_MSG_CHECKING([looking for Apple CoreService Framework])
 496     # How do I check a framework "library" - AC_CHECK_LIB prob. won't work??, just assign LIBS & hope
 497     AC_CHECK_HEADER([/Developer/Headers/FlatCarbon/CoreServices.h],
 498         [LIBS="$LIBS -framework CoreServices"],
 499         [AC_CHECK_HEADERS([/System/Library/Frameworks/CoreServices.framework/Headers/CoreServices.h],
 500             [LIBS="$LIBS -framework CoreServices"],
 501             [AC_MSG_ERROR([CoreServices.h header file not found])]
 502         )]
 503     )
 504
 505     AC_MSG_RESULT([ok])
 506     AC_DEFINE([HAVE_CLOCK_GETTIME], 1, [Using clock_gettime() replacement])
 507     HAVE_BONJOUR=1
 508 fi
 509
 510 AM_CONDITIONAL([HAVE_BONJOUR], [test "x$HAVE_BONJOUR" = x1])
 511
 512 # Windows
 513 AC_SEARCH_LIBS([regexec], [pcreposix])
 514 # This magic is needed so we do not needlessly add static libs to the win32  build, disabling its ability to make dlls.
 515 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 516
 517
 518 #### Check for functions ####
 519
 520 # ISO
 521 AC_CHECK_FUNCS_ONCE([lrintf strtof])
 522
 523 # POSIX
 524 AC_FUNC_FORK
 525 AC_FUNC_GETGROUPS
 526 AC_CHECK_FUNCS_ONCE([chmod chown fstat fchown fchmod clock_gettime getaddrinfo getgrgid_r getgrnam_r \
 527     getpwnam_r getpwuid_r gettimeofday getuid mlock nanosleep \
 528     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 529     sigaction sleep symlink sysconf uname pthread_setaffinity_np pthread_getname_np pthread_setname_np])
 530 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 531 AC_SUBST(HAVE_MKFIFO)
 532 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 533
 534 # X/OPEN
 535 AC_CHECK_FUNCS_ONCE([readlink])
 536
 537 # SUSv2
 538 AC_CHECK_FUNCS_ONCE([ctime_r usleep])
 539
 540 # SUSv3
 541 AC_CHECK_FUNCS_ONCE([strerror_r])
 542
 543 # BSD
 544 AC_CHECK_FUNCS_ONCE([lstat])
 545
 546 # Non-standard
 547 AC_CHECK_FUNCS_ONCE([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l pipe2 accept4])
 548
 549 AC_FUNC_ALLOCA
 550
 551 AC_CHECK_FUNCS([regexec], [HAVE_REGEX=1], [HAVE_REGEX=0])
 552 AM_CONDITIONAL(HAVE_REGEX, [test "x$HAVE_REGEX" = "x1"])
 553
 554 # Large File-Support (LFS)
 555 AC_SYS_LARGEFILE
 556 # Check for open64 to know if the current system does have open64() and similar functions
 557 AC_CHECK_FUNCS_ONCE([open64])
 558
 559
 560 ###################################
 561 #      External libraries         #
 562 ###################################
 563
 564 #### [lib]iconv ####
 565
 566 AM_ICONV
 567
 568 #### X11 (optional) ####
 569
 570 AC_ARG_ENABLE([x11],
 571     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]))
 572
 573 AS_IF([test "x$enable_x11" != "xno"],
 574     [PKG_CHECK_MODULES(X11, [ x11-xcb xcb >= 1.6 ice sm xtst ], HAVE_X11=1, HAVE_X11=0)],
 575     HAVE_X11=0)
 576
 577 AS_IF([test "x$enable_x11" = "xyes" && test "x$HAVE_X11" = "x0"],
 578     [AC_MSG_ERROR([*** X11 not found])])
 579
 580 AC_SUBST(X11_CFLAGS)
 581 AC_SUBST(X11_LIBS)
 582 AC_SUBST(HAVE_X11)
 583 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 584 AS_IF([test "x$HAVE_X11" = "x1"], AC_DEFINE([HAVE_X11], 1, [Have X11?]))
 585
 586 #### Capabilities (optional) ####
 587
 588 CAP_LIBS=''
 589
 590 AC_ARG_WITH([caps],
 591     AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 592
 593 if test "x${with_caps}" != "xno"; then
 594     AC_SEARCH_LIBS([cap_init], [cap], [], [
 595                     if test "x${with_caps}" = "xyes" ; then
 596                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 597                     fi])
 598     AC_CHECK_HEADERS([sys/capability.h], [], [
 599                     if test "x${with_caps}" = "xyes" ; then
 600                         AC_MSG_ERROR([*** POSIX caps headers not found])
 601                     fi])
 602 fi
 603
 604 #### Valgrind (optional) ####
 605
 606 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 607
 608 #### check unit tests ####
 609
 610 AC_ARG_ENABLE([tests],
 611     AS_HELP_STRING([--disable-tests],[Disable unit tests]))
 612
 613 AS_IF([test "x$enable_tests" != "xno"],
 614     [PKG_CHECK_MODULES(LIBCHECK, [ check ], HAVE_LIBCHECK=1, HAVE_LIBCHECK=0)],
 615     HAVE_LIBCHECK=0)
 616
 617 AC_SUBST(LIBCHECK_CFLAGS)
 618 AC_SUBST(LIBCHECK_LIBS)
 619
 620 AS_IF([test "x$enable_tests" = "xyes" && test "x$HAVE_LIBCHECK" = "x0"],
 621     [AC_MSG_ERROR([*** check library not found])])
 622
 623 AM_CONDITIONAL([HAVE_TESTS], [test "x$HAVE_LIBCHECK" = x1])
 624
 625 #### json parsing ####
 626
 627 PKG_CHECK_MODULES(LIBJSON, [ json-c >= 0.11 ], [],
 628                   [PKG_CHECK_MODULES(LIBJSON, [ json >= 0.9 ])])
 629 AC_SUBST(LIBJSON_CFLAGS)
 630 AC_SUBST(LIBJSON_LIBS)
 631
 632 #### Sound file ####
 633
 634 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.20 ])
 635 AC_SUBST(LIBSNDFILE_CFLAGS)
 636 AC_SUBST(LIBSNDFILE_LIBS)
 637
 638 #### atomic-ops ####
 639
 640 AC_MSG_CHECKING([whether we need libatomic_ops])
 641 if test "x$need_libatomic_ops" = "xyes"; then
 642     AC_MSG_RESULT([yes])
 643     AC_CHECK_HEADERS([atomic_ops.h],
 644         [CFLAGS="$CFLAGS -DAO_REQUIRE_CAS"],
 645         [AC_MSG_ERROR([*** libatomic-ops headers not found])])
 646
 647     # Win32 does not need the lib and breaks horribly if we try to include it
 648     AS_IF([test "x$os_is_win32" != "x1"], [LIBS="$LIBS -latomic_ops"])
 649 else
 650     AC_MSG_RESULT([no])
 651 fi
 652
 653 #### Libsamplerate support (optional) ####
 654
 655 AC_ARG_ENABLE([samplerate],
 656     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]))
 657
 658 AS_IF([test "x$enable_samplerate" != "xno"],
 659     [PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ], HAVE_LIBSAMPLERATE=1, HAVE_LIBSAMPLERATE=0)],
 660     HAVE_LIBSAMPLERATE=0)
 661
 662 AS_IF([test "x$enable_samplerate" = "xyes" && test "x$HAVE_LIBSAMPLERATE" = "x0"],
 663     [AC_MSG_ERROR([*** Libsamplerate not found])])
 664
 665 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 666 AC_SUBST(LIBSAMPLERATE_LIBS)
 667 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 668 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?]))
 669
 670 #### Database support ####
 671
 672 AC_ARG_WITH([database],
 673     AS_HELP_STRING([--with-database=auto|tdb|gdbm|simple],[Choose database backend.]),[],[with_database=auto])
 674
 675
 676 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xtdb"],
 677     [PKG_CHECK_MODULES(TDB, [ tdb ], HAVE_TDB=1, HAVE_TDB=0)],
 678     HAVE_TDB=0)
 679 AS_IF([test "x$HAVE_TDB" = "x1"], with_database=tdb)
 680
 681 AS_IF([test "x$with_database" = "xtdb" && test "x$HAVE_TDB" = "x0"],
 682     [AC_MSG_ERROR([*** tdb not found])])
 683
 684
 685 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xgdbm"],
 686     [
 687         HAVE_GDBM=1
 688         AC_CHECK_LIB(gdbm, gdbm_open, [], HAVE_GDBM=0)
 689         AC_CHECK_HEADERS(gdbm.h, [], HAVE_GDBM=0)
 690     ],
 691     HAVE_GDBM=0)
 692 AS_IF([test "x$HAVE_GDBM" = "x1"],
 693     [
 694         with_database=gdbm
 695         GDBM_CFLAGS=
 696         GDBM_LIBS=-lgdbm
 697     ])
 698
 699 AS_IF([test "x$with_database" = "xgdbm" && test "x$HAVE_GDBM" = "x0"],
 700     [AC_MSG_ERROR([*** gdbm not found])])
 701
 702
 703 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xsimple"],
 704     HAVE_SIMPLEDB=1,
 705     HAVE_SIMPLEDB=0)
 706 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], with_database=simple)
 707
 708 AS_IF([test "x$HAVE_TDB" != x1 -a "x$HAVE_GDBM" != x1 -a "x$HAVE_SIMPLEDB" != x1],
 709     AC_MSG_ERROR([*** missing database backend]))
 710
 711
 712 AC_SUBST(TDB_CFLAGS)
 713 AC_SUBST(TDB_LIBS)
 714 AM_CONDITIONAL([HAVE_TDB], [test "x$HAVE_TDB" = x1])
 715 AS_IF([test "x$HAVE_TDB" = "x1"], AC_DEFINE([HAVE_TDB], 1, [Have tdb?]))
 716
 717 AC_SUBST(GDBM_CFLAGS)
 718 AC_SUBST(GDBM_LIBS)
 719 AM_CONDITIONAL([HAVE_GDBM], [test "x$HAVE_GDBM" = x1])
 720 AS_IF([test "x$HAVE_GDBM" = "x1"], AC_DEFINE([HAVE_GDBM], 1, [Have gdbm?]))
 721
 722 AM_CONDITIONAL([HAVE_SIMPLEDB], [test "x$HAVE_SIMPLEDB" = x1])
 723 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], AC_DEFINE([HAVE_SIMPLEDB], 1, [Have simple?]))
 724
 725 #### OSS support (optional) ####
 726
 727 AC_ARG_ENABLE([oss-output],
 728     AS_HELP_STRING([--disable-oss-output],[Disable optional OSS output support]))
 729
 730 AC_ARG_ENABLE([oss-wrapper],
 731     AS_HELP_STRING([--disable-oss-wrapper],[Disable optional OSS wrapper support]))
 732
 733 AS_IF([test "x$enable_oss_output" != "xno" -o "x$enable_oss_wrapper" != "xno"],
 734     [AC_CHECK_HEADERS([sys/soundcard.h], HAVE_OSS=1, HAVE_OSS=0)],
 735     HAVE_OSS=0)
 736
 737 AS_IF([test "x$enable_oss_output" = "xyes" -o "x$enable_oss_wrapper" = "xyes" && test "x$HAVE_OSS" = "x0"],
 738     [AC_MSG_ERROR([*** OSS support not found])])
 739
 740 AS_IF([test "x$enable_oss_output" != "xno"],
 741     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_OUTPUT=1, HAVE_OSS_OUTPUT=0)],
 742     HAVE_OSS_OUTPUT=0)
 743
 744 AS_IF([test "x$enable_oss_wrapper" != "xno"],
 745     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_WRAPPER=1, HAVE_OSS_WRAPPER=0)],
 746     HAVE_OSS_WRAPPER=0)
 747
 748 AC_SUBST(HAVE_OSS_OUTPUT)
 749 AM_CONDITIONAL([HAVE_OSS_OUTPUT], [test "x$HAVE_OSS_OUTPUT" = "x1"])
 750 AM_CONDITIONAL([HAVE_OSS_WRAPPER], [test "x$HAVE_OSS_WRAPPER" = "x1"])
 751 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], AC_DEFINE([HAVE_OSS_OUTPUT], 1, [Have OSS output?]))
 752 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], AC_DEFINE([HAVE_OSS_WRAPPER], 1, [Have OSS wrapper (padsp)?]))
 753
 754 #### CoreAudio support (optional) ####
 755
 756 AC_ARG_ENABLE([coreaudio-output],
 757     AS_HELP_STRING([--disable-coreaudio-output],[Disable optional CoreAudio output support]))
 758
 759 AS_IF([test "x$enable_coreaudio_output" != "xno"],
 760     [AC_CHECK_HEADERS([CoreAudio/CoreAudio.h], HAVE_COREAUDIO=1, HAVE_COREAUDIO=0)],
 761     HAVE_COREAUDIO=0)
 762
 763 AS_IF([test "x$enable_coreaudio_output" = "xyes" && test "x$HAVE_COREAUDIO" = "x0"],
 764     [AC_MSG_ERROR([*** CoreAudio output support not found])])
 765
 766 AM_CONDITIONAL([HAVE_COREAUDIO], [test "x$HAVE_COREAUDIO" = "x1" && test "x$enable_coreaudio_output" != "xno"])
 767
 768 #### ALSA support (optional) ####
 769
 770 AC_ARG_ENABLE([alsa],
 771     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]))
 772
 773 AS_IF([test "x$enable_alsa" != "xno"],
 774     [PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.24 ], HAVE_ALSA=1, HAVE_ALSA=0)],
 775     HAVE_ALSA=0)
 776
 777 AS_IF([test "x$enable_alsa" = "xyes" && test "x$HAVE_ALSA" = "x0"],
 778     [AC_MSG_ERROR([*** Needed alsa >= 1.0.24 support not found])])
 779
 780 AC_SUBST(ASOUNDLIB_CFLAGS)
 781 AC_SUBST(ASOUNDLIB_LIBS)
 782 AC_SUBST(HAVE_ALSA)
 783 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 784 AS_IF([test "x$HAVE_ALSA" = "x1"], AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?]))
 785
 786 #### EsounD support (optional) ####
 787
 788 AC_ARG_ENABLE([esound],
 789     AS_HELP_STRING([--disable-esound],[Disable optional EsounD support]))
 790 AM_CONDITIONAL([HAVE_ESOUND], [test "x$enable_esound" != "xno"])
 791 AS_IF([test "x$enable_esound" != "xno"], [HAVE_ESOUND=1])
 792
 793 #### Solaris audio support (optional) ####
 794
 795 AC_ARG_ENABLE([solaris],
 796     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]))
 797
 798 AS_IF([test "x$enable_solaris" != "xno"],
 799     [AC_CHECK_HEADERS([sys/audio.h], HAVE_SOLARIS=1, HAVE_SOLARIS=0)],
 800     HAVE_SOLARIS=0)
 801
 802 AS_IF([test "x$enable_solaris" = "xyes" && test "x$HAVE_SOLARIS" = "x0"],
 803     [AC_MSG_ERROR([*** Solaris audio support not found])])
 804
 805 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 806 AS_IF([test "x$HAVE_SOLARIS" = "x1"], AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?]))
 807
 808 #### WaveOut audio support (optional) ####
 809
 810 AC_ARG_ENABLE([waveout],
 811     AS_HELP_STRING([--disable-waveout],[Disable optional WaveOut audio support]))
 812
 813 AS_IF([test "x$enable_waveout" != "xno"],
 814     [AC_CHECK_HEADERS([mmsystem.h], HAVE_WAVEOUT=1, HAVE_WAVEOUT=0, [#include <windows.h>])],
 815     HAVE_WAVEOUT=0)
 816
 817 AS_IF([test "x$enable_waveout" = "xyes" && test "x$HAVE_WAVEOUT" = "x0"],
 818     [AC_MSG_ERROR([*** WaveOut audio support not found])])
 819
 820 AC_SUBST(HAVE_WAVEOUT)
 821 AM_CONDITIONAL([HAVE_WAVEOUT], [test "x$HAVE_WAVEOUT" = x1])
 822 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], AC_DEFINE([HAVE_WAVEOUT], 1, [Have WaveOut audio?]))
 823
 824 #### GLib 2 support (optional) ####
 825
 826 AC_ARG_ENABLE([glib2],
 827     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]))
 828
 829 AS_IF([test "x$enable_glib2" != "xno"],
 830     [PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)],
 831     HAVE_GLIB20=0)
 832
 833 AS_IF([test "x$enable_glib2" = "xyes" && test "x$HAVE_GLIB20" = "x0"],
 834     [AC_MSG_ERROR([*** GLib 2 support not found])])
 835
 836 AC_SUBST(GLIB20_CFLAGS)
 837 AC_SUBST(GLIB20_LIBS)
 838 AC_SUBST(HAVE_GLIB20)
 839 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 840 AS_IF([test "x$HAVE_GLIB20" = "x1"], AC_DEFINE([HAVE_GLIB], 1, [Have GLIB?]))
 841
 842 #### GTK3 support (optional) ####
 843
 844 AC_ARG_ENABLE([gtk3],
 845     AS_HELP_STRING([--disable-gtk3],[Disable optional Gtk+ 3 support]))
 846
 847 AS_IF([test "x$enable_gtk3" != "xno"],
 848     [PKG_CHECK_MODULES(GTK30, [ gtk+-3.0 ], HAVE_GTK30=1, HAVE_GTK30=0)],
 849     HAVE_GTK30=0)
 850
 851 AS_IF([test "x$enable_gtk3" = "xyes" && test "x$HAVE_GTK30" = "x0"],
 852     [AC_MSG_ERROR([*** Gtk+ 3 support not found])])
 853
 854 AC_SUBST(GTK30_CFLAGS)
 855 AC_SUBST(GTK30_LIBS)
 856 AM_CONDITIONAL([HAVE_GTK30], [test "x$HAVE_GTK30" = x1])
 857 AS_IF([test "x$HAVE_GTK30" = "x1"], AC_DEFINE([HAVE_GTK], 1, [Have GTK?]))
 858
 859 #### GConf support (optional) ####
 860
 861 AC_ARG_ENABLE([gconf],
 862     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]))
 863
 864 AS_IF([test "x$enable_gconf" != "xno"],
 865     [PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 gobject-2.0 ], HAVE_GCONF=1, HAVE_GCONF=0)],
 866     HAVE_GCONF=0)
 867
 868 AS_IF([test "x$enable_gconf" = "xyes" && test "x$HAVE_GCONF" = "x0"],
 869     [AC_MSG_ERROR([*** GConf support not found])])
 870
 871 AC_SUBST(GCONF_CFLAGS)
 872 AC_SUBST(GCONF_LIBS)
 873 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 874
 875 #### Avahi support (optional) ####
 876
 877 AC_ARG_ENABLE([avahi],
 878     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]))
 879
 880 AS_IF([test "x$enable_avahi" != "xno"],
 881     [PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ], HAVE_AVAHI=1, HAVE_AVAHI=0)],
 882     HAVE_AVAHI=0)
 883
 884 AS_IF([test "x$enable_avahi" = "xyes" && test "x$HAVE_AVAHI" = "x0"],
 885     [AC_MSG_ERROR([*** Avahi support not found])])
 886
 887 AC_SUBST(AVAHI_CFLAGS)
 888 AC_SUBST(AVAHI_LIBS)
 889 AC_SUBST(HAVE_AVAHI)
 890 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 891
 892 #### JACK (optional) ####
 893
 894 AC_ARG_ENABLE([jack],
 895     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]))
 896
 897 AS_IF([test "x$enable_jack" != "xno"],
 898     [PKG_CHECK_MODULES(JACK, [ jack >= 0.117.0 ], HAVE_JACK=1, HAVE_JACK=0)],
 899     HAVE_JACK=0)
 900
 901 AS_IF([test "x$enable_jack" = "xyes" && test "x$HAVE_JACK" = "x0"],
 902     [AC_MSG_ERROR([*** JACK support not found])])
 903
 904 AC_SUBST(JACK_CFLAGS)
 905 AC_SUBST(JACK_LIBS)
 906 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 907
 908 #### Async DNS support (optional) ####
 909
 910 AC_ARG_ENABLE([asyncns],
 911     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]))
 912
 913 AS_IF([test "x$enable_asyncns" != "xno"],
 914     [PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)],
 915     HAVE_LIBASYNCNS=0)
 916
 917 AS_IF([test "x$enable_asyncns" = "xyes" && test "x$HAVE_LIBASYNCNS" = "x0"],
 918     [AC_MSG_ERROR([*** Async DNS support not found])])
 919
 920 AC_SUBST(LIBASYNCNS_CFLAGS)
 921 AC_SUBST(LIBASYNCNS_LIBS)
 922 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 923 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?]))
 924
 925 #### TCP wrappers (optional) ####
 926
 927 AC_ARG_ENABLE([tcpwrap],
 928     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]))
 929
 930 AS_IF([test "x$enable_tcpwrap" != "xno"],
 931     [
 932         ACX_LIBWRAP
 933         AS_IF([test "x$LIBWRAP_LIBS" != "x"], HAVE_TCPWRAP=1, HAVE_TCPWRAP=0)
 934     ],
 935     HAVE_TCPWRAP=0)
 936
 937 AS_IF([test "x$enable_tcpwrap" = "xyes" && test "x$HAVE_TCPWRAP" = "x0"],
 938     [AC_MSG_ERROR([*** TCP wrappers support not found])])
 939
 940 AC_SUBST(LIBWRAP_LIBS)
 941
 942 #### LIRC support (optional) ####
 943
 944 AC_ARG_ENABLE([lirc],
 945     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]))
 946
 947 LIRC_CFLAGS=
 948 LIRC_LIBS=
 949
 950 AS_IF([test "x$enable_lirc" != "xno"],
 951     [
 952         HAVE_LIRC=1
 953         AC_CHECK_HEADER(lirc/lirc_client.h, [], [HAVE_LIRC=0])
 954         AC_CHECK_LIB(lirc_client, lirc_init, [LIRC_LIBS=-llirc_client], [HAVE_LIRC=0])
 955     ],
 956     HAVE_LIRC=0)
 957
 958 AS_IF([test "x$enable_lirc" = "xyes" && test "x$HAVE_LIRC" = "x0"],
 959     [AC_MSG_ERROR([*** LIRC support not found])])
 960
 961 AC_SUBST(LIRC_CFLAGS)
 962 AC_SUBST(LIRC_LIBS)
 963 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 964
 965 #### D-Bus support (optional) ####
 966
 967 AC_ARG_ENABLE([dbus],
 968     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]))
 969
 970 AS_IF([test "x$enable_dbus" != "xno"],
 971     [PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.4.12 ], HAVE_DBUS=1, HAVE_DBUS=0)],
 972     HAVE_DBUS=0)
 973
 974 AS_IF([test "x$enable_dbus" = "xyes" && test "x$HAVE_DBUS" = "x0"],
 975     [AC_MSG_ERROR([*** D-Bus not available or too old version])])
 976
 977 AS_IF([test "x$HAVE_DBUS" = "x1"],
 978     [
 979         save_CFLAGS="$CFLAGS"; CFLAGS="$CFLAGS $DBUS_CFLAGS"
 980         save_LIBS="$LIBS"; LIBS="$LIBS $DBUS_LIBS"
 981         AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 982         CFLAGS="$save_CFLAGS"
 983         LIBS="$save_LIBS"
 984     ])
 985
 986 AC_SUBST(DBUS_CFLAGS)
 987 AC_SUBST(DBUS_LIBS)
 988 AC_SUBST(HAVE_DBUS)
 989 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 990 AS_IF([test "x$HAVE_DBUS" = "x1"], AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.]))
 991
 992 PA_MACHINE_ID="${sysconfdir}/machine-id"
 993 AX_DEFINE_DIR(PA_MACHINE_ID, PA_MACHINE_ID, [D-Bus machine-id file])
 994 PA_MACHINE_ID_FALLBACK="${localstatedir}/lib/dbus/machine-id"
 995 AX_DEFINE_DIR(PA_MACHINE_ID_FALLBACK, PA_MACHINE_ID_FALLBACK,
 996               [Fallback machine-id file])
 997
 998 #### BlueZ support (optional, dependant on D-Bus) ####
 999
1000 AC_ARG_ENABLE([bluez],
1001     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]))
1002
1003 AS_IF([test "x$enable_bluez" != "xno"],
1004     [PKG_CHECK_MODULES(BLUEZ, [ bluez >= 4.99 ], HAVE_BLUEZ=1, HAVE_BLUEZ=0)],
1005     HAVE_BLUEZ=0)
1006 AS_IF([test "x$enable_bluez" != "xno"],
1007     [PKG_CHECK_MODULES(SBC, [ sbc >= 1.0 ], HAVE_SBC=1, HAVE_SBC=0)],
1008     HAVE_SBC=0)
1009 AS_IF([test "x$HAVE_SBC" != "x1"], HAVE_BLUEZ=0)
1010 AS_IF([test "x$HAVE_DBUS" != "x1"], HAVE_BLUEZ=0)
1011
1012 AS_IF([test "x$enable_bluez" = "xyes" && test "x$HAVE_BLUEZ" = "x0"],
1013     [AC_MSG_ERROR([*** BLUEZ support not found (requires BlueZ, sbc, and D-Bus)])])
1014
1015 AC_SUBST(BLUEZ_CFLAGS)
1016 AC_SUBST(BLUEZ_LIBS)
1017 AC_SUBST(HAVE_BLUEZ)
1018 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
1019
1020 #### UDEV support (optional) ####
1021
1022 AC_ARG_ENABLE([udev],
1023     AS_HELP_STRING([--disable-udev],[Disable optional UDEV support]))
1024
1025 AS_IF([test "x$enable_udev" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
1026     [PKG_CHECK_MODULES(UDEV, [ libudev >= 143 ], HAVE_UDEV=1, HAVE_UDEV=0)],
1027     HAVE_UDEV=0)
1028
1029 AS_IF([test "x$enable_udev" = "xyes" && test "x$HAVE_UDEV" = "x0"],
1030     [AC_MSG_ERROR([*** UDEV support not found])])
1031
1032 AC_SUBST(UDEV_CFLAGS)
1033 AC_SUBST(UDEV_LIBS)
1034 AC_SUBST(HAVE_UDEV)
1035 AM_CONDITIONAL([HAVE_UDEV], [test "x$HAVE_UDEV" = x1])
1036 AS_IF([test "x$HAVE_UDEV" = "x1"], AC_DEFINE([HAVE_UDEV], 1, [Have UDEV.]))
1037
1038 #### HAL compat support (optional, dependant on UDEV) ####
1039
1040 AC_ARG_ENABLE([hal-compat],
1041     AS_HELP_STRING([--disable-hal-compat],[Disable optional HAL->udev transition compatibility support]))
1042
1043 AS_IF([test "x$enable_hal_compat" != "xno"],
1044     [AS_IF([test "x$HAVE_UDEV" = "x1"], HAVE_HAL_COMPAT=1, HAVE_HAL_COMPAT=0)],
1045     HAVE_HAL_COMPAT=0)
1046
1047 AM_CONDITIONAL([HAVE_HAL_COMPAT], [test "x$HAVE_HAL_COMPAT" = x1])
1048 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], AC_DEFINE([HAVE_HAL_COMPAT], 1, [Have HAL compatibility.]))
1049
1050 #### IPv6 connection support (optional) ####
1051
1052 AC_ARG_ENABLE([ipv6],
1053     AS_HELP_STRING([--disable-ipv6],[Disable optional IPv6 support]))
1054
1055 AS_IF([test "x$enable_ipv6" != "xno"], [HAVE_IPV6=1], [HAVE_IPV6=0])
1056
1057 AS_IF([test "x$HAVE_IPV6" = "x1"], AC_DEFINE([HAVE_IPV6], 1, [Define this to enable IPv6 connection support]))
1058
1059 #### OpenSSL support (optional) ####
1060
1061 AC_ARG_ENABLE([openssl],
1062     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]))
1063
1064 AS_IF([test "x$enable_openssl" != "xno"],
1065     [PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ], HAVE_OPENSSL=1, HAVE_OPENSSL=0)],
1066     HAVE_OPENSSL=0)
1067
1068 AS_IF([test "x$enable_openssl" = "xyes" && test "x$HAVE_OPENSSL" = "x0"],
1069     [AC_MSG_ERROR([*** OpenSSL support not found])])
1070
1071 AC_SUBST(OPENSSL_CFLAGS)
1072 AC_SUBST(OPENSSL_LIBS)
1073 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1074 AS_IF([test "x$HAVE_OPENSSL" = "x1"], AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL]))
1075
1076 #### FFTW (optional) ####
1077
1078 AC_ARG_WITH([fftw],
1079     AS_HELP_STRING([--without-fftw],[Omit FFTW-using modules (equalizer)]))
1080
1081 AS_IF([test "x$with_fftw" != "xno"],
1082     [PKG_CHECK_MODULES(FFTW, [ fftw3f ], HAVE_FFTW=1, HAVE_FFTW=0)],
1083     HAVE_FFTW=0)
1084
1085 AS_IF([test "x$with_fftw" = "xyes" && test "x$HAVE_FFTW" = "x0"],
1086     [AC_MSG_ERROR([*** FFTW support not found])])
1087
1088 AM_CONDITIONAL([HAVE_FFTW], [test "x$HAVE_FFTW" = "x1"])
1089
1090 #### speex (optional) ####
1091
1092 AC_ARG_WITH([speex],
1093     AS_HELP_STRING([--without-speex],[Omit speex (resampling, AEC)]))
1094
1095 AS_IF([test "x$with_speex" != "xno"],
1096     [PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ], HAVE_SPEEX=1, HAVE_SPEEX=0)],
1097     HAVE_SPEEX=0)
1098
1099 AS_IF([test "x$with_speex" = "xyes" && test "x$HAVE_SPEEX" = "x0"],
1100     [AC_MSG_ERROR([*** speex support not found])])
1101
1102 AM_CONDITIONAL([HAVE_SPEEX], [test "x$HAVE_SPEEX" = "x1"])
1103 AS_IF([test "x$HAVE_SPEEX" = "x1"], AC_DEFINE([HAVE_SPEEX], 1, [Have speex]))
1104
1105 AC_SUBST(LIBSPEEX_CFLAGS)
1106 AC_SUBST(LIBSPEEX_LIBS)
1107
1108 #### Xen support (optional) ####
1109
1110 AC_ARG_ENABLE([xen],
1111     AS_HELP_STRING([--disable-xen],[Disable optional Xen paravirtualized driver]))
1112
1113 XEN_CFLAGS=
1114 XEN_LIBS=
1115
1116 AS_IF([test "x$enable_xen" != "xno"],
1117     [
1118         HAVE_XEN=1
1119         AC_CHECK_HEADER(xenctrl.h, [], [HAVE_XEN=0])
1120         AC_CHECK_HEADER(xs.h, [], [HAVE_XEN=0])
1121         AC_CHECK_LIB(xenctrl, xc_interface_open, [XEN_LIBS="$XEN_LIBS -lxenctrl"], [HAVE_XEN=0])
1122         AC_CHECK_LIB(xenstore, xs_domain_open, [XEN_LIBS="$XEN_LIBS -lxenstore"], [HAVE_XEN=0])
1123     ],
1124     HAVE_XEN=0)
1125
1126 AS_IF([test "x$enable_xen" = "xyes" && test "x$HAVE_XEN" = "x0"],
1127     [AC_MSG_ERROR([*** Xen development headers or libraries not found])])
1128
1129 AC_SUBST(XEN_CFLAGS)
1130 AC_SUBST(XEN_LIBS)
1131 AM_CONDITIONAL([HAVE_XEN], [test "x$HAVE_XEN" = x1])
1132
1133 #### gcov support (optional) #####
1134
1135 AC_ARG_ENABLE([gcov],
1136     AS_HELP_STRING([--enable-gcov],[Enable optional gcov coverage analysis]))
1137
1138 GCOV_CFLAGS=
1139 GCOV_LIBS=" -lgcov"
1140
1141 AS_IF([test "x$enable_gcov" = "xyes"],
1142     [
1143         HAVE_GCOV=1
1144         GCOV_CFLAGS="$GCOV_CFLAGS -fprofile-arcs -ftest-coverage"
1145         GCOV_LIBS="$GCOV_LIBS -fprofile-arcs"
1146     ],
1147     HAVE_GCOV=0)
1148
1149 AC_SUBST(GCOV_CFLAGS)
1150 AC_SUBST(GCOV_LIBS)
1151 AM_CONDITIONAL([HAVE_GCOV], [test "x$HAVE_GCOV" = x1])
1152
1153 #### ORC (optional) ####
1154
1155 ORC_CHECK([0.4.11])
1156
1157 #### systemd support (optional) ####
1158
1159 AC_ARG_ENABLE([systemd],
1160     AS_HELP_STRING([--disable-systemd],[Disable optional systemd support]))
1161
1162 AS_IF([test "x$enable_systemd" != "xno"],
1163     [PKG_CHECK_MODULES(SYSTEMD, [ libsystemd-login ], HAVE_SYSTEMD=1, HAVE_SYSTEMD=0)],
1164     HAVE_SYSTEMD=0)
1165
1166 AS_IF([test "x$enable_systemd" = "xyes" && test "x$HAVE_SYSTEMD" = "x0"],
1167     [AC_MSG_ERROR([*** Needed systemd support not found])])
1168
1169 AC_SUBST(HAVE_SYSTEMD)
1170 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$HAVE_SYSTEMD" = x1])
1171 AS_IF([test "x$HAVE_SYSTEMD" = "x1"], AC_DEFINE([HAVE_SYSTEMD], 1, [Have SYSTEMD?]))
1172
1173 #### Build and Install man pages ####
1174
1175 AC_ARG_ENABLE([manpages],
1176     AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]))
1177
1178 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" != "xno"])
1179
1180 #### PulseAudio system group & user  #####
1181
1182 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1183 if test -z "$with_system_user" ; then
1184     PA_SYSTEM_USER=pulse
1185 else
1186     PA_SYSTEM_USER=$with_system_user
1187 fi
1188 AC_SUBST(PA_SYSTEM_USER)
1189 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1190
1191 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1192 if test -z "$with_system_group" ; then
1193     PA_SYSTEM_GROUP=pulse
1194 else
1195     PA_SYSTEM_GROUP=$with_system_group
1196 fi
1197 AC_SUBST(PA_SYSTEM_GROUP)
1198 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1199
1200 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1201 if test -z "$with_access_group" ; then
1202     PA_ACCESS_GROUP=pulse-access
1203 else
1204     PA_ACCESS_GROUP=$with_access_group
1205 fi
1206 AC_SUBST(PA_ACCESS_GROUP)
1207 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1208
1209 AC_ARG_ENABLE([per-user-esound-socket],
1210     AS_HELP_STRING([--disable-per-user-esound-socket],[Use global esound socket directory /tmp/.esd/socket.]))
1211
1212 if test "x$enable_per_user_esound_socket" != "xno"; then
1213     USE_PER_USER_ESOUND_SOCKET=1
1214     AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1215 else
1216     USE_PER_USER_ESOUND_SOCKET=0
1217 fi
1218
1219 #### PulseAudio system runtime dir ####
1220
1221 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1222 AX_DEFINE_DIR(PA_SYSTEM_RUNTIME_PATH, PA_SYSTEM_RUNTIME_PATH, [System runtime dir])
1223 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1224 AX_DEFINE_DIR(PA_SYSTEM_CONFIG_PATH, PA_SYSTEM_CONFIG_PATH, [System config dir])
1225 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1226 AX_DEFINE_DIR(PA_SYSTEM_STATE_PATH, PA_SYSTEM_STATE_PATH, [System state dir])
1227
1228 PA_BINARY=${bindir}/pulseaudio${EXEEXT}
1229 AX_DEFINE_DIR(PA_BINARY, PA_BINARY, [Location of pulseaudio binary])
1230
1231 PACTL_BINARY=${bindir}/pactl${EXEEXT}
1232 AX_DEFINE_DIR(PACTL_BINARY, PACTL_BINARY, [Location of pactl binary])
1233
1234 AC_SUBST(PA_SOEXT, [.so])
1235
1236 AC_SUBST(pulseconfdir, ["${sysconfdir}/pulse"])
1237 AX_DEFINE_DIR(PA_DEFAULT_CONFIG_DIR, pulseconfdir, [Location of configuration files])
1238
1239 #### Mac OSX specific stuff #####
1240
1241 AC_ARG_ENABLE(mac-universal,
1242     AS_HELP_STRING([--enable-mac-universal], [Build Mac universal binaries]),
1243     enable_mac_universal=$enableval, enable_mac_universal="no")
1244
1245 AC_ARG_WITH(mac-version-min,
1246     AS_HELP_STRING([--with-mac-version-min=<version>], [Defines the earliest version of MacOS X that the executables will run on.]),
1247     mac_version_min=$withval, mac_version_min="10.5")
1248
1249 AC_ARG_WITH(mac-sysroot,
1250     AS_HELP_STRING([--with-mac-sysroot=<path>], [SDK basedir to use as the logical root directory for headers and libraries.]),
1251     mac_sysroot=$withval, mac_sysroot="/Developer/SDKs/MacOSX10.5.sdk")
1252
1253 if test "x$os_is_darwin" = "x1" ; then
1254     LDFLAGS="$LDFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1255     CFLAGS="$CFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1256
1257     if test "x$enable_mac_universal" = "xyes" ; then
1258         mac_arches="-arch i386 -arch x86_64"
1259         LDFLAGS="$LDFLAGS $mac_arches"
1260         CFLAGS="$CFLAGS $mac_arches"
1261     fi
1262 fi
1263
1264 AC_ARG_ENABLE([webrtc-aec],
1265     AS_HELP_STRING([--enable-webrtc-aec], [Enable the optional WebRTC-based echo canceller]))
1266
1267 AS_IF([test "x$enable_webrtc_aec" != "xno"],
1268     [PKG_CHECK_MODULES(WEBRTC, [ webrtc-audio-processing ], [HAVE_WEBRTC=1], [HAVE_WEBRTC=0])],
1269     [HAVE_WEBRTC=0])
1270
1271 AS_IF([test "x$enable_webrtc_aec" = "xyes" && test "x$HAVE_WEBRTC" = "x0"],
1272     [AC_MSG_ERROR([*** webrtc-audio-processing library not found])])
1273
1274 AC_SUBST(WEBRTC_CFLAGS)
1275 AC_SUBST(WEBRTC_LIBS)
1276 AM_CONDITIONAL([HAVE_WEBRTC], [test "x$HAVE_WEBRTC" = "x1"])
1277
1278 AC_ARG_ENABLE([adrian-aec],
1279     AS_HELP_STRING([--enable-adrian-aec], [Enable Adrian's optional echo canceller]))
1280 AS_IF([test "x$enable_adrian_aec" != "xno"],
1281     [HAVE_ADRIAN_EC=1])
1282 AM_CONDITIONAL([HAVE_ADRIAN_EC], [test "x$HAVE_ADRIAN_EC" = "x1"])
1283
1284
1285
1286 ###################################
1287 #            Output               #
1288 ###################################
1289
1290 AC_DEFINE_UNQUOTED(PA_CFLAGS, "$CFLAGS", [The CFLAGS used during compilation])
1291
1292 # Check whether to build tests by default (as compile-test) or not
1293 AC_ARG_ENABLE([default-build-tests],
1294     AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
1295 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" != "xno"])
1296
1297 AC_ARG_ENABLE([legacy-database-entry-format],
1298         AS_HELP_STRING([--disable-legacy-database-entry-format], [Try to load legacy (< 1.0) database files (card, device and volume restore).]))
1299 if test "x$enable_legacy_database_entry_format" != "xno" ; then
1300         AC_DEFINE(ENABLE_LEGACY_DATABASE_ENTRY_FORMAT, [1], [Legacy database entry format])
1301 fi
1302 AC_DEFINE([WIBBLE], 1, [Just a test.])
1303
1304 AC_ARG_ENABLE([static-bins],
1305     AS_HELP_STRING([--enable-static-bins],[Statically link executables.]))
1306 AM_CONDITIONAL([STATIC_BINS], [test "x$enable_static_bins" = "xyes"])
1307
1308 AC_ARG_WITH(
1309         [preopen-mods],
1310         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1311         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1312 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1313 if test "x$PREOPEN_MODS" != "xall" ; then
1314     tmpLIBS=""
1315     for mod in $PREOPEN_MODS; do
1316         tmpLIBS="$tmpLIBS module-$mod.la"
1317     done
1318     PREOPEN_MODS="$tmpLIBS"
1319     AC_SUBST(PREOPEN_MODS)
1320 fi
1321
1322 AC_ARG_WITH(
1323         [module-dir],
1324         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules]),
1325         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules"])
1326
1327 AC_SUBST(modlibexecdir)
1328 AX_DEFINE_DIR(PA_DLSEARCHPATH, modlibexecdir, [Modules dir])
1329
1330 AC_ARG_WITH(
1331         [udev-rules-dir],
1332         AS_HELP_STRING([--with-udev-rules-dir],[Directory where to install udev rules to (defaults to /lib/udev/rules.d)]),
1333         [udevrulesdir=$withval], [udevrulesdir="/lib/udev/rules.d"])
1334
1335 AC_SUBST(udevrulesdir)
1336
1337 AC_ARG_ENABLE([force-preopen],
1338     AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]))
1339
1340 if test "x$enable_force_preopen" = "xyes"; then
1341     FORCE_PREOPEN=yes
1342 else
1343     FORCE_PREOPEN=no
1344 fi
1345
1346 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1347
1348 AC_CONFIG_FILES([
1349 Makefile
1350 src/Makefile
1351 man/Makefile
1352 libpulse.pc
1353 libpulse-simple.pc
1354 libpulse-mainloop-glib.pc
1355 doxygen/Makefile
1356 doxygen/doxygen.conf
1357 src/pulse/version.h
1358 po/Makefile.in
1359 man/pulseaudio.1.xml
1360 man/esdcompat.1.xml
1361 man/pax11publish.1.xml
1362 man/paplay.1.xml
1363 man/pacat.1.xml
1364 man/pacmd.1.xml
1365 man/pactl.1.xml
1366 man/pasuspender.1.xml
1367 man/padsp.1.xml
1368 man/pulse-daemon.conf.5.xml
1369 man/pulse-client.conf.5.xml
1370 man/default.pa.5.xml
1371 man/pulse-cli-syntax.5.xml
1372 man/start-pulseaudio-kde.1.xml
1373 man/start-pulseaudio-x11.1.xml
1374 ])
1375
1376 AC_CONFIG_FILES([src/esdcompat:src/daemon/esdcompat.in], [chmod +x src/esdcompat])
1377 AC_CONFIG_FILES([src/start-pulseaudio-x11:src/daemon/start-pulseaudio-x11.in], [chmod +x src/start-pulseaudio-x11])
1378 AC_CONFIG_FILES([src/start-pulseaudio-kde:src/daemon/start-pulseaudio-kde.in], [chmod +x src/start-pulseaudio-kde])
1379 AC_CONFIG_FILES([src/client.conf:src/pulse/client.conf.in])
1380 AC_CONFIG_FILES([src/daemon.conf:src/daemon/daemon.conf.in],
1381     [m4 src/daemon.conf > src/daemon.conf.gen && mv src/daemon.conf.gen src/daemon.conf])
1382 AC_CONFIG_FILES([src/default.pa:src/daemon/default.pa.in],
1383     [m4 src/default.pa > src/default.pa.gen && mv src/default.pa.gen src/default.pa])
1384 AC_CONFIG_FILES([src/system.pa:src/daemon/system.pa.in],
1385     [m4 src/system.pa > src/system.pa.gen && mv src/system.pa.gen src/system.pa])
1386
1387 # CMake related ProjectConfig files
1388 PA_LIBDIR="$libdir"
1389 AX_DEFINE_DIR(PA_LIBDIR, PA_LIBDIR, [PulseAudio library dir])
1390 PA_INCDIR="$includedir"
1391 AX_DEFINE_DIR(PA_INCDIR, PA_INCDIR, [PulseAudio include dir])
1392
1393 AC_CONFIG_FILES([PulseAudioConfig.cmake:PulseAudioConfig.cmake.in],
1394     [m4 PulseAudioConfig.cmake > PulseAudioConfig.cmake.gen && mv PulseAudioConfig.cmake.gen PulseAudioConfig.cmake])
1395 AC_CONFIG_FILES([PulseAudioConfigVersion.cmake])
1396
1397 AC_OUTPUT
1398
1399 # ==========================================================================
1400
1401 AS_IF([test "x$HAVE_X11" = "x1"], ENABLE_X11=yes, ENABLE_X11=no)
1402 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], ENABLE_OSS_OUTPUT=yes, ENABLE_OSS_OUTPUT=no)
1403 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], ENABLE_OSS_WRAPPER=yes, ENABLE_OSS_WRAPPER=no)
1404 AS_IF([test "x$HAVE_ALSA" = "x1"], ENABLE_ALSA=yes, ENABLE_ALSA=no)
1405 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], ENABLE_COREAUDIO=yes, ENABLE_COREAUDIO=no)
1406 AS_IF([test "x$HAVE_SOLARIS" = "x1"], ENABLE_SOLARIS=yes, ENABLE_SOLARIS=no)
1407 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], ENABLE_WAVEOUT=yes, ENABLE_WAVEOUT=no)
1408 AS_IF([test "x$HAVE_GLIB20" = "x1"], ENABLE_GLIB20=yes, ENABLE_GLIB20=no)
1409 AS_IF([test "x$HAVE_GTK30" = "x1"], ENABLE_GTK30=yes, ENABLE_GTK30=no)
1410 AS_IF([test "x$HAVE_GCONF" = "x1"], ENABLE_GCONF=yes, ENABLE_GCONF=no)
1411 AS_IF([test "x$HAVE_AVAHI" = "x1"], ENABLE_AVAHI=yes, ENABLE_AVAHI=no)
1412 AS_IF([test "x$HAVE_JACK" = "x1"], ENABLE_JACK=yes, ENABLE_JACK=no)
1413 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], ENABLE_LIBASYNCNS=yes, ENABLE_LIBASYNCNS=no)
1414 AS_IF([test "x$HAVE_LIRC" = "x1"], ENABLE_LIRC=yes, ENABLE_LIRC=no)
1415 AS_IF([test "x$HAVE_XEN" = "x1"], ENABLE_XEN=yes, ENABLE_XEN=no)
1416 AS_IF([test "x$HAVE_DBUS" = "x1"], ENABLE_DBUS=yes, ENABLE_DBUS=no)
1417 AS_IF([test "x$HAVE_UDEV" = "x1"], ENABLE_UDEV=yes, ENABLE_UDEV=no)
1418 AS_IF([test "x$HAVE_SYSTEMD" = "x1"], ENABLE_SYSTEMD=yes, ENABLE_SYSTEMD=no)
1419 AS_IF([test "x$HAVE_BLUEZ" = "x1"], ENABLE_BLUEZ=yes, ENABLE_BLUEZ=no)
1420 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], ENABLE_HAL_COMPAT=yes, ENABLE_HAL_COMPAT=no)
1421 AS_IF([test "x$HAVE_TCPWRAP" = "x1"], ENABLE_TCPWRAP=yes, ENABLE_TCPWRAP=no)
1422 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], ENABLE_LIBSAMPLERATE=yes, ENABLE_LIBSAMPLERATE=no)
1423 AS_IF([test "x$HAVE_IPV6" = "x1"], ENABLE_IPV6=yes, ENABLE_IPV6=no)
1424 AS_IF([test "x$HAVE_OPENSSL" = "x1"], ENABLE_OPENSSL=yes, ENABLE_OPENSSL=no)
1425 AS_IF([test "x$HAVE_FFTW" = "x1"], ENABLE_FFTW=yes, ENABLE_FFTW=no)
1426 AS_IF([test "x$HAVE_ORC" = "xyes"], ENABLE_ORC=yes, ENABLE_ORC=no)
1427 AS_IF([test "x$HAVE_ADRIAN_EC" = "x1"], ENABLE_ADRIAN_EC=yes, ENABLE_ADRIAN_EC=no)
1428 AS_IF([test "x$HAVE_SPEEX" = "x1"], ENABLE_SPEEX=yes, ENABLE_SPEEX=no)
1429 AS_IF([test "x$HAVE_WEBRTC" = "x1"], ENABLE_WEBRTC=yes, ENABLE_WEBRTC=no)
1430 AS_IF([test "x$HAVE_TDB" = "x1"], ENABLE_TDB=yes, ENABLE_TDB=no)
1431 AS_IF([test "x$HAVE_GDBM" = "x1"], ENABLE_GDBM=yes, ENABLE_GDBM=no)
1432 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], ENABLE_SIMPLEDB=yes, ENABLE_SIMPLEDB=no)
1433 AS_IF([test "x$HAVE_ESOUND" = "x1"], ENABLE_ESOUND=yes, ENABLE_ESOUND=no)
1434 AS_IF([test "x$HAVE_ESOUND" = "x1" -a "x$USE_PER_USER_ESOUND_SOCKET" = "x1"], ENABLE_PER_USER_ESOUND_SOCKET=yes, ENABLE_PER_USER_ESOUND_SOCKET=no)
1435 AS_IF([test "x$HAVE_GCOV" = "x1"], ENABLE_GCOV=yes, ENABLE_GCOV=no)
1436 AS_IF([test "x$HAVE_LIBCHECK" = "x1"], ENABLE_TESTS=yes, ENABLE_TESTS=no)
1437 AS_IF([test "x$enable_legacy_database_entry_format" != "xno"], ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=yes, ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=no)
1438
1439 echo "
1440  ---{ $PACKAGE_NAME $VERSION }---
1441
1442     prefix:                        ${prefix}
1443     sysconfdir:                    ${sysconfdir}
1444     localstatedir:                 ${localstatedir}
1445     modlibexecdir:                 ${modlibexecdir}
1446     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1447     System State Path:             ${PA_SYSTEM_STATE_PATH}
1448     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1449     Compiler:                      ${CC}
1450     CFLAGS:                        ${CFLAGS}
1451     LIBS:                          ${LIBS}
1452
1453     Enable X11:                    ${ENABLE_X11}
1454     Enable OSS Output:             ${ENABLE_OSS_OUTPUT}
1455     Enable OSS Wrapper:            ${ENABLE_OSS_WRAPPER}
1456     Enable EsounD:                 ${ENABLE_ESOUND}
1457     Enable Alsa:                   ${ENABLE_ALSA}
1458     Enable CoreAudio:              ${ENABLE_COREAUDIO}
1459     Enable Solaris:                ${ENABLE_SOLARIS}
1460     Enable WaveOut:                ${ENABLE_WAVEOUT}
1461     Enable GLib 2.0:               ${ENABLE_GLIB20}
1462     Enable Gtk+ 3.0:               ${ENABLE_GTK30}
1463     Enable GConf:                  ${ENABLE_GCONF}
1464     Enable Avahi:                  ${ENABLE_AVAHI}
1465     Enable Jack:                   ${ENABLE_JACK}
1466     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1467     Enable LIRC:                   ${ENABLE_LIRC}
1468     Enable Xen PV driver:          ${ENABLE_XEN}
1469     Enable D-Bus:                  ${ENABLE_DBUS}
1470       Enable BlueZ:                ${ENABLE_BLUEZ}
1471     Enable udev:                   ${ENABLE_UDEV}
1472       Enable HAL->udev compat:     ${ENABLE_HAL_COMPAT}
1473     Enable systemd login:          ${ENABLE_SYSTEMD}
1474     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1475     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1476     Enable IPv6:                   ${ENABLE_IPV6}
1477     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1478     Enable fftw:                   ${ENABLE_FFTW}
1479     Enable orc:                    ${ENABLE_ORC}
1480     Enable Adrian echo canceller:  ${ENABLE_ADRIAN_EC}
1481     Enable speex (resampler, AEC): ${ENABLE_SPEEX}
1482     Enable WebRTC echo canceller:  ${ENABLE_WEBRTC}
1483     Enable gcov coverage:          ${ENABLE_GCOV}
1484     Enable unit tests:             ${ENABLE_TESTS}
1485     Database
1486       tdb:                         ${ENABLE_TDB}
1487       gdbm:                        ${ENABLE_GDBM}
1488       simple database:             ${ENABLE_SIMPLEDB}
1489
1490     System User:                   ${PA_SYSTEM_USER}
1491     System Group:                  ${PA_SYSTEM_GROUP}
1492     Access Group:                  ${PA_ACCESS_GROUP}
1493     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1494     Force preopen:                 ${FORCE_PREOPEN}
1495     Preopened modules:             ${PREOPEN_MODS}
1496
1497     Legacy Database Entry Support: ${ENABLE_LEGACY_DATABASE_ENTRY_FORMAT}
1498 "
1499
1500 if test "${ENABLE_SPEEX}" = "no" && test "${ENABLE_WEBRTC}" = "no" && test "${ENABLE_ADRIAN_EC}" = "no" ; then
1501 AC_MSG_ERROR([At least one echo canceller implementation must be available.])
1502 fi
1503
1504 if test "${ENABLE_DBUS}" = "no" && test "x$os_is_win32" != "x1" ; then
1505    echo "
1506 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1507 You do not have D-Bus support enabled. It is strongly recommended
1508 that you enable D-Bus support if your platform supports it.
1509 Many parts of PulseAudio use D-Bus, from ConsoleKit interaction
1510 to the Device Reservation Protocol to speak to JACK, Bluetooth
1511 support and even a native control protocol for communicating and
1512 controling the PulseAudio daemon itself.
1513 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1514 "
1515 fi
1516
1517 if test "${ENABLE_UDEV}" = "no" && test "x$os_is_win32" != "x1" ; then
1518    echo "
1519 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1520 You do not have udev support enabled. It is strongly recommended
1521 that you enable udev support if your platform supports it as it is
1522 the primary method used to detect hardware audio devices (on Linux)
1523 and is thus a critical part of PulseAudio on that platform.
1524 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1525 "
1526 fi
1527
1528 if test "${ENABLE_SPEEX}" = "no" && test "x$os_is_win32" != "x1" ; then
1529    echo "
1530 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1531 You do not have speex support enabled. It is strongly recommended
1532 that you enable speex support if your platform supports it as it is
1533 the primary method used for audio resampling and is thus a critical
1534 part of PulseAudio on that platform.
1535 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1536 "
1537 fi