configure.ac

   1 AC_PREREQ([2.64])
   2
   3 m4_define([libinput_major_version], [0])
   4 m4_define([libinput_minor_version], [1])
   5 m4_define([libinput_micro_version], [0])
   6 m4_define([libinput_version],
   7           [libinput_major_version.libinput_minor_version.libinput_micro_version])
   8
   9 AC_INIT([libinput],
  10         [libinput_version],
  11         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=libinput&version=libinput_version],
  12         [libinput],
  13         [http://www.freedesktop.org/wiki/Software/libinput/])
  14
  15 AC_SUBST([LIBINPUT_VERSION_MAJOR], [libinput_major_version])
  16 AC_SUBST([LIBINPUT_VERSION_MINOR], [libinput_minor_version])
  17 AC_SUBST([LIBINPUT_VERSION_MICRO], [libinput_micro_version])
  18 AC_SUBST([LIBINPUT_VERSION], [libinput_version])
  19
  20 AC_CONFIG_HEADERS([config.h])
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz])
  24
  25 AM_SILENT_RULES([yes])
  26
  27 # Check for programs
  28 AC_PROG_CC_C99
  29
  30 # Initialize libtool
  31 LT_PREREQ([2.2])
  32 LT_INIT
  33
  34 AC_CHECK_DECL(EPOLL_CLOEXEC, [],
  35               [AC_MSG_ERROR("EPOLL_CLOEXEC is needed to compile libinput")],
  36               [[#include <sys/epoll.h>]])
  37 AC_CHECK_DECL(TFD_CLOEXEC,[],
  38               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile libinput")],
  39               [[#include <sys/timerfd.h>]])
  40 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
  41               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile libinput")],
  42               [[#include <time.h>]])
  43
  44 PKG_PROG_PKG_CONFIG()
  45 PKG_CHECK_MODULES(MTDEV, [mtdev >= 1.1.0])
  46 PKG_CHECK_MODULES(LIBUDEV, [libudev])
  47 PKG_CHECK_MODULES(LIBEVDEV, [libevdev >= 0.4])
  48
  49 if test "x$GCC" = "xyes"; then
  50         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter -g -Wstrict-prototypes -Wmissing-prototypes -fvisibility=hidden"
  51 fi
  52 AC_SUBST(GCC_CFLAGS)
  53
  54 AC_PATH_PROG(DOXYGEN, [doxygen])
  55 if test "x$DOXYGEN" = "x"; then
  56         AC_MSG_WARN([doxygen not found - required for documentation])
  57         have_doxygen="no"
  58 else
  59         have_doxygen="yes"
  60 fi
  61 AM_CONDITIONAL([HAVE_DOXYGEN], [test "x$have_doxygen" = "xyes"])
  62
  63 AC_ARG_ENABLE(tests,
  64               AS_HELP_STRING([--enable-tests], [Build the tests (default=auto)]),
  65               [build_tests="$enableval"],
  66               [build_tests="auto"])
  67
  68 PKG_CHECK_MODULES(CHECK, [check >= 0.9.9], [HAVE_CHECK="yes"], [HAVE_CHECK="no"])
  69
  70 if test "x$build_tests" = "xauto"; then
  71         if test "x$HAVE_CHECK" = "xyes"; then
  72                 build_tests="yes"
  73         fi
  74 fi
  75 if test "x$build_tests" = "xyes" -a "x$HAVE_CHECK" = "xno"; then
  76        AC_MSG_ERROR([Cannot build tests, check is missing])
  77 fi
  78
  79 AM_CONDITIONAL(BUILD_TESTS, [test "x$build_tests" = "xyes"])
  80
  81 AC_CONFIG_FILES([Makefile
  82                  doc/Makefile
  83                  doc/libinput.doxygen
  84                  src/Makefile
  85                  src/libinput.pc
  86                  src/libinput-version.h
  87                  test/Makefile
  88                  tools/Makefile])
  89 AC_OUTPUT