configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ(2.60)
  22 AC_INIT([libdrm], 2.4.21, [dri-devel@lists.sourceforge.net], libdrm)
  23 AC_USE_SYSTEM_EXTENSIONS
  24 AC_CONFIG_SRCDIR([Makefile.am])
  25 AM_INIT_AUTOMAKE([dist-bzip2])
  26
  27 AM_CONFIG_HEADER([config.h])
  28
  29 AC_DISABLE_STATIC
  30 AC_PROG_LIBTOOL
  31 AC_PROG_CC
  32
  33 AC_HEADER_STDC
  34 AC_SYS_LARGEFILE
  35 AC_FUNC_ALLOCA
  36
  37 # Enable quiet compiles on automake 1.11.
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39
  40 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  41 AC_SUBST(PTHREADSTUBS_CFLAGS)
  42 AC_SUBST(PTHREADSTUBS_LIBS)
  43
  44 pkgconfigdir=${libdir}/pkgconfig
  45 AC_SUBST(pkgconfigdir)
  46 AC_ARG_ENABLE(udev,     AS_HELP_STRING([--enable-udev],
  47                                 [Enable support for using udev instead of mknod (default: disabled)]),
  48                                 [UDEV=$enableval], [UDEV=no])
  49
  50 AC_ARG_ENABLE(libkms,
  51               AS_HELP_STRING([--disable-libkms],
  52               [Disable KMS mm abstraction library (default: auto)]),
  53               [LIBKMS=$enableval], [LIBKMS=auto])
  54
  55 AC_ARG_ENABLE(intel,
  56               AS_HELP_STRING([--disable-intel],
  57               [Enable support for intel's KMS API (default: auto)]),
  58               [INTEL=$enableval], [INTEL=auto])
  59
  60 AC_ARG_ENABLE(radeon,
  61               AS_HELP_STRING([--disable-radeon],
  62               [Enable support for radeon's KMS API (default: auto)]),
  63               [RADEON=$enableval], [RADEON=auto])
  64
  65 AC_ARG_ENABLE(vmwgfx-experimental-api,
  66               AS_HELP_STRING([--enable-vmwgfx-experimental-api],
  67               [Install vmwgfx's experimental kernel API header (default: disabled)]),
  68               [VMWGFX=$enableval], [VMWGFX=no])
  69
  70 AC_ARG_ENABLE(nouveau-experimental-api,
  71               AS_HELP_STRING([--enable-nouveau-experimental-api],
  72               [Enable support for nouveau's experimental API (default: disabled)]),
  73               [NOUVEAU=$enableval], [NOUVEAU=no])
  74
  75
  76 dnl ===========================================================================
  77 dnl check compiler flags
  78 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
  79   AC_MSG_CHECKING([whether $CC supports $1])
  80
  81   libdrm_save_CFLAGS="$CFLAGS"
  82   CFLAGS="$CFLAGS $1"
  83
  84   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
  85   CFLAGS="$libdrm_save_CFLAGS"
  86
  87   if test "x$libdrm_cc_flag" = "xyes"; then
  88     ifelse([$2], , :, [$2])
  89   else
  90     ifelse([$3], , :, [$3])
  91   fi
  92   AC_MSG_RESULT([$libdrm_cc_flag])
  93 ])
  94
  95 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
  96
  97 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
  98                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
  99                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 100 AC_SUBST([CLOCK_LIB])
 101
 102 dnl Use lots of warning flags with with gcc and compatible compilers
 103
 104 dnl Note: if you change the following variable, the cache is automatically
 105 dnl skipped and all flags rechecked.  So there's no need to do anything
 106 dnl else.  If for any reason you need to force a recheck, just change
 107 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 108
 109 MAYBE_WARN="-Wall -Wextra \
 110 -Wsign-compare -Werror-implicit-function-declaration \
 111 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 112 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 113 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 114 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
 115 -Wdeclaration-after-statement -Wold-style-definition \
 116 -Wno-missing-field-initializers -Wno-unused-parameter \
 117 -Wno-attributes -Wno-long-long -Winline"
 118
 119 # invalidate cached value if MAYBE_WARN has changed
 120 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 121         unset libdrm_cv_warn_cflags
 122 fi
 123 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 124         echo
 125         WARN_CFLAGS=""
 126
 127         # Some warning options are not supported by all versions of
 128         # gcc, so test all desired options against the current
 129         # compiler.
 130         #
 131         # Note that there are some order dependencies
 132         # here. Specifically, an option that disables a warning will
 133         # have no net effect if a later option then enables that
 134         # warnings, (perhaps implicitly). So we put some grouped
 135         # options (-Wall and -Wextra) up front and the -Wno options
 136         # last.
 137
 138         for W in $MAYBE_WARN; do
 139                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 140         done
 141
 142         libdrm_cv_warn_cflags=$WARN_CFLAGS
 143         libdrm_cv_warn_maybe=$MAYBE_WARN
 144
 145         AC_MSG_CHECKING([which warning flags were supported])])
 146 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 147
 148 if test "x$UDEV" = xyes; then
 149         AC_DEFINE(UDEV, 1, [Have UDEV support])
 150 fi
 151
 152 AC_CANONICAL_HOST
 153 if test "x$LIBKMS" = xauto ; then
 154         case $host_os in
 155                 linux*)         LIBKMS="yes" ;;
 156                 *)              LIBKMS="no" ;;
 157         esac
 158 fi
 159
 160 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 161
 162 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 163 if test "x$VMWGFX" = xyes; then
 164         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 165 fi
 166
 167 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 168 if test "x$NOUVEAU" = xyes; then
 169         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 170 fi
 171
 172 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 173 if test "x$HAVE_CAIRO" = xyes; then
 174         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
 175 fi
 176 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
 177
 178 # For enumerating devices in test case
 179 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 180 if test "x$HAVE_LIBUDEV" = xyes; then
 181         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 182 fi
 183 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 184
 185 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno"; then
 186     # Check for atomic intrinsics
 187     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
 188     [
 189             drm_cv_atomic_primitives="none"
 190
 191             AC_TRY_LINK([
 192     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 193     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 194     ], [],
 195               drm_cv_atomic_primitives="Intel"
 196               )
 197
 198             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 199                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 200             fi
 201
 202             # atomic functions defined in <atomic.h> & libc on Solaris
 203             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 204                     AC_CHECK_FUNC([atomic_cas_uint],
 205                                   drm_cv_atomic_primitives="Solaris")
 206             fi
 207
 208     ])
 209     if test "x$drm_cv_atomic_primitives" = xIntel; then
 210             AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 211                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
 212     fi
 213     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 214             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 215     fi
 216
 217     if test "x$drm_cv_atomic_primitives" = "xnone"; then
 218            if test "x$INTEL" != "xauto"; then
 219                    if test "x$INTEL" != "xno"; then
 220                         AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
 221                    fi
 222            else
 223                    AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 224                    INTEL=no
 225            fi
 226            if test "x$RADEON" != "xauto"; then
 227                    if test "x$RADEON" != "xno"; then
 228                         AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
 229                    fi
 230            else
 231                    AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 232                    RADEON=no
 233            fi
 234
 235     else
 236            if test "x$INTEL" != "xno"; then
 237                    INTEL=yes
 238            fi
 239            if test "x$RADEON" != "xno"; then
 240                    RADEON=yes
 241            fi
 242     fi
 243 fi
 244
 245 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
 246 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" != "xno"])
 247
 248 AC_ARG_WITH([kernel-source],
 249             [AS_HELP_STRING([--with-kernel-source],
 250               [specify path to linux kernel source])],
 251             [kernel_source="$with_kernel_source"])
 252 AC_SUBST(kernel_source)
 253
 254 AC_SUBST(WARN_CFLAGS)
 255 AC_OUTPUT([
 256         Makefile
 257         libkms/Makefile
 258         libkms/libkms.pc
 259         intel/Makefile
 260         intel/libdrm_intel.pc
 261         radeon/Makefile
 262         radeon/libdrm_radeon.pc
 263         nouveau/Makefile
 264         nouveau/libdrm_nouveau.pc
 265         tests/Makefile
 266         tests/modeprint/Makefile
 267         tests/modetest/Makefile
 268         tests/kmstest/Makefile
 269         tests/vbltest/Makefile
 270         include/Makefile
 271         include/drm/Makefile
 272         libdrm.pc])
 273
 274 echo ""
 275 echo "$PACKAGE_STRING will be compiled with:"
 276 echo ""
 277 echo "  libkms         $LIBKMS"
 278 echo "  Intel API      $INTEL"
 279 echo "  vmwgfx API     $VMWGFX"
 280 echo "  Radeon API     $RADEON"
 281 echo "  Nouveau API    $NOUVEAU"
 282 echo ""