configure.ac

   1 AC_PREREQ([2.64])
   2
   3 m4_define([libinput_major_version], [0])
   4 m4_define([libinput_minor_version], [2])
   5 m4_define([libinput_micro_version], [0])
   6 m4_define([libinput_version],
   7           [libinput_major_version.libinput_minor_version.libinput_micro_version])
   8
   9 AC_INIT([libinput],
  10         [libinput_version],
  11         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=libinput&version=libinput_version],
  12         [libinput],
  13         [http://www.freedesktop.org/wiki/Software/libinput/])
  14
  15 AC_SUBST([LIBINPUT_VERSION_MAJOR], [libinput_major_version])
  16 AC_SUBST([LIBINPUT_VERSION_MINOR], [libinput_minor_version])
  17 AC_SUBST([LIBINPUT_VERSION_MICRO], [libinput_micro_version])
  18 AC_SUBST([LIBINPUT_VERSION], [libinput_version])
  19
  20 AC_CONFIG_HEADERS([config.h])
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz])
  24
  25 # Before making a release, the LIBINPUT_LT_VERSION string should be
  26 # modified.
  27 # The string is of the form C:R:A.
  28 # - If interfaces have been changed or added, but binary compatibility has
  29 #   been preserved, change to C+1:0:A+1
  30 # - If binary compatibility has been broken (eg removed or changed interfaces)
  31 #   change to C+1:0:0
  32 # - If the interface is the same as the previous version, change to C:R+1:A
  33 LIBINPUT_LT_VERSION=1:0:1
  34 AC_SUBST(LIBINPUT_LT_VERSION)
  35
  36 AM_SILENT_RULES([yes])
  37
  38 # Check for programs
  39 AC_PROG_CC_C99
  40 AC_PROG_CXX # Only used by build C++ test
  41
  42 # Initialize libtool
  43 LT_PREREQ([2.2])
  44 LT_INIT
  45
  46 AC_CHECK_DECL(EPOLL_CLOEXEC, [],
  47               [AC_MSG_ERROR("EPOLL_CLOEXEC is needed to compile libinput")],
  48               [[#include <sys/epoll.h>]])
  49 AC_CHECK_DECL(TFD_CLOEXEC,[],
  50               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile libinput")],
  51               [[#include <sys/timerfd.h>]])
  52 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
  53               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile libinput")],
  54               [[#include <time.h>]])
  55
  56 PKG_PROG_PKG_CONFIG()
  57 PKG_CHECK_MODULES(MTDEV, [mtdev >= 1.1.0])
  58 PKG_CHECK_MODULES(LIBUDEV, [libudev])
  59 PKG_CHECK_MODULES(LIBEVDEV, [libevdev >= 0.4])
  60
  61 if test "x$GCC" = "xyes"; then
  62         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter -g -Wstrict-prototypes -Wmissing-prototypes -fvisibility=hidden"
  63 fi
  64 AC_SUBST(GCC_CFLAGS)
  65
  66 AC_PATH_PROG(DOXYGEN, [doxygen])
  67 if test "x$DOXYGEN" = "x"; then
  68         AC_MSG_WARN([doxygen not found - required for documentation])
  69         have_doxygen="no"
  70 else
  71         have_doxygen="yes"
  72 fi
  73 AM_CONDITIONAL([HAVE_DOXYGEN], [test "x$have_doxygen" = "xyes"])
  74
  75 AC_ARG_ENABLE(tests,
  76               AS_HELP_STRING([--enable-tests], [Build the tests (default=auto)]),
  77               [build_tests="$enableval"],
  78               [build_tests="auto"])
  79
  80 PKG_CHECK_MODULES(CHECK, [check >= 0.9.9], [HAVE_CHECK="yes"], [HAVE_CHECK="no"])
  81
  82 if test "x$build_tests" = "xauto"; then
  83         build_tests="$HAVE_CHECK"
  84 fi
  85 if test "x$build_tests" = "xyes"; then
  86         if test "x$HAVE_CHECK" = "xno"; then
  87                 AC_MSG_ERROR([Cannot build tests, check is missing])
  88         fi
  89
  90         AC_PATH_PROG(VALGRIND, [valgrind])
  91 fi
  92
  93 AM_CONDITIONAL(HAVE_VALGRIND, [test "x$VALGRIND" != "x"])
  94 AM_CONDITIONAL(BUILD_TESTS, [test "x$build_tests" = "xyes"])
  95
  96 AC_CONFIG_FILES([Makefile
  97                  doc/Makefile
  98                  doc/libinput.doxygen
  99                  src/Makefile
 100                  src/libinput.pc
 101                  src/libinput-version.h
 102                  test/Makefile
 103                  tools/Makefile])
 104 AC_OUTPUT