configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19 AM_INIT_AUTOMAKE([foreign -Wall])
  20
  21 dnl http://people.gnome.org/~walters/docs/build-api.txt
  22 dnl We don't support srcdir != builddir.
  23 echo \#buildapi-variable-no-builddir >/dev/null
  24
  25 # Support silent build rules, requires at least automake-1.11. Disable
  26 # by either passing --disable-silent-rules to configure or passing V=1
  27 # to make
  28 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  29
  30 LT_PREREQ([2.2])
  31 LT_INIT([disable-static])
  32
  33 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  34 USER_CFLAGS="$CFLAGS"
  35 USER_CXXFLAGS="$CXXFLAGS"
  36
  37 dnl Versions for external dependencies
  38 LIBDRM_REQUIRED=2.4.24
  39 LIBDRM_RADEON_REQUIRED=2.4.31
  40 LIBDRM_INTEL_REQUIRED=2.4.32
  41 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  42 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  43 DRI2PROTO_REQUIRED=2.6
  44 GLPROTO_REQUIRED=1.4.14
  45 LIBDRM_XORG_REQUIRED=2.4.24
  46 LIBKMS_XORG_REQUIRED=1.0.0
  47
  48 dnl Check for progs
  49 AC_PROG_CPP
  50 AC_PROG_CC
  51 AC_PROG_CXX
  52 AM_PROG_CC_C_O
  53 AC_CHECK_PROGS([MAKE], [gmake make])
  54 AC_CHECK_PROGS([PYTHON2], [python2 python])
  55 AC_PROG_SED
  56 AC_PROG_MKDIR_P
  57 AC_PATH_PROG([MKDEP], [makedepend])
  58
  59 if test "x$MKDEP" = "x"; then
  60     AC_MSG_ERROR([makedepend is required to build Mesa])
  61 fi
  62
  63 AC_PROG_YACC
  64 AC_PATH_PROG([YACC_INST], $YACC)
  65 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  66     if test -z "$YACC_INST"; then
  67         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  68     fi
  69 fi
  70 AC_PROG_LEX
  71
  72 AC_PATH_PROG([PERL], [perl])
  73
  74 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  75 dnl configuration in that case.
  76 AC_PROG_INSTALL
  77 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 106     AC_MSG_CHECKING([whether gcc version is sufficient])
 107     major=0
 108     minor=0
 109
 110     GCC_VERSION=`$CC -dumpversion`
 111     if test $? -eq 0; then
 112         major=`echo $GCC_VERSION | cut -d. -f1`
 113         minor=`echo $GCC_VERSION | cut -d. -f2`
 114     fi
 115
 116     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
 117         AC_MSG_RESULT([no])
 118         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 119     else
 120         AC_MSG_RESULT([yes])
 121     fi
 122 fi
 123
 124
 125 MKDEP_OPTIONS=-fdepend
 126 dnl Ask gcc where it's keeping its secret headers
 127 if test "x$GCC" = xyes; then
 128     for dir in include include-fixed; do
 129         GCC_INCLUDES=`$CC -print-file-name=$dir`
 130         if test "x$GCC_INCLUDES" != x && \
 131            test "$GCC_INCLUDES" != "$dir" && \
 132            test -d "$GCC_INCLUDES"; then
 133             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 134         fi
 135     done
 136 fi
 137 AC_SUBST([MKDEP_OPTIONS])
 138
 139 dnl Make sure the pkg-config macros are defined
 140 m4_ifndef([PKG_PROG_PKG_CONFIG],
 141     [m4_fatal([Could not locate the pkg-config autoconf macros.
 142   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 143   are in a different location, try setting the environment variable
 144   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 145 PKG_PROG_PKG_CONFIG()
 146
 147 dnl LIB_DIR - library basename
 148 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 149 AC_SUBST([LIB_DIR])
 150
 151 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 152 _SAVE_LDFLAGS="$LDFLAGS"
 153 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 154 AC_SUBST([EXTRA_LIB_PATH])
 155
 156 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 157 _SAVE_CPPFLAGS="$CPPFLAGS"
 158 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 159 AC_SUBST([X11_INCLUDES])
 160
 161 dnl Compiler macros
 162 DEFINES=""
 163 AC_SUBST([DEFINES])
 164 case "$host_os" in
 165 linux*|*-gnu*|gnu*)
 166     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 167     ;;
 168 solaris*)
 169     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 170     ;;
 171 cygwin*)
 172     DEFINES="$DEFINES -DPTHREADS"
 173     ;;
 174 esac
 175
 176 dnl Add flags for gcc and g++
 177 if test "x$GCC" = xyes; then
 178     CFLAGS="$CFLAGS -Wall -std=c99"
 179
 180     # Enable -Werror=implicit-function-declaration and
 181     # -Werror=missing-prototypes, if available, or otherwise, just
 182     # -Wmissing-prototypes.  This is particularly useful to avoid
 183     # generating a loadable driver module that has undefined symbols.
 184     save_CFLAGS="$CFLAGS"
 185     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 186     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 187     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 189                    AC_MSG_RESULT([yes]),
 190                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 191                     AC_MSG_RESULT([no])]);
 192
 193     # Enable -fvisibility=hidden if using a gcc that supports it
 194     save_CFLAGS="$CFLAGS"
 195     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 196     VISIBILITY_CFLAGS="-fvisibility=hidden"
 197     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 198     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 199                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 200
 201     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 202     CFLAGS=$save_CFLAGS
 203
 204     # Work around aliasing bugs - developers should comment this out
 205     CFLAGS="$CFLAGS -fno-strict-aliasing"
 206
 207     # gcc's builtin memcmp is slower than glibc's
 208     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 209     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 210 fi
 211 if test "x$GXX" = xyes; then
 212     CXXFLAGS="$CXXFLAGS -Wall"
 213
 214     # Enable -fvisibility=hidden if using a gcc that supports it
 215     save_CXXFLAGS="$CXXFLAGS"
 216     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 217     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 218     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 219     AC_LANG_PUSH([C++])
 220     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 221                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 222     AC_LANG_POP([C++])
 223
 224     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 225     CXXFLAGS=$save_CXXFLAGS
 226
 227     # Work around aliasing bugs - developers should comment this out
 228     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 229
 230     # gcc's builtin memcmp is slower than glibc's
 231     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 232     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 233 fi
 234
 235 dnl even if the compiler appears to support it, using visibility attributes isn't
 236 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 237 case "$host_os" in
 238 cygwin*)
 239     VISIBILITY_CFLAGS=""
 240     VISIBILITY_CXXFLAGS=""
 241     ;;
 242 esac
 243
 244 AC_SUBST([VISIBILITY_CFLAGS])
 245 AC_SUBST([VISIBILITY_CXXFLAGS])
 246
 247 dnl These should be unnecessary, but let the user set them if they want
 248 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 249     Default is to use CFLAGS.])
 250 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 251     compiler. Default is to use CFLAGS.])
 252 AC_SUBST([OPT_FLAGS])
 253 AC_SUBST([ARCH_FLAGS])
 254
 255 dnl
 256 dnl Hacks to enable 32 or 64 bit build
 257 dnl
 258 AC_ARG_ENABLE([32-bit],
 259     [AS_HELP_STRING([--enable-32-bit],
 260         [build 32-bit libraries @<:@default=auto@:>@])],
 261     [enable_32bit="$enableval"],
 262     [enable_32bit=auto]
 263 )
 264 if test "x$enable_32bit" = xyes; then
 265     if test "x$GCC" = xyes; then
 266         CFLAGS="$CFLAGS -m32"
 267         ARCH_FLAGS="$ARCH_FLAGS -m32"
 268     fi
 269     if test "x$GXX" = xyes; then
 270         CXXFLAGS="$CXXFLAGS -m32"
 271     fi
 272 fi
 273 AC_ARG_ENABLE([64-bit],
 274     [AS_HELP_STRING([--enable-64-bit],
 275         [build 64-bit libraries @<:@default=auto@:>@])],
 276     [enable_64bit="$enableval"],
 277     [enable_64bit=auto]
 278 )
 279 if test "x$enable_64bit" = xyes; then
 280     if test "x$GCC" = xyes; then
 281         CFLAGS="$CFLAGS -m64"
 282     fi
 283     if test "x$GXX" = xyes; then
 284         CXXFLAGS="$CXXFLAGS -m64"
 285     fi
 286 fi
 287
 288 dnl Can't have static and shared libraries, default to static if user
 289 dnl explicitly requested. If both disabled, set to static since shared
 290 dnl was explicitly requested.
 291 case "x$enable_static$enable_shared" in
 292 xyesyes )
 293     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 294     enable_shared=no
 295     ;;
 296 xnono )
 297     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 298     enable_static=yes
 299     ;;
 300 esac
 301
 302 dnl
 303 dnl mklib options
 304 dnl
 305 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 306 if test "$enable_static" = yes; then
 307     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 308 fi
 309 AC_SUBST([MKLIB_OPTIONS])
 310
 311 dnl
 312 dnl other compiler options
 313 dnl
 314 AC_ARG_ENABLE([debug],
 315     [AS_HELP_STRING([--enable-debug],
 316         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 317     [enable_debug="$enableval"],
 318     [enable_debug=no]
 319 )
 320 if test "x$enable_debug" = xyes; then
 321     DEFINES="$DEFINES -DDEBUG"
 322     if test "x$GCC" = xyes; then
 323         CFLAGS="$CFLAGS -g"
 324     fi
 325     if test "x$GXX" = xyes; then
 326         CXXFLAGS="$CXXFLAGS -g"
 327     fi
 328 fi
 329
 330 dnl
 331 dnl library names
 332 dnl
 333 LIB_PREFIX_GLOB='lib'
 334 LIB_VERSION_SEPARATOR='.'
 335 if test "$enable_static" = yes; then
 336     LIB_EXTENSION='a'
 337 else
 338     case "$host_os" in
 339     darwin* )
 340         LIB_EXTENSION='dylib' ;;
 341     cygwin* )
 342         dnl prefix can be 'cyg' or 'lib'
 343         LIB_PREFIX_GLOB='???'
 344         LIB_VERSION_SEPARATOR='-'
 345         LIB_EXTENSION='dll' ;;
 346     aix* )
 347         LIB_EXTENSION='a' ;;
 348     * )
 349         LIB_EXTENSION='so' ;;
 350     esac
 351 fi
 352
 353 dnl
 354 dnl Mangled Mesa support
 355 dnl
 356 AC_ARG_ENABLE([mangling],
 357   [AS_HELP_STRING([--enable-mangling],
 358     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 359   [enable_mangling="${enableval}"],
 360   [enable_mangling=no]
 361 )
 362 GL_LIB="GL"
 363 GLU_LIB="GLU"
 364 OSMESA_LIB="OSMesa"
 365 if test "x${enable_mangling}" = "xyes" ; then
 366   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 367   GL_LIB="MangledGL"
 368   GLU_LIB="MangledGLU"
 369   OSMESA_LIB="MangledOSMesa"
 370 fi
 371 AC_SUBST([GL_LIB])
 372 AC_SUBST([GLU_LIB])
 373 AC_SUBST([OSMESA_LIB])
 374 AM_CONDITIONAL(HAVE_MANGLED_GL, test $GL_LIB = MangledGL)
 375
 376 dnl
 377 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 378 dnl
 379 AC_ARG_ENABLE([texture-float],
 380     [AS_HELP_STRING([--enable-texture-float],
 381         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 382     [enable_texture_float="$enableval"],
 383     [enable_texture_float=no]
 384 )
 385 if test "x$enable_texture_float" = xyes; then
 386     AC_MSG_WARN([Floating-point textures enabled.])
 387     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 388     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 389 fi
 390
 391 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 392 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 393 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 394 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 395 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 396 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 397 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 398 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 399
 400 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409
 410 AC_SUBST([GL_LIB_NAME])
 411 AC_SUBST([GLU_LIB_NAME])
 412 AC_SUBST([OSMESA_LIB_NAME])
 413 AC_SUBST([EGL_LIB_NAME])
 414 AC_SUBST([GLESv1_CM_LIB_NAME])
 415 AC_SUBST([GLESv2_LIB_NAME])
 416 AC_SUBST([VG_LIB_NAME])
 417 AC_SUBST([GLAPI_LIB_NAME])
 418
 419 AC_SUBST([GL_LIB_GLOB])
 420 AC_SUBST([GLU_LIB_GLOB])
 421 AC_SUBST([OSMESA_LIB_GLOB])
 422 AC_SUBST([EGL_LIB_GLOB])
 423 AC_SUBST([GLESv1_CM_LIB_GLOB])
 424 AC_SUBST([GLESv2_LIB_GLOB])
 425 AC_SUBST([VG_LIB_GLOB])
 426 AC_SUBST([GLAPI_LIB_GLOB])
 427
 428 dnl
 429 dnl Arch/platform-specific settings
 430 dnl
 431 AC_ARG_ENABLE([asm],
 432     [AS_HELP_STRING([--disable-asm],
 433         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 434     [enable_asm="$enableval"],
 435     [enable_asm=yes]
 436 )
 437 asm_arch=""
 438 ASM_FLAGS=""
 439 MESA_ASM_SOURCES=""
 440 GLAPI_ASM_SOURCES=""
 441 AC_MSG_CHECKING([whether to enable assembly])
 442 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 443 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 444 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 445     case "$host_cpu" in
 446     i?86 | x86_64)
 447         enable_asm=no
 448         AC_MSG_RESULT([no, cross compiling])
 449         ;;
 450     esac
 451 fi
 452 # check for supported arches
 453 if test "x$enable_asm" = xyes; then
 454     case "$host_cpu" in
 455     i?86)
 456         case "$host_os" in
 457         linux* | *freebsd* | dragonfly* | *netbsd*)
 458             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 459             ;;
 460         esac
 461         ;;
 462     x86_64)
 463         case "$host_os" in
 464         linux* | *freebsd* | dragonfly* | *netbsd*)
 465             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 466             ;;
 467         esac
 468         ;;
 469     powerpc)
 470         case "$host_os" in
 471         linux*)
 472             asm_arch=ppc
 473             ;;
 474         esac
 475         ;;
 476     sparc*)
 477         case "$host_os" in
 478         linux*)
 479             asm_arch=sparc
 480             ;;
 481         esac
 482         ;;
 483     esac
 484
 485     case "$asm_arch" in
 486     x86)
 487         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 488         MESA_ASM_SOURCES='$(X86_SOURCES)'
 489         GLAPI_ASM_SOURCES='$(X86_API)'
 490         AC_MSG_RESULT([yes, x86])
 491         ;;
 492     x86_64)
 493         ASM_FLAGS="-DUSE_X86_64_ASM"
 494         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 495         GLAPI_ASM_SOURCES='$(X86-64_API)'
 496         AC_MSG_RESULT([yes, x86_64])
 497         ;;
 498     sparc)
 499         ASM_FLAGS="-DUSE_SPARC_ASM"
 500         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 501         GLAPI_ASM_SOURCES='$(SPARC_API)'
 502         AC_MSG_RESULT([yes, sparc])
 503         ;;
 504     *)
 505         AC_MSG_RESULT([no, platform not supported])
 506         ;;
 507     esac
 508 fi
 509 AC_SUBST([ASM_FLAGS])
 510 AC_SUBST([MESA_ASM_SOURCES])
 511 AC_SUBST([GLAPI_ASM_SOURCES])
 512
 513 dnl PIC code macro
 514 MESA_PIC_FLAGS
 515
 516 dnl Check to see if dlopen is in default libraries (like Solaris, which
 517 dnl has it in libc), or if libdl is needed to get it.
 518 AC_CHECK_FUNC([dlopen], [],
 519     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 520 AC_SUBST([DLOPEN_LIBS])
 521
 522 dnl See if posix_memalign is available
 523 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 524
 525 dnl SELinux awareness.
 526 AC_ARG_ENABLE([selinux],
 527     [AS_HELP_STRING([--enable-selinux],
 528         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 529     [MESA_SELINUX="$enableval"],
 530     [MESA_SELINUX=no])
 531 if test "x$enable_selinux" = "xyes"; then
 532     AC_CHECK_HEADER([selinux/selinux.h],[],
 533                     [AC_MSG_ERROR([SELinux headers not found])])
 534     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 535                  [AC_MSG_ERROR([SELinux library not found])])
 536     SELINUX_LIBS="-lselinux"
 537     DEFINES="$DEFINES -DMESA_SELINUX"
 538 fi
 539
 540 dnl Options for APIs
 541 AC_ARG_ENABLE([opengl],
 542     [AS_HELP_STRING([--disable-opengl],
 543         [disable support for standard OpenGL API @<:@default=no@:>@])],
 544     [enable_opengl="$enableval"],
 545     [enable_opengl=yes])
 546 AC_ARG_ENABLE([gles1],
 547     [AS_HELP_STRING([--enable-gles1],
 548         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 549     [enable_gles1="$enableval"],
 550     [enable_gles1=no])
 551 AC_ARG_ENABLE([gles2],
 552     [AS_HELP_STRING([--enable-gles2],
 553         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 554     [enable_gles2="$enableval"],
 555     [enable_gles2=no])
 556 AC_ARG_ENABLE([openvg],
 557     [AS_HELP_STRING([--enable-openvg],
 558         [enable support for OpenVG API @<:@default=no@:>@])],
 559     [enable_openvg="$enableval"],
 560     [enable_openvg=no])
 561
 562 AC_ARG_ENABLE([dri],
 563     [AS_HELP_STRING([--enable-dri],
 564         [enable DRI modules @<:@default=auto@:>@])],
 565     [enable_dri="$enableval"],
 566     [enable_dri=auto])
 567 AC_ARG_ENABLE([glx],
 568     [AS_HELP_STRING([--enable-glx],
 569         [enable GLX library @<:@default=auto@:>@])],
 570     [enable_glx="$enableval"],
 571     [enable_glx=auto])
 572 AC_ARG_ENABLE([osmesa],
 573     [AS_HELP_STRING([--enable-osmesa],
 574         [enable OSMesa library @<:@default=auto@:>@])],
 575     [enable_osmesa="$enableval"],
 576     [enable_osmesa=auto])
 577 AC_ARG_ENABLE([egl],
 578     [AS_HELP_STRING([--disable-egl],
 579         [disable EGL library @<:@default=enabled@:>@])],
 580     [enable_egl="$enableval"],
 581     [enable_egl=yes])
 582
 583 AC_ARG_ENABLE([xorg],
 584     [AS_HELP_STRING([--enable-xorg],
 585         [enable support for X.Org DDX API @<:@default=no@:>@])],
 586     [enable_xorg="$enableval"],
 587     [enable_xorg=no])
 588 AC_ARG_ENABLE([xa],
 589     [AS_HELP_STRING([--enable-xa],
 590         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 591     [enable_xa="$enableval"],
 592     [enable_xa=no])
 593 AC_ARG_ENABLE([d3d1x],
 594     [AS_HELP_STRING([--enable-d3d1x],
 595         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 596     [enable_d3d1x="$enableval"],
 597     [enable_d3d1x=no])
 598 AC_ARG_ENABLE([gbm],
 599    [AS_HELP_STRING([--enable-gbm],
 600          [enable gbm library @<:@default=auto@:>@])],
 601    [enable_gbm="$enableval"],
 602    [enable_gbm=auto])
 603
 604 AC_ARG_ENABLE([xvmc],
 605    [AS_HELP_STRING([--enable-xvmc],
 606          [enable xvmc library @<:@default=auto@:>@])],
 607    [enable_xvmc="$enableval"],
 608    [enable_xvmc=auto])
 609 AC_ARG_ENABLE([vdpau],
 610    [AS_HELP_STRING([--enable-vdpau],
 611          [enable vdpau library @<:@default=auto@:>@])],
 612    [enable_vdpau="$enableval"],
 613    [enable_vdpau=auto])
 614 AC_ARG_ENABLE([va],
 615    [AS_HELP_STRING([--enable-va],
 616          [enable va library @<:@default=auto@:>@])],
 617    [enable_va="$enableval"],
 618    [enable_va=auto])
 619
 620 AC_ARG_ENABLE([xlib_glx],
 621     [AS_HELP_STRING([--enable-xlib-glx],
 622         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 623     [enable_xlib_glx="$enableval"],
 624     [enable_xlib_glx=auto])
 625 AC_ARG_ENABLE([gallium_egl],
 626     [AS_HELP_STRING([--enable-gallium-egl],
 627         [enable optional EGL state tracker (not required
 628          for EGL support in Gallium with OpenGL and OpenGL ES)
 629          @<:@default=disable@:>@])],
 630     [enable_gallium_egl="$enableval"],
 631     [enable_gallium_egl=no])
 632 AC_ARG_ENABLE([gallium_gbm],
 633     [AS_HELP_STRING([--enable-gallium-gbm],
 634         [enable optional gbm state tracker (not required for
 635          gbm support in Gallium)
 636          @<:@default=auto@:>@])],
 637     [enable_gallium_gbm="$enableval"],
 638     [enable_gallium_gbm=auto])
 639
 640 AC_ARG_ENABLE([r600-llvm-compiler],
 641     [AS_HELP_STRING([--enable-r600-llvm-compilerl],
 642         [Enable experimental LLVM backend for graphics shaders @<:default=disable@:>@])],
 643     [enable_r600_llvm="$enableval"],
 644     [enable_r600_llvm=no])
 645
 646 AC_ARG_ENABLE([gallium_tests],
 647     [AS_HELP_STRING([--enable-gallium-tests],
 648         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 649     [enable_gallium_tests="$enableval"],
 650     [enable_gallium_tests=no])
 651
 652 # Option for Gallium drivers
 653 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 654
 655 AC_ARG_WITH([gallium-drivers],
 656     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 657         [comma delimited Gallium drivers list, e.g.
 658         "i915,nouveau,r300,r600,svga,swrast"
 659         @<:@default=r300,r600,swrast@:>@])],
 660     [with_gallium_drivers="$withval"],
 661     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 662
 663 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 664 # here so that the script doesn't choke on an unknown driver name later.
 665 case "$with_gallium_drivers" in
 666     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 667     no) with_gallium_drivers='' ;;
 668 esac
 669
 670 if test "x$enable_opengl" = xno -a \
 671         "x$enable_gles1" = xno -a \
 672         "x$enable_gles2" = xno -a \
 673         "x$enable_openvg" = xno -a \
 674         "x$enable_xorg" = xno -a \
 675         "x$enable_xa" = xno -a \
 676         "x$enable_d3d1x" = xno -a \
 677         "x$enable_xvmc" = xno -a \
 678         "x$enable_vdpau" = xno -a \
 679         "x$enable_va" = xno; then
 680     AC_MSG_ERROR([at least one API should be enabled])
 681 fi
 682
 683 API_DEFINES=""
 684 if test "x$enable_opengl" = xno; then
 685     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 686 else
 687     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 688 fi
 689 if test "x$enable_gles1" = xyes; then
 690     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 691 fi
 692 if test "x$enable_gles2" = xyes; then
 693     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 694 fi
 695 AC_SUBST([API_DEFINES])
 696
 697 AC_ARG_ENABLE([shared-glapi],
 698     [AS_HELP_STRING([--enable-shared-glapi],
 699         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 700     [enable_shared_glapi="$enableval"],
 701     [enable_shared_glapi=no])
 702
 703 SHARED_GLAPI="0"
 704 if test "x$enable_shared_glapi" = xyes; then
 705     SHARED_GLAPI="1"
 706     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 707     # the remap table)
 708     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 709     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 710 fi
 711 AC_SUBST([SHARED_GLAPI])
 712 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 713
 714 dnl
 715 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 716 dnl More later: fbdev, ...
 717 dnl
 718 default_driver="xlib"
 719
 720 case "$host_os" in
 721 linux*)
 722     case "$host_cpu" in
 723     i*86|x86_64|powerpc*|sparc*|ia64*) default_driver="dri";;
 724     esac
 725     ;;
 726 *freebsd* | dragonfly* | *netbsd*)
 727     case "$host_cpu" in
 728     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 729     esac
 730     ;;
 731 esac
 732
 733 if test "x$enable_opengl" = xno; then
 734     default_driver="no"
 735 fi
 736
 737 AC_ARG_WITH([driver],
 738     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 739     [mesa_driver="$withval"],
 740     [mesa_driver=auto])
 741 dnl Check for valid option
 742 case "x$mesa_driver" in
 743 xxlib|xdri|xosmesa|xno)
 744     if test "x$enable_dri" != xauto -o \
 745             "x$enable_glx" != xauto -o \
 746             "x$enable_osmesa" != xauto -o \
 747             "x$enable_xlib_glx" != xauto; then
 748         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 749     fi
 750     ;;
 751 xauto)
 752     mesa_driver="$default_driver"
 753     ;;
 754 *)
 755     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 756     ;;
 757 esac
 758
 759 # map $mesa_driver to APIs
 760 if test "x$enable_dri" = xauto; then
 761     case "x$mesa_driver" in
 762     xdri) enable_dri=yes ;;
 763     *)    enable_dri=no ;;
 764     esac
 765 fi
 766
 767 if test "x$enable_glx" = xauto; then
 768     case "x$mesa_driver" in
 769     xdri|xxlib) enable_glx=yes ;;
 770     *)          enable_glx=no ;;
 771     esac
 772 fi
 773
 774 if test "x$enable_osmesa" = xauto; then
 775     case "x$mesa_driver" in
 776     xxlib|xosmesa) enable_osmesa=yes ;;
 777     *)             enable_osmesa=no ;;
 778     esac
 779 fi
 780
 781 if test "x$enable_xlib_glx" = xauto; then
 782     case "x$mesa_driver" in
 783     xxlib) enable_xlib_glx=yes ;;
 784     *)     enable_xlib_glx=no ;;
 785     esac
 786 fi
 787
 788 if test "x$enable_glx" = xno; then
 789     enable_xlib_glx=no
 790 fi
 791
 792 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 793
 794 dnl
 795 dnl Driver specific build directories
 796 dnl
 797
 798 dnl this variable will be prepended to SRC_DIRS and is not exported
 799 CORE_DIRS=""
 800
 801 SRC_DIRS="gtest"
 802 GLU_DIRS="sgi"
 803 GALLIUM_DIRS="auxiliary drivers state_trackers"
 804 GALLIUM_TARGET_DIRS=""
 805 GALLIUM_WINSYS_DIRS="sw"
 806 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 807 GALLIUM_STATE_TRACKERS_DIRS=""
 808
 809 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 810 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 811 x*yes*)
 812     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 813     ;;
 814 esac
 815
 816 # build glapi if OpenGL is enabled
 817 if test "x$enable_opengl" = xyes; then
 818     CORE_DIRS="$CORE_DIRS mapi/glapi"
 819 fi
 820
 821 # build es1api if OpenGL ES 1.x is enabled
 822 if test "x$enable_gles1" = xyes; then
 823     CORE_DIRS="$CORE_DIRS mapi/es1api"
 824 fi
 825
 826 # build es2api if OpenGL ES 2.x is enabled
 827 if test "x$enable_gles2" = xyes; then
 828     CORE_DIRS="$CORE_DIRS mapi/es2api"
 829 fi
 830
 831 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 832 case "x$enable_opengl$enable_gles1$enable_gles2" in
 833 x*yes*)
 834     CORE_DIRS="$CORE_DIRS glsl mesa"
 835     ;;
 836 esac
 837
 838 case "x$enable_glx$enable_xlib_glx" in
 839 xyesyes)
 840     DRIVER_DIRS="$DRIVER_DIRS x11"
 841     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 842     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 843     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 844     HAVE_WINSYS_XLIB="yes"
 845     ;;
 846 xyesno)
 847     # DRI-based GLX
 848     SRC_DIRS="$SRC_DIRS glx"
 849     ;;
 850 esac
 851
 852 if test "x$enable_dri" = xyes; then
 853     DRIVER_DIRS="$DRIVER_DIRS dri"
 854
 855     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 856     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 857     HAVE_ST_DRI="yes"
 858 fi
 859
 860 if test "x$enable_osmesa" = xyes; then
 861     # the empty space matters for osmesa... (see src/mesa/Makefile)
 862     if test -n "$DRIVER_DIRS"; then
 863         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 864     else
 865         DRIVER_DIRS="osmesa"
 866     fi
 867 fi
 868
 869 AC_SUBST([SRC_DIRS])
 870 AC_SUBST([GLU_DIRS])
 871 AC_SUBST([DRIVER_DIRS])
 872 AC_SUBST([GALLIUM_DIRS])
 873 AC_SUBST([GALLIUM_TARGET_DIRS])
 874 AC_SUBST([GALLIUM_WINSYS_DIRS])
 875 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 876 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 877 AC_SUBST([MESA_LLVM])
 878
 879 # Check for libdrm
 880 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 881                   [have_libdrm=yes], [have_libdrm=no])
 882
 883 if test "x$enable_dri" = xyes; then
 884     # DRI must be shared, I think
 885     if test "$enable_static" = yes; then
 886         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 887     fi
 888
 889     # not a hard requirement as swrast does not depend on it
 890     if test "x$have_libdrm" = xyes; then
 891         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 892     fi
 893 fi
 894
 895 dnl
 896 dnl Find out if X is available. The variable have_x is set if libX11 is
 897 dnl found to mimic AC_PATH_XTRA.
 898 dnl
 899 if test -n "$PKG_CONFIG"; then
 900     AC_MSG_CHECKING([pkg-config files for X11 are available])
 901     PKG_CHECK_EXISTS([x11],[
 902         x11_pkgconfig=yes
 903         have_x=yes
 904         ],[
 905         x11_pkgconfig=no
 906     ])
 907     AC_MSG_RESULT([$x11_pkgconfig])
 908 else
 909     x11_pkgconfig=no
 910 fi
 911 dnl Use the autoconf macro if no pkg-config files
 912 if test "$x11_pkgconfig" = yes; then
 913     PKG_CHECK_MODULES([X11], [x11])
 914 else
 915     AC_PATH_XTRA
 916     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 917     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 918     AC_SUBST([X11_CFLAGS])
 919     AC_SUBST([X11_LIBS])
 920 fi
 921
 922 dnl Try to tell the user that the --x-* options are only used when
 923 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 924 m4_divert_once([HELP_BEGIN],
 925 [These options are only used when the X libraries cannot be found by the
 926 pkg-config utility.])
 927
 928 dnl We need X for xlib and dri, so bomb now if it's not found
 929 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 930     AC_MSG_ERROR([X11 development libraries needed for GLX])
 931 fi
 932
 933 if test "x$enable_glx" = xyes; then
 934     DEFINES="$DEFINES -DUSE_XCB"
 935 fi
 936
 937 dnl Direct rendering or just indirect rendering
 938 case "$host_os" in
 939 gnu*)
 940     dnl Disable by default on GNU/Hurd
 941     driglx_direct_default="no"
 942     ;;
 943 cygwin*)
 944     dnl Disable by default on cygwin
 945     driglx_direct_default="no"
 946     ;;
 947 *)
 948     driglx_direct_default="yes"
 949     ;;
 950 esac
 951 AC_ARG_ENABLE([driglx-direct],
 952     [AS_HELP_STRING([--disable-driglx-direct],
 953         [enable direct rendering in GLX and EGL for DRI \
 954             @<:@default=auto@:>@])],
 955     [driglx_direct="$enableval"],
 956     [driglx_direct="$driglx_direct_default"])
 957
 958 dnl
 959 dnl libGL configuration per driver
 960 dnl
 961 case "x$enable_glx$enable_xlib_glx" in
 962 xyesyes)
 963     # Xlib-based GLX
 964     if test "$x11_pkgconfig" = yes; then
 965         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 966         GL_PC_REQ_PRIV="x11 xext"
 967         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 968         GL_LIB_DEPS="$XLIBGL_LIBS"
 969     else
 970         # should check these...
 971         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 972         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 973         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 974         GL_PC_CFLAGS="$X11_INCLUDES"
 975     fi
 976     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 977     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 978     ;;
 979 xyesno)
 980     # DRI-based GLX
 981     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 982     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 983     if test x"$driglx_direct" = xyes; then
 984         if test "x$have_libdrm" != xyes; then
 985             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 986         fi
 987         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 988         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 989     fi
 990
 991     # find the DRI deps for libGL
 992     if test "$x11_pkgconfig" = yes; then
 993         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
 994
 995         # add xf86vidmode if available
 996         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 997         if test "$HAVE_XF86VIDMODE" = yes ; then
 998             dri_modules="$dri_modules xxf86vm"
 999         fi
1000
1001         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1002         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1003         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1004         GL_LIB_DEPS="$DRIGL_LIBS"
1005     else
1006         # should check these...
1007         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
1008         if test "x$HAVE_XF86VIDMODE" == xyes; then
1009            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
1010         else
1011            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1012         fi
1013         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1014         GL_PC_CFLAGS="$X11_INCLUDES"
1015
1016         # XCB can only be used from pkg-config
1017         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
1018         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1019         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1020         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1021     fi
1022
1023     # Check to see if the xcb-glx library is new enough to support
1024     # GLX_ARB_create_context.  This bit of hackery is necessary until XCB 1.8
1025     # is released.
1026     save_CPPFLAGS="$CPPFLAGS"
1027     save_LDFLAGS="$LDFLAGS"
1028     CPPFLAGS="$CPPFLAGS $X11_INCLUDES"
1029     LDFLAGS="$LDFLAGS $GL_LIB_DEPS"
1030     AC_CHECK_LIB(xcb-glx, xcb_glx_create_context_attribs_arb_checked,
1031         [HAVE_XCB_GLX_CREATE_CONTEXT=yes],
1032         [HAVE_XCB_GLX_CREATE_CONTEXT=no])
1033     CPPFLAGS="$save_CPPFLAGS"
1034     LDFLAGS="$save_LDFLAGS"
1035
1036     if test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes; then
1037         X11_INCLUDES="$X11_INCLUDES -DHAVE_XCB_GLX_CREATE_CONTEXT"
1038     fi
1039
1040     # need DRM libs, -lpthread, etc.
1041     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1042     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1043     ;;
1044 esac
1045
1046 # This is outside the case (above) so that it is invoked even for non-GLX
1047 # builds.
1048 AM_CONDITIONAL(HAVE_XCB_GLX_CREATE_CONTEXT,
1049     test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes)
1050 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1051
1052 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1053 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1054 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1055 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1056
1057 AC_SUBST([GL_LIB_DEPS])
1058 AC_SUBST([GL_PC_REQ_PRIV])
1059 AC_SUBST([GL_PC_LIB_PRIV])
1060 AC_SUBST([GL_PC_CFLAGS])
1061 AC_SUBST([DRI_PC_REQ_PRIV])
1062 AC_SUBST([GLESv1_CM_LIB_DEPS])
1063 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1064 AC_SUBST([GLESv2_LIB_DEPS])
1065 AC_SUBST([GLESv2_PC_LIB_PRIV])
1066
1067 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1068 AC_SUBST([GLAPI_LIB_DEPS])
1069
1070
1071 dnl Setup default DRI CFLAGS
1072 DRI_CFLAGS='$(CFLAGS)'
1073 DRI_CXXFLAGS='$(CXXFLAGS)'
1074 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1075 MESA_MODULES='$(TOP)/src/mesa/libmesa.a'
1076
1077 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1078     DRICORE_GLSL_LIBS='$(TOP)/$(LIB_DIR)/libglsl.so'
1079     DRICORE_LIBS='$(TOP)/$(LIB_DIR)/libdricore.so'
1080     DRICORE_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -lglsl'
1081     DRI_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -ldricore -lglsl'
1082     DRI_CFLAGS='$(CFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1083     DRI_CXXFLAGS='$(CXXFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1084     MESA_MODULES='$(DRICORE_LIBS) $(DRICORE_GLSL_LIBS)'
1085 fi
1086 AC_SUBST([DRICORE_LIBS])
1087 AC_SUBST([DRICORE_GLSL_LIBS])
1088 AC_SUBST([DRICORE_LIB_DEPS])
1089 AC_SUBST([DRI_CXXFLAGS])
1090 AC_SUBST([DRI_CFLAGS])
1091 AC_SUBST([MESA_MODULES])
1092
1093 AC_SUBST([HAVE_XF86VIDMODE])
1094
1095 dnl
1096 dnl More GLX setup
1097 dnl
1098 case "x$enable_glx$enable_xlib_glx" in
1099 xyesyes)
1100     DEFINES="$DEFINES -DUSE_XSHM"
1101     ;;
1102 xyesno)
1103     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1104     if test "x$driglx_direct" = xyes; then
1105         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1106     fi
1107     ;;
1108 esac
1109
1110 dnl
1111 dnl TLS detection
1112 dnl
1113
1114 AC_ARG_ENABLE([glx-tls],
1115     [AS_HELP_STRING([--enable-glx-tls],
1116         [enable TLS support in GLX @<:@default=disabled@:>@])],
1117     [GLX_USE_TLS="$enableval"],
1118     [GLX_USE_TLS=no])
1119 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1120
1121 AS_IF([test "x$GLX_USE_TLS" = xyes],
1122       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1123
1124 dnl
1125 dnl More DRI setup
1126 dnl
1127 dnl Directory for DRI drivers
1128 AC_ARG_WITH([dri-driverdir],
1129     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1130         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1131     [DRI_DRIVER_INSTALL_DIR="$withval"],
1132     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1133 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1134 dnl Extra search path for DRI drivers
1135 AC_ARG_WITH([dri-searchpath],
1136     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1137         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1138     [DRI_DRIVER_SEARCH_DIR="$withval"],
1139     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1140 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1141 dnl Which drivers to build - default is chosen by platform
1142 AC_ARG_WITH([dri-drivers],
1143     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1144         [comma delimited DRI drivers list, e.g.
1145         "swrast,i965,radeon" @<:@default=auto@:>@])],
1146     [with_dri_drivers="$withval"],
1147     [with_dri_drivers=yes])
1148 if test "x$with_dri_drivers" = x; then
1149     with_dri_drivers=no
1150 fi
1151
1152 dnl If $with_dri_drivers is yes, directories will be added through
1153 dnl platform checks
1154 DRI_DIRS=""
1155 case "$with_dri_drivers" in
1156 no) ;;
1157 yes)
1158     # classic DRI drivers require FEATURE_GL to build
1159     if test "x$enable_opengl" = xyes; then
1160         DRI_DIRS="yes"
1161     fi
1162     ;;
1163 *)
1164     # verify the requested driver directories exist
1165     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1166     for driver in $dri_drivers; do
1167         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1168             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1169     done
1170     DRI_DIRS="$dri_drivers"
1171     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1172         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1173     fi
1174     ;;
1175 esac
1176
1177 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1178 if test "x$enable_dri" = xyes; then
1179     # Platform specific settings and drivers to build
1180     case "$host_os" in
1181     linux*)
1182         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1183         DEFINES="$DEFINES -DHAVE_ALIAS"
1184
1185         case "$host_cpu" in
1186         x86_64)
1187             if test "x$DRI_DIRS" = "xyes"; then
1188                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1189             fi
1190             ;;
1191         powerpc*)
1192             # Build only the drivers for cards that exist on PowerPC.
1193             if test "x$DRI_DIRS" = "xyes"; then
1194                 DRI_DIRS="r200 radeon swrast"
1195             fi
1196             ;;
1197         sparc*)
1198             # Build only the drivers for cards that exist on sparc
1199             if test "x$DRI_DIRS" = "xyes"; then
1200                 DRI_DIRS="r200 radeon swrast"
1201             fi
1202             ;;
1203         esac
1204         ;;
1205     freebsd* | dragonfly* | *netbsd*)
1206         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1207         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1208
1209         if test "x$DRI_DIRS" = "xyes"; then
1210             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1211         fi
1212         ;;
1213     gnu*)
1214         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1215         DEFINES="$DEFINES -DHAVE_ALIAS"
1216         ;;
1217     solaris*)
1218         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1219         ;;
1220     cygwin*)
1221         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1222         if test "x$DRI_DIRS" = "xyes"; then
1223             DRI_DIRS="swrast"
1224         fi
1225         ;;
1226     esac
1227
1228     # default drivers
1229     if test "x$DRI_DIRS" = "xyes"; then
1230         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1231     fi
1232
1233     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1234
1235     # Check for expat
1236     if test "x$enable_dri" = xyes; then
1237         EXPAT_INCLUDES=""
1238         EXPAT_LIB=-lexpat
1239         AC_ARG_WITH([expat],
1240             [AS_HELP_STRING([--with-expat=DIR],
1241                 [expat install directory])],[
1242             EXPAT_INCLUDES="-I$withval/include"
1243             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1244             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1245             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1246             ])
1247         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1248         save_LIBS="$LIBS"
1249         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1250             [AC_MSG_ERROR([Expat required for DRI.])])
1251         LIBS="$save_LIBS"
1252     fi
1253
1254     # if we are building any dri driver other than swrast ...
1255     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1256         # ... libdrm is required
1257         if test "x$have_libdrm" != xyes; then
1258             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1259         fi
1260         # ... and build dricommon
1261         HAVE_COMMON_DRI=yes
1262     fi
1263
1264     # put all the necessary libs together
1265     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1266 fi
1267 AC_SUBST([DRI_DIRS])
1268 AC_SUBST([EXPAT_INCLUDES])
1269 AC_SUBST([DRI_LIB_DEPS])
1270
1271 case $DRI_DIRS in
1272 *i915*|*i965*)
1273     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1274
1275     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1276         case $d in
1277         i915)
1278             HAVE_I915_DRI=yes;
1279             ;;
1280         i965)
1281             HAVE_I965_DRI=yes;
1282             ;;
1283         esac
1284     done
1285
1286     ;;
1287 esac
1288
1289 case $DRI_DIRS in
1290 *nouveau*)
1291     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1292     HAVE_NOUVEAU_DRI=yes;
1293     ;;
1294 esac
1295
1296 case $DRI_DIRS in
1297 *radeon*|*r200*)
1298     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1299
1300     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1301         case $d in
1302         radeon)
1303             HAVE_RADEON_DRI=yes;
1304             ;;
1305         r200)
1306             HAVE_R200_DRI=yes;
1307             ;;
1308         esac
1309     done
1310
1311     ;;
1312 esac
1313
1314 case $DRI_DIRS in
1315 *swrast*)
1316     HAVE_SWRAST_DRI=yes;
1317     ;;
1318 esac
1319
1320 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1321 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1322 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1323 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1324 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1325 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1326 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1327
1328 dnl
1329 dnl OSMesa configuration
1330 dnl
1331
1332 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1333 AC_ARG_WITH([osmesa-bits],
1334     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1335         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1336     [osmesa_bits="$withval"],
1337     [osmesa_bits=8])
1338 if test "x$osmesa_bits" != x8; then
1339     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1340         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1341         osmesa_bits=8
1342     fi
1343 fi
1344 case "x$osmesa_bits" in
1345 x8)
1346     OSMESA_LIB="${OSMESA_LIB}"
1347     ;;
1348 x16|x32)
1349     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1350     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1351     ;;
1352 *)
1353     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1354     ;;
1355 esac
1356
1357 if test "x$enable_osmesa" = xyes; then
1358     # only link libraries with osmesa if shared
1359     if test "$enable_static" = no; then
1360         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1361     else
1362         OSMESA_LIB_DEPS=""
1363     fi
1364     OSMESA_MESA_DEPS=""
1365     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1366 fi
1367 AC_SUBST([OSMESA_LIB_DEPS])
1368 AC_SUBST([OSMESA_MESA_DEPS])
1369 AC_SUBST([OSMESA_PC_REQ])
1370 AC_SUBST([OSMESA_PC_LIB_PRIV])
1371
1372 dnl
1373 dnl gbm configuration
1374 dnl
1375 if test "x$enable_gbm" = xauto; then
1376     case "$with_egl_platforms" in
1377         *drm*)
1378             enable_gbm=yes ;;
1379          *)
1380             enable_gbm=no ;;
1381     esac
1382 fi
1383 if test "x$enable_gbm" = xyes; then
1384     SRC_DIRS="$SRC_DIRS gbm"
1385
1386     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1387                       AC_MSG_ERROR([gbm needs udev]))
1388
1389     if test "x$enable_dri" = xyes; then
1390         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1391         if test "$SHARED_GLAPI" -eq 0; then
1392             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1393         fi
1394     fi
1395 fi
1396 GBM_PC_REQ_PRIV="libudev"
1397 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1398 AC_SUBST([GBM_PC_REQ_PRIV])
1399 AC_SUBST([GBM_PC_LIB_PRIV])
1400
1401 dnl
1402 dnl EGL configuration
1403 dnl
1404 EGL_CLIENT_APIS=""
1405
1406 if test "x$enable_egl" = xyes; then
1407     SRC_DIRS="$SRC_DIRS egl"
1408     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1409
1410     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1411
1412     if test "$enable_static" != yes; then
1413         # build egl_glx when libGL is built
1414         if test "x$enable_glx" = xyes; then
1415             HAVE_EGL_DRIVER_GLX=1
1416         fi
1417
1418         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1419                           [have_libudev=yes],[have_libudev=no])
1420         if test "$have_libudev" = yes; then
1421             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1422         fi
1423         if test "x$enable_dri" = xyes; then
1424             # build egl_dri2 when xcb-dri2 is available
1425             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1426                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1427             if test "$have_xcb_dri2" = yes; then
1428                 HAVE_EGL_DRIVER_DRI2=1
1429                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1430                 save_LIBS="$LIBS"
1431                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1432                           [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1433                 LIBS="$save_LIBS"
1434             fi
1435         fi
1436
1437     fi
1438 fi
1439 AC_SUBST([EGL_LIB_DEPS])
1440
1441 dnl
1442 dnl EGL Gallium configuration
1443 dnl
1444 if test "x$enable_gallium_egl" = xyes; then
1445     if test "x$with_gallium_drivers" = x; then
1446         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1447     fi
1448     if test "x$enable_egl" = xno; then
1449         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1450     fi
1451     if test "x$have_libdrm" != xyes; then
1452         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1453     fi
1454
1455     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1456     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1457     HAVE_ST_EGL="yes"
1458 fi
1459
1460 dnl
1461 dnl gbm Gallium configuration
1462 dnl
1463 if test "x$enable_gallium_gbm" = xauto; then
1464     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1465         yesyesyes*drm*)
1466             enable_gallium_gbm=yes ;;
1467          *)
1468             enable_gallium_gbm=no ;;
1469     esac
1470 fi
1471 if test "x$enable_gallium_gbm" = xyes; then
1472     if test "x$with_gallium_drivers" = x; then
1473         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1474     fi
1475     if test "x$enable_gbm" = xno; then
1476         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1477     fi
1478     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1479     if test "x$enable_dri" = xno; then
1480         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1481     fi
1482
1483     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1484     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1485     HAVE_ST_GBM="yes"
1486 fi
1487
1488 dnl
1489 dnl X.Org DDX configuration
1490 dnl
1491 if test "x$enable_xorg" = xyes; then
1492     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1493     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1494     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1495     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1496         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1497         HAVE_XEXTPROTO_71="no")
1498     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1499     HAVE_ST_XORG=yes
1500 fi
1501
1502 dnl
1503 dnl XA configuration
1504 dnl
1505 if test "x$enable_xa" = xyes; then
1506 AC_PROG_AWK
1507 AC_PROG_GREP
1508 AC_CHECK_PROG(NM, nm, "nm")
1509 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1510 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1511 enable_xa=no
1512 fi
1513 fi
1514 if test "x$enable_xa" = xyes; then
1515     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1516     HAVE_ST_XA=yes
1517     AC_SUBST(AWK)
1518     AC_SUBST(GREP)
1519     AC_SUBST(NM)
1520 fi
1521
1522 dnl
1523 dnl OpenVG configuration
1524 dnl
1525 VG_LIB_DEPS=""
1526
1527 if test "x$enable_openvg" = xyes; then
1528     if test "x$enable_egl" = xno; then
1529         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1530     fi
1531     if test "x$with_gallium_drivers" = x; then
1532         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1533     fi
1534     if test "x$enable_gallium_egl" = xno; then
1535         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1536     fi
1537
1538     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1539     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1540     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1541     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1542     HAVE_ST_VEGA=yes
1543 fi
1544
1545 dnl
1546 dnl D3D1X configuration
1547 dnl
1548
1549 if test "x$enable_d3d1x" = xyes; then
1550     if test "x$with_gallium_drivers" = x; then
1551         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1552     fi
1553
1554     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1555     HAVE_ST_D3D1X=yes
1556 fi
1557
1558 dnl
1559 dnl Gallium G3DVL configuration
1560 dnl
1561 AC_ARG_ENABLE([gallium-g3dvl],
1562     [AS_HELP_STRING([--enable-gallium-g3dvl],
1563         [build gallium g3dvl @<:@default=disabled@:>@])],
1564     [enable_gallium_g3dvl="$enableval"],
1565     [enable_gallium_g3dvl=no])
1566 if test "x$enable_gallium_g3dvl" = xyes; then
1567     if test "x$with_gallium_drivers" = x; then
1568         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1569     fi
1570
1571     if test "x$enable_xvmc" = xauto; then
1572         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1573     fi
1574
1575     if test "x$enable_vdpau" = xauto; then
1576         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1577     fi
1578
1579     if test "x$enable_va" = xauto; then
1580         #don't enable vaapi state tracker even if package exists
1581         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1582         enable_va=no
1583     fi
1584 fi
1585
1586 if test "x$enable_xvmc" = xyes; then
1587     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1588     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1589     HAVE_ST_XVMC="yes"
1590 fi
1591
1592 if test "x$enable_vdpau" = xyes; then
1593     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1594     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1595     HAVE_ST_VDPAU="yes"
1596 fi
1597
1598 if test "x$enable_va" = xyes; then
1599     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1600     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1601     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1602     HAVE_ST_VA="yes"
1603 fi
1604
1605 dnl
1606 dnl GLU configuration
1607 dnl
1608 AC_ARG_ENABLE([glu],
1609     [AS_HELP_STRING([--disable-glu],
1610         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1611     [enable_glu="$enableval"],
1612     [enable_glu=yes])
1613
1614 if test "x$enable_glu" = xyes; then
1615     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1616         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1617         enable_glu=no
1618     fi
1619 fi
1620
1621 if test "x$enable_glu" = xyes; then
1622     SRC_DIRS="$SRC_DIRS glu"
1623
1624     if test "x$enable_glx" = xno; then
1625         # Link libGLU to libOSMesa instead of libGL
1626         GLU_LIB_DEPS=""
1627         GLU_PC_REQ="osmesa"
1628         if test "$enable_static" = no; then
1629             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1630         else
1631             GLU_MESA_DEPS=""
1632         fi
1633     else
1634         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1635         GLU_PC_REQ="gl"
1636         GLU_PC_LIB_PRIV="-lm"
1637         if test "$enable_static" = no; then
1638             GLU_LIB_DEPS="-lm"
1639             GLU_MESA_DEPS='-l$(GL_LIB)'
1640         else
1641             GLU_LIB_DEPS=""
1642             GLU_MESA_DEPS=""
1643         fi
1644     fi
1645 fi
1646 if test "$enable_static" = no; then
1647     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1648 fi
1649 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1650 AC_SUBST([GLU_LIB_DEPS])
1651 AC_SUBST([GLU_MESA_DEPS])
1652 AC_SUBST([GLU_PC_REQ])
1653 AC_SUBST([GLU_PC_REQ_PRIV])
1654 AC_SUBST([GLU_PC_LIB_PRIV])
1655 AC_SUBST([GLU_PC_CFLAGS])
1656
1657 AC_SUBST([PROGRAM_DIRS])
1658
1659 dnl
1660 dnl Gallium configuration
1661 dnl
1662 if test "x$with_gallium_drivers" != x; then
1663     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1664 fi
1665
1666 AC_SUBST([LLVM_BINDIR])
1667 AC_SUBST([LLVM_CFLAGS])
1668 AC_SUBST([LLVM_CXXFLAGS])
1669 AC_SUBST([LLVM_LIBS])
1670 AC_SUBST([LLVM_LDFLAGS])
1671 AC_SUBST([LLVM_INCLUDEDIR])
1672 AC_SUBST([LLVM_VERSION])
1673
1674 case "x$enable_opengl$enable_gles1$enable_gles2" in
1675 x*yes*)
1676     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1677     ;;
1678 esac
1679
1680 AC_SUBST([VG_LIB_DEPS])
1681 AC_SUBST([EGL_CLIENT_APIS])
1682
1683 AC_ARG_WITH([egl-platforms],
1684     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1685         [comma delimited native platforms libEGL supports, e.g.
1686         "x11,drm" @<:@default=auto@:>@])],
1687     [with_egl_platforms="$withval"],
1688     [if test "x$enable_egl" = xyes; then
1689         with_egl_platforms="x11"
1690     else
1691         with_egl_platforms=""
1692     fi])
1693
1694 EGL_PLATFORMS=""
1695
1696 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1697     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1698 fi
1699
1700 # verify the requested driver directories exist
1701 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1702 for plat in $egl_platforms; do
1703         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1704             AC_MSG_ERROR([EGL platform '$plat' does not exist])
1705         if test "$plat" = "fbdev"; then
1706                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1707         fi
1708         if test "$plat" = "null"; then
1709                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1710         fi
1711         if test "$plat" = "wayland"; then
1712                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1713                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1714                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1715
1716                 m4_ifdef([WAYLAND_SCANNER_RULES],
1717                          [WAYLAND_SCANNER_RULES(['$(top_srcdir)/src/egl/wayland/wayland-drm/protocol'])])
1718         fi
1719         if test "$plat" = "drm" && test "x$enable_gbm" = "xno"; then
1720                 AC_MSG_ERROR([EGL platform drm needs gbm])
1721         fi
1722         case "$plat$have_libudev" in
1723                 waylandno|drmno)
1724                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1725         esac
1726 done
1727
1728 # libEGL wants to default to the first platform specified in
1729 # ./configure.  parse that here.
1730 if test "x$egl_platforms" != "x"; then
1731     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1732     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1733 else
1734     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1735 fi
1736
1737 EGL_PLATFORMS="$egl_platforms"
1738
1739 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1740 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1741 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1742 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1743 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1744
1745 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1746 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1747
1748 AC_SUBST([EGL_NATIVE_PLATFORM])
1749 AC_SUBST([EGL_PLATFORMS])
1750 AC_SUBST([EGL_CFLAGS])
1751
1752 AC_ARG_WITH([egl-driver-dir],
1753     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1754                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1755     [EGL_DRIVER_INSTALL_DIR="$withval"],
1756     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1757 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1758
1759 AC_ARG_WITH([xorg-driver-dir],
1760     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1761                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1762     [XORG_DRIVER_INSTALL_DIR="$withval"],
1763     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1764 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1765
1766 AC_ARG_WITH([max-width],
1767     [AS_HELP_STRING([--with-max-width=N],
1768                     [Maximum framebuffer width (4096)])],
1769     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1770      AS_IF([test "${withval}" -gt "4096"],
1771            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1772 )
1773 AC_ARG_WITH([max-height],
1774     [AS_HELP_STRING([--with-max-height=N],
1775                     [Maximum framebuffer height (4096)])],
1776     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1777      AS_IF([test "${withval}" -gt "4096"],
1778            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1779 )
1780
1781 dnl
1782 dnl Gallium LLVM
1783 dnl
1784 AC_ARG_ENABLE([gallium-llvm],
1785     [AS_HELP_STRING([--enable-gallium-llvm],
1786         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1787     [enable_gallium_llvm="$enableval"],
1788     [enable_gallium_llvm=auto])
1789
1790 AC_ARG_WITH([llvm-shared-libs],
1791     [AS_HELP_STRING([--with-llvm-shared-libs],
1792         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1793     [with_llvm_shared_libs=yes],
1794     [with_llvm_shared_libs=no])
1795
1796 if test "x$with_gallium_drivers" = x; then
1797     enable_gallium_llvm=no
1798 fi
1799 if test "x$enable_gallium_llvm" = xauto; then
1800     case "$host_cpu" in
1801     i*86|x86_64) enable_gallium_llvm=yes;;
1802     esac
1803 fi
1804 if test "x$enable_gallium_llvm" = xyes; then
1805     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1806
1807     if test "x$LLVM_CONFIG" != xno; then
1808         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1809         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g'`
1810         if test "x$with_llvm_shared_libs" = xyes; then
1811             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1812             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1813         else
1814             LLVM_LIBS="`$LLVM_CONFIG --libs engine bitwriter`"
1815         fi
1816         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1817         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1818         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1819         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1820         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1821         MESA_LLVM=1
1822     else
1823         MESA_LLVM=0
1824     fi
1825 else
1826     MESA_LLVM=0
1827 fi
1828
1829 dnl Directory for XVMC libs
1830 AC_ARG_WITH([xvmc-libdir],
1831     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1832         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1833     [XVMC_LIB_INSTALL_DIR="$withval"],
1834     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1835 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1836
1837 dnl Directory for VDPAU libs
1838 AC_ARG_WITH([vdpau-libdir],
1839     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1840         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1841     [VDPAU_LIB_INSTALL_DIR="$withval"],
1842     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1843 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1844
1845 dnl Directory for VA libs
1846 AC_ARG_WITH([va-libdir],
1847     [AS_HELP_STRING([--with-va-libdir=DIR],
1848         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1849     [VA_LIB_INSTALL_DIR="$withval"],
1850     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1851 AC_SUBST([VA_LIB_INSTALL_DIR])
1852
1853 dnl
1854 dnl Gallium helper functions
1855 dnl
1856 gallium_check_st() {
1857     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1858          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1859          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1860          if test "x$have_libdrm" != xyes; then
1861             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1862          fi
1863          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1864     fi
1865     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1866          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1867     fi
1868     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1869          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1870     fi
1871     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1872          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1873     fi
1874     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1875          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1876     fi
1877     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1878          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1879     fi
1880     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1881          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1882     fi
1883 }
1884
1885 gallium_require_llvm() {
1886     if test "x$MESA_LLVM" = x0; then
1887         case "$host_cpu" in
1888         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1889         esac
1890     fi
1891 }
1892
1893 dnl Gallium drivers
1894 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1895 if test "x$with_gallium_drivers" != x; then
1896     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1897     for driver in $gallium_drivers; do
1898         case "x$driver" in
1899         xsvga)
1900             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1901             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1902             ;;
1903         xi915)
1904             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1905             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1906             if test "x$MESA_LLVM" = x1; then
1907                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1908             fi
1909             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1910             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1911             ;;
1912         xr300)
1913             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1914             gallium_require_llvm "Gallium R300"
1915             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1916             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1917             ;;
1918         xr600)
1919             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1920             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1921             if test "x$enable_r600_llvm" = xyes; then
1922                 if test "x$LLVM_VERSION" != "x3.1"; then
1923                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1924                 fi
1925                 NEED_RADEON_GALLIUM=yes;
1926                 USE_R600_LLVM_COMPILER=yes;
1927             fi
1928             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1929             ;;
1930         xradeonsi)
1931             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1932             if test "x$LLVM_VERSION" != "x3.1"; then
1933                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1934             fi
1935             NEED_RADEON_GALLIUM=yes;
1936             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi"
1937             ;;
1938         xnouveau)
1939             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1940             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1941             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1942             ;;
1943         xswrast)
1944             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1945             if test "x$MESA_LLVM" = x1; then
1946                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1947             fi
1948
1949             if test "x$HAVE_ST_DRI" = xyes; then
1950                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1951             fi
1952             if test "x$HAVE_ST_VDPAU" = xyes; then
1953                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1954             fi
1955             if test "x$HAVE_ST_XVMC" = xyes; then
1956                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1957             fi
1958             if test "x$HAVE_ST_VA" = xyes; then
1959                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1960             fi
1961             if test "x$HAVE_ST_VDPAU" = xyes ||
1962                test "x$HAVE_ST_XVMC" = xyes ||
1963                test "x$HAVE_ST_VA" = xyes; then
1964                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1965                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1966                fi
1967             fi
1968             ;;
1969         *)
1970             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1971             ;;
1972         esac
1973     done
1974 fi
1975
1976 if test "x$enable_gallium_tests" = xyes; then
1977     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1978     enable_gallium_loader=yes
1979 fi
1980
1981 if test "x$enable_gallium_loader" = xyes; then
1982     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1983     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1984     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1985     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1986
1987     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1988         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1989         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1990     fi
1991
1992     if test "x$enable_gallium_drm_loader" = xyes; then
1993         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1994     fi
1995
1996     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1997     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1998 fi
1999
2000 dnl Tell Automake which drivers to build
2001 for driver in $GALLIUM_DRIVERS_DIRS; do
2002     case "x$driver" in
2003         xgalahad)
2004             HAVE_GALAHAD_GALLIUM=yes;
2005             ;;
2006         xidentity)
2007             HAVE_IDENTITY_GALLIUM=yes;
2008             ;;
2009         xnoop)
2010             HAVE_NOOP_GALLIUM=yes;
2011             ;;
2012         *)
2013             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
2014             ;;
2015     esac
2016 done
2017
2018 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2019 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2020 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2021 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2022 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2023 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2024 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2025 AC_SUBST([GALLIUM_MAKE_DIRS])
2026
2027 dnl prepend CORE_DIRS to SRC_DIRS
2028 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2029
2030 dnl Restore LDFLAGS and CPPFLAGS
2031 LDFLAGS="$_SAVE_LDFLAGS"
2032 CPPFLAGS="$_SAVE_CPPFLAGS"
2033
2034 dnl Add user CFLAGS and CXXFLAGS
2035 CFLAGS="$CFLAGS $USER_CFLAGS"
2036 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2037
2038 dnl Substitute the config
2039 AC_CONFIG_FILES([configs/autoconf
2040                 src/gallium/auxiliary/pipe-loader/Makefile
2041                 src/gallium/drivers/Makefile
2042                 src/gallium/drivers/r300/Makefile
2043                 src/gallium/drivers/r600/Makefile
2044                 src/gbm/Makefile
2045                 src/gbm/main/gbm.pc
2046                 src/egl/drivers/Makefile
2047                 src/egl/drivers/dri2/Makefile
2048                 src/egl/drivers/glx/Makefile
2049                 src/egl/main/Makefile
2050                 src/egl/main/egl.pc
2051                 src/egl/wayland/Makefile
2052                 src/egl/wayland/wayland-egl/Makefile
2053                 src/egl/wayland/wayland-egl/wayland-egl.pc
2054                 src/egl/wayland/wayland-drm/Makefile
2055                 src/glsl/tests/Makefile
2056                 src/glx/Makefile
2057                 src/mapi/shared-glapi/Makefile
2058                 src/gtest/Makefile
2059                 src/mesa/drivers/dri/dri.pc
2060                 src/mesa/drivers/dri/Makefile
2061                 src/mesa/drivers/dri/common/Makefile
2062                 src/mesa/drivers/dri/i915/Makefile
2063                 src/mesa/drivers/dri/i965/Makefile
2064                 src/mesa/drivers/dri/nouveau/Makefile
2065                 src/mesa/drivers/dri/r200/Makefile
2066                 src/mesa/drivers/dri/radeon/Makefile
2067                 src/mesa/drivers/dri/swrast/Makefile
2068                 tests/Makefile
2069                 tests/glx/Makefile])
2070
2071 dnl Replace the configs/current symlink
2072 AC_CONFIG_COMMANDS([configs],[
2073 if test -f configs/current || test -L configs/current; then
2074     rm -f configs/current
2075 fi
2076 ln -s autoconf configs/current
2077 ])
2078
2079 dnl Sort the dirs alphabetically
2080 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2081 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2082 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2083 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2084 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2085
2086 AC_OUTPUT
2087
2088 dnl
2089 dnl Output some configuration info for the user
2090 dnl
2091 echo ""
2092 echo "        prefix:          $prefix"
2093 echo "        exec_prefix:     $exec_prefix"
2094 echo "        libdir:          $libdir"
2095 echo "        includedir:      $includedir"
2096
2097 dnl API info
2098 echo ""
2099 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2100 echo "        OpenVG:          $enable_openvg"
2101
2102 dnl Driver info
2103 echo ""
2104 if test "x$enable_osmesa" != xno; then
2105         echo "        OSMesa:          lib$OSMESA_LIB"
2106 else
2107         echo "        OSMesa:          no"
2108 fi
2109
2110 if test "x$enable_dri" != xno; then
2111         # cleanup the drivers var
2112         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2113         if test "x$DRI_DIRS" = x; then
2114             echo "        DRI drivers:     no"
2115         else
2116             echo "        DRI drivers:     $dri_dirs"
2117         fi
2118         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2119 fi
2120
2121 case "x$enable_glx$enable_xlib_glx" in
2122 xyesyes)
2123     echo "        GLX:             Xlib-based"
2124     ;;
2125 xyesno)
2126     echo "        GLX:             DRI-based"
2127     ;;
2128 *)
2129     echo "        GLX:             $enable_glx"
2130     ;;
2131 esac
2132
2133 echo ""
2134 echo "        GLU:             $enable_glu"
2135
2136 dnl EGL
2137 echo ""
2138 echo "        EGL:             $enable_egl"
2139 if test "$enable_egl" = yes; then
2140     echo "        EGL platforms:   $EGL_PLATFORMS"
2141
2142     egl_drivers=""
2143     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2144         egl_drivers="$egl_drivers builtin:egl_glx"
2145     fi
2146     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2147         egl_drivers="$egl_drivers builtin:egl_dri2"
2148     fi
2149
2150     if test "x$HAVE_ST_EGL" = xyes; then
2151         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2152         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2153     else
2154         echo "        EGL drivers:    $egl_drivers"
2155     fi
2156 fi
2157
2158 echo ""
2159 if test "x$MESA_LLVM" = x1; then
2160     echo "        llvm:            yes"
2161     echo "        llvm-config:     $LLVM_CONFIG"
2162     echo "        llvm-version:    $LLVM_VERSION"
2163 else
2164     echo "        llvm:            no"
2165 fi
2166
2167 echo ""
2168 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2169     echo "        Gallium:         yes"
2170     echo "        Gallium dirs:    $GALLIUM_DIRS"
2171     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2172     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2173     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2174     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2175 else
2176     echo "        Gallium:         no"
2177 fi
2178
2179
2180 dnl Libraries
2181 echo ""
2182 echo "        Shared libs:     $enable_shared"
2183 echo "        Static libs:     $enable_static"
2184
2185 dnl Compiler options
2186 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2187 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2188     $SED 's/^ *//;s/  */ /;s/ *$//'`
2189 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2190     $SED 's/^ *//;s/  */ /;s/ *$//'`
2191 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2192 echo ""
2193 echo "        CFLAGS:          $cflags"
2194 echo "        CXXFLAGS:        $cxxflags"
2195 echo "        Macros:          $defines"
2196 echo ""
2197 echo "        PYTHON2:         $PYTHON2"
2198
2199 echo ""
2200 echo "        Run '${MAKE-make}' to build Mesa"
2201 echo ""